SUBROUTINE lpm_extend_tail_array( number_of_new_tails )

!------------------------------------------------------------------------------!
! Current revisions:
! ------------------
! 
!
! Former revisions:
! -----------------
! $Id: lpm_extend_tail_array.f90 850 2012-03-15 12:09:25Z letzel $
!
! 849 2012-03-15 10:35:09Z raasch
! initial revision (former part of advec_particles)
!
!
! Description:
! ------------
! Allocates more memory for the particle tail array.
!------------------------------------------------------------------------------!

    USE particle_attributes

    IMPLICIT NONE

    INTEGER ::  new_maximum_number, number_of_new_tails

    LOGICAL, DIMENSION(maximum_number_of_tails) ::  tmp_tail_mask

    REAL, DIMENSION(maximum_number_of_tailpoints,5,maximum_number_of_tails) :: &
                                                    tmp_tail


    new_maximum_number = maximum_number_of_tails + &
                         MAX( 5*number_of_new_tails, number_of_initial_tails )

    IF ( write_particle_statistics )  THEN
       CALL check_open( 80 )
       WRITE ( 80, '(''*** Request: '', I5, '' new_maximum_number(tails)'')' ) &
                            new_maximum_number
       CALL close_file( 80 )
    ENDIF
    WRITE (9,*) '*** Request: ',new_maximum_number,' new_maximum_number(tails)'

    tmp_tail(:,:,1:number_of_tails)  = &
                                particle_tail_coordinates(:,:,1:number_of_tails)
    tmp_tail_mask(1:number_of_tails) = tail_mask(1:number_of_tails)

    DEALLOCATE( new_tail_id, particle_tail_coordinates, tail_mask )
    ALLOCATE( new_tail_id(new_maximum_number),                          &
              particle_tail_coordinates(maximum_number_of_tailpoints,5, &
              new_maximum_number),                                      &
              tail_mask(new_maximum_number) )

    maximum_number_of_tails = new_maximum_number

    particle_tail_coordinates = 0.0
    particle_tail_coordinates(:,:,1:number_of_tails) = &
                                                 tmp_tail(:,:,1:number_of_tails)
    tail_mask(1:number_of_tails) = tmp_tail_mask(1:number_of_tails)
    tail_mask(number_of_tails+1:maximum_number_of_tails) = .TRUE.


 END SUBROUTINE lpm_extend_tail_array