source: palm/trunk/SOURCE/lpm_collision_kernels.f90 @ 1077

Last change on this file since 1077 was 1072, checked in by franke, 11 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 36.1 KB
Line 
1 MODULE lpm_collision_kernels_mod
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: lpm_collision_kernels.f90 1072 2012-11-29 17:04:39Z hoffmann $
27!
28! 1071 2012-11-29 16:54:55Z franke
29! Bugfix: collision efficiencies for Hall kernel should not be < 1.0E-20
30!
31! 1036 2012-10-22 13:43:42Z raasch
32! code put under GPL (PALM 3.9)
33!
34! 1007 2012-09-19 14:30:36Z franke
35! converted all units to SI units and replaced some parameters by corresponding
36! PALM parameters
37! Bugfix: factor in calculation of enhancement factor for collision efficencies
38! changed from 10. to 1.0
39!
40! 849 2012-03-15 10:35:09Z raasch
41! routine collision_efficiency_rogers added (moved from former advec_particles
42! to here)
43!
44! 835 2012-02-22 11:21:19Z raasch $
45! Bugfix: array diss can be used only in case of Wang kernel
46!
47! 828 2012-02-21 12:00:36Z raasch
48! code has been completely reformatted, routine colker renamed
49! recalculate_kernel,
50! routine init_kernels added, radius is now communicated to the collision
51! routines by array radclass
52!
53! Bugfix: transformation factor for dissipation changed from 1E5 to 1E4
54!
55! 825 2012-02-19 03:03:44Z raasch
56! routine renamed from wang_kernel to lpm_collision_kernels,
57! turbulence_effects on collision replaced by wang_kernel
58!
59! 799 2011-12-21 17:48:03Z franke
60! speed optimizations and formatting
61! Bugfix: iq=1 is not allowed (routine effic)
62! Bugfix: replaced stop by ec=0.0 in case of very small ec (routine effic)
63!
64! 790 2011-11-29 03:11:20Z raasch
65! initial revision
66!
67! Description:
68! ------------
69! This module calculates collision efficiencies either due to pure gravitational
70! effects (Hall kernel, see Hall, 1980: J. Atmos. Sci., 2486-2507) or
71! including the effects of (SGS) turbulence (Wang kernel, see Wang and
72! Grabowski, 2009: Atmos. Sci. Lett., 10, 1-8). The original code has been
73! provided by L.-P. Wang but is substantially reformatted and speed optimized
74! here.
75!
76! ATTENTION:
77! Physical quantities (like g, densities, etc.) used in this module still
78! have to be adjusted to those values used in the main PALM code.
79! Also, quantities in CGS-units should be converted to SI-units eventually.
80!------------------------------------------------------------------------------!
81
82    USE arrays_3d
83    USE cloud_parameters
84    USE constants
85    USE particle_attributes
86    USE pegrid
87
88
89    IMPLICIT NONE
90
91    PRIVATE
92
93    PUBLIC  ckernel, collision_efficiency_rogers, init_kernels, &
94            rclass_lbound, rclass_ubound, recalculate_kernel
95
96    REAL ::  epsilon, eps2, rclass_lbound, rclass_ubound, urms, urms2
97
98    REAL, DIMENSION(:),   ALLOCATABLE ::  epsclass, radclass, winf
99    REAL, DIMENSION(:,:), ALLOCATABLE ::  ec, ecf, gck, hkernel, hwratio
100    REAL, DIMENSION(:,:,:), ALLOCATABLE ::  ckernel
101
102    SAVE
103
104!
105!-- Public interfaces
106    INTERFACE collision_efficiency_rogers
107       MODULE PROCEDURE collision_efficiency_rogers
108    END INTERFACE collision_efficiency_rogers
109
110    INTERFACE init_kernels
111       MODULE PROCEDURE init_kernels
112    END INTERFACE init_kernels
113
114    INTERFACE recalculate_kernel
115       MODULE PROCEDURE recalculate_kernel
116    END INTERFACE recalculate_kernel
117
118
119    CONTAINS
120
121
122    SUBROUTINE init_kernels
123!------------------------------------------------------------------------------!
124! Initialization of the collision efficiency matrix with fixed radius and
125! dissipation classes, calculated at simulation start only.
126!------------------------------------------------------------------------------!
127
128       IMPLICIT NONE
129
130       INTEGER ::  i, j, k
131
132
133!
134!--    Calculate collision efficiencies for fixed radius- and dissipation
135!--    classes
136       IF ( collision_kernel(6:9) == 'fast' )  THEN
137
138          ALLOCATE( ckernel(1:radius_classes,1:radius_classes,               &
139                    0:dissipation_classes), epsclass(1:dissipation_classes), &
140                    radclass(1:radius_classes) )
141
142!
143!--       Calculate the radius class bounds with logarithmic distances
144!--       in the interval [1.0E-6, 2.0E-4] m
145          rclass_lbound = LOG( 1.0E-6 )
146          rclass_ubound = LOG( 2.0E-4 )
147          radclass(1)   = 1.0E-6
148          DO  i = 2, radius_classes
149             radclass(i) = EXP( rclass_lbound +                                &
150                                ( rclass_ubound - rclass_lbound ) * ( i-1.0 ) /&
151                                ( radius_classes - 1.0 ) )
152!             IF ( myid == 0 )  THEN
153!                PRINT*, 'i=', i, ' r = ', radclass(i)*1.0E6
154!             ENDIF
155          ENDDO
156
157!
158!--       Set the class bounds for dissipation in interval [0.0, 0.1] m**2/s**3
159          DO  i = 1, dissipation_classes
160             epsclass(i) = 0.1 * REAL( i ) / dissipation_classes
161!             IF ( myid == 0 )  THEN
162!                PRINT*, 'i=', i, ' eps = ', epsclass(i)
163!             ENDIF
164          ENDDO
165!
166!--       Calculate collision efficiencies of the Wang/ayala kernel
167          ALLOCATE( ec(1:radius_classes,1:radius_classes),  &
168                    ecf(1:radius_classes,1:radius_classes), &
169                    gck(1:radius_classes,1:radius_classes), &
170                    winf(1:radius_classes) )
171
172          DO  k = 1, dissipation_classes
173
174             epsilon = epsclass(k)
175             urms    = 2.02 * ( epsilon / 0.04 )**( 1.0 / 3.0 )
176
177             CALL turbsd
178             CALL turb_enhance_eff
179             CALL effic
180
181             DO  j = 1, radius_classes
182                DO  i = 1, radius_classes
183                   ckernel(i,j,k) = ec(i,j) * gck(i,j) * ecf(i,j)
184                ENDDO
185             ENDDO
186
187          ENDDO
188
189!
190!--       Calculate collision efficiencies of the Hall kernel
191          ALLOCATE( hkernel(1:radius_classes,1:radius_classes), &
192                    hwratio(1:radius_classes,1:radius_classes) )
193
194          CALL fallg
195          CALL effic
196
197          DO  j = 1, radius_classes
198             DO  i =  1, radius_classes
199                hkernel(i,j) = pi * ( radclass(j) + radclass(i) )**2 &
200                                  * ec(i,j) * ABS( winf(j) - winf(i) )
201                ckernel(i,j,0) = hkernel(i,j)  ! hall kernel stored on index 0
202              ENDDO
203          ENDDO
204
205!
206!--       Test output of efficiencies
207          IF ( j == -1 )  THEN
208
209             PRINT*, '*** Hall kernel'
210             WRITE ( *,'(5X,20(F4.0,1X))' ) ( radclass(i)*1.0E6, &
211                                              i = 1,radius_classes )
212             DO  j = 1, radius_classes
213                WRITE ( *,'(F4.0,1X,20(F8.4,1X))' ) radclass(j),  &
214                                          ( hkernel(i,j), i = 1,radius_classes )
215             ENDDO
216
217             DO  k = 1, dissipation_classes
218                DO  i = 1, radius_classes
219                   DO  j = 1, radius_classes
220                      IF ( hkernel(i,j) == 0.0 )  THEN
221                         hwratio(i,j) = 9999999.9
222                      ELSE
223                         hwratio(i,j) = ckernel(i,j,k) / hkernel(i,j)
224                      ENDIF
225                   ENDDO
226                ENDDO
227
228                PRINT*, '*** epsilon = ', epsclass(k)
229                WRITE ( *,'(5X,20(F4.0,1X))' ) ( radclass(i)*1.0E6, &
230                                                 i = 1,radius_classes )
231                DO  j = 1, radius_classes
232!                   WRITE ( *,'(F4.0,1X,20(F4.2,1X))' ) radclass(j)*1.0E6, &
233!                                       ( ckernel(i,j,k), i = 1,radius_classes )
234                   WRITE ( *,'(F4.0,1X,20(F8.4,1X))' ) radclass(j)*1.0E6, &
235                                          ( hwratio(i,j), i = 1,radius_classes )
236                ENDDO
237             ENDDO
238
239          ENDIF
240
241          DEALLOCATE( ec, ecf, epsclass, gck, hkernel, winf )
242
243       ELSEIF( collision_kernel == 'hall'  .OR.  collision_kernel == 'wang' ) &
244       THEN
245!
246!--       Initial settings for Hall- and Wang-Kernel
247!--       To be done: move here parts from turbsd, fallg, ecoll, etc.
248       ENDIF
249
250    END SUBROUTINE init_kernels
251
252
253!------------------------------------------------------------------------------!
254! Calculation of collision kernels during each timestep and for each grid box
255!------------------------------------------------------------------------------!
256    SUBROUTINE recalculate_kernel( i1, j1, k1 )
257
258       USE arrays_3d
259       USE cloud_parameters
260       USE constants
261       USE cpulog
262       USE indices
263       USE interfaces
264       USE particle_attributes
265
266       IMPLICIT NONE
267
268       INTEGER ::  i, i1, j, j1, k1, pend, pstart
269
270
271       pstart = prt_start_index(k1,j1,i1)
272       pend   = prt_start_index(k1,j1,i1) + prt_count(k1,j1,i1) - 1
273       radius_classes = prt_count(k1,j1,i1)
274
275       ALLOCATE( ec(1:radius_classes,1:radius_classes), &
276                 radclass(1:radius_classes), winf(1:radius_classes) )
277
278!
279!--    Store particle radii on the radclass array
280       radclass(1:radius_classes) = particles(pstart:pend)%radius
281
282       IF ( wang_kernel )  THEN
283          epsilon = diss(k1,j1,i1)   ! dissipation rate in m**2/s**3
284       ELSE
285          epsilon = 0.0
286       ENDIF
287       urms    = 2.02 * ( epsilon / 0.04 )**( 0.33333333333 )
288
289       IF ( wang_kernel  .AND.  epsilon > 1.0E-7 )  THEN
290!
291!--       Call routines to calculate efficiencies for the Wang kernel
292          ALLOCATE( gck(1:radius_classes,1:radius_classes), &
293                    ecf(1:radius_classes,1:radius_classes) )
294
295          CALL turbsd
296          CALL turb_enhance_eff
297          CALL effic
298
299          DO  j = 1, radius_classes
300             DO  i =  1, radius_classes
301                ckernel(pstart+i-1,pstart+j-1,1) = ec(i,j) * gck(i,j) * ecf(i,j)
302             ENDDO
303          ENDDO
304
305          DEALLOCATE( gck, ecf )
306
307       ELSE
308!
309!--       Call routines to calculate efficiencies for the Hall kernel
310          CALL fallg
311          CALL effic
312
313          DO  j = 1, radius_classes
314             DO  i =  1, radius_classes
315                ckernel(pstart+i-1,pstart+j-1,1) = pi *                       &
316                                          ( radclass(j) + radclass(i) )**2    &
317                                          * ec(i,j) * ABS( winf(j) - winf(i) )
318             ENDDO
319          ENDDO
320
321       ENDIF
322
323       DEALLOCATE( ec, radclass, winf )
324
325    END SUBROUTINE recalculate_kernel
326
327
328!------------------------------------------------------------------------------!
329! Calculation of gck
330! This is from Aayala 2008b, page 37ff.
331! Necessary input parameters: water density, radii of droplets, air density,
332! air viscosity, turbulent dissipation rate, taylor microscale reynolds number,
333! gravitational acceleration  --> to be replaced by PALM parameters
334!------------------------------------------------------------------------------!
335    SUBROUTINE turbsd
336
337       USE constants
338       USE cloud_parameters
339       USE particle_attributes
340       USE arrays_3d
341       USE control_parameters
342
343       IMPLICIT NONE
344
345       INTEGER ::  i, j
346
347       LOGICAL, SAVE ::  first = .TRUE.
348
349       REAL ::  ao, ao_gr, bbb, be, b1, b2, ccc, c1, c1_gr, c2, d1, d2, eta, &
350                e1, e2, fao_gr, fr, grfin, lambda, lambda_re, lf, rc, rrp,   &
351                sst, tauk, tl, t2, tt, t1, vk, vrms1xy, vrms2xy, v1, v1v2xy, &
352                v1xysq, v2, v2xysq, wrfin, wrgrav2, wrtur2xy, xx, yy, z
353
354       REAL, DIMENSION(1:radius_classes) ::  st, tau
355
356
357!
358!--    Initial assignment of constants
359       IF ( first )  THEN
360
361          first = .FALSE.
362
363       ENDIF
364
365       lambda    = urms * SQRT( 15.0 * molecular_viscosity / epsilon )    ! in m
366       lambda_re = urms**2 * SQRT( 15.0 / epsilon / molecular_viscosity )
367       tl        = urms**2 / epsilon                       ! in s
368       lf        = 0.5 * urms**3 / epsilon                 ! in m
369       tauk      = SQRT( molecular_viscosity / epsilon )                  ! in s
370       eta       = ( molecular_viscosity**3 / epsilon )**0.25             ! in m
371       vk        = eta / tauk
372
373       ao = ( 11.0 + 7.0 * lambda_re ) / ( 205.0 + lambda_re )
374       tt = SQRT( 2.0 * lambda_re / ( SQRT( 15.0 ) * ao ) ) * tauk   ! in s
375
376       CALL fallg    ! gives winf in m/s
377
378       DO  i = 1, radius_classes
379          tau(i) = winf(i) / g    ! in s
380          st(i)  = tau(i) / tauk
381       ENDDO
382
383!
384!--    Calculate wr (from Aayala 2008b, page 38f)
385       z   = tt / tl
386       be  = SQRT( 2.0 ) * lambda / lf
387       bbb = SQRT( 1.0 - 2.0 * be**2 )
388       d1  = ( 1.0 + bbb ) / ( 2.0 * bbb )
389       e1  = lf * ( 1.0 + bbb ) * 0.5   ! in m
390       d2  = ( 1.0 - bbb ) * 0.5 / bbb
391       e2  = lf * ( 1.0 - bbb ) * 0.5   ! in m
392       ccc = SQRT( 1.0 - 2.0 * z**2 )
393       b1  = ( 1.0 + ccc ) * 0.5 / ccc
394       c1  = tl * ( 1.0 + ccc ) * 0.5   ! in s
395       b2  = ( 1.0 - ccc ) * 0.5 / ccc
396       c2  = tl * ( 1.0 - ccc ) * 0.5   ! in s
397
398       DO  i = 1, radius_classes
399
400          v1 = winf(i)        ! in m/s
401          t1 = tau(i)         ! in s
402
403          DO  j = 1, i
404             rrp = radclass(i) + radclass(j)
405             v2  = winf(j)                                 ! in m/s
406             t2  = tau(j)                                  ! in s
407
408             v1xysq  = b1 * d1 * phi_w(c1,e1,v1,t1) - b1 * d2 * phi_w(c1,e2,v1,t1) &
409                     - b2 * d1 * phi_w(c2,e1,v1,t1) + b2 * d2 * phi_w(c2,e2,v1,t1)
410             v1xysq  = v1xysq * urms**2 / t1                ! in m**2/s**2
411             vrms1xy = SQRT( v1xysq )                       ! in m/s
412
413             v2xysq  = b1 * d1 * phi_w(c1,e1,v2,t2) - b1 * d2 * phi_w(c1,e2,v2,t2) &
414                     - b2 * d1 * phi_w(c2,e1,v2,t2) + b2 * d2 * phi_w(c2,e2,v2,t2)
415             v2xysq  = v2xysq * urms**2 / t2                ! in m**2/s**2
416             vrms2xy = SQRT( v2xysq )                       ! in m/s
417
418             IF ( winf(i) >= winf(j) )  THEN
419                v1 = winf(i)
420                t1 = tau(i)
421                v2 = winf(j)
422                t2 = tau(j)
423             ELSE
424                v1 = winf(j)
425                t1 = tau(j)
426                v2 = winf(i)
427                t2 = tau(i)
428             ENDIF
429
430             v1v2xy   =  b1 * d1 * zhi(c1,e1,v1,t1,v2,t2) - &
431                         b1 * d2 * zhi(c1,e2,v1,t1,v2,t2) - &
432                         b2 * d1 * zhi(c2,e1,v1,t1,v2,t2) + &
433                         b2 * d2* zhi(c2,e2,v1,t1,v2,t2)
434             fr       = d1 * EXP( -rrp / e1 ) - d2 * EXP( -rrp / e2 )
435             v1v2xy   = v1v2xy * fr * urms**2 / tau(i) / tau(j)  ! in m**2/s**2
436             wrtur2xy = vrms1xy**2 + vrms2xy**2 - 2.0 * v1v2xy   ! in m**2/s**2
437             IF ( wrtur2xy < 0.0 )  wrtur2xy = 0.0
438             wrgrav2  = pi / 8.0 * ( winf(j) - winf(i) )**2
439             wrfin    = SQRT( ( 2.0 / pi ) * ( wrtur2xy + wrgrav2) )   ! in m/s
440
441!
442!--          Calculate gr
443             IF ( st(j) > st(i) )  THEN
444                sst = st(j)
445             ELSE
446                sst = st(i)
447             ENDIF
448
449             xx = -0.1988 * sst**4 + 1.5275 * sst**3 - 4.2942 * sst**2 + &
450                   5.3406 * sst
451             IF ( xx < 0.0 )  xx = 0.0
452             yy = 0.1886 * EXP( 20.306 / lambda_re )
453
454             c1_gr  =  xx / ( g / vk * tauk )**yy
455
456             ao_gr  = ao + ( pi / 8.0) * ( g / vk * tauk )**2
457             fao_gr = 20.115 * SQRT( ao_gr / lambda_re )
458             rc     = SQRT( fao_gr * ABS( st(j) - st(i) ) ) * eta   ! in cm
459
460             grfin  = ( ( eta**2 + rc**2 ) / ( rrp**2 + rc**2) )**( c1_gr*0.5 )
461             IF ( grfin < 1.0 )  grfin = 1.0
462
463             gck(i,j) = 2.0 * pi * rrp**2 * wrfin * grfin           ! in cm**3/s
464             gck(j,i) = gck(i,j)
465
466          ENDDO
467       ENDDO
468
469    END SUBROUTINE turbsd
470
471
472!------------------------------------------------------------------------------!
473! phi_w as a function
474!------------------------------------------------------------------------------!
475    REAL FUNCTION phi_w( a, b, vsett, tau0 )
476
477       IMPLICIT NONE
478
479       REAL ::  a, aa1, b, tau0, vsett
480
481       aa1 = 1.0 / tau0 + 1.0 / a + vsett / b
482       phi_w = 1.0 / aa1  - 0.5 * vsett / b / aa1**2  ! in s
483
484    END FUNCTION phi_w
485
486
487!------------------------------------------------------------------------------!
488! zhi as a function
489!------------------------------------------------------------------------------!
490    REAL FUNCTION zhi( a, b, vsett1, tau1, vsett2, tau2 )
491
492       IMPLICIT NONE
493
494       REAL ::  a, aa1, aa2, aa3, aa4, aa5, aa6, b, tau1, tau2, vsett1, vsett2
495
496       aa1 = vsett2 / b - 1.0 / tau2 - 1.0 / a
497       aa2 = vsett1 / b + 1.0 / tau1 + 1.0 / a
498       aa3 = ( vsett1 - vsett2 ) / b + 1.0 / tau1 + 1.0 / tau2
499       aa4 = ( vsett2 / b )**2 - ( 1.0 / tau2 + 1.0 / a )**2
500       aa5 = vsett2 / b + 1.0 / tau2 + 1.0 / a
501       aa6 = 1.0 / tau1 - 1.0 / a + ( 1.0 / tau2 + 1.0 / a) * vsett1 / vsett2
502       zhi = (1.0 / aa1 - 1.0 / aa2 ) * ( vsett1 - vsett2 ) * 0.5 / b / aa3**2 &
503           + (4.0 / aa4 - 1.0 / aa5**2 - 1.0 / aa1**2 ) * vsett2 * 0.5 / b /aa6&
504           + (2.0 * ( b / aa2 - b / aa1 ) - vsett1 / aa2**2 + vsett2 / aa1**2 )&
505           * 0.5 / b / aa3      ! in s**2
506
507    END FUNCTION zhi
508
509
510!------------------------------------------------------------------------------!
511! Calculation of terminal velocity winf following Equations 10-138 to 10-145
512! from (Pruppacher and Klett, 1997)
513!------------------------------------------------------------------------------!
514    SUBROUTINE fallg
515
516       USE constants
517       USE cloud_parameters
518       USE particle_attributes
519       USE arrays_3d
520       USE control_parameters
521
522       IMPLICIT NONE
523
524       INTEGER ::  i, j
525
526       LOGICAL, SAVE ::  first = .TRUE.
527
528       REAL, SAVE ::  cunh, eta, phy, py, rho_a, sigma, stb, stok, &
529                      t0, xlamb
530
531       REAL ::  bond, x, xrey, y
532
533       REAL, DIMENSION(1:7), SAVE  ::  b
534       REAL, DIMENSION(1:6), SAVE  ::  c
535
536!
537!--    Initial assignment of constants
538       IF ( first )  THEN
539
540          first = .FALSE.
541          b = (/  -0.318657E1,  0.992696E0, -0.153193E-2, -0.987059E-3, &
542                 -0.578878E-3, 0.855176E-4, -0.327815E-5 /)
543          c = (/  -0.500015E1,  0.523778E1,  -0.204914E1,   0.475294E0, &
544                 -0.542819E-1, 0.238449E-2 /)
545
546!
547!--       Parameter values for p = 1013,25 hPa and T = 293,15 K
548          eta   = 1.818E-5         ! in kg/(m s)
549          xlamb = 6.6E-8           ! in m
550          rho_a = 1.204            ! in kg/m**3
551          cunh  = 1.26 * xlamb     ! in m
552          sigma = 0.07363          ! in kg/s**2
553          stok  = 2.0  * g * ( rho_l - rho_a ) / ( 9.0 * eta ) ! in 1/(m s)
554          stb   = 32.0 * rho_a * ( rho_l - rho_a) * g / (3.0 * eta * eta)
555          phy   = sigma**3 * rho_a**2 / ( eta**4 * g * ( rho_l - rho_a ) )
556          py    = phy**( 1.0 / 6.0 )
557
558       ENDIF
559
560       DO  j = 1, radius_classes
561
562          IF ( radclass(j) <= 1.0E-5 ) THEN
563
564             winf(j) = stok * ( radclass(j)**2 + cunh * radclass(j) )
565
566          ELSEIF ( radclass(j) > 1.0E-5  .AND.  radclass(j) <= 5.35E-4 )  THEN
567
568             x = LOG( stb * radclass(j)**3 )
569             y = 0.0
570
571             DO  i = 1, 7
572                y = y + b(i) * x**(i-1)
573             ENDDO
574!
575!--          Note: this Eq. is wrong in (Pruppacher and Klett, 1997, p. 418)
576!--          for correct version see (Beard, 1976)
577             xrey = ( 1.0 + cunh / radclass(j) ) * EXP( y ) 
578
579             winf(j) = xrey * eta / ( 2.0 * rho_a * radclass(j) )
580
581          ELSEIF ( radclass(j) > 5.35E-4 )  THEN
582
583             IF ( radclass(j) > 0.0035 )  THEN
584                bond = g * ( rho_l - rho_a ) * 0.0035**2 / sigma
585             ELSE
586               bond = g * ( rho_l - rho_a ) * radclass(j)**2 / sigma
587             ENDIF
588
589             x = LOG( 16.0 * bond * py / 3.0 )
590             y = 0.0
591
592             DO  i = 1, 6
593                y = y + c(i) * x**(i-1)
594             ENDDO
595
596             xrey = py * EXP( y )
597
598             IF ( radclass(j) > 0.0035 )  THEN
599                winf(j) = xrey * eta / ( 2.0 * rho_a * 0.0035 )
600             ELSE
601                winf(j) = xrey * eta / ( 2.0 * rho_a * radclass(j) )
602             ENDIF
603
604          ENDIF
605
606       ENDDO
607
608    END SUBROUTINE fallg
609
610
611!------------------------------------------------------------------------------!
612! Calculation of collision efficiencies for the Hall kernel
613!------------------------------------------------------------------------------!
614    SUBROUTINE effic
615
616       USE arrays_3d
617       USE cloud_parameters
618       USE constants
619       USE particle_attributes
620
621       IMPLICIT NONE
622
623       INTEGER ::  i, iq, ir, j, k, kk
624
625       INTEGER, DIMENSION(:), ALLOCATABLE ::  ira
626
627       LOGICAL, SAVE ::  first = .TRUE.
628
629       REAL ::  ek, particle_radius, pp, qq, rq
630
631       REAL, DIMENSION(1:21), SAVE ::  rat
632       REAL, DIMENSION(1:15), SAVE ::  r0
633       REAL, DIMENSION(1:15,1:21), SAVE ::  ecoll
634
635!
636!--    Initial assignment of constants
637       IF ( first )  THEN
638
639         first = .FALSE.
640         r0  = (/ 6.0, 8.0, 10.0, 15.0, 20.0, 25.0, 30.0, 40.0, 50.0, 60., &
641                  70.0, 100.0, 150.0, 200.0, 300.0 /)
642         rat = (/ 0.00, 0.05, 0.10, 0.15, 0.20, 0.25, 0.30, 0.35, 0.40, 0.45, &
643                  0.50, 0.55, 0.60, 0.65, 0.70, 0.75, 0.80, 0.85, 0.90, 0.95, &
644                  1.00 /)
645
646         ecoll(:,1) = (/0.001, 0.001, 0.001, 0.001, 0.001, 0.001, 0.001, &
647                        0.001, 0.001, 0.001, 0.001, 0.001, 0.001, 0.001, 0.001/)
648         ecoll(:,2) = (/0.003, 0.003, 0.003, 0.004, 0.005, 0.005, 0.005, &
649                        0.010, 0.100, 0.050, 0.200, 0.500, 0.770, 0.870, 0.970/)
650         ecoll(:,3) = (/0.007, 0.007, 0.007, 0.008, 0.009, 0.010, 0.010, &
651                        0.070, 0.400, 0.430, 0.580, 0.790, 0.930, 0.960, 1.000/)
652         ecoll(:,4) = (/0.009, 0.009, 0.009, 0.012, 0.015, 0.010, 0.020, &
653                        0.280, 0.600, 0.640, 0.750, 0.910, 0.970, 0.980, 1.000/)
654         ecoll(:,5) = (/0.014, 0.014, 0.014, 0.015, 0.016, 0.030, 0.060, &
655                        0.500, 0.700, 0.770, 0.840, 0.950, 0.970, 1.000, 1.000/)
656         ecoll(:,6) = (/0.017, 0.017, 0.017, 0.020, 0.022, 0.060, 0.100, &
657                        0.620, 0.780, 0.840, 0.880, 0.950, 1.000, 1.000, 1.000/)
658         ecoll(:,7) = (/0.030, 0.030, 0.024, 0.022, 0.032, 0.062, 0.200, &
659                        0.680, 0.830, 0.870, 0.900, 0.950, 1.000, 1.000, 1.000/)
660         ecoll(:,8) = (/0.025, 0.025, 0.025, 0.036, 0.043, 0.130, 0.270, &
661                        0.740, 0.860, 0.890, 0.920, 1.000, 1.000, 1.000, 1.000/)
662         ecoll(:,9) = (/0.027, 0.027, 0.027, 0.040, 0.052, 0.200, 0.400, &
663                        0.780, 0.880, 0.900, 0.940, 1.000, 1.000, 1.000, 1.000/)
664         ecoll(:,10)= (/0.030, 0.030, 0.030, 0.047, 0.064, 0.250, 0.500, &
665                        0.800, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
666         ecoll(:,11)= (/0.040, 0.040, 0.033, 0.037, 0.068, 0.240, 0.550, &
667                        0.800, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
668         ecoll(:,12)= (/0.035, 0.035, 0.035, 0.055, 0.079, 0.290, 0.580, &
669                        0.800, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
670         ecoll(:,13)= (/0.037, 0.037, 0.037, 0.062, 0.082, 0.290, 0.590, &
671                        0.780, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
672         ecoll(:,14)= (/0.037, 0.037, 0.037, 0.060, 0.080, 0.290, 0.580, &
673                        0.770, 0.890, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
674         ecoll(:,15)= (/0.037, 0.037, 0.037, 0.041, 0.075, 0.250, 0.540, &
675                        0.760, 0.880, 0.920, 0.950, 1.000, 1.000, 1.000, 1.000/)
676         ecoll(:,16)= (/0.037, 0.037, 0.037, 0.052, 0.067, 0.250, 0.510, &
677                        0.770, 0.880, 0.930, 0.970, 1.000, 1.000, 1.000, 1.000/)
678         ecoll(:,17)= (/0.037, 0.037, 0.037, 0.047, 0.057, 0.250, 0.490, &
679                        0.770, 0.890, 0.950, 1.000, 1.000, 1.000, 1.000, 1.000/)
680         ecoll(:,18)= (/0.036, 0.036, 0.036, 0.042, 0.048, 0.230, 0.470, &
681                        0.780, 0.920, 1.000, 1.020, 1.020, 1.020, 1.020, 1.020/)
682         ecoll(:,19)= (/0.040, 0.040, 0.035, 0.033, 0.040, 0.112, 0.450, &
683                        0.790, 1.010, 1.030, 1.040, 1.040, 1.040, 1.040, 1.040/)
684         ecoll(:,20)= (/0.033, 0.033, 0.033, 0.033, 0.033, 0.119, 0.470, &
685                        0.950, 1.300, 1.700, 2.300, 2.300, 2.300, 2.300, 2.300/)
686         ecoll(:,21)= (/0.027, 0.027, 0.027, 0.027, 0.027, 0.125, 0.520, &
687                        1.400, 2.300, 3.000, 4.000, 4.000, 4.000, 4.000, 4.000/)
688       ENDIF
689
690!
691!--    Calculate the radius class index of particles with respect to array r
692!--    Radius has to be in µm
693       ALLOCATE( ira(1:radius_classes) )
694       DO  j = 1, radius_classes
695          particle_radius = radclass(j) * 1.0E6
696          DO  k = 1, 15
697             IF ( particle_radius < r0(k) )  THEN
698                ira(j) = k
699                EXIT
700             ENDIF
701          ENDDO
702          IF ( particle_radius >= r0(15) )  ira(j) = 16
703       ENDDO
704
705!
706!--    Two-dimensional linear interpolation of the collision efficiency.
707!--    Radius has to be in µm
708       DO  j = 1, radius_classes
709          DO  i = 1, j
710
711             ir = ira(j)
712             rq = radclass(i) / radclass(j)
713             iq = INT( rq * 20 ) + 1
714             iq = MAX( iq , 2)
715
716             IF ( ir < 16 )  THEN
717                IF ( ir >= 2 )  THEN
718                   pp = ( ( radclass(j) * 1.0E06 ) - r0(ir-1) ) / &
719                        ( r0(ir) - r0(ir-1) )
720                   qq = ( rq- rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
721                   ec(j,i) = ( 1.0-pp ) * ( 1.0-qq ) * ecoll(ir-1,iq-1)  &
722                             + pp * ( 1.0-qq ) * ecoll(ir,iq-1)          &
723                             + qq * ( 1.0-pp ) * ecoll(ir-1,iq)          &
724                             + pp * qq * ecoll(ir,iq)
725                ELSE
726                   qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
727                   ec(j,i) = (1.0-qq) * ecoll(1,iq-1) + qq * ecoll(1,iq)
728                ENDIF
729             ELSE
730                qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
731                ek = ( 1.0 - qq ) * ecoll(15,iq-1) + qq * ecoll(15,iq)
732                ec(j,i) = MIN( ek, 1.0 )
733             ENDIF
734
735             IF ( ec(j,i) < 1.0E-20 )  ec(j,i) = 0.0
736
737             ec(i,j) = ec(j,i)
738
739          ENDDO
740       ENDDO
741
742       DEALLOCATE( ira )
743
744    END SUBROUTINE effic
745
746
747!------------------------------------------------------------------------------!
748! Calculation of enhancement factor for collision efficencies due to turbulence
749!------------------------------------------------------------------------------!
750    SUBROUTINE turb_enhance_eff
751
752       USE constants
753       USE cloud_parameters
754       USE particle_attributes
755       USE arrays_3d
756
757       IMPLICIT NONE
758
759       INTEGER :: i, ik, iq, ir, j, k, kk
760
761       INTEGER, DIMENSION(:), ALLOCATABLE ::  ira
762
763       REAL ::  particle_radius, pp, qq, rq, x1, x2, x3, y1, y2, y3
764
765       LOGICAL, SAVE ::  first = .TRUE.
766
767       REAL, DIMENSION(1:11), SAVE ::  rat
768       REAL, DIMENSION(1:7), SAVE  ::  r0
769       REAL, DIMENSION(1:7,1:11), SAVE ::  ecoll_100, ecoll_400
770
771!
772!--    Initial assignment of constants
773       IF ( first )  THEN
774
775          first = .FALSE.
776
777          r0  = (/ 10.0, 20.0, 30.0, 40.0, 50.0, 60.0, 100.0 /)
778          rat = (/ 0.0, 0.1, 0.2, 0.3, 0.4, 0.5, 0.6, 0.7, 0.8, 0.9, 1.0 /)
779!
780!--       for 100 cm**2/s**3
781          ecoll_100(:,1) = (/1.74,  1.74,  1.773, 1.49,  1.207,  1.207,  1.0 /)
782          ecoll_100(:,2) = (/1.46,  1.46,  1.421, 1.245, 1.069,  1.069,  1.0 /)
783          ecoll_100(:,3) = (/1.32,  1.32,  1.245, 1.123, 1.000,  1.000,  1.0 /)
784          ecoll_100(:,4) = (/1.250, 1.250, 1.148, 1.087, 1.025,  1.025,  1.0 /)
785          ecoll_100(:,5) = (/1.186, 1.186, 1.066, 1.060, 1.056,  1.056,  1.0 /)
786          ecoll_100(:,6) = (/1.045, 1.045, 1.000, 1.014, 1.028,  1.028,  1.0 /)
787          ecoll_100(:,7) = (/1.070, 1.070, 1.030, 1.038, 1.046,  1.046,  1.0 /)
788          ecoll_100(:,8) = (/1.000, 1.000, 1.054, 1.042, 1.029,  1.029,  1.0 /)
789          ecoll_100(:,9) = (/1.223, 1.223, 1.117, 1.069, 1.021,  1.021,  1.0 /)
790          ecoll_100(:,10)= (/1.570, 1.570, 1.244, 1.166, 1.088,  1.088,  1.0 /)
791          ecoll_100(:,11)= (/20.3,  20.3,  14.6 , 8.61,  2.60,   2.60 ,  1.0 /)
792!
793!--       for 400 cm**2/s**3
794          ecoll_400(:,1) = (/4.976, 4.976,  3.593, 2.519, 1.445,  1.445,  1.0 /)
795          ecoll_400(:,2) = (/2.984, 2.984,  2.181, 1.691, 1.201,  1.201,  1.0 /)
796          ecoll_400(:,3) = (/1.988, 1.988,  1.475, 1.313, 1.150,  1.150,  1.0 /)
797          ecoll_400(:,4) = (/1.490, 1.490,  1.187, 1.156, 1.126,  1.126,  1.0 /)
798          ecoll_400(:,5) = (/1.249, 1.249,  1.088, 1.090, 1.092,  1.092,  1.0 /)
799          ecoll_400(:,6) = (/1.139, 1.139,  1.130, 1.091, 1.051,  1.051,  1.0 /)
800          ecoll_400(:,7) = (/1.220, 1.220,  1.190, 1.138, 1.086,  1.086,  1.0 /)
801          ecoll_400(:,8) = (/1.325, 1.325,  1.267, 1.165, 1.063,  1.063,  1.0 /)
802          ecoll_400(:,9) = (/1.716, 1.716,  1.345, 1.223, 1.100,  1.100,  1.0 /)
803          ecoll_400(:,10)= (/3.788, 3.788,  1.501, 1.311, 1.120,  1.120,  1.0 /)
804          ecoll_400(:,11)= (/36.52, 36.52,  19.16, 22.80,  26.0,   26.0,  1.0 /)
805
806       ENDIF
807
808!
809!--    Calculate the radius class index of particles with respect to array r0
810!--    Radius has to be in µm
811       ALLOCATE( ira(1:radius_classes) )
812
813       DO  j = 1, radius_classes
814          particle_radius = radclass(j) * 1.0E6
815          DO  k = 1, 7
816             IF ( particle_radius < r0(k) )  THEN
817                ira(j) = k
818                EXIT
819             ENDIF
820          ENDDO
821          IF ( particle_radius >= r0(7) )  ira(j) = 8
822       ENDDO
823
824!
825!--    Two-dimensional linear interpolation of the collision efficiencies
826!--    Radius has to be in µm
827       DO  j =  1, radius_classes
828          DO  i = 1, j
829
830             ir = ira(j)
831             rq = radclass(i) / radclass(j)
832
833             DO  kk = 2, 11
834                IF ( rq <= rat(kk) )  THEN
835                   iq = kk
836                   EXIT
837                ENDIF
838             ENDDO
839
840             y1 = 0.0001      ! for 0 m**2/s**3
841
842             IF ( ir < 8 )  THEN
843                IF ( ir >= 2 )  THEN
844                   pp = ( radclass(j)*1.0E6 - r0(ir-1) ) / ( r0(ir) - r0(ir-1) )
845                   qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
846                   y2 = ( 1.0-pp ) * ( 1.0-qq ) * ecoll_100(ir-1,iq-1) +  &
847                                pp * ( 1.0-qq ) * ecoll_100(ir,iq-1)   +  &
848                                qq * ( 1.0-pp ) * ecoll_100(ir-1,iq)   +  &
849                                pp * qq         * ecoll_100(ir,iq)
850                   y3 = ( 1.0-pp ) * ( 1.0-qq ) * ecoll_400(ir-1,iq-1) +  &
851                                pp * ( 1.0-qq ) * ecoll_400(ir,iq-1)   +  &
852                                qq * ( 1.0-pp ) * ecoll_400(ir-1,iq)   +  &
853                                pp * qq         * ecoll_400(ir,iq)
854                ELSE
855                   qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
856                   y2 = ( 1.0-qq ) * ecoll_100(1,iq-1) + qq * ecoll_100(1,iq)
857                   y3 = ( 1.0-qq ) * ecoll_400(1,iq-1) + qq * ecoll_400(1,iq)
858                ENDIF
859             ELSE
860                qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
861                y2 = ( 1.0-qq ) * ecoll_100(7,iq-1) + qq * ecoll_100(7,iq)
862                y3 = ( 1.0-qq ) * ecoll_400(7,iq-1) + qq * ecoll_400(7,iq)
863             ENDIF
864!
865!--          Linear interpolation of dissipation rate in m**2/s**3
866             IF ( epsilon <= 0.01 )  THEN
867                ecf(j,i) = ( epsilon - 0.01 ) / (   0.0 - 0.01 ) * y1 &
868                         + ( epsilon -   0.0 ) / ( 0.01 -   0.0 ) * y2
869             ELSEIF ( epsilon <= 0.06 )  THEN
870                ecf(j,i) = ( epsilon - 0.04 ) / ( 0.01 - 0.04 ) * y2 &
871                         + ( epsilon - 0.01 ) / ( 0.04 - 0.01 ) * y3
872             ELSE
873                ecf(j,i) = (   0.06 - 0.04 ) / ( 0.01 - 0.04 ) * y2 &
874                         + (   0.06 - 0.01 ) / ( 0.04 - 0.01 ) * y3
875             ENDIF
876
877             IF ( ecf(j,i) < 1.0 )  ecf(j,i) = 1.0
878
879             ecf(i,j) = ecf(j,i)
880
881          ENDDO
882       ENDDO
883
884    END SUBROUTINE turb_enhance_eff
885
886
887
888    SUBROUTINE collision_efficiency_rogers( mean_r, r, e)
889!------------------------------------------------------------------------------!
890! Collision efficiencies from table 8.2 in Rogers and Yau (1989, 3rd edition).
891! Values are calculated from table by bilinear interpolation.
892!------------------------------------------------------------------------------!
893
894       IMPLICIT NONE
895
896       INTEGER       ::  i, j, k
897
898       LOGICAL, SAVE ::  first = .TRUE.
899
900       REAL          ::  aa, bb, cc, dd, dx, dy, e, gg, mean_r, mean_rm, r, &
901                         rm, x, y
902
903       REAL, DIMENSION(1:9), SAVE      ::  collected_r = 0.0
904       REAL, DIMENSION(1:19), SAVE     ::  collector_r = 0.0
905       REAL, DIMENSION(1:9,1:19), SAVE ::  ef = 0.0
906
907       mean_rm = mean_r * 1.0E06
908       rm      = r      * 1.0E06
909
910       IF ( first )  THEN
911
912          collected_r = (/ 2.0, 3.0, 4.0, 6.0, 8.0, 10.0, 15.0, 20.0, 25.0 /)
913          collector_r = (/ 10.0, 20.0, 30.0, 40.0, 50.0, 60.0, 80.0, 100.0,  &
914                           150.0, 200.0, 300.0, 400.0, 500.0, 600.0, 1000.0, &
915                           1400.0, 1800.0, 2400.0, 3000.0 /)
916
917          ef(:,1) = (/0.017, 0.027, 0.037, 0.052, 0.052, 0.052, 0.052, 0.0, &
918                      0.0 /)
919          ef(:,2) = (/0.001, 0.016, 0.027, 0.060, 0.12, 0.17, 0.17, 0.17, 0.0 /)
920          ef(:,3) = (/0.001, 0.001, 0.02,  0.13,  0.28, 0.37, 0.54, 0.55, 0.47/)
921          ef(:,4) = (/0.001, 0.001, 0.02,  0.23,  0.4,  0.55, 0.7,  0.75, 0.75/)
922          ef(:,5) = (/0.01,  0.01,  0.03,  0.3,   0.4,  0.58, 0.73, 0.75, 0.79/)
923          ef(:,6) = (/0.01,  0.01,  0.13,  0.38,  0.57, 0.68, 0.80, 0.86, 0.91/)
924          ef(:,7) = (/0.01,  0.085, 0.23,  0.52,  0.68, 0.76, 0.86, 0.92, 0.95/)
925          ef(:,8) = (/0.01,  0.14,  0.32,  0.60,  0.73, 0.81, 0.90, 0.94, 0.96/)
926          ef(:,9) = (/0.025, 0.25,  0.43,  0.66,  0.78, 0.83, 0.92, 0.95, 0.96/)
927          ef(:,10)= (/0.039, 0.3,   0.46,  0.69,  0.81, 0.87, 0.93, 0.95, 0.96/)
928          ef(:,11)= (/0.095, 0.33,  0.51,  0.72,  0.82, 0.87, 0.93, 0.96, 0.97/)
929          ef(:,12)= (/0.098, 0.36,  0.51,  0.73,  0.83, 0.88, 0.93, 0.96, 0.97/)
930          ef(:,13)= (/0.1,   0.36,  0.52,  0.74,  0.83, 0.88, 0.93, 0.96, 0.97/)
931          ef(:,14)= (/0.17,  0.4,   0.54,  0.72,  0.83, 0.88, 0.94, 0.98, 1.0 /)
932          ef(:,15)= (/0.15,  0.37,  0.52,  0.74,  0.82, 0.88, 0.94, 0.98, 1.0 /)
933          ef(:,16)= (/0.11,  0.34,  0.49,  0.71,  0.83, 0.88, 0.94, 0.95, 1.0 /)
934          ef(:,17)= (/0.08,  0.29,  0.45,  0.68,  0.8,  0.86, 0.96, 0.94, 1.0 /)
935          ef(:,18)= (/0.04,  0.22,  0.39,  0.62,  0.75, 0.83, 0.92, 0.96, 1.0 /)
936          ef(:,19)= (/0.02,  0.16,  0.33,  0.55,  0.71, 0.81, 0.90, 0.94, 1.0 /)
937
938       ENDIF
939
940       DO  k = 1, 8
941          IF ( collected_r(k) <= mean_rm )  i = k
942       ENDDO
943
944       DO  k = 1, 18
945          IF ( collector_r(k) <= rm )  j = k
946       ENDDO
947
948       IF ( rm < 10.0 )  THEN
949          e = 0.0
950       ELSEIF ( mean_rm < 2.0 )  THEN
951          e = 0.001
952       ELSEIF ( mean_rm >= 25.0 )  THEN
953          IF( j <= 2 )  e = 0.0
954          IF( j == 3 )  e = 0.47
955          IF( j == 4 )  e = 0.8
956          IF( j == 5 )  e = 0.9
957          IF( j >=6  )  e = 1.0
958       ELSEIF ( rm >= 3000.0 )  THEN
959          IF( i == 1 )  e = 0.02
960          IF( i == 2 )  e = 0.16
961          IF( i == 3 )  e = 0.33
962          IF( i == 4 )  e = 0.55
963          IF( i == 5 )  e = 0.71
964          IF( i == 6 )  e = 0.81
965          IF( i == 7 )  e = 0.90
966          IF( i >= 8 )  e = 0.94
967       ELSE
968          x  = mean_rm - collected_r(i)
969          y  = rm - collector_r(j)
970          dx = collected_r(i+1) - collected_r(i)
971          dy = collector_r(j+1) - collector_r(j)
972          aa = x**2 + y**2
973          bb = ( dx - x )**2 + y**2
974          cc = x**2 + ( dy - y )**2
975          dd = ( dx - x )**2 + ( dy - y )**2
976          gg = aa + bb + cc + dd
977
978          e = ( (gg-aa)*ef(i,j) + (gg-bb)*ef(i+1,j) + (gg-cc)*ef(i,j+1) + &
979                (gg-dd)*ef(i+1,j+1) ) / (3.0*gg)
980       ENDIF
981
982    END SUBROUTINE collision_efficiency_rogers
983
984 END MODULE lpm_collision_kernels_mod
Note: See TracBrowser for help on using the repository browser.