source: palm/trunk/SOURCE/lpm_collision_kernels.f90 @ 1036

Last change on this file since 1036 was 1036, checked in by raasch, 9 years ago

code has been put under the GNU General Public License (v3)

  • Property svn:keywords set to Id
File size: 35.9 KB
Line 
1 MODULE lpm_collision_kernels_mod
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: lpm_collision_kernels.f90 1036 2012-10-22 13:43:42Z raasch $
27!
28! 1007 2012-09-19 14:30:36Z franke
29! converted all units to SI units and replaced some parameters by corresponding
30! PALM parameters
31! Bugfix: factor in calculation of enhancement factor for collision efficencies
32! changed from 10. to 1.0
33!
34! 849 2012-03-15 10:35:09Z raasch
35! routine collision_efficiency_rogers added (moved from former advec_particles
36! to here)
37!
38! 835 2012-02-22 11:21:19Z raasch $
39! Bugfix: array diss can be used only in case of Wang kernel
40!
41! 828 2012-02-21 12:00:36Z raasch
42! code has been completely reformatted, routine colker renamed
43! recalculate_kernel,
44! routine init_kernels added, radius is now communicated to the collision
45! routines by array radclass
46!
47! Bugfix: transformation factor for dissipation changed from 1E5 to 1E4
48!
49! 825 2012-02-19 03:03:44Z raasch
50! routine renamed from wang_kernel to lpm_collision_kernels,
51! turbulence_effects on collision replaced by wang_kernel
52!
53! 799 2011-12-21 17:48:03Z franke
54! speed optimizations and formatting
55! Bugfix: iq=1 is not allowed (routine effic)
56! Bugfix: replaced stop by ec=0.0 in case of very small ec (routine effic)
57!
58! 790 2011-11-29 03:11:20Z raasch
59! initial revision
60!
61! Description:
62! ------------
63! This module calculates collision efficiencies either due to pure gravitational
64! effects (Hall kernel, see Hall, 1980: J. Atmos. Sci., 2486-2507) or
65! including the effects of (SGS) turbulence (Wang kernel, see Wang and
66! Grabowski, 2009: Atmos. Sci. Lett., 10, 1-8). The original code has been
67! provided by L.-P. Wang but is substantially reformatted and speed optimized
68! here.
69!
70! ATTENTION:
71! Physical quantities (like g, densities, etc.) used in this module still
72! have to be adjusted to those values used in the main PALM code.
73! Also, quantities in CGS-units should be converted to SI-units eventually.
74!------------------------------------------------------------------------------!
75
76    USE arrays_3d
77    USE cloud_parameters
78    USE constants
79    USE particle_attributes
80    USE pegrid
81
82
83    IMPLICIT NONE
84
85    PRIVATE
86
87    PUBLIC  ckernel, collision_efficiency_rogers, init_kernels, &
88            rclass_lbound, rclass_ubound, recalculate_kernel
89
90    REAL ::  epsilon, eps2, rclass_lbound, rclass_ubound, urms, urms2
91
92    REAL, DIMENSION(:),   ALLOCATABLE ::  epsclass, radclass, winf
93    REAL, DIMENSION(:,:), ALLOCATABLE ::  ec, ecf, gck, hkernel, hwratio
94    REAL, DIMENSION(:,:,:), ALLOCATABLE ::  ckernel
95
96    SAVE
97
98!
99!-- Public interfaces
100    INTERFACE collision_efficiency_rogers
101       MODULE PROCEDURE collision_efficiency_rogers
102    END INTERFACE collision_efficiency_rogers
103
104    INTERFACE init_kernels
105       MODULE PROCEDURE init_kernels
106    END INTERFACE init_kernels
107
108    INTERFACE recalculate_kernel
109       MODULE PROCEDURE recalculate_kernel
110    END INTERFACE recalculate_kernel
111
112
113    CONTAINS
114
115
116    SUBROUTINE init_kernels
117!------------------------------------------------------------------------------!
118! Initialization of the collision efficiency matrix with fixed radius and
119! dissipation classes, calculated at simulation start only.
120!------------------------------------------------------------------------------!
121
122       IMPLICIT NONE
123
124       INTEGER ::  i, j, k
125
126
127!
128!--    Calculate collision efficiencies for fixed radius- and dissipation
129!--    classes
130       IF ( collision_kernel(6:9) == 'fast' )  THEN
131
132          ALLOCATE( ckernel(1:radius_classes,1:radius_classes,               &
133                    0:dissipation_classes), epsclass(1:dissipation_classes), &
134                    radclass(1:radius_classes) )
135
136!
137!--       Calculate the radius class bounds with logarithmic distances
138!--       in the interval [1.0E-6, 2.0E-4] m
139          rclass_lbound = LOG( 1.0E-6 )
140          rclass_ubound = LOG( 2.0E-4 )
141          radclass(1)   = 1.0E-6
142          DO  i = 2, radius_classes
143             radclass(i) = EXP( rclass_lbound +                                &
144                                ( rclass_ubound - rclass_lbound ) * ( i-1.0 ) /&
145                                ( radius_classes - 1.0 ) )
146!             IF ( myid == 0 )  THEN
147!                PRINT*, 'i=', i, ' r = ', radclass(i)*1.0E6
148!             ENDIF
149          ENDDO
150
151!
152!--       Set the class bounds for dissipation in interval [0.0, 0.1] m**2/s**3
153          DO  i = 1, dissipation_classes
154             epsclass(i) = 0.1 * REAL( i ) / dissipation_classes
155!             IF ( myid == 0 )  THEN
156!                PRINT*, 'i=', i, ' eps = ', epsclass(i)
157!             ENDIF
158          ENDDO
159!
160!--       Calculate collision efficiencies of the Wang/ayala kernel
161          ALLOCATE( ec(1:radius_classes,1:radius_classes),  &
162                    ecf(1:radius_classes,1:radius_classes), &
163                    gck(1:radius_classes,1:radius_classes), &
164                    winf(1:radius_classes) )
165
166          DO  k = 1, dissipation_classes
167
168             epsilon = epsclass(k)
169             urms    = 2.02 * ( epsilon / 0.04 )**( 1.0 / 3.0 )
170
171             CALL turbsd
172             CALL turb_enhance_eff
173             CALL effic
174
175             DO  j = 1, radius_classes
176                DO  i = 1, radius_classes
177                   ckernel(i,j,k) = ec(i,j) * gck(i,j) * ecf(i,j)
178                ENDDO
179             ENDDO
180
181          ENDDO
182
183!
184!--       Calculate collision efficiencies of the Hall kernel
185          ALLOCATE( hkernel(1:radius_classes,1:radius_classes), &
186                    hwratio(1:radius_classes,1:radius_classes) )
187
188          CALL fallg
189          CALL effic
190
191          DO  j = 1, radius_classes
192             DO  i =  1, radius_classes
193                hkernel(i,j) = pi * ( radclass(j) + radclass(i) )**2 &
194                                  * ec(i,j) * ABS( winf(j) - winf(i) )
195                ckernel(i,j,0) = hkernel(i,j)  ! hall kernel stored on index 0
196              ENDDO
197          ENDDO
198
199!
200!--       Test output of efficiencies
201          IF ( j == -1 )  THEN
202
203             PRINT*, '*** Hall kernel'
204             WRITE ( *,'(5X,20(F4.0,1X))' ) ( radclass(i)*1.0E6, &
205                                              i = 1,radius_classes )
206             DO  j = 1, radius_classes
207                WRITE ( *,'(F4.0,1X,20(F8.4,1X))' ) radclass(j),  &
208                                          ( hkernel(i,j), i = 1,radius_classes )
209             ENDDO
210
211             DO  k = 1, dissipation_classes
212                DO  i = 1, radius_classes
213                   DO  j = 1, radius_classes
214                      IF ( hkernel(i,j) == 0.0 )  THEN
215                         hwratio(i,j) = 9999999.9
216                      ELSE
217                         hwratio(i,j) = ckernel(i,j,k) / hkernel(i,j)
218                      ENDIF
219                   ENDDO
220                ENDDO
221
222                PRINT*, '*** epsilon = ', epsclass(k)
223                WRITE ( *,'(5X,20(F4.0,1X))' ) ( radclass(i)*1.0E6, &
224                                                 i = 1,radius_classes )
225                DO  j = 1, radius_classes
226!                   WRITE ( *,'(F4.0,1X,20(F4.2,1X))' ) radclass(j)*1.0E6, &
227!                                       ( ckernel(i,j,k), i = 1,radius_classes )
228                   WRITE ( *,'(F4.0,1X,20(F8.4,1X))' ) radclass(j)*1.0E6, &
229                                          ( hwratio(i,j), i = 1,radius_classes )
230                ENDDO
231             ENDDO
232
233          ENDIF
234
235          DEALLOCATE( ec, ecf, epsclass, gck, hkernel, winf )
236
237       ELSEIF( collision_kernel == 'hall'  .OR.  collision_kernel == 'wang' ) &
238       THEN
239!
240!--       Initial settings for Hall- and Wang-Kernel
241!--       To be done: move here parts from turbsd, fallg, ecoll, etc.
242       ENDIF
243
244    END SUBROUTINE init_kernels
245
246
247!------------------------------------------------------------------------------!
248! Calculation of collision kernels during each timestep and for each grid box
249!------------------------------------------------------------------------------!
250    SUBROUTINE recalculate_kernel( i1, j1, k1 )
251
252       USE arrays_3d
253       USE cloud_parameters
254       USE constants
255       USE cpulog
256       USE indices
257       USE interfaces
258       USE particle_attributes
259
260       IMPLICIT NONE
261
262       INTEGER ::  i, i1, j, j1, k1, pend, pstart
263
264
265       pstart = prt_start_index(k1,j1,i1)
266       pend   = prt_start_index(k1,j1,i1) + prt_count(k1,j1,i1) - 1
267       radius_classes = prt_count(k1,j1,i1)
268
269       ALLOCATE( ec(1:radius_classes,1:radius_classes), &
270                 radclass(1:radius_classes), winf(1:radius_classes) )
271
272!
273!--    Store particle radii on the radclass array
274       radclass(1:radius_classes) = particles(pstart:pend)%radius
275
276       IF ( wang_kernel )  THEN
277          epsilon = diss(k1,j1,i1)   ! dissipation rate in m**2/s**3
278       ELSE
279          epsilon = 0.0
280       ENDIF
281       urms    = 2.02 * ( epsilon / 0.04 )**( 0.33333333333 )
282
283       IF ( wang_kernel  .AND.  epsilon > 1.0E-7 )  THEN
284!
285!--       Call routines to calculate efficiencies for the Wang kernel
286          ALLOCATE( gck(1:radius_classes,1:radius_classes), &
287                    ecf(1:radius_classes,1:radius_classes) )
288
289          CALL turbsd
290          CALL turb_enhance_eff
291          CALL effic
292
293          DO  j = 1, radius_classes
294             DO  i =  1, radius_classes
295                ckernel(pstart+i-1,pstart+j-1,1) = ec(i,j) * gck(i,j) * ecf(i,j)
296             ENDDO
297          ENDDO
298
299          DEALLOCATE( gck, ecf )
300
301       ELSE
302!
303!--       Call routines to calculate efficiencies for the Hall kernel
304          CALL fallg
305          CALL effic
306
307          DO  j = 1, radius_classes
308             DO  i =  1, radius_classes
309                ckernel(pstart+i-1,pstart+j-1,1) = pi *                       &
310                                          ( radclass(j) + radclass(i) )**2    &
311                                          * ec(i,j) * ABS( winf(j) - winf(i) )
312             ENDDO
313          ENDDO
314
315       ENDIF
316
317       DEALLOCATE( ec, radclass, winf )
318
319    END SUBROUTINE recalculate_kernel
320
321
322!------------------------------------------------------------------------------!
323! Calculation of gck
324! This is from Aayala 2008b, page 37ff.
325! Necessary input parameters: water density, radii of droplets, air density,
326! air viscosity, turbulent dissipation rate, taylor microscale reynolds number,
327! gravitational acceleration  --> to be replaced by PALM parameters
328!------------------------------------------------------------------------------!
329    SUBROUTINE turbsd
330
331       USE constants
332       USE cloud_parameters
333       USE particle_attributes
334       USE arrays_3d
335       USE control_parameters
336
337       IMPLICIT NONE
338
339       INTEGER ::  i, j
340
341       LOGICAL, SAVE ::  first = .TRUE.
342
343       REAL ::  ao, ao_gr, bbb, be, b1, b2, ccc, c1, c1_gr, c2, d1, d2, eta, &
344                e1, e2, fao_gr, fr, grfin, lambda, lambda_re, lf, rc, rrp,   &
345                sst, tauk, tl, t2, tt, t1, vk, vrms1xy, vrms2xy, v1, v1v2xy, &
346                v1xysq, v2, v2xysq, wrfin, wrgrav2, wrtur2xy, xx, yy, z
347
348       REAL, DIMENSION(1:radius_classes) ::  st, tau
349
350
351!
352!--    Initial assignment of constants
353       IF ( first )  THEN
354
355          first = .FALSE.
356
357       ENDIF
358
359       lambda    = urms * SQRT( 15.0 * molecular_viscosity / epsilon )    ! in m
360       lambda_re = urms**2 * SQRT( 15.0 / epsilon / molecular_viscosity )
361       tl        = urms**2 / epsilon                       ! in s
362       lf        = 0.5 * urms**3 / epsilon                 ! in m
363       tauk      = SQRT( molecular_viscosity / epsilon )                  ! in s
364       eta       = ( molecular_viscosity**3 / epsilon )**0.25             ! in m
365       vk        = eta / tauk
366
367       ao = ( 11.0 + 7.0 * lambda_re ) / ( 205.0 + lambda_re )
368       tt = SQRT( 2.0 * lambda_re / ( SQRT( 15.0 ) * ao ) ) * tauk   ! in s
369
370       CALL fallg    ! gives winf in m/s
371
372       DO  i = 1, radius_classes
373          tau(i) = winf(i) / g    ! in s
374          st(i)  = tau(i) / tauk
375       ENDDO
376
377!
378!--    Calculate wr (from Aayala 2008b, page 38f)
379       z   = tt / tl
380       be  = SQRT( 2.0 ) * lambda / lf
381       bbb = SQRT( 1.0 - 2.0 * be**2 )
382       d1  = ( 1.0 + bbb ) / ( 2.0 * bbb )
383       e1  = lf * ( 1.0 + bbb ) * 0.5   ! in m
384       d2  = ( 1.0 - bbb ) * 0.5 / bbb
385       e2  = lf * ( 1.0 - bbb ) * 0.5   ! in m
386       ccc = SQRT( 1.0 - 2.0 * z**2 )
387       b1  = ( 1.0 + ccc ) * 0.5 / ccc
388       c1  = tl * ( 1.0 + ccc ) * 0.5   ! in s
389       b2  = ( 1.0 - ccc ) * 0.5 / ccc
390       c2  = tl * ( 1.0 - ccc ) * 0.5   ! in s
391
392       DO  i = 1, radius_classes
393
394          v1 = winf(i)        ! in m/s
395          t1 = tau(i)         ! in s
396
397          DO  j = 1, i
398             rrp = radclass(i) + radclass(j)
399             v2  = winf(j)                                 ! in m/s
400             t2  = tau(j)                                  ! in s
401
402             v1xysq  = b1 * d1 * phi_w(c1,e1,v1,t1) - b1 * d2 * phi_w(c1,e2,v1,t1) &
403                     - b2 * d1 * phi_w(c2,e1,v1,t1) + b2 * d2 * phi_w(c2,e2,v1,t1)
404             v1xysq  = v1xysq * urms**2 / t1                ! in m**2/s**2
405             vrms1xy = SQRT( v1xysq )                       ! in m/s
406
407             v2xysq  = b1 * d1 * phi_w(c1,e1,v2,t2) - b1 * d2 * phi_w(c1,e2,v2,t2) &
408                     - b2 * d1 * phi_w(c2,e1,v2,t2) + b2 * d2 * phi_w(c2,e2,v2,t2)
409             v2xysq  = v2xysq * urms**2 / t2                ! in m**2/s**2
410             vrms2xy = SQRT( v2xysq )                       ! in m/s
411
412             IF ( winf(i) >= winf(j) )  THEN
413                v1 = winf(i)
414                t1 = tau(i)
415                v2 = winf(j)
416                t2 = tau(j)
417             ELSE
418                v1 = winf(j)
419                t1 = tau(j)
420                v2 = winf(i)
421                t2 = tau(i)
422             ENDIF
423
424             v1v2xy   =  b1 * d1 * zhi(c1,e1,v1,t1,v2,t2) - &
425                         b1 * d2 * zhi(c1,e2,v1,t1,v2,t2) - &
426                         b2 * d1 * zhi(c2,e1,v1,t1,v2,t2) + &
427                         b2 * d2* zhi(c2,e2,v1,t1,v2,t2)
428             fr       = d1 * EXP( -rrp / e1 ) - d2 * EXP( -rrp / e2 )
429             v1v2xy   = v1v2xy * fr * urms**2 / tau(i) / tau(j)  ! in m**2/s**2
430             wrtur2xy = vrms1xy**2 + vrms2xy**2 - 2.0 * v1v2xy   ! in m**2/s**2
431             IF ( wrtur2xy < 0.0 )  wrtur2xy = 0.0
432             wrgrav2  = pi / 8.0 * ( winf(j) - winf(i) )**2
433             wrfin    = SQRT( ( 2.0 / pi ) * ( wrtur2xy + wrgrav2) )   ! in m/s
434
435!
436!--          Calculate gr
437             IF ( st(j) > st(i) )  THEN
438                sst = st(j)
439             ELSE
440                sst = st(i)
441             ENDIF
442
443             xx = -0.1988 * sst**4 + 1.5275 * sst**3 - 4.2942 * sst**2 + &
444                   5.3406 * sst
445             IF ( xx < 0.0 )  xx = 0.0
446             yy = 0.1886 * EXP( 20.306 / lambda_re )
447
448             c1_gr  =  xx / ( g / vk * tauk )**yy
449
450             ao_gr  = ao + ( pi / 8.0) * ( g / vk * tauk )**2
451             fao_gr = 20.115 * SQRT( ao_gr / lambda_re )
452             rc     = SQRT( fao_gr * ABS( st(j) - st(i) ) ) * eta   ! in cm
453
454             grfin  = ( ( eta**2 + rc**2 ) / ( rrp**2 + rc**2) )**( c1_gr*0.5 )
455             IF ( grfin < 1.0 )  grfin = 1.0
456
457             gck(i,j) = 2.0 * pi * rrp**2 * wrfin * grfin           ! in cm**3/s
458             gck(j,i) = gck(i,j)
459
460          ENDDO
461       ENDDO
462
463    END SUBROUTINE turbsd
464
465
466!------------------------------------------------------------------------------!
467! phi_w as a function
468!------------------------------------------------------------------------------!
469    REAL FUNCTION phi_w( a, b, vsett, tau0 )
470
471       IMPLICIT NONE
472
473       REAL ::  a, aa1, b, tau0, vsett
474
475       aa1 = 1.0 / tau0 + 1.0 / a + vsett / b
476       phi_w = 1.0 / aa1  - 0.5 * vsett / b / aa1**2  ! in s
477
478    END FUNCTION phi_w
479
480
481!------------------------------------------------------------------------------!
482! zhi as a function
483!------------------------------------------------------------------------------!
484    REAL FUNCTION zhi( a, b, vsett1, tau1, vsett2, tau2 )
485
486       IMPLICIT NONE
487
488       REAL ::  a, aa1, aa2, aa3, aa4, aa5, aa6, b, tau1, tau2, vsett1, vsett2
489
490       aa1 = vsett2 / b - 1.0 / tau2 - 1.0 / a
491       aa2 = vsett1 / b + 1.0 / tau1 + 1.0 / a
492       aa3 = ( vsett1 - vsett2 ) / b + 1.0 / tau1 + 1.0 / tau2
493       aa4 = ( vsett2 / b )**2 - ( 1.0 / tau2 + 1.0 / a )**2
494       aa5 = vsett2 / b + 1.0 / tau2 + 1.0 / a
495       aa6 = 1.0 / tau1 - 1.0 / a + ( 1.0 / tau2 + 1.0 / a) * vsett1 / vsett2
496       zhi = (1.0 / aa1 - 1.0 / aa2 ) * ( vsett1 - vsett2 ) * 0.5 / b / aa3**2 &
497           + (4.0 / aa4 - 1.0 / aa5**2 - 1.0 / aa1**2 ) * vsett2 * 0.5 / b /aa6&
498           + (2.0 * ( b / aa2 - b / aa1 ) - vsett1 / aa2**2 + vsett2 / aa1**2 )&
499           * 0.5 / b / aa3      ! in s**2
500
501    END FUNCTION zhi
502
503
504!------------------------------------------------------------------------------!
505! Calculation of terminal velocity winf following Equations 10-138 to 10-145
506! from (Pruppacher and Klett, 1997)
507!------------------------------------------------------------------------------!
508    SUBROUTINE fallg
509
510       USE constants
511       USE cloud_parameters
512       USE particle_attributes
513       USE arrays_3d
514       USE control_parameters
515
516       IMPLICIT NONE
517
518       INTEGER ::  i, j
519
520       LOGICAL, SAVE ::  first = .TRUE.
521
522       REAL, SAVE ::  cunh, eta, phy, py, rho_a, sigma, stb, stok, &
523                      t0, xlamb
524
525       REAL ::  bond, x, xrey, y
526
527       REAL, DIMENSION(1:7), SAVE  ::  b
528       REAL, DIMENSION(1:6), SAVE  ::  c
529
530!
531!--    Initial assignment of constants
532       IF ( first )  THEN
533
534          first = .FALSE.
535          b = (/  -0.318657E1,  0.992696E0, -0.153193E-2, -0.987059E-3, &
536                 -0.578878E-3, 0.855176E-4, -0.327815E-5 /)
537          c = (/  -0.500015E1,  0.523778E1,  -0.204914E1,   0.475294E0, &
538                 -0.542819E-1, 0.238449E-2 /)
539
540!
541!--       Parameter values for p = 1013,25 hPa and T = 293,15 K
542          eta   = 1.818E-5         ! in kg/(m s)
543          xlamb = 6.6E-8           ! in m
544          rho_a = 1.204            ! in kg/m**3
545          cunh  = 1.26 * xlamb     ! in m
546          sigma = 0.07363          ! in kg/s**2
547          stok  = 2.0  * g * ( rho_l - rho_a ) / ( 9.0 * eta ) ! in 1/(m s)
548          stb   = 32.0 * rho_a * ( rho_l - rho_a) * g / (3.0 * eta * eta)
549          phy   = sigma**3 * rho_a**2 / ( eta**4 * g * ( rho_l - rho_a ) )
550          py    = phy**( 1.0 / 6.0 )
551
552       ENDIF
553
554       DO  j = 1, radius_classes
555
556          IF ( radclass(j) <= 1.0E-5 ) THEN
557
558             winf(j) = stok * ( radclass(j)**2 + cunh * radclass(j) )
559
560          ELSEIF ( radclass(j) > 1.0E-5  .AND.  radclass(j) <= 5.35E-4 )  THEN
561
562             x = LOG( stb * radclass(j)**3 )
563             y = 0.0
564
565             DO  i = 1, 7
566                y = y + b(i) * x**(i-1)
567             ENDDO
568!
569!--          Note: this Eq. is wrong in (Pruppacher and Klett, 1997, p. 418)
570!--          for correct version see (Beard, 1976)
571             xrey = ( 1.0 + cunh / radclass(j) ) * EXP( y ) 
572
573             winf(j) = xrey * eta / ( 2.0 * rho_a * radclass(j) )
574
575          ELSEIF ( radclass(j) > 5.35E-4 )  THEN
576
577             IF ( radclass(j) > 0.0035 )  THEN
578                bond = g * ( rho_l - rho_a ) * 0.0035**2 / sigma
579             ELSE
580               bond = g * ( rho_l - rho_a ) * radclass(j)**2 / sigma
581             ENDIF
582
583             x = LOG( 16.0 * bond * py / 3.0 )
584             y = 0.0
585
586             DO  i = 1, 6
587                y = y + c(i) * x**(i-1)
588             ENDDO
589
590             xrey = py * EXP( y )
591
592             IF ( radclass(j) > 0.0035 )  THEN
593                winf(j) = xrey * eta / ( 2.0 * rho_a * 0.0035 )
594             ELSE
595                winf(j) = xrey * eta / ( 2.0 * rho_a * radclass(j) )
596             ENDIF
597
598          ENDIF
599
600       ENDDO
601
602    END SUBROUTINE fallg
603
604
605!------------------------------------------------------------------------------!
606! Calculation of collision efficencies for the Hall kernel
607!------------------------------------------------------------------------------!
608    SUBROUTINE effic
609
610       USE arrays_3d
611       USE cloud_parameters
612       USE constants
613       USE particle_attributes
614
615       IMPLICIT NONE
616
617       INTEGER ::  i, iq, ir, j, k, kk
618
619       INTEGER, DIMENSION(:), ALLOCATABLE ::  ira
620
621       LOGICAL, SAVE ::  first = .TRUE.
622
623       REAL ::  ek, particle_radius, pp, qq, rq
624
625       REAL, DIMENSION(1:21), SAVE ::  rat
626       REAL, DIMENSION(1:15), SAVE ::  r0
627       REAL, DIMENSION(1:15,1:21), SAVE ::  ecoll
628
629!
630!--    Initial assignment of constants
631       IF ( first )  THEN
632
633         first = .FALSE.
634         r0  = (/ 6.0, 8.0, 10.0, 15.0, 20.0, 25.0, 30.0, 40.0, 50.0, 60., &
635                  70.0, 100.0, 150.0, 200.0, 300.0 /)
636         rat = (/ 0.00, 0.05, 0.10, 0.15, 0.20, 0.25, 0.30, 0.35, 0.40, 0.45, &
637                  0.50, 0.55, 0.60, 0.65, 0.70, 0.75, 0.80, 0.85, 0.90, 0.95, &
638                  1.00 /)
639
640         ecoll(:,1) = (/0.001, 0.001, 0.001, 0.001, 0.001, 0.001, 0.001, &
641                        0.001, 0.001, 0.001, 0.001, 0.001, 0.001, 0.001, 0.001/)
642         ecoll(:,2) = (/0.003, 0.003, 0.003, 0.004, 0.005, 0.005, 0.005, &
643                        0.010, 0.100, 0.050, 0.200, 0.500, 0.770, 0.870, 0.970/)
644         ecoll(:,3) = (/0.007, 0.007, 0.007, 0.008, 0.009, 0.010, 0.010, &
645                        0.070, 0.400, 0.430, 0.580, 0.790, 0.930, 0.960, 1.000/)
646         ecoll(:,4) = (/0.009, 0.009, 0.009, 0.012, 0.015, 0.010, 0.020, &
647                        0.280, 0.600, 0.640, 0.750, 0.910, 0.970, 0.980, 1.000/)
648         ecoll(:,5) = (/0.014, 0.014, 0.014, 0.015, 0.016, 0.030, 0.060, &
649                        0.500, 0.700, 0.770, 0.840, 0.950, 0.970, 1.000, 1.000/)
650         ecoll(:,6) = (/0.017, 0.017, 0.017, 0.020, 0.022, 0.060, 0.100, &
651                        0.620, 0.780, 0.840, 0.880, 0.950, 1.000, 1.000, 1.000/)
652         ecoll(:,7) = (/0.030, 0.030, 0.024, 0.022, 0.032, 0.062, 0.200, &
653                        0.680, 0.830, 0.870, 0.900, 0.950, 1.000, 1.000, 1.000/)
654         ecoll(:,8) = (/0.025, 0.025, 0.025, 0.036, 0.043, 0.130, 0.270, &
655                        0.740, 0.860, 0.890, 0.920, 1.000, 1.000, 1.000, 1.000/)
656         ecoll(:,9) = (/0.027, 0.027, 0.027, 0.040, 0.052, 0.200, 0.400, &
657                        0.780, 0.880, 0.900, 0.940, 1.000, 1.000, 1.000, 1.000/)
658         ecoll(:,10)= (/0.030, 0.030, 0.030, 0.047, 0.064, 0.250, 0.500, &
659                        0.800, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
660         ecoll(:,11)= (/0.040, 0.040, 0.033, 0.037, 0.068, 0.240, 0.550, &
661                        0.800, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
662         ecoll(:,12)= (/0.035, 0.035, 0.035, 0.055, 0.079, 0.290, 0.580, &
663                        0.800, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
664         ecoll(:,13)= (/0.037, 0.037, 0.037, 0.062, 0.082, 0.290, 0.590, &
665                        0.780, 0.900, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
666         ecoll(:,14)= (/0.037, 0.037, 0.037, 0.060, 0.080, 0.290, 0.580, &
667                        0.770, 0.890, 0.910, 0.950, 1.000, 1.000, 1.000, 1.000/)
668         ecoll(:,15)= (/0.037, 0.037, 0.037, 0.041, 0.075, 0.250, 0.540, &
669                        0.760, 0.880, 0.920, 0.950, 1.000, 1.000, 1.000, 1.000/)
670         ecoll(:,16)= (/0.037, 0.037, 0.037, 0.052, 0.067, 0.250, 0.510, &
671                        0.770, 0.880, 0.930, 0.970, 1.000, 1.000, 1.000, 1.000/)
672         ecoll(:,17)= (/0.037, 0.037, 0.037, 0.047, 0.057, 0.250, 0.490, &
673                        0.770, 0.890, 0.950, 1.000, 1.000, 1.000, 1.000, 1.000/)
674         ecoll(:,18)= (/0.036, 0.036, 0.036, 0.042, 0.048, 0.230, 0.470, &
675                        0.780, 0.920, 1.000, 1.020, 1.020, 1.020, 1.020, 1.020/)
676         ecoll(:,19)= (/0.040, 0.040, 0.035, 0.033, 0.040, 0.112, 0.450, &
677                        0.790, 1.010, 1.030, 1.040, 1.040, 1.040, 1.040, 1.040/)
678         ecoll(:,20)= (/0.033, 0.033, 0.033, 0.033, 0.033, 0.119, 0.470, &
679                        0.950, 1.300, 1.700, 2.300, 2.300, 2.300, 2.300, 2.300/)
680         ecoll(:,21)= (/0.027, 0.027, 0.027, 0.027, 0.027, 0.125, 0.520, &
681                        1.400, 2.300, 3.000, 4.000, 4.000, 4.000, 4.000, 4.000/)
682       ENDIF
683
684!
685!--    Calculate the radius class index of particles with respect to array r
686!--    Radius has to be in µm
687       ALLOCATE( ira(1:radius_classes) )
688       DO  j = 1, radius_classes
689          particle_radius = radclass(j) * 1.0E6
690          DO  k = 1, 15
691             IF ( particle_radius < r0(k) )  THEN
692                ira(j) = k
693                EXIT
694             ENDIF
695          ENDDO
696          IF ( particle_radius >= r0(15) )  ira(j) = 16
697       ENDDO
698
699!
700!--    Two-dimensional linear interpolation of the collision efficiency.
701!--    Radius has to be in µm
702       DO  j = 1, radius_classes
703          DO  i = 1, j
704
705             ir = ira(j)
706             rq = radclass(i) / radclass(j)
707             iq = INT( rq * 20 ) + 1
708             iq = MAX( iq , 2)
709
710             IF ( ir < 16 )  THEN
711                IF ( ir >= 2 )  THEN
712                   pp = ( ( radclass(j) * 1.0E06 ) - r0(ir-1) ) / &
713                        ( r0(ir) - r0(ir-1) )
714                   qq = ( rq- rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
715                   ec(j,i) = ( 1.0-pp ) * ( 1.0-qq ) * ecoll(ir-1,iq-1)  &
716                             + pp * ( 1.0-qq ) * ecoll(ir,iq-1)          &
717                             + qq * ( 1.0-pp ) * ecoll(ir-1,iq)          &
718                             + pp * qq * ecoll(ir,iq)
719                ELSE
720                   qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
721                   ec(j,i) = (1.0-qq) * ecoll(1,iq-1) + qq * ecoll(1,iq)
722                ENDIF
723             ELSE
724                qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
725                ek = ( 1.0 - qq ) * ecoll(15,iq-1) + qq * ecoll(15,iq)
726                ec(j,i) = MIN( ek, 1.0 )
727             ENDIF
728
729             ec(i,j) = ec(j,i)
730             IF ( ec(i,j) < 1.0E-20 )  ec(i,j) = 0.0
731
732          ENDDO
733       ENDDO
734
735       DEALLOCATE( ira )
736
737    END SUBROUTINE effic
738
739
740!------------------------------------------------------------------------------!
741! Calculation of enhancement factor for collision efficencies due to turbulence
742!------------------------------------------------------------------------------!
743    SUBROUTINE turb_enhance_eff
744
745       USE constants
746       USE cloud_parameters
747       USE particle_attributes
748       USE arrays_3d
749
750       IMPLICIT NONE
751
752       INTEGER :: i, ik, iq, ir, j, k, kk
753
754       INTEGER, DIMENSION(:), ALLOCATABLE ::  ira
755
756       REAL ::  particle_radius, pp, qq, rq, x1, x2, x3, y1, y2, y3
757
758       LOGICAL, SAVE ::  first = .TRUE.
759
760       REAL, DIMENSION(1:11), SAVE ::  rat
761       REAL, DIMENSION(1:7), SAVE  ::  r0
762       REAL, DIMENSION(1:7,1:11), SAVE ::  ecoll_100, ecoll_400
763
764!
765!--    Initial assignment of constants
766       IF ( first )  THEN
767
768          first = .FALSE.
769
770          r0  = (/ 10.0, 20.0, 30.0, 40.0, 50.0, 60.0, 100.0 /)
771          rat = (/ 0.0, 0.1, 0.2, 0.3, 0.4, 0.5, 0.6, 0.7, 0.8, 0.9, 1.0 /)
772!
773!--       for 100 cm**2/s**3
774          ecoll_100(:,1) = (/1.74,  1.74,  1.773, 1.49,  1.207,  1.207,  1.0 /)
775          ecoll_100(:,2) = (/1.46,  1.46,  1.421, 1.245, 1.069,  1.069,  1.0 /)
776          ecoll_100(:,3) = (/1.32,  1.32,  1.245, 1.123, 1.000,  1.000,  1.0 /)
777          ecoll_100(:,4) = (/1.250, 1.250, 1.148, 1.087, 1.025,  1.025,  1.0 /)
778          ecoll_100(:,5) = (/1.186, 1.186, 1.066, 1.060, 1.056,  1.056,  1.0 /)
779          ecoll_100(:,6) = (/1.045, 1.045, 1.000, 1.014, 1.028,  1.028,  1.0 /)
780          ecoll_100(:,7) = (/1.070, 1.070, 1.030, 1.038, 1.046,  1.046,  1.0 /)
781          ecoll_100(:,8) = (/1.000, 1.000, 1.054, 1.042, 1.029,  1.029,  1.0 /)
782          ecoll_100(:,9) = (/1.223, 1.223, 1.117, 1.069, 1.021,  1.021,  1.0 /)
783          ecoll_100(:,10)= (/1.570, 1.570, 1.244, 1.166, 1.088,  1.088,  1.0 /)
784          ecoll_100(:,11)= (/20.3,  20.3,  14.6 , 8.61,  2.60,   2.60 ,  1.0 /)
785!
786!--       for 400 cm**2/s**3
787          ecoll_400(:,1) = (/4.976, 4.976,  3.593, 2.519, 1.445,  1.445,  1.0 /)
788          ecoll_400(:,2) = (/2.984, 2.984,  2.181, 1.691, 1.201,  1.201,  1.0 /)
789          ecoll_400(:,3) = (/1.988, 1.988,  1.475, 1.313, 1.150,  1.150,  1.0 /)
790          ecoll_400(:,4) = (/1.490, 1.490,  1.187, 1.156, 1.126,  1.126,  1.0 /)
791          ecoll_400(:,5) = (/1.249, 1.249,  1.088, 1.090, 1.092,  1.092,  1.0 /)
792          ecoll_400(:,6) = (/1.139, 1.139,  1.130, 1.091, 1.051,  1.051,  1.0 /)
793          ecoll_400(:,7) = (/1.220, 1.220,  1.190, 1.138, 1.086,  1.086,  1.0 /)
794          ecoll_400(:,8) = (/1.325, 1.325,  1.267, 1.165, 1.063,  1.063,  1.0 /)
795          ecoll_400(:,9) = (/1.716, 1.716,  1.345, 1.223, 1.100,  1.100,  1.0 /)
796          ecoll_400(:,10)= (/3.788, 3.788,  1.501, 1.311, 1.120,  1.120,  1.0 /)
797          ecoll_400(:,11)= (/36.52, 36.52,  19.16, 22.80,  26.0,   26.0,  1.0 /)
798
799       ENDIF
800
801!
802!--    Calculate the radius class index of particles with respect to array r0
803!--    Radius has to be in µm
804       ALLOCATE( ira(1:radius_classes) )
805
806       DO  j = 1, radius_classes
807          particle_radius = radclass(j) * 1.0E6
808          DO  k = 1, 7
809             IF ( particle_radius < r0(k) )  THEN
810                ira(j) = k
811                EXIT
812             ENDIF
813          ENDDO
814          IF ( particle_radius >= r0(7) )  ira(j) = 8
815       ENDDO
816
817!
818!--    Two-dimensional linear interpolation of the collision efficiencies
819!--    Radius has to be in µm
820       DO  j =  1, radius_classes
821          DO  i = 1, j
822
823             ir = ira(j)
824             rq = radclass(i) / radclass(j)
825
826             DO  kk = 2, 11
827                IF ( rq <= rat(kk) )  THEN
828                   iq = kk
829                   EXIT
830                ENDIF
831             ENDDO
832
833             y1 = 0.0001      ! for 0 m**2/s**3
834
835             IF ( ir < 8 )  THEN
836                IF ( ir >= 2 )  THEN
837                   pp = ( radclass(j)*1.0E6 - r0(ir-1) ) / ( r0(ir) - r0(ir-1) )
838                   qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
839                   y2 = ( 1.0-pp ) * ( 1.0-qq ) * ecoll_100(ir-1,iq-1) +  &
840                                pp * ( 1.0-qq ) * ecoll_100(ir,iq-1)   +  &
841                                qq * ( 1.0-pp ) * ecoll_100(ir-1,iq)   +  &
842                                pp * qq         * ecoll_100(ir,iq)
843                   y3 = ( 1.0-pp ) * ( 1.0-qq ) * ecoll_400(ir-1,iq-1) +  &
844                                pp * ( 1.0-qq ) * ecoll_400(ir,iq-1)   +  &
845                                qq * ( 1.0-pp ) * ecoll_400(ir-1,iq)   +  &
846                                pp * qq         * ecoll_400(ir,iq)
847                ELSE
848                   qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
849                   y2 = ( 1.0-qq ) * ecoll_100(1,iq-1) + qq * ecoll_100(1,iq)
850                   y3 = ( 1.0-qq ) * ecoll_400(1,iq-1) + qq * ecoll_400(1,iq)
851                ENDIF
852             ELSE
853                qq = ( rq - rat(iq-1) ) / ( rat(iq) - rat(iq-1) )
854                y2 = ( 1.0-qq ) * ecoll_100(7,iq-1) + qq * ecoll_100(7,iq)
855                y3 = ( 1.0-qq ) * ecoll_400(7,iq-1) + qq * ecoll_400(7,iq)
856             ENDIF
857!
858!--          Linear interpolation of dissipation rate in m**2/s**3
859             IF ( epsilon <= 0.01 )  THEN
860                ecf(j,i) = ( epsilon - 0.01 ) / (   0.0 - 0.01 ) * y1 &
861                         + ( epsilon -   0.0 ) / ( 0.01 -   0.0 ) * y2
862             ELSEIF ( epsilon <= 0.06 )  THEN
863                ecf(j,i) = ( epsilon - 0.04 ) / ( 0.01 - 0.04 ) * y2 &
864                         + ( epsilon - 0.01 ) / ( 0.04 - 0.01 ) * y3
865             ELSE
866                ecf(j,i) = (   0.06 - 0.04 ) / ( 0.01 - 0.04 ) * y2 &
867                         + (   0.06 - 0.01 ) / ( 0.04 - 0.01 ) * y3
868             ENDIF
869
870             IF ( ecf(j,i) < 1.0 )  ecf(j,i) = 1.0
871
872             ecf(i,j) = ecf(j,i)
873
874          ENDDO
875       ENDDO
876
877    END SUBROUTINE turb_enhance_eff
878
879
880
881    SUBROUTINE collision_efficiency_rogers( mean_r, r, e)
882!------------------------------------------------------------------------------!
883! Collision efficiencies from table 8.2 in Rogers and Yau (1989, 3rd edition).
884! Values are calculated from table by bilinear interpolation.
885!------------------------------------------------------------------------------!
886
887       IMPLICIT NONE
888
889       INTEGER       ::  i, j, k
890
891       LOGICAL, SAVE ::  first = .TRUE.
892
893       REAL          ::  aa, bb, cc, dd, dx, dy, e, gg, mean_r, mean_rm, r, &
894                         rm, x, y
895
896       REAL, DIMENSION(1:9), SAVE      ::  collected_r = 0.0
897       REAL, DIMENSION(1:19), SAVE     ::  collector_r = 0.0
898       REAL, DIMENSION(1:9,1:19), SAVE ::  ef = 0.0
899
900       mean_rm = mean_r * 1.0E06
901       rm      = r      * 1.0E06
902
903       IF ( first )  THEN
904
905          collected_r = (/ 2.0, 3.0, 4.0, 6.0, 8.0, 10.0, 15.0, 20.0, 25.0 /)
906          collector_r = (/ 10.0, 20.0, 30.0, 40.0, 50.0, 60.0, 80.0, 100.0,  &
907                           150.0, 200.0, 300.0, 400.0, 500.0, 600.0, 1000.0, &
908                           1400.0, 1800.0, 2400.0, 3000.0 /)
909
910          ef(:,1) = (/0.017, 0.027, 0.037, 0.052, 0.052, 0.052, 0.052, 0.0, &
911                      0.0 /)
912          ef(:,2) = (/0.001, 0.016, 0.027, 0.060, 0.12, 0.17, 0.17, 0.17, 0.0 /)
913          ef(:,3) = (/0.001, 0.001, 0.02,  0.13,  0.28, 0.37, 0.54, 0.55, 0.47/)
914          ef(:,4) = (/0.001, 0.001, 0.02,  0.23,  0.4,  0.55, 0.7,  0.75, 0.75/)
915          ef(:,5) = (/0.01,  0.01,  0.03,  0.3,   0.4,  0.58, 0.73, 0.75, 0.79/)
916          ef(:,6) = (/0.01,  0.01,  0.13,  0.38,  0.57, 0.68, 0.80, 0.86, 0.91/)
917          ef(:,7) = (/0.01,  0.085, 0.23,  0.52,  0.68, 0.76, 0.86, 0.92, 0.95/)
918          ef(:,8) = (/0.01,  0.14,  0.32,  0.60,  0.73, 0.81, 0.90, 0.94, 0.96/)
919          ef(:,9) = (/0.025, 0.25,  0.43,  0.66,  0.78, 0.83, 0.92, 0.95, 0.96/)
920          ef(:,10)= (/0.039, 0.3,   0.46,  0.69,  0.81, 0.87, 0.93, 0.95, 0.96/)
921          ef(:,11)= (/0.095, 0.33,  0.51,  0.72,  0.82, 0.87, 0.93, 0.96, 0.97/)
922          ef(:,12)= (/0.098, 0.36,  0.51,  0.73,  0.83, 0.88, 0.93, 0.96, 0.97/)
923          ef(:,13)= (/0.1,   0.36,  0.52,  0.74,  0.83, 0.88, 0.93, 0.96, 0.97/)
924          ef(:,14)= (/0.17,  0.4,   0.54,  0.72,  0.83, 0.88, 0.94, 0.98, 1.0 /)
925          ef(:,15)= (/0.15,  0.37,  0.52,  0.74,  0.82, 0.88, 0.94, 0.98, 1.0 /)
926          ef(:,16)= (/0.11,  0.34,  0.49,  0.71,  0.83, 0.88, 0.94, 0.95, 1.0 /)
927          ef(:,17)= (/0.08,  0.29,  0.45,  0.68,  0.8,  0.86, 0.96, 0.94, 1.0 /)
928          ef(:,18)= (/0.04,  0.22,  0.39,  0.62,  0.75, 0.83, 0.92, 0.96, 1.0 /)
929          ef(:,19)= (/0.02,  0.16,  0.33,  0.55,  0.71, 0.81, 0.90, 0.94, 1.0 /)
930
931       ENDIF
932
933       DO  k = 1, 8
934          IF ( collected_r(k) <= mean_rm )  i = k
935       ENDDO
936
937       DO  k = 1, 18
938          IF ( collector_r(k) <= rm )  j = k
939       ENDDO
940
941       IF ( rm < 10.0 )  THEN
942          e = 0.0
943       ELSEIF ( mean_rm < 2.0 )  THEN
944          e = 0.001
945       ELSEIF ( mean_rm >= 25.0 )  THEN
946          IF( j <= 2 )  e = 0.0
947          IF( j == 3 )  e = 0.47
948          IF( j == 4 )  e = 0.8
949          IF( j == 5 )  e = 0.9
950          IF( j >=6  )  e = 1.0
951       ELSEIF ( rm >= 3000.0 )  THEN
952          IF( i == 1 )  e = 0.02
953          IF( i == 2 )  e = 0.16
954          IF( i == 3 )  e = 0.33
955          IF( i == 4 )  e = 0.55
956          IF( i == 5 )  e = 0.71
957          IF( i == 6 )  e = 0.81
958          IF( i == 7 )  e = 0.90
959          IF( i >= 8 )  e = 0.94
960       ELSE
961          = mean_rm - collected_r(i)
962          y  = rm - collector_r(j)
963          dx = collected_r(i+1) - collected_r(i)
964          dy = collector_r(j+1) - collector_r(j)
965          aa = x**2 + y**2
966          bb = ( dx - x )**2 + y**2
967          cc = x**2 + ( dy - y )**2
968          dd = ( dx - x )**2 + ( dy - y )**2
969          gg = aa + bb + cc + dd
970
971          e = ( (gg-aa)*ef(i,j) + (gg-bb)*ef(i+1,j) + (gg-cc)*ef(i,j+1) + &
972                (gg-dd)*ef(i+1,j+1) ) / (3.0*gg)
973       ENDIF
974
975    END SUBROUTINE collision_efficiency_rogers
976
977 END MODULE lpm_collision_kernels_mod
Note: See TracBrowser for help on using the repository browser.