source: palm/trunk/SOURCE/lagrangian_particle_model_mod.f90 @ 4336

Last change on this file since 4336 was 4336, checked in by raasch, 17 months ago

bugfix: wrong header output of particle group features (density ratio) in case of restarts corrected

  • Property svn:keywords set to Id
File size: 353.9 KB
Line 
1!> @file lagrangian_particle_model_mod.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2019 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: lagrangian_particle_model_mod.f90 4336 2019-12-13 10:12:05Z raasch $
27! bugfix: wrong header output of particle group features (density ratio) in case
28! of restarts corrected
29!
30! 4329 2019-12-10 15:46:36Z motisi
31! Renamed wall_flags_0 to wall_flags_static_0
32!
33! 4282 2019-10-29 16:18:46Z schwenkel
34! Bugfix of particle timeseries in case of more than one particle group
35!
36! 4277 2019-10-28 16:53:23Z schwenkel
37! Bugfix: Added first_call_lpm in use statement
38!
39! 4276 2019-10-28 16:03:29Z schwenkel
40! Modularize lpm: Move conditions in time intergration to module
41!
42! 4275 2019-10-28 15:34:55Z schwenkel
43! Change call of simple predictor corrector method, i.e. two divergence free
44! velocitiy fields are now used.
45!
46! 4232 2019-09-20 09:34:22Z knoop
47! Removed INCLUDE "mpif.h", as it is not needed because of USE pegrid
48!
49! 4195 2019-08-28 13:44:27Z schwenkel
50! Bugfix for simple_corrector interpolation method in case of ocean runs and
51! output particle advection interpolation method into header
52!
53! 4182 2019-08-22 15:20:23Z scharf
54! Corrected "Former revisions" section
55!
56! 4168 2019-08-16 13:50:17Z suehring
57! Replace function get_topography_top_index by topo_top_ind
58!
59! 4145 2019-08-06 09:55:22Z schwenkel
60! Some reformatting
61!
62! 4144 2019-08-06 09:11:47Z raasch
63! relational operators .EQ., .NE., etc. replaced by ==, /=, etc.
64!
65! 4143 2019-08-05 15:14:53Z schwenkel
66! Rename variable and change select case to if statement
67!
68! 4122 2019-07-26 13:11:56Z schwenkel
69! Implement reset method as bottom boundary condition
70!
71! 4121 2019-07-26 10:01:22Z schwenkel
72! Implementation of an simple method for interpolating the velocities to
73! particle position
74!
75! 4114 2019-07-23 14:09:27Z schwenkel
76! Bugfix: Added working precision for if statement
77!
78! 4054 2019-06-27 07:42:18Z raasch
79! bugfix for calculating the minimum particle time step
80!
81! 4044 2019-06-19 12:28:27Z schwenkel
82! Bugfix in case of grid strecting: corrected calculation of k-Index
83!
84! 4043 2019-06-18 16:59:00Z schwenkel
85! Remove min_nr_particle, Add lpm_droplet_interactions_ptq into module
86!
87! 4028 2019-06-13 12:21:37Z schwenkel
88! Further modularization of particle code components
89!
90! 4020 2019-06-06 14:57:48Z schwenkel
91! Removing submodules
92!
93! 4018 2019-06-06 13:41:50Z eckhard
94! Bugfix for former revision
95!
96! 4017 2019-06-06 12:16:46Z schwenkel
97! Modularization of all lagrangian particle model code components
98!
99! 3655 2019-01-07 16:51:22Z knoop
100! bugfix to guarantee correct particle releases in case that the release
101! interval is smaller than the model timestep
102!
103! Revision 1.1  1999/11/25 16:16:06  raasch
104! Initial revision
105!
106!
107! Description:
108! ------------
109!> The embedded LPM allows for studying transport and dispersion processes within
110!> turbulent flows. This model including passive particles that do not show any
111!> feedback on the turbulent flow. Further also particles with inertia and
112!> cloud droplets ca be simulated explicitly.
113!>
114!> @todo test lcm
115!>       implement simple interpolation method for subgrid scale velocites
116!> @note <Enter notes on the module>
117!> @bug  <Enter bug on the module>
118!------------------------------------------------------------------------------!
119 MODULE lagrangian_particle_model_mod
120
121    USE, INTRINSIC ::  ISO_C_BINDING
122
123    USE arrays_3d,                                                             &
124        ONLY:  de_dx, de_dy, de_dz, dzw, zu, zw,  ql_c, ql_v, ql_vp, hyp,      &
125               pt, q, exner, ql, diss, e, u, v, w, km, ql_1, ql_2, pt_p, q_p,  &
126               d_exner
127 
128    USE averaging,                                                             &
129        ONLY:  ql_c_av, pr_av, pc_av, ql_vp_av, ql_v_av
130
131    USE basic_constants_and_equations_mod,                                     &
132        ONLY: molecular_weight_of_solute, molecular_weight_of_water, magnus,   &
133              pi, rd_d_rv, rho_l, r_v, rho_s, vanthoff, l_v, kappa, g, lv_d_cp
134
135    USE control_parameters,                                                    &
136        ONLY:  bc_dirichlet_l, bc_dirichlet_n, bc_dirichlet_r, bc_dirichlet_s, &
137               cloud_droplets, constant_flux_layer, current_timestep_number,   &
138               dt_3d, dt_3d_reached, first_call_lpm, humidity,                 &
139               dt_3d_reached_l, dt_dopts, dz, initializing_actions,            &
140               intermediate_timestep_count, intermediate_timestep_count_max,   &
141               message_string, molecular_viscosity, ocean_mode,                &
142               particle_maximum_age, iran,                                     & 
143               simulated_time, topography, dopts_time_count,                   &
144               time_since_reference_point, rho_surface, u_gtrans, v_gtrans,    &
145               dz_stretch_level, dz_stretch_level_start
146
147    USE cpulog,                                                                &
148        ONLY:  cpu_log, log_point, log_point_s
149
150    USE indices,                                                               &
151        ONLY:  nx, nxl, nxlg, nxrg, nxr, ny, nyn, nys, nyng, nysg, nz, nzb,    &
152               nzb_max, nzt,nbgp, ngp_2dh_outer,                               &
153               topo_top_ind,                                                   &
154               wall_flags_static_0
155
156    USE kinds
157
158    USE pegrid
159
160    USE particle_attributes
161
162    USE pmc_particle_interface,                                                &
163        ONLY: pmcp_c_get_particle_from_parent, pmcp_p_fill_particle_win,       &
164              pmcp_c_send_particle_to_parent, pmcp_p_empty_particle_win,       &
165              pmcp_p_delete_particles_in_fine_grid_area, pmcp_g_init,          &
166              pmcp_g_print_number_of_particles
167
168    USE pmc_interface,                                                         &
169        ONLY: nested_run
170
171    USE grid_variables,                                                        &
172        ONLY:  ddx, dx, ddy, dy
173
174    USE netcdf_interface,                                                      &
175        ONLY:  netcdf_data_format, netcdf_deflate, dopts_num, id_set_pts,      &
176               id_var_dopts, id_var_time_pts, nc_stat,                         &
177               netcdf_handle_error
178
179    USE random_function_mod,                                                   &
180        ONLY:  random_function
181
182    USE statistics,                                                            &
183        ONLY:  hom
184
185    USE surface_mod,                                                           &
186        ONLY:  bc_h,                                                           &
187               surf_def_h,                                                     &
188               surf_lsm_h,                                                     &
189               surf_usm_h
190
191#if defined( __parallel )  &&  !defined( __mpifh )
192    USE MPI
193#endif
194
195#if defined( __netcdf )
196    USE NETCDF
197#endif
198
199    IMPLICIT NONE
200
201    CHARACTER(LEN=15) ::  aero_species = 'nacl'                   !< aerosol species
202    CHARACTER(LEN=15) ::  aero_type    = 'maritime'               !< aerosol type
203    CHARACTER(LEN=15) ::  bc_par_lr    = 'cyclic'                 !< left/right boundary condition
204    CHARACTER(LEN=15) ::  bc_par_ns    = 'cyclic'                 !< north/south boundary condition
205    CHARACTER(LEN=15) ::  bc_par_b     = 'reflect'                !< bottom boundary condition
206    CHARACTER(LEN=15) ::  bc_par_t     = 'absorb'                 !< top boundary condition
207    CHARACTER(LEN=15) ::  collision_kernel   = 'none'             !< collision kernel
208
209    CHARACTER(LEN=5)  ::  splitting_function = 'gamma'            !< function for calculation critical weighting factor
210    CHARACTER(LEN=5)  ::  splitting_mode     = 'const'            !< splitting mode
211
212    CHARACTER(LEN=25) ::  particle_advection_interpolation = 'trilinear' !< interpolation method for calculatin the particle
213
214    INTEGER(iwp) ::  deleted_particles = 0                        !< number of deleted particles per time step   
215    INTEGER(iwp) ::  i_splitting_mode                             !< dummy for splitting mode
216    INTEGER(iwp) ::  iran_part = -1234567                         !< number for random generator   
217    INTEGER(iwp) ::  max_number_particles_per_gridbox = 100       !< namelist parameter (see documentation)
218    INTEGER(iwp) ::  isf                                          !< dummy for splitting function
219    INTEGER(iwp) ::  number_particles_per_gridbox = -1            !< namelist parameter (see documentation)
220    INTEGER(iwp) ::  number_of_sublayers = 20                     !< number of sublayers for particle velocities betwenn surface and first grid level
221    INTEGER(iwp) ::  offset_ocean_nzt = 0                         !< in case of oceans runs, the vertical index calculations need an offset
222    INTEGER(iwp) ::  offset_ocean_nzt_m1 = 0                      !< in case of oceans runs, the vertical index calculations need an offset
223    INTEGER(iwp) ::  particles_per_point = 1                      !< namelist parameter (see documentation)
224    INTEGER(iwp) ::  radius_classes = 20                          !< namelist parameter (see documentation)
225    INTEGER(iwp) ::  splitting_factor = 2                         !< namelist parameter (see documentation)
226    INTEGER(iwp) ::  splitting_factor_max = 5                     !< namelist parameter (see documentation)
227    INTEGER(iwp) ::  step_dealloc = 100                           !< namelist parameter (see documentation)
228    INTEGER(iwp) ::  total_number_of_particles                    !< total number of particles in the whole model domain
229    INTEGER(iwp) ::  trlp_count_sum                               !< parameter for particle exchange of PEs
230    INTEGER(iwp) ::  trlp_count_recv_sum                          !< parameter for particle exchange of PEs
231    INTEGER(iwp) ::  trrp_count_sum                               !< parameter for particle exchange of PEs
232    INTEGER(iwp) ::  trrp_count_recv_sum                          !< parameter for particle exchange of PEs
233    INTEGER(iwp) ::  trsp_count_sum                               !< parameter for particle exchange of PEs
234    INTEGER(iwp) ::  trsp_count_recv_sum                          !< parameter for particle exchange of PEs
235    INTEGER(iwp) ::  trnp_count_sum                               !< parameter for particle exchange of PEs
236    INTEGER(iwp) ::  trnp_count_recv_sum                          !< parameter for particle exchange of PEs
237
238    LOGICAL ::  lagrangian_particle_model = .FALSE.       !< namelist parameter (see documentation)
239    LOGICAL ::  curvature_solution_effects = .FALSE.      !< namelist parameter (see documentation)
240    LOGICAL ::  deallocate_memory = .TRUE.                !< namelist parameter (see documentation)
241    LOGICAL ::  hall_kernel = .FALSE.                     !< flag for collision kernel
242    LOGICAL ::  merging = .FALSE.                         !< namelist parameter (see documentation)
243    LOGICAL ::  random_start_position = .FALSE.           !< namelist parameter (see documentation)
244    LOGICAL ::  read_particles_from_restartfile = .TRUE.  !< namelist parameter (see documentation)
245    LOGICAL ::  seed_follows_topography = .FALSE.         !< namelist parameter (see documentation)
246    LOGICAL ::  splitting = .FALSE.                       !< namelist parameter (see documentation)
247    LOGICAL ::  use_kernel_tables = .FALSE.               !< parameter, which turns on the use of precalculated collision kernels
248    LOGICAL ::  write_particle_statistics = .FALSE.       !< namelist parameter (see documentation)
249    LOGICAL ::  interpolation_simple_predictor = .FALSE.  !< flag for simple particle advection interpolation with predictor step
250    LOGICAL ::  interpolation_simple_corrector = .FALSE.  !< flag for simple particle advection interpolation with corrector step
251    LOGICAL ::  interpolation_trilinear = .FALSE.         !< flag for trilinear particle advection interpolation
252
253    LOGICAL, DIMENSION(max_number_of_particle_groups) ::   vertical_particle_advection = .TRUE. !< Switch for vertical particle transport
254
255    REAL(wp) ::  aero_weight = 1.0_wp                      !< namelist parameter (see documentation)
256    REAL(wp) ::  dt_min_part = 0.0002_wp                   !< minimum particle time step when SGS velocities are used (s)
257    REAL(wp) ::  dt_prel = 9999999.9_wp                    !< namelist parameter (see documentation)
258    REAL(wp) ::  dt_write_particle_data = 9999999.9_wp     !< namelist parameter (see documentation)
259    REAL(wp) ::  end_time_prel = 9999999.9_wp              !< namelist parameter (see documentation)
260    REAL(wp) ::  initial_weighting_factor = 1.0_wp         !< namelist parameter (see documentation)
261    REAL(wp) ::  last_particle_release_time = 0.0_wp       !< last time of particle release
262    REAL(wp) ::  log_sigma(3) = 1.0_wp                     !< namelist parameter (see documentation)
263    REAL(wp) ::  na(3) = 0.0_wp                            !< namelist parameter (see documentation)
264    REAL(wp) ::  number_concentration = -1.0_wp            !< namelist parameter (see documentation)
265    REAL(wp) ::  radius_merge = 1.0E-7_wp                  !< namelist parameter (see documentation)
266    REAL(wp) ::  radius_split = 40.0E-6_wp                 !< namelist parameter (see documentation)
267    REAL(wp) ::  rm(3) = 1.0E-6_wp                         !< namelist parameter (see documentation)
268    REAL(wp) ::  sgs_wf_part                               !< parameter for sgs
269    REAL(wp) ::  time_write_particle_data = 0.0_wp         !< write particle data at current time on file
270    REAL(wp) ::  weight_factor_merge = -1.0_wp             !< namelist parameter (see documentation)
271    REAL(wp) ::  weight_factor_split = -1.0_wp             !< namelist parameter (see documentation)
272    REAL(wp) ::  z0_av_global                              !< horizontal mean value of z0
273
274    REAL(wp) ::  rclass_lbound !<
275    REAL(wp) ::  rclass_ubound !<
276
277    REAL(wp), PARAMETER ::  c_0 = 3.0_wp         !< parameter for lagrangian timescale
278
279    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  density_ratio = 9999999.9_wp  !< namelist parameter (see documentation)
280    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pdx = 9999999.9_wp            !< namelist parameter (see documentation)
281    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pdy = 9999999.9_wp            !< namelist parameter (see documentation)
282    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pdz = 9999999.9_wp            !< namelist parameter (see documentation)
283    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psb = 9999999.9_wp            !< namelist parameter (see documentation)
284    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psl = 9999999.9_wp            !< namelist parameter (see documentation)
285    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psn = 9999999.9_wp            !< namelist parameter (see documentation)
286    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psr = 9999999.9_wp            !< namelist parameter (see documentation)
287    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pss = 9999999.9_wp            !< namelist parameter (see documentation)
288    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pst = 9999999.9_wp            !< namelist parameter (see documentation).
289    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  radius = 9999999.9_wp         !< namelist parameter (see documentation)
290
291    REAL(wp), DIMENSION(:), ALLOCATABLE     ::  log_z_z0   !< Precalculate LOG(z/z0) 
292
293    INTEGER(iwp), PARAMETER ::  NR_2_direction_move = 10000 !<
294    INTEGER(iwp)            ::  nr_move_north               !<
295    INTEGER(iwp)            ::  nr_move_south               !<
296
297    TYPE(particle_type), DIMENSION(:), ALLOCATABLE ::  move_also_north
298    TYPE(particle_type), DIMENSION(:), ALLOCATABLE ::  move_also_south
299
300    REAL(wp) ::  epsilon_collision !<
301    REAL(wp) ::  urms              !<
302
303    REAL(wp), DIMENSION(:),   ALLOCATABLE ::  epsclass  !< dissipation rate class
304    REAL(wp), DIMENSION(:),   ALLOCATABLE ::  radclass  !< radius class
305    REAL(wp), DIMENSION(:),   ALLOCATABLE ::  winf      !<
306
307    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  ec        !<
308    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  ecf       !<
309    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  gck       !<
310    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  hkernel   !<
311    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  hwratio   !<
312
313    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  ckernel !<
314    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  u_t   !< u value of old timelevel t
315    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  v_t   !< v value of old timelevel t
316    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  w_t   !< w value of old timelevel t
317
318
319    INTEGER(iwp), PARAMETER         ::  PHASE_INIT    = 1  !<
320    INTEGER(iwp), PARAMETER, PUBLIC ::  PHASE_RELEASE = 2  !<
321
322    SAVE
323
324    PRIVATE
325
326    PUBLIC lpm_parin,     &
327           lpm_header,    &
328           lpm_init_arrays,&
329           lpm_init,      &
330           lpm_actions,   &
331           lpm_data_output_ptseries, &
332           lpm_interaction_droplets_ptq, &
333           lpm_rrd_local_particles, &
334           lpm_wrd_local, &
335           lpm_rrd_global, &
336           lpm_wrd_global, &
337           lpm_rrd_local, &
338           lpm_check_parameters
339
340    PUBLIC lagrangian_particle_model
341
342    INTERFACE lpm_check_parameters
343       MODULE PROCEDURE lpm_check_parameters
344    END INTERFACE lpm_check_parameters
345
346    INTERFACE lpm_parin
347       MODULE PROCEDURE lpm_parin
348    END INTERFACE lpm_parin
349
350    INTERFACE lpm_header
351       MODULE PROCEDURE lpm_header
352    END INTERFACE lpm_header
353
354    INTERFACE lpm_init_arrays
355       MODULE PROCEDURE lpm_init_arrays
356    END INTERFACE lpm_init_arrays
357 
358    INTERFACE lpm_init
359       MODULE PROCEDURE lpm_init
360    END INTERFACE lpm_init
361
362    INTERFACE lpm_actions
363       MODULE PROCEDURE lpm_actions
364    END INTERFACE lpm_actions
365
366    INTERFACE lpm_data_output_ptseries
367       MODULE PROCEDURE lpm_data_output_ptseries
368    END INTERFACE
369
370    INTERFACE lpm_rrd_local_particles
371       MODULE PROCEDURE lpm_rrd_local_particles
372    END INTERFACE lpm_rrd_local_particles
373
374    INTERFACE lpm_rrd_global
375       MODULE PROCEDURE lpm_rrd_global
376    END INTERFACE lpm_rrd_global
377
378    INTERFACE lpm_rrd_local
379       MODULE PROCEDURE lpm_rrd_local
380    END INTERFACE lpm_rrd_local
381
382    INTERFACE lpm_wrd_local
383       MODULE PROCEDURE lpm_wrd_local
384    END INTERFACE lpm_wrd_local
385
386    INTERFACE lpm_wrd_global
387       MODULE PROCEDURE lpm_wrd_global
388    END INTERFACE lpm_wrd_global
389
390    INTERFACE lpm_advec
391       MODULE PROCEDURE lpm_advec
392    END INTERFACE lpm_advec
393
394    INTERFACE lpm_calc_liquid_water_content
395       MODULE PROCEDURE lpm_calc_liquid_water_content
396    END INTERFACE
397
398    INTERFACE lpm_interaction_droplets_ptq
399       MODULE PROCEDURE lpm_interaction_droplets_ptq
400       MODULE PROCEDURE lpm_interaction_droplets_ptq_ij
401    END INTERFACE lpm_interaction_droplets_ptq
402
403    INTERFACE lpm_boundary_conds
404       MODULE PROCEDURE lpm_boundary_conds
405    END INTERFACE lpm_boundary_conds
406
407    INTERFACE lpm_droplet_condensation
408       MODULE PROCEDURE lpm_droplet_condensation
409    END INTERFACE
410
411    INTERFACE lpm_droplet_collision
412       MODULE PROCEDURE lpm_droplet_collision
413    END INTERFACE lpm_droplet_collision
414
415    INTERFACE lpm_init_kernels
416       MODULE PROCEDURE lpm_init_kernels
417    END INTERFACE lpm_init_kernels
418
419    INTERFACE lpm_splitting
420       MODULE PROCEDURE lpm_splitting
421    END INTERFACE lpm_splitting
422
423    INTERFACE lpm_merging
424       MODULE PROCEDURE lpm_merging
425    END INTERFACE lpm_merging
426
427    INTERFACE lpm_exchange_horiz
428       MODULE PROCEDURE lpm_exchange_horiz
429    END INTERFACE lpm_exchange_horiz
430
431    INTERFACE lpm_move_particle
432       MODULE PROCEDURE lpm_move_particle
433    END INTERFACE lpm_move_particle
434
435    INTERFACE realloc_particles_array
436       MODULE PROCEDURE realloc_particles_array
437    END INTERFACE realloc_particles_array
438
439    INTERFACE dealloc_particles_array
440       MODULE PROCEDURE dealloc_particles_array
441    END INTERFACE dealloc_particles_array
442
443    INTERFACE lpm_sort_and_delete
444       MODULE PROCEDURE lpm_sort_and_delete
445    END INTERFACE lpm_sort_and_delete
446
447    INTERFACE lpm_sort_timeloop_done
448       MODULE PROCEDURE lpm_sort_timeloop_done
449    END INTERFACE lpm_sort_timeloop_done
450
451    INTERFACE lpm_pack
452       MODULE PROCEDURE lpm_pack
453    END INTERFACE lpm_pack
454
455 CONTAINS
456 
457
458!------------------------------------------------------------------------------!
459! Description:
460! ------------
461!> Parin for &particle_parameters for the Lagrangian particle model
462!------------------------------------------------------------------------------!
463 SUBROUTINE lpm_parin
464 
465    CHARACTER (LEN=80) ::  line  !<
466
467    NAMELIST /particles_par/ &
468       aero_species, &
469       aero_type, &
470       aero_weight, &
471       alloc_factor, &
472       bc_par_b, &
473       bc_par_lr, &
474       bc_par_ns, &
475       bc_par_t, &
476       collision_kernel, &
477       curvature_solution_effects, &
478       deallocate_memory, &
479       density_ratio, &
480       dissipation_classes, &
481       dt_dopts, &
482       dt_min_part, &
483       dt_prel, &
484       dt_write_particle_data, &
485       end_time_prel, &
486       initial_weighting_factor, &
487       log_sigma, &
488       max_number_particles_per_gridbox, &
489       merging, &
490       na, &
491       number_concentration, &
492       number_of_particle_groups, &
493       number_particles_per_gridbox, &
494       particles_per_point, &
495       particle_advection_start, &
496       particle_advection_interpolation, &
497       particle_maximum_age, &
498       pdx, &
499       pdy, &
500       pdz, &
501       psb, &
502       psl, &
503       psn, &
504       psr, &
505       pss, &
506       pst, &
507       radius, &
508       radius_classes, &
509       radius_merge, &
510       radius_split, &
511       random_start_position, &
512       read_particles_from_restartfile, &
513       rm, &
514       seed_follows_topography, &
515       splitting, &
516       splitting_factor, &
517       splitting_factor_max, &
518       splitting_function, &
519       splitting_mode, &
520       step_dealloc, &
521       use_sgs_for_particles, &
522       vertical_particle_advection, &
523       weight_factor_merge, &
524       weight_factor_split, &
525       write_particle_statistics
526
527       NAMELIST /particle_parameters/ &
528       aero_species, &
529       aero_type, &
530       aero_weight, &
531       alloc_factor, &
532       bc_par_b, &
533       bc_par_lr, &
534       bc_par_ns, &
535       bc_par_t, &
536       collision_kernel, &
537       curvature_solution_effects, &
538       deallocate_memory, &
539       density_ratio, &
540       dissipation_classes, &
541       dt_dopts, &
542       dt_min_part, &
543       dt_prel, &
544       dt_write_particle_data, &
545       end_time_prel, &
546       initial_weighting_factor, &
547       log_sigma, &
548       max_number_particles_per_gridbox, &
549       merging, &
550       na, &
551       number_concentration, &
552       number_of_particle_groups, &
553       number_particles_per_gridbox, &
554       particles_per_point, &
555       particle_advection_start, &
556       particle_advection_interpolation, &
557       particle_maximum_age, &
558       pdx, &
559       pdy, &
560       pdz, &
561       psb, &
562       psl, &
563       psn, &
564       psr, &
565       pss, &
566       pst, &
567       radius, &
568       radius_classes, &
569       radius_merge, &
570       radius_split, &
571       random_start_position, &
572       read_particles_from_restartfile, &
573       rm, &
574       seed_follows_topography, &
575       splitting, &
576       splitting_factor, &
577       splitting_factor_max, &
578       splitting_function, &
579       splitting_mode, &
580       step_dealloc, &
581       use_sgs_for_particles, &
582       vertical_particle_advection, &
583       weight_factor_merge, &
584       weight_factor_split, &
585       write_particle_statistics
586
587!
588!-- Position the namelist-file at the beginning (it was already opened in
589!-- parin), search for the namelist-group of the package and position the
590!-- file at this line. Do the same for each optionally used package.
591    line = ' '
592   
593!
594!-- Try to find particles package
595    REWIND ( 11 )
596    line = ' '
597    DO   WHILE ( INDEX( line, '&particle_parameters' ) == 0 )
598       READ ( 11, '(A)', END=12 )  line
599    ENDDO
600    BACKSPACE ( 11 )
601!
602!-- Read user-defined namelist
603    READ ( 11, particle_parameters, ERR = 10 )
604!
605!-- Set flag that indicates that particles are switched on
606    particle_advection = .TRUE.
607   
608    GOTO 14
609
61010  BACKSPACE( 11 )
611    READ( 11 , '(A)') line
612    CALL parin_fail_message( 'particle_parameters', line )
613!
614!-- Try to find particles package (old namelist)
61512  REWIND ( 11 )
616    line = ' '
617    DO WHILE ( INDEX( line, '&particles_par' ) == 0 )
618       READ ( 11, '(A)', END=14 )  line
619    ENDDO
620    BACKSPACE ( 11 )
621!
622!-- Read user-defined namelist
623    READ ( 11, particles_par, ERR = 13, END = 14 )
624
625    message_string = 'namelist particles_par is deprecated and will be ' //    &
626                     'removed in near future. Please use namelist ' //         &
627                     'particle_parameters instead'
628    CALL message( 'package_parin', 'PA0487', 0, 1, 0, 6, 0 )
629
630!
631!-- Set flag that indicates that particles are switched on
632    particle_advection = .TRUE.
633
634    GOTO 14
635
63613    BACKSPACE( 11 )
637       READ( 11 , '(A)') line
638       CALL parin_fail_message( 'particles_par', line )
639
64014 CONTINUE
641
642 END SUBROUTINE lpm_parin
643 
644!------------------------------------------------------------------------------!
645! Description:
646! ------------
647!> Writes used particle attributes in header file.
648!------------------------------------------------------------------------------!
649 SUBROUTINE lpm_header ( io )
650
651    CHARACTER (LEN=40) ::  output_format       !< netcdf format
652
653    INTEGER(iwp) ::  i               !<
654    INTEGER(iwp), INTENT(IN) ::  io  !< Unit of the output file
655
656
657     IF ( humidity  .AND.  cloud_droplets )  THEN
658       WRITE ( io, 433 )
659       IF ( curvature_solution_effects )  WRITE ( io, 434 )
660       IF ( collision_kernel /= 'none' )  THEN
661          WRITE ( io, 435 )  TRIM( collision_kernel )
662          IF ( collision_kernel(6:9) == 'fast' )  THEN
663             WRITE ( io, 436 )  radius_classes, dissipation_classes
664          ENDIF
665       ELSE
666          WRITE ( io, 437 )
667       ENDIF
668    ENDIF
669 
670    IF ( particle_advection )  THEN
671!
672!--    Particle attributes
673       WRITE ( io, 480 )  particle_advection_start, TRIM(particle_advection_interpolation), &
674                          dt_prel, bc_par_lr, &
675                          bc_par_ns, bc_par_b, bc_par_t, particle_maximum_age, &
676                          end_time_prel
677       IF ( use_sgs_for_particles )  WRITE ( io, 488 )  dt_min_part
678       IF ( random_start_position )  WRITE ( io, 481 )
679       IF ( seed_follows_topography )  WRITE ( io, 496 )
680       IF ( particles_per_point > 1 )  WRITE ( io, 489 )  particles_per_point
681       WRITE ( io, 495 )  total_number_of_particles
682       IF ( dt_write_particle_data /= 9999999.9_wp )  THEN
683          WRITE ( io, 485 )  dt_write_particle_data
684          IF ( netcdf_data_format > 1 )  THEN
685             output_format = 'netcdf (64 bit offset) and binary'
686          ELSE
687             output_format = 'netcdf and binary'
688          ENDIF
689          IF ( netcdf_deflate == 0 )  THEN
690             WRITE ( io, 344 )  output_format
691          ELSE
692             WRITE ( io, 354 )  TRIM( output_format ), netcdf_deflate
693          ENDIF
694       ENDIF
695       IF ( dt_dopts /= 9999999.9_wp )  WRITE ( io, 494 )  dt_dopts
696       IF ( write_particle_statistics )  WRITE ( io, 486 )
697
698       WRITE ( io, 487 )  number_of_particle_groups
699
700       DO  i = 1, number_of_particle_groups
701          WRITE ( io, 490 )  i, radius(i)
702          IF ( density_ratio(i) /= 0.0_wp )  THEN
703             WRITE ( io, 491 )  density_ratio(i)
704          ELSE
705             WRITE ( io, 492 )
706          ENDIF
707          WRITE ( io, 493 )  psl(i), psr(i), pss(i), psn(i), psb(i), pst(i), &
708                             pdx(i), pdy(i), pdz(i)
709          IF ( .NOT. vertical_particle_advection(i) )  WRITE ( io, 482 )
710       ENDDO
711
712    ENDIF
713   
714344 FORMAT ('       Output format: ',A/)
715354 FORMAT ('       Output format: ',A, '   compressed with level: ',I1/)
716
717433 FORMAT ('    Cloud droplets treated explicitly using the Lagrangian part', &
718                 'icle model')
719434 FORMAT ('    Curvature and solution effecs are considered for growth of', &
720                 ' droplets < 1.0E-6 m')
721435 FORMAT ('    Droplet collision is handled by ',A,'-kernel')
722436 FORMAT ('       Fast kernel with fixed radius- and dissipation classes ', &
723                    'are used'/ &
724            '          number of radius classes:       ',I3,'    interval ', &
725                       '[1.0E-6,2.0E-4] m'/ &
726            '          number of dissipation classes:   ',I2,'    interval ', &
727                       '[0,1000] cm**2/s**3')
728437 FORMAT ('    Droplet collision is switched off')
729
730480 FORMAT ('    Particles:'/ &
731            '    ---------'// &
732            '       Particle advection is active (switched on at t = ', F7.1, &
733                    ' s)'/ &
734            '       Interpolation of particle velocities is done by using ', A, &
735                    ' method'/ &
736            '       Start of new particle generations every  ',F6.1,' s'/ &
737            '       Boundary conditions: left/right: ', A, ' north/south: ', A/&
738            '                            bottom:     ', A, ' top:         ', A/&
739            '       Maximum particle age:                 ',F9.1,' s'/ &
740            '       Advection stopped at t = ',F9.1,' s'/)
741481 FORMAT ('       Particles have random start positions'/)
742482 FORMAT ('          Particles are advected only horizontally'/)
743485 FORMAT ('       Particle data are written on file every ', F9.1, ' s')
744486 FORMAT ('       Particle statistics are written on file'/)
745487 FORMAT ('       Number of particle groups: ',I2/)
746488 FORMAT ('       SGS velocity components are used for particle advection'/ &
747            '          minimum timestep for advection:', F8.5/)
748489 FORMAT ('       Number of particles simultaneously released at each ', &
749                    'point: ', I5/)
750490 FORMAT ('       Particle group ',I2,':'/ &
751            '          Particle radius: ',E10.3, 'm')
752491 FORMAT ('          Particle inertia is activated'/ &
753            '             density_ratio (rho_fluid/rho_particle) =',F6.3/)
754492 FORMAT ('          Particles are advected only passively (no inertia)'/)
755493 FORMAT ('          Boundaries of particle source: x:',F8.1,' - ',F8.1,' m'/&
756            '                                         y:',F8.1,' - ',F8.1,' m'/&
757            '                                         z:',F8.1,' - ',F8.1,' m'/&
758            '          Particle distances:  dx = ',F8.1,' m  dy = ',F8.1, &
759                       ' m  dz = ',F8.1,' m'/)
760494 FORMAT ('       Output of particle time series in NetCDF format every ', &
761                    F8.2,' s'/)
762495 FORMAT ('       Number of particles in total domain: ',I10/)
763496 FORMAT ('       Initial vertical particle positions are interpreted ', &
764                    'as relative to the given topography')
765   
766 END SUBROUTINE lpm_header
767 
768!------------------------------------------------------------------------------!
769! Description:
770! ------------
771!> Writes used particle attributes in header file.
772!------------------------------------------------------------------------------! 
773 SUBROUTINE lpm_check_parameters
774 
775!
776!-- Collision kernels:
777    SELECT CASE ( TRIM( collision_kernel ) )
778
779       CASE ( 'hall', 'hall_fast' )
780          hall_kernel = .TRUE.
781
782       CASE ( 'wang', 'wang_fast' )
783          wang_kernel = .TRUE.
784
785       CASE ( 'none' )
786
787
788       CASE DEFAULT
789          message_string = 'unknown collision kernel: collision_kernel = "' // &
790                           TRIM( collision_kernel ) // '"'
791          CALL message( 'lpm_check_parameters', 'PA0350', 1, 2, 0, 6, 0 )
792
793    END SELECT
794    IF ( collision_kernel(6:9) == 'fast' )  use_kernel_tables = .TRUE.
795
796!
797!-- Subgrid scale velocites with the simple interpolation method for resolved
798!-- velocites is not implemented for passive particles. However, for cloud
799!-- it can be combined as the sgs-velocites for active particles are
800!-- calculated differently, i.e. no subboxes are needed.
801    IF ( .NOT. TRIM( particle_advection_interpolation ) == 'trilinear'  .AND.  &
802       use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
803          message_string = 'subrgrid scale velocities in combination with ' // &
804                           'simple interpolation method is not '            // &
805                           'implemented'
806          CALL message( 'lpm_check_parameters', 'PA0659', 1, 2, 0, 6, 0 )
807    ENDIF
808
809    IF ( nested_run  .AND.  cloud_droplets )  THEN
810       message_string = 'nested runs in combination with cloud droplets ' // &
811                        'is not implemented'
812          CALL message( 'lpm_check_parameters', 'PA0687', 1, 2, 0, 6, 0 )
813    ENDIF
814
815
816 END SUBROUTINE lpm_check_parameters
817 
818!------------------------------------------------------------------------------!
819! Description:
820! ------------
821!> Initialize arrays for lpm
822!------------------------------------------------------------------------------!   
823 SUBROUTINE lpm_init_arrays
824 
825    IF ( cloud_droplets )  THEN
826!
827!--    Liquid water content, change in liquid water content
828       ALLOCATE ( ql_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                      &
829                  ql_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
830!
831!--    Real volume of particles (with weighting), volume of particles
832       ALLOCATE ( ql_v(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                      &
833                     ql_vp(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
834    ENDIF
835
836
837    ALLOCATE( u_t(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                             &
838              v_t(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                             &
839              w_t(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
840!
841!-- Initialize values with current time step
842    u_t = u
843    v_t = v
844    w_t = w
845!
846!--    Initial assignment of the pointers
847    IF ( cloud_droplets )  THEN
848       ql   => ql_1
849       ql_c => ql_2
850    ENDIF
851
852 END SUBROUTINE lpm_init_arrays
853 
854!------------------------------------------------------------------------------!
855! Description:
856! ------------
857!> Initialize Lagrangian particle model
858!------------------------------------------------------------------------------!
859 SUBROUTINE lpm_init
860
861    INTEGER(iwp) ::  i                           !<
862    INTEGER(iwp) ::  j                           !<
863    INTEGER(iwp) ::  k                           !<
864
865    REAL(wp) ::  div                             !<
866    REAL(wp) ::  height_int                      !<
867    REAL(wp) ::  height_p                        !<
868    REAL(wp) ::  z_p                             !<
869    REAL(wp) ::  z0_av_local                     !<
870
871!
872!-- In case of oceans runs, the vertical index calculations need an offset,
873!-- because otherwise the k indices will become negative
874    IF ( ocean_mode )  THEN
875       offset_ocean_nzt    = nzt
876       offset_ocean_nzt_m1 = nzt - 1
877    ENDIF
878
879!
880!-- Define block offsets for dividing a gridcell in 8 sub cells
881!-- See documentation for List of subgrid boxes
882!-- See pack_and_sort in lpm_pack_arrays.f90 for assignment of the subgrid boxes
883    block_offset(0) = block_offset_def ( 0, 0, 0)
884    block_offset(1) = block_offset_def ( 0, 0,-1)
885    block_offset(2) = block_offset_def ( 0,-1, 0)
886    block_offset(3) = block_offset_def ( 0,-1,-1)
887    block_offset(4) = block_offset_def (-1, 0, 0)
888    block_offset(5) = block_offset_def (-1, 0,-1)
889    block_offset(6) = block_offset_def (-1,-1, 0)
890    block_offset(7) = block_offset_def (-1,-1,-1)
891!
892!-- Check the number of particle groups.
893    IF ( number_of_particle_groups > max_number_of_particle_groups )  THEN
894       WRITE( message_string, * ) 'max_number_of_particle_groups =',           &
895                                  max_number_of_particle_groups ,              &
896                                  '&number_of_particle_groups reset to ',      &
897                                  max_number_of_particle_groups
898       CALL message( 'lpm_init', 'PA0213', 0, 1, 0, 6, 0 )
899       number_of_particle_groups = max_number_of_particle_groups
900    ENDIF
901!
902!-- Check if downward-facing walls exist. This case, reflection boundary
903!-- conditions (as well as subgrid-scale velocities) may do not work
904!-- propably (not realized so far).
905    IF ( surf_def_h(1)%ns >= 1 )  THEN
906       WRITE( message_string, * ) 'Overhanging topography do not work '//      &
907                                  'with particles'
908       CALL message( 'lpm_init', 'PA0212', 0, 1, 0, 6, 0 )
909
910    ENDIF
911
912!
913!-- Set default start positions, if necessary
914    IF ( psl(1) == 9999999.9_wp )  psl(1) = 0.0_wp
915    IF ( psr(1) == 9999999.9_wp )  psr(1) = ( nx +1 ) * dx
916    IF ( pss(1) == 9999999.9_wp )  pss(1) = 0.0_wp
917    IF ( psn(1) == 9999999.9_wp )  psn(1) = ( ny +1 ) * dy
918    IF ( psb(1) == 9999999.9_wp )  psb(1) = zu(nz/2)
919    IF ( pst(1) == 9999999.9_wp )  pst(1) = psb(1)
920
921    IF ( pdx(1) == 9999999.9_wp  .OR.  pdx(1) == 0.0_wp )  pdx(1) = dx
922    IF ( pdy(1) == 9999999.9_wp  .OR.  pdy(1) == 0.0_wp )  pdy(1) = dy
923    IF ( pdz(1) == 9999999.9_wp  .OR.  pdz(1) == 0.0_wp )  pdz(1) = zu(2) - zu(1)
924
925!
926!-- If number_particles_per_gridbox is set, the parametres pdx, pdy and pdz are
927!-- calculated diagnostically. Therfore an isotropic distribution is prescribed.
928    IF ( number_particles_per_gridbox /= -1 .AND.   &
929         number_particles_per_gridbox >= 1 )    THEN
930       pdx(1) = (( dx * dy * ( zu(2) - zu(1) ) ) /  &
931             REAL(number_particles_per_gridbox))**0.3333333_wp
932!
933!--    Ensure a smooth value (two significant digits) of distance between
934!--    particles (pdx, pdy, pdz).
935       div = 1000.0_wp
936       DO  WHILE ( pdx(1) < div )
937          div = div / 10.0_wp
938       ENDDO
939       pdx(1) = NINT( pdx(1) * 100.0_wp / div ) * div / 100.0_wp
940       pdy(1) = pdx(1)
941       pdz(1) = pdx(1)
942
943    ENDIF
944
945    DO  j = 2, number_of_particle_groups
946       IF ( psl(j) == 9999999.9_wp )  psl(j) = psl(j-1)
947       IF ( psr(j) == 9999999.9_wp )  psr(j) = psr(j-1)
948       IF ( pss(j) == 9999999.9_wp )  pss(j) = pss(j-1)
949       IF ( psn(j) == 9999999.9_wp )  psn(j) = psn(j-1)
950       IF ( psb(j) == 9999999.9_wp )  psb(j) = psb(j-1)
951       IF ( pst(j) == 9999999.9_wp )  pst(j) = pst(j-1)
952       IF ( pdx(j) == 9999999.9_wp  .OR.  pdx(j) == 0.0_wp )  pdx(j) = pdx(j-1)
953       IF ( pdy(j) == 9999999.9_wp  .OR.  pdy(j) == 0.0_wp )  pdy(j) = pdy(j-1)
954       IF ( pdz(j) == 9999999.9_wp  .OR.  pdz(j) == 0.0_wp )  pdz(j) = pdz(j-1)
955    ENDDO
956
957!
958!-- Allocate arrays required for calculating particle SGS velocities.
959!-- Initialize prefactor required for stoachastic Weil equation.
960    IF ( use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
961       ALLOCATE( de_dx(nzb:nzt+1,nysg:nyng,nxlg:nxrg), &
962                 de_dy(nzb:nzt+1,nysg:nyng,nxlg:nxrg), &
963                 de_dz(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
964
965       de_dx = 0.0_wp
966       de_dy = 0.0_wp
967       de_dz = 0.0_wp
968
969       sgs_wf_part = 1.0_wp / 3.0_wp
970    ENDIF
971
972!
973!-- Allocate array required for logarithmic vertical interpolation of
974!-- horizontal particle velocities between the surface and the first vertical
975!-- grid level. In order to avoid repeated CPU cost-intensive CALLS of
976!-- intrinsic FORTRAN procedure LOG(z/z0), LOG(z/z0) is precalculated for
977!-- several heights. Splitting into 20 sublayers turned out to be sufficient.
978!-- To obtain exact height levels of particles, linear interpolation is applied
979!-- (see lpm_advec.f90).
980    IF ( constant_flux_layer )  THEN
981
982       ALLOCATE ( log_z_z0(0:number_of_sublayers) )
983       z_p = zu(nzb+1) - zw(nzb)
984
985!
986!--    Calculate horizontal mean value of z0 used for logartihmic
987!--    interpolation. Note: this is not exact for heterogeneous z0.
988!--    However, sensitivity studies showed that the effect is
989!--    negligible.
990       z0_av_local  = SUM( surf_def_h(0)%z0 ) + SUM( surf_lsm_h%z0 ) +         &
991                      SUM( surf_usm_h%z0 )
992       z0_av_global = 0.0_wp
993
994#if defined( __parallel )
995       CALL MPI_ALLREDUCE(z0_av_local, z0_av_global, 1, MPI_REAL, MPI_SUM, &
996                          comm2d, ierr )
997#else
998       z0_av_global = z0_av_local
999#endif
1000
1001       z0_av_global = z0_av_global  / ( ( ny + 1 ) * ( nx + 1 ) )
1002!
1003!--    Horizontal wind speed is zero below and at z0
1004       log_z_z0(0) = 0.0_wp
1005!
1006!--    Calculate vertical depth of the sublayers
1007       height_int  = ( z_p - z0_av_global ) / REAL( number_of_sublayers, KIND=wp )
1008!
1009!--    Precalculate LOG(z/z0)
1010       height_p    = z0_av_global
1011       DO  k = 1, number_of_sublayers
1012
1013          height_p    = height_p + height_int
1014          log_z_z0(k) = LOG( height_p / z0_av_global )
1015
1016       ENDDO
1017
1018    ENDIF
1019
1020!
1021!-- Check which particle interpolation method should be used
1022    IF ( TRIM( particle_advection_interpolation )  ==  'trilinear' )  THEN
1023       interpolation_simple_corrector = .FALSE.
1024       interpolation_simple_predictor = .FALSE.
1025       interpolation_trilinear        = .TRUE.
1026    ELSEIF ( TRIM( particle_advection_interpolation )  ==  'simple_corrector' )  THEN
1027       interpolation_simple_corrector = .TRUE.
1028       interpolation_simple_predictor = .FALSE.
1029       interpolation_trilinear        = .FALSE.
1030    ELSEIF ( TRIM( particle_advection_interpolation )  ==  'simple_predictor' )  THEN
1031       interpolation_simple_corrector = .FALSE.
1032       interpolation_simple_predictor = .TRUE.
1033       interpolation_trilinear        = .FALSE.
1034    ENDIF
1035
1036!
1037!-- Check boundary condition and set internal variables
1038    SELECT CASE ( bc_par_b )
1039
1040       CASE ( 'absorb' )
1041          ibc_par_b = 1
1042
1043       CASE ( 'reflect' )
1044          ibc_par_b = 2
1045
1046       CASE ( 'reset' )
1047          ibc_par_b = 3
1048
1049       CASE DEFAULT
1050          WRITE( message_string, * )  'unknown boundary condition ',           &
1051                                       'bc_par_b = "', TRIM( bc_par_b ), '"'
1052          CALL message( 'lpm_init', 'PA0217', 1, 2, 0, 6, 0 )
1053
1054    END SELECT
1055    SELECT CASE ( bc_par_t )
1056
1057       CASE ( 'absorb' )
1058          ibc_par_t = 1
1059
1060       CASE ( 'reflect' )
1061          ibc_par_t = 2
1062
1063       CASE ( 'nested' )
1064          ibc_par_t = 3
1065
1066       CASE DEFAULT
1067          WRITE( message_string, * ) 'unknown boundary condition ',            &
1068                                     'bc_par_t = "', TRIM( bc_par_t ), '"'
1069          CALL message( 'lpm_init', 'PA0218', 1, 2, 0, 6, 0 )
1070
1071    END SELECT
1072    SELECT CASE ( bc_par_lr )
1073
1074       CASE ( 'cyclic' )
1075          ibc_par_lr = 0
1076
1077       CASE ( 'absorb' )
1078          ibc_par_lr = 1
1079
1080       CASE ( 'reflect' )
1081          ibc_par_lr = 2
1082
1083       CASE ( 'nested' )
1084          ibc_par_lr = 3
1085
1086       CASE DEFAULT
1087          WRITE( message_string, * ) 'unknown boundary condition ',   &
1088                                     'bc_par_lr = "', TRIM( bc_par_lr ), '"'
1089          CALL message( 'lpm_init', 'PA0219', 1, 2, 0, 6, 0 )
1090
1091    END SELECT
1092    SELECT CASE ( bc_par_ns )
1093
1094       CASE ( 'cyclic' )
1095          ibc_par_ns = 0
1096
1097       CASE ( 'absorb' )
1098          ibc_par_ns = 1
1099
1100       CASE ( 'reflect' )
1101          ibc_par_ns = 2
1102
1103       CASE ( 'nested' )
1104          ibc_par_ns = 3
1105
1106       CASE DEFAULT
1107          WRITE( message_string, * ) 'unknown boundary condition ',   &
1108                                     'bc_par_ns = "', TRIM( bc_par_ns ), '"'
1109          CALL message( 'lpm_init', 'PA0220', 1, 2, 0, 6, 0 )
1110
1111    END SELECT
1112    SELECT CASE ( splitting_mode )
1113
1114       CASE ( 'const' )
1115          i_splitting_mode = 1
1116
1117       CASE ( 'cl_av' )
1118          i_splitting_mode = 2
1119
1120       CASE ( 'gb_av' )
1121          i_splitting_mode = 3
1122
1123       CASE DEFAULT
1124          WRITE( message_string, * )  'unknown splitting_mode = "',            &
1125                                      TRIM( splitting_mode ), '"'
1126          CALL message( 'lpm_init', 'PA0146', 1, 2, 0, 6, 0 )
1127
1128    END SELECT
1129    SELECT CASE ( splitting_function )
1130
1131       CASE ( 'gamma' )
1132          isf = 1
1133
1134       CASE ( 'log' )
1135          isf = 2
1136
1137       CASE ( 'exp' )
1138          isf = 3
1139
1140       CASE DEFAULT
1141          WRITE( message_string, * )  'unknown splitting function = "',        &
1142                                       TRIM( splitting_function ), '"'
1143          CALL message( 'lpm_init', 'PA0147', 1, 2, 0, 6, 0 )
1144
1145    END SELECT
1146!
1147!-- Initialize collision kernels
1148    IF ( collision_kernel /= 'none' )  CALL lpm_init_kernels
1149!
1150!-- For the first model run of a possible job chain initialize the
1151!-- particles, otherwise read the particle data from restart file.
1152    IF ( TRIM( initializing_actions ) == 'read_restart_data'  &
1153         .AND.  read_particles_from_restartfile )  THEN
1154       CALL lpm_rrd_local_particles
1155    ELSE
1156!
1157!--    Allocate particle arrays and set attributes of the initial set of
1158!--    particles, which can be also periodically released at later times.
1159       ALLOCATE( prt_count(nzb:nzt+1,nysg:nyng,nxlg:nxrg), &
1160                 grid_particles(nzb+1:nzt,nys:nyn,nxl:nxr) )
1161
1162       number_of_particles = 0
1163       prt_count           = 0
1164!
1165!--    initialize counter for particle IDs
1166       grid_particles%id_counter = 1
1167!
1168!--    Initialize all particles with dummy values (otherwise errors may
1169!--    occur within restart runs). The reason for this is still not clear
1170!--    and may be presumably caused by errors in the respective user-interface.
1171       zero_particle = particle_type( 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1172                                      0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1173                                      0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1174                                      0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1175                                      0, 0, 0_idp, .FALSE., -1 )
1176
1177       particle_groups = particle_groups_type( 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp )
1178!
1179!--    Set values for the density ratio and radius for all particle
1180!--    groups, if necessary
1181       IF ( density_ratio(1) == 9999999.9_wp )  density_ratio(1) = 0.0_wp
1182       IF ( radius(1)        == 9999999.9_wp )  radius(1) = 0.0_wp
1183       DO  i = 2, number_of_particle_groups
1184          IF ( density_ratio(i) == 9999999.9_wp )  THEN
1185             density_ratio(i) = density_ratio(i-1)
1186          ENDIF
1187          IF ( radius(i) == 9999999.9_wp )  radius(i) = radius(i-1)
1188       ENDDO
1189
1190       DO  i = 1, number_of_particle_groups
1191          IF ( density_ratio(i) /= 0.0_wp  .AND.  radius(i) == 0 )  THEN
1192             WRITE( message_string, * ) 'particle group #', i, ' has a',       &
1193                                        'density ratio /= 0 but radius = 0'
1194             CALL message( 'lpm_init', 'PA0215', 1, 2, 0, 6, 0 )
1195          ENDIF
1196          particle_groups(i)%density_ratio = density_ratio(i)
1197          particle_groups(i)%radius        = radius(i)
1198       ENDDO
1199!
1200!--    Set a seed value for the random number generator to be exclusively
1201!--    used for the particle code. The generated random numbers should be
1202!--    different on the different PEs.
1203       iran_part = iran_part + myid
1204!
1205!--    Create the particle set, and set the initial particles
1206       CALL lpm_create_particle( phase_init )
1207       last_particle_release_time = particle_advection_start
1208!
1209!--    User modification of initial particles
1210       CALL user_lpm_init
1211!
1212!--    Open file for statistical informations about particle conditions
1213       IF ( write_particle_statistics )  THEN
1214          CALL check_open( 80 )
1215          WRITE ( 80, 8000 )  current_timestep_number, simulated_time,         &
1216                              number_of_particles
1217          CALL close_file( 80 )
1218       ENDIF
1219
1220    ENDIF
1221
1222    IF ( nested_run )  CALL pmcp_g_init
1223!
1224!-- To avoid programm abort, assign particles array to the local version of
1225!-- first grid cell
1226    number_of_particles = prt_count(nzb+1,nys,nxl)
1227    particles => grid_particles(nzb+1,nys,nxl)%particles(1:number_of_particles)
1228!
1229!-- Formats
12308000 FORMAT (I6,1X,F7.2,4X,I10,71X,I10)
1231
1232 END SUBROUTINE lpm_init
1233 
1234!------------------------------------------------------------------------------!
1235! Description:
1236! ------------
1237!> Create Lagrangian particles
1238!------------------------------------------------------------------------------! 
1239 SUBROUTINE lpm_create_particle (phase)
1240
1241    INTEGER(iwp)               ::  alloc_size  !< relative increase of allocated memory for particles
1242    INTEGER(iwp)               ::  i           !< loop variable ( particle groups )
1243    INTEGER(iwp)               ::  ip          !< index variable along x
1244    INTEGER(iwp)               ::  j           !< loop variable ( particles per point )
1245    INTEGER(iwp)               ::  jp          !< index variable along y
1246    INTEGER(iwp)               ::  k           !< index variable along z
1247    INTEGER(iwp)               ::  k_surf      !< index of surface grid point
1248    INTEGER(iwp)               ::  kp          !< index variable along z
1249    INTEGER(iwp)               ::  loop_stride !< loop variable for initialization
1250    INTEGER(iwp)               ::  n           !< loop variable ( number of particles )
1251    INTEGER(iwp)               ::  new_size    !< new size of allocated memory for particles
1252
1253    INTEGER(iwp), INTENT(IN)   ::  phase       !< mode of inititialization
1254
1255    INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  local_count !< start address of new particle
1256    INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  local_start !< start address of new particle
1257
1258    LOGICAL                    ::  first_stride !< flag for initialization
1259
1260    REAL(wp)                   ::  pos_x      !< increment for particle position in x
1261    REAL(wp)                   ::  pos_y      !< increment for particle position in y
1262    REAL(wp)                   ::  pos_z      !< increment for particle position in z
1263    REAL(wp)                   ::  rand_contr !< dummy argument for random position
1264
1265    TYPE(particle_type),TARGET ::  tmp_particle !< temporary particle used for initialization
1266
1267
1268!
1269!-- Calculate particle positions and store particle attributes, if
1270!-- particle is situated on this PE
1271    DO  loop_stride = 1, 2
1272       first_stride = (loop_stride == 1)
1273       IF ( first_stride )   THEN
1274          local_count = 0           ! count number of particles
1275       ELSE
1276          local_count = prt_count   ! Start address of new particles
1277       ENDIF
1278
1279!
1280!--    Calculate initial_weighting_factor diagnostically
1281       IF ( number_concentration /= -1.0_wp  .AND.  number_concentration > 0.0_wp )  THEN
1282          initial_weighting_factor =  number_concentration  *                           &
1283                                      pdx(1) * pdy(1) * pdz(1)
1284       END IF
1285
1286       n = 0
1287       DO  i = 1, number_of_particle_groups
1288          pos_z = psb(i)
1289          DO WHILE ( pos_z <= pst(i) )
1290             IF ( pos_z >= zw(0) .AND.  pos_z < zw(nzt) )  THEN
1291                pos_y = pss(i)
1292                DO WHILE ( pos_y <= psn(i) )
1293                   IF ( pos_y >= nys * dy  .AND.                  &
1294                        pos_y <  ( nyn + 1 ) * dy  )  THEN
1295                      pos_x = psl(i)
1296               xloop: DO WHILE ( pos_x <= psr(i) )
1297                         IF ( pos_x >= nxl * dx  .AND.            &
1298                              pos_x <  ( nxr + 1) * dx )  THEN
1299                            DO  j = 1, particles_per_point
1300                               n = n + 1
1301                               tmp_particle%x             = pos_x
1302                               tmp_particle%y             = pos_y
1303                               tmp_particle%z             = pos_z
1304                               tmp_particle%age           = 0.0_wp
1305                               tmp_particle%age_m         = 0.0_wp
1306                               tmp_particle%dt_sum        = 0.0_wp
1307                               tmp_particle%e_m           = 0.0_wp
1308                               tmp_particle%rvar1         = 0.0_wp
1309                               tmp_particle%rvar2         = 0.0_wp
1310                               tmp_particle%rvar3         = 0.0_wp
1311                               tmp_particle%speed_x       = 0.0_wp
1312                               tmp_particle%speed_y       = 0.0_wp
1313                               tmp_particle%speed_z       = 0.0_wp
1314                               tmp_particle%origin_x      = pos_x
1315                               tmp_particle%origin_y      = pos_y
1316                               tmp_particle%origin_z      = pos_z
1317                               IF ( curvature_solution_effects )  THEN
1318                                  tmp_particle%aux1      = 0.0_wp    ! dry aerosol radius
1319                                  tmp_particle%aux2      = dt_3d     ! last Rosenbrock timestep
1320                               ELSE
1321                                  tmp_particle%aux1      = 0.0_wp    ! free to use
1322                                  tmp_particle%aux2      = 0.0_wp    ! free to use
1323                               ENDIF
1324                               tmp_particle%radius        = particle_groups(i)%radius
1325                               tmp_particle%weight_factor = initial_weighting_factor
1326                               tmp_particle%class         = 1
1327                               tmp_particle%group         = i
1328                               tmp_particle%id            = 0_idp
1329                               tmp_particle%particle_mask = .TRUE.
1330                               tmp_particle%block_nr      = -1
1331!
1332!--                            Determine the grid indices of the particle position
1333                               ip = INT( tmp_particle%x * ddx )
1334                               jp = INT( tmp_particle%y * ddy )
1335!
1336!--                            In case of stretching the actual k index is found iteratively
1337                               IF ( dz_stretch_level /= -9999999.9_wp  .OR.           &
1338                                    dz_stretch_level_start(1) /= -9999999.9_wp )  THEN
1339                                  kp = MINLOC( ABS( tmp_particle%z - zu ), DIM = 1 ) - 1
1340                               ELSE
1341                                  kp = INT( tmp_particle%z / dz(1) + 1 + offset_ocean_nzt )
1342                               ENDIF
1343!
1344!--                            Determine surface level. Therefore, check for
1345!--                            upward-facing wall on w-grid.
1346                               k_surf = topo_top_ind(jp,ip,3)
1347                               IF ( seed_follows_topography )  THEN
1348!
1349!--                               Particle height is given relative to topography
1350                                  kp = kp + k_surf
1351                                  tmp_particle%z = tmp_particle%z + zw(k_surf)
1352!--                               Skip particle release if particle position is
1353!--                               above model top, or within topography in case
1354!--                               of overhanging structures.
1355                                  IF ( kp > nzt  .OR.                          &
1356                                 .NOT. BTEST( wall_flags_static_0(kp,jp,ip), 0 ) )  THEN
1357                                     pos_x = pos_x + pdx(i)
1358                                     CYCLE xloop
1359                                  ENDIF
1360!
1361!--                            Skip particle release if particle position is
1362!--                            below surface, or within topography in case
1363!--                            of overhanging structures.
1364                               ELSEIF ( .NOT. seed_follows_topography .AND.    &
1365                                         tmp_particle%z <= zw(k_surf)  .OR.    &
1366                                        .NOT. BTEST( wall_flags_static_0(kp,jp,ip), 0 ) )&
1367                               THEN
1368                                  pos_x = pos_x + pdx(i)
1369                                  CYCLE xloop
1370                               ENDIF
1371
1372                               local_count(kp,jp,ip) = local_count(kp,jp,ip) + 1
1373
1374                               IF ( .NOT. first_stride )  THEN
1375                                  IF ( ip < nxl  .OR.  jp < nys  .OR.  kp < nzb+1 )  THEN
1376                                     write(6,*) 'xl ',ip,jp,kp,nxl,nys,nzb+1
1377                                  ENDIF
1378                                  IF ( ip > nxr  .OR.  jp > nyn  .OR.  kp > nzt )  THEN
1379                                     write(6,*) 'xu ',ip,jp,kp,nxr,nyn,nzt
1380                                  ENDIF
1381                                  grid_particles(kp,jp,ip)%particles(local_count(kp,jp,ip)) = tmp_particle
1382                               ENDIF
1383                            ENDDO
1384                         ENDIF
1385                         pos_x = pos_x + pdx(i)
1386                      ENDDO xloop
1387                   ENDIF
1388                   pos_y = pos_y + pdy(i)
1389                ENDDO
1390             ENDIF
1391
1392             pos_z = pos_z + pdz(i)
1393          ENDDO
1394       ENDDO
1395
1396       IF ( first_stride )  THEN
1397          DO  ip = nxl, nxr
1398             DO  jp = nys, nyn
1399                DO  kp = nzb+1, nzt
1400                   IF ( phase == PHASE_INIT )  THEN
1401                      IF ( local_count(kp,jp,ip) > 0 )  THEN
1402                         alloc_size = MAX( INT( local_count(kp,jp,ip) *        &
1403                            ( 1.0_wp + alloc_factor / 100.0_wp ) ),            &
1404                            1 )
1405                      ELSE
1406                         alloc_size = 1
1407                      ENDIF
1408                      ALLOCATE(grid_particles(kp,jp,ip)%particles(1:alloc_size))
1409                      DO  n = 1, alloc_size
1410                         grid_particles(kp,jp,ip)%particles(n) = zero_particle
1411                      ENDDO
1412                   ELSEIF ( phase == PHASE_RELEASE )  THEN
1413                      IF ( local_count(kp,jp,ip) > 0 )  THEN
1414                         new_size   = local_count(kp,jp,ip) + prt_count(kp,jp,ip)
1415                         alloc_size = MAX( INT( new_size * ( 1.0_wp +          &
1416                            alloc_factor / 100.0_wp ) ), 1 )
1417                         IF( alloc_size > SIZE( grid_particles(kp,jp,ip)%particles) )  THEN
1418                            CALL realloc_particles_array( ip, jp, kp, alloc_size )
1419                         ENDIF
1420                      ENDIF
1421                   ENDIF
1422                ENDDO
1423             ENDDO
1424          ENDDO
1425       ENDIF
1426
1427    ENDDO
1428
1429    local_start = prt_count+1
1430    prt_count   = local_count
1431!
1432!-- Calculate particle IDs
1433    DO  ip = nxl, nxr
1434       DO  jp = nys, nyn
1435          DO  kp = nzb+1, nzt
1436             number_of_particles = prt_count(kp,jp,ip)
1437             IF ( number_of_particles <= 0 )  CYCLE
1438             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1439
1440             DO  n = local_start(kp,jp,ip), number_of_particles  !only new particles
1441
1442                particles(n)%id = 10000_idp**3 * grid_particles(kp,jp,ip)%id_counter + &
1443                                  10000_idp**2 * kp + 10000_idp * jp + ip
1444!
1445!--             Count the number of particles that have been released before
1446                grid_particles(kp,jp,ip)%id_counter =                          &
1447                                         grid_particles(kp,jp,ip)%id_counter + 1
1448
1449             ENDDO
1450
1451          ENDDO
1452       ENDDO
1453    ENDDO
1454!
1455!-- Initialize aerosol background spectrum
1456    IF ( curvature_solution_effects )  THEN
1457       CALL lpm_init_aerosols( local_start )
1458    ENDIF
1459!
1460!-- Add random fluctuation to particle positions.
1461    IF ( random_start_position )  THEN
1462       DO  ip = nxl, nxr
1463          DO  jp = nys, nyn
1464             DO  kp = nzb+1, nzt
1465                number_of_particles = prt_count(kp,jp,ip)
1466                IF ( number_of_particles <= 0 )  CYCLE
1467                particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1468!
1469!--             Move only new particles. Moreover, limit random fluctuation
1470!--             in order to prevent that particles move more than one grid box,
1471!--             which would lead to problems concerning particle exchange
1472!--             between processors in case pdx/pdy are larger than dx/dy,
1473!--             respectively.
1474                DO  n = local_start(kp,jp,ip), number_of_particles
1475                   IF ( psl(particles(n)%group) /= psr(particles(n)%group) )  THEN
1476                      rand_contr = ( random_function( iran_part ) - 0.5_wp ) * &
1477                                     pdx(particles(n)%group)
1478                      particles(n)%x = particles(n)%x +                        &
1479                              MERGE( rand_contr, SIGN( dx, rand_contr ),       &
1480                                     ABS( rand_contr ) < dx                    &
1481                                   )
1482                   ENDIF
1483                   IF ( pss(particles(n)%group) /= psn(particles(n)%group) )  THEN
1484                      rand_contr = ( random_function( iran_part ) - 0.5_wp ) * &
1485                                     pdy(particles(n)%group)
1486                      particles(n)%y = particles(n)%y +                        &
1487                              MERGE( rand_contr, SIGN( dy, rand_contr ),       &
1488                                     ABS( rand_contr ) < dy                    &
1489                                   )
1490                   ENDIF
1491                   IF ( psb(particles(n)%group) /= pst(particles(n)%group) )  THEN
1492                      rand_contr = ( random_function( iran_part ) - 0.5_wp ) * &
1493                                     pdz(particles(n)%group)
1494                      particles(n)%z = particles(n)%z +                        &
1495                              MERGE( rand_contr, SIGN( dzw(kp), rand_contr ),  &
1496                                     ABS( rand_contr ) < dzw(kp)               &
1497                                   )
1498                   ENDIF
1499                ENDDO
1500!
1501!--             Identify particles located outside the model domain and reflect
1502!--             or absorb them if necessary.
1503                CALL lpm_boundary_conds( 'bottom/top', i, j, k )
1504!
1505!--             Furthermore, remove particles located in topography. Note, as
1506!--             the particle speed is still zero at this point, wall
1507!--             reflection boundary conditions will not work in this case.
1508                particles =>                                                   &
1509                       grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1510                DO  n = local_start(kp,jp,ip), number_of_particles
1511                   i = particles(n)%x * ddx
1512                   j = particles(n)%y * ddy
1513                   k = particles(n)%z / dz(1) + 1 + offset_ocean_nzt
1514                   DO WHILE( zw(k) < particles(n)%z )
1515                      k = k + 1
1516                   ENDDO
1517                   DO WHILE( zw(k-1) > particles(n)%z )
1518                      k = k - 1
1519                   ENDDO
1520!
1521!--                Check if particle is within topography
1522                   IF ( .NOT. BTEST( wall_flags_static_0(k,j,i), 0 ) )  THEN
1523                      particles(n)%particle_mask = .FALSE.
1524                      deleted_particles = deleted_particles + 1
1525                   ENDIF
1526
1527                ENDDO
1528             ENDDO
1529          ENDDO
1530       ENDDO
1531!
1532!--    Exchange particles between grid cells and processors
1533       CALL lpm_move_particle
1534       CALL lpm_exchange_horiz
1535
1536    ENDIF
1537!
1538!-- In case of random_start_position, delete particles identified by
1539!-- lpm_exchange_horiz and lpm_boundary_conds. Then sort particles into blocks,
1540!-- which is needed for a fast interpolation of the LES fields on the particle
1541!-- position.
1542    CALL lpm_sort_and_delete
1543!
1544!-- Determine the current number of particles
1545    DO  ip = nxl, nxr
1546       DO  jp = nys, nyn
1547          DO  kp = nzb+1, nzt
1548             number_of_particles         = number_of_particles                 &
1549                                           + prt_count(kp,jp,ip)
1550          ENDDO
1551       ENDDO
1552    ENDDO
1553!
1554!-- Calculate the number of particles of the total domain
1555#if defined( __parallel )
1556    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1557    CALL MPI_ALLREDUCE( number_of_particles, total_number_of_particles, 1, &
1558    MPI_INTEGER, MPI_SUM, comm2d, ierr )
1559#else
1560    total_number_of_particles = number_of_particles
1561#endif
1562
1563    RETURN
1564
1565 END SUBROUTINE lpm_create_particle
1566 
1567 
1568!------------------------------------------------------------------------------!
1569! Description:
1570! ------------
1571!> This routine initialize the particles as aerosols with physio-chemical
1572!> properties.
1573!------------------------------------------------------------------------------!   
1574 SUBROUTINE lpm_init_aerosols(local_start)
1575
1576    REAL(wp) ::  afactor            !< curvature effects
1577    REAL(wp) ::  bfactor            !< solute effects
1578    REAL(wp) ::  dlogr              !< logarithmic width of radius bin
1579    REAL(wp) ::  e_a                !< vapor pressure
1580    REAL(wp) ::  e_s                !< saturation vapor pressure
1581    REAL(wp) ::  rmin = 0.005e-6_wp !< minimum aerosol radius
1582    REAL(wp) ::  rmax = 10.0e-6_wp  !< maximum aerosol radius
1583    REAL(wp) ::  r_mid              !< mean radius of bin
1584    REAL(wp) ::  r_l                !< left radius of bin
1585    REAL(wp) ::  r_r                !< right radius of bin
1586    REAL(wp) ::  sigma              !< surface tension
1587    REAL(wp) ::  t_int              !< temperature
1588
1589    INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg), INTENT(IN) ::  local_start !<
1590
1591    INTEGER(iwp) ::  n              !<
1592    INTEGER(iwp) ::  ip             !<
1593    INTEGER(iwp) ::  jp             !<
1594    INTEGER(iwp) ::  kp             !<
1595
1596!
1597!-- Set constants for different aerosol species
1598    IF ( TRIM( aero_species ) == 'nacl' )  THEN
1599       molecular_weight_of_solute = 0.05844_wp 
1600       rho_s                      = 2165.0_wp
1601       vanthoff                   = 2.0_wp
1602    ELSEIF ( TRIM( aero_species ) == 'c3h4o4' )  THEN
1603       molecular_weight_of_solute = 0.10406_wp 
1604       rho_s                      = 1600.0_wp
1605       vanthoff                   = 1.37_wp
1606    ELSEIF ( TRIM( aero_species ) == 'nh4o3' )  THEN
1607       molecular_weight_of_solute = 0.08004_wp 
1608       rho_s                      = 1720.0_wp
1609       vanthoff                   = 2.31_wp
1610    ELSE
1611       WRITE( message_string, * ) 'unknown aerosol species ',   &
1612                                'aero_species = "', TRIM( aero_species ), '"'
1613       CALL message( 'lpm_init', 'PA0470', 1, 2, 0, 6, 0 )
1614    ENDIF
1615!
1616!-- The following typical aerosol spectra are taken from Jaenicke (1993):
1617!-- Tropospheric aerosols. Published in Aerosol-Cloud-Climate Interactions.
1618    IF ( TRIM( aero_type ) == 'polar' )  THEN
1619       na        = (/ 2.17e1, 1.86e-1, 3.04e-4 /) * 1.0E6_wp
1620       rm        = (/ 0.0689, 0.375, 4.29 /) * 1.0E-6_wp
1621       log_sigma = (/ 0.245, 0.300, 0.291 /)
1622    ELSEIF ( TRIM( aero_type ) == 'background' )  THEN
1623       na        = (/ 1.29e2, 5.97e1, 6.35e1 /) * 1.0E6_wp
1624       rm        = (/ 0.0036, 0.127, 0.259 /) * 1.0E-6_wp
1625       log_sigma = (/ 0.645, 0.253, 0.425 /)
1626    ELSEIF ( TRIM( aero_type ) == 'maritime' )  THEN
1627       na        = (/ 1.33e2, 6.66e1, 3.06e0 /) * 1.0E6_wp
1628       rm        = (/ 0.0039, 0.133, 0.29 /) * 1.0E-6_wp
1629       log_sigma = (/ 0.657, 0.210, 0.396 /)
1630    ELSEIF ( TRIM( aero_type ) == 'continental' )  THEN
1631       na        = (/ 3.20e3, 2.90e3, 3.00e-1 /) * 1.0E6_wp
1632       rm        = (/ 0.01, 0.058, 0.9 /) * 1.0E-6_wp
1633       log_sigma = (/ 0.161, 0.217, 0.380 /)
1634    ELSEIF ( TRIM( aero_type ) == 'desert' )  THEN
1635       na        = (/ 7.26e2, 1.14e3, 1.78e-1 /) * 1.0E6_wp
1636       rm        = (/ 0.001, 0.0188, 10.8 /) * 1.0E-6_wp
1637       log_sigma = (/ 0.247, 0.770, 0.438 /)
1638    ELSEIF ( TRIM( aero_type ) == 'rural' )  THEN
1639       na        = (/ 6.65e3, 1.47e2, 1.99e3 /) * 1.0E6_wp
1640       rm        = (/ 0.00739, 0.0269, 0.0419 /) * 1.0E-6_wp
1641       log_sigma = (/ 0.225, 0.557, 0.266 /)
1642    ELSEIF ( TRIM( aero_type ) == 'urban' )  THEN
1643       na        = (/ 9.93e4, 1.11e3, 3.64e4 /) * 1.0E6_wp
1644       rm        = (/ 0.00651, 0.00714, 0.0248 /) * 1.0E-6_wp
1645       log_sigma = (/ 0.245, 0.666, 0.337 /)
1646    ELSEIF ( TRIM( aero_type ) == 'user' )  THEN
1647       CONTINUE
1648    ELSE
1649       WRITE( message_string, * ) 'unknown aerosol type ',   &
1650                                'aero_type = "', TRIM( aero_type ), '"'
1651       CALL message( 'lpm_init', 'PA0459', 1, 2, 0, 6, 0 )
1652    ENDIF
1653
1654    DO  ip = nxl, nxr
1655       DO  jp = nys, nyn
1656          DO  kp = nzb+1, nzt
1657
1658             number_of_particles = prt_count(kp,jp,ip)
1659             IF ( number_of_particles <= 0 )  CYCLE
1660             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1661
1662             dlogr   = ( LOG10(rmax) - LOG10(rmin) ) / ( number_of_particles - local_start(kp,jp,ip) + 1 )
1663!
1664!--          Initialize the aerosols with a predefined spectral distribution
1665!--          of the dry radius (logarithmically increasing bins) and a varying
1666!--          weighting factor
1667             DO  n = local_start(kp,jp,ip), number_of_particles  !only new particles
1668
1669                r_l   = 10.0**( LOG10( rmin ) + (n-1) * dlogr )
1670                r_r   = 10.0**( LOG10( rmin ) + n * dlogr )
1671                r_mid = SQRT( r_l * r_r )
1672
1673                particles(n)%aux1          = r_mid
1674                particles(n)%weight_factor =                                           &
1675                   ( na(1) / ( SQRT( 2.0_wp * pi ) * log_sigma(1) ) *                     &
1676                     EXP( - LOG10( r_mid / rm(1) )**2 / ( 2.0_wp * log_sigma(1)**2 ) ) +  &
1677                     na(2) / ( SQRT( 2.0_wp * pi ) * log_sigma(2) ) *                     &
1678                     EXP( - LOG10( r_mid / rm(2) )**2 / ( 2.0_wp * log_sigma(2)**2 ) ) +  &
1679                     na(3) / ( SQRT( 2.0_wp * pi ) * log_sigma(3) ) *                     &
1680                     EXP( - LOG10( r_mid / rm(3) )**2 / ( 2.0_wp * log_sigma(3)**2 ) )    &
1681                   ) * ( LOG10(r_r) - LOG10(r_l) ) * ( dx * dy * dzw(kp) )
1682
1683!
1684!--             Multiply weight_factor with the namelist parameter aero_weight
1685!--             to increase or decrease the number of simulated aerosols
1686                particles(n)%weight_factor = particles(n)%weight_factor * aero_weight
1687
1688                IF ( particles(n)%weight_factor - FLOOR(particles(n)%weight_factor,KIND=wp) &
1689                     > random_function( iran_part ) )  THEN
1690                   particles(n)%weight_factor = FLOOR(particles(n)%weight_factor,KIND=wp) + 1.0_wp
1691                ELSE
1692                   particles(n)%weight_factor = FLOOR(particles(n)%weight_factor,KIND=wp)
1693                ENDIF
1694!
1695!--             Unnecessary particles will be deleted
1696                IF ( particles(n)%weight_factor <= 0.0_wp )  particles(n)%particle_mask = .FALSE.
1697
1698             ENDDO
1699!
1700!--          Set particle radius to equilibrium radius based on the environmental
1701!--          supersaturation (Khvorostyanov and Curry, 2007, JGR). This avoids
1702!--          the sometimes lengthy growth toward their equilibrium radius within
1703!--          the simulation.
1704             t_int  = pt(kp,jp,ip) * exner(kp)
1705
1706             e_s = magnus( t_int )
1707             e_a = q(kp,jp,ip) * hyp(kp) / ( q(kp,jp,ip) + rd_d_rv )
1708
1709             sigma   = 0.0761_wp - 0.000155_wp * ( t_int - 273.15_wp )
1710             afactor = 2.0_wp * sigma / ( rho_l * r_v * t_int )
1711
1712             bfactor = vanthoff * molecular_weight_of_water *    &
1713                       rho_s / ( molecular_weight_of_solute * rho_l )
1714!
1715!--          The formula is only valid for subsaturated environments. For
1716!--          supersaturations higher than -5 %, the supersaturation is set to -5%.
1717             IF ( e_a / e_s >= 0.95_wp )  e_a = 0.95_wp * e_s
1718
1719             DO  n = local_start(kp,jp,ip), number_of_particles  !only new particles
1720!
1721!--             For details on this equation, see Eq. (14) of Khvorostyanov and
1722!--             Curry (2007, JGR)
1723                particles(n)%radius = bfactor**0.3333333_wp *                  &
1724                   particles(n)%aux1 / ( 1.0_wp - e_a / e_s )**0.3333333_wp / &
1725                   ( 1.0_wp + ( afactor / ( 3.0_wp * bfactor**0.3333333_wp *   &
1726                     particles(n)%aux1 ) ) /                                  &
1727                     ( 1.0_wp - e_a / e_s )**0.6666666_wp                      &
1728                   )
1729
1730             ENDDO
1731
1732          ENDDO
1733       ENDDO
1734    ENDDO
1735
1736 END SUBROUTINE lpm_init_aerosols
1737
1738
1739!------------------------------------------------------------------------------!
1740! Description:
1741! ------------
1742!> Calculates quantities required for considering the SGS velocity fluctuations
1743!> in the particle transport by a stochastic approach. The respective
1744!> quantities are: SGS-TKE gradients and horizontally averaged profiles of the
1745!> SGS TKE and the resolved-scale velocity variances.
1746!------------------------------------------------------------------------------!
1747 SUBROUTINE lpm_init_sgs_tke
1748
1749    USE statistics,                                                            &
1750        ONLY:  flow_statistics_called, hom, sums, sums_l
1751
1752    INTEGER(iwp) ::  i      !< index variable along x
1753    INTEGER(iwp) ::  j      !< index variable along y
1754    INTEGER(iwp) ::  k      !< index variable along z
1755    INTEGER(iwp) ::  m      !< running index for the surface elements
1756
1757    REAL(wp) ::  flag1      !< flag to mask topography
1758
1759!
1760!-- TKE gradient along x and y
1761    DO  i = nxl, nxr
1762       DO  j = nys, nyn
1763          DO  k = nzb, nzt+1
1764
1765             IF ( .NOT. BTEST( wall_flags_static_0(k,j,i-1), 0 )  .AND.               &
1766                        BTEST( wall_flags_static_0(k,j,i), 0   )  .AND.               &
1767                        BTEST( wall_flags_static_0(k,j,i+1), 0 ) )                    &
1768             THEN
1769                de_dx(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1770                               ( e(k,j,i+1) - e(k,j,i) ) * ddx
1771             ELSEIF ( BTEST( wall_flags_static_0(k,j,i-1), 0 )  .AND.                 &
1772                      BTEST( wall_flags_static_0(k,j,i), 0   )  .AND.                 &
1773                .NOT. BTEST( wall_flags_static_0(k,j,i+1), 0 ) )                      &
1774             THEN
1775                de_dx(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1776                               ( e(k,j,i) - e(k,j,i-1) ) * ddx
1777             ELSEIF ( .NOT. BTEST( wall_flags_static_0(k,j,i), 22   )  .AND.          &
1778                      .NOT. BTEST( wall_flags_static_0(k,j,i+1), 22 ) )               &   
1779             THEN
1780                de_dx(k,j,i) = 0.0_wp
1781             ELSEIF ( .NOT. BTEST( wall_flags_static_0(k,j,i-1), 22 )  .AND.          &
1782                      .NOT. BTEST( wall_flags_static_0(k,j,i), 22   ) )               &
1783             THEN
1784                de_dx(k,j,i) = 0.0_wp
1785             ELSE
1786                de_dx(k,j,i) = sgs_wf_part * ( e(k,j,i+1) - e(k,j,i-1) ) * ddx
1787             ENDIF
1788
1789             IF ( .NOT. BTEST( wall_flags_static_0(k,j-1,i), 0 )  .AND.               &
1790                        BTEST( wall_flags_static_0(k,j,i), 0   )  .AND.               &
1791                        BTEST( wall_flags_static_0(k,j+1,i), 0 ) )                    &
1792             THEN
1793                de_dy(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1794                               ( e(k,j+1,i) - e(k,j,i) ) * ddy
1795             ELSEIF ( BTEST( wall_flags_static_0(k,j-1,i), 0 )  .AND.                 &
1796                      BTEST( wall_flags_static_0(k,j,i), 0   )  .AND.                 &
1797                .NOT. BTEST( wall_flags_static_0(k,j+1,i), 0 ) )                      &
1798             THEN
1799                de_dy(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1800                               ( e(k,j,i) - e(k,j-1,i) ) * ddy
1801             ELSEIF ( .NOT. BTEST( wall_flags_static_0(k,j,i), 22   )  .AND.          &
1802                      .NOT. BTEST( wall_flags_static_0(k,j+1,i), 22 ) )               &   
1803             THEN
1804                de_dy(k,j,i) = 0.0_wp
1805             ELSEIF ( .NOT. BTEST( wall_flags_static_0(k,j-1,i), 22 )  .AND.          &
1806                      .NOT. BTEST( wall_flags_static_0(k,j,i), 22   ) )               &
1807             THEN
1808                de_dy(k,j,i) = 0.0_wp
1809             ELSE
1810                de_dy(k,j,i) = sgs_wf_part * ( e(k,j+1,i) - e(k,j-1,i) ) * ddy
1811             ENDIF
1812
1813          ENDDO
1814       ENDDO
1815    ENDDO
1816
1817!
1818!-- TKE gradient along z at topograhy and  including bottom and top boundary conditions
1819    DO  i = nxl, nxr
1820       DO  j = nys, nyn
1821          DO  k = nzb+1, nzt-1
1822!
1823!--          Flag to mask topography
1824             flag1 = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_static_0(k,j,i), 0  ) )
1825
1826             de_dz(k,j,i) = 2.0_wp * sgs_wf_part *                             &
1827                           ( e(k+1,j,i) - e(k-1,j,i) ) / ( zu(k+1) - zu(k-1) ) &
1828                                                 * flag1
1829          ENDDO
1830!
1831!--       upward-facing surfaces
1832          DO  m = bc_h(0)%start_index(j,i), bc_h(0)%end_index(j,i)
1833             k            = bc_h(0)%k(m)
1834             de_dz(k,j,i) = 2.0_wp * sgs_wf_part *                             &
1835                           ( e(k+1,j,i) - e(k,j,i)   ) / ( zu(k+1) - zu(k) )
1836          ENDDO
1837!
1838!--       downward-facing surfaces
1839          DO  m = bc_h(1)%start_index(j,i), bc_h(1)%end_index(j,i)
1840             k            = bc_h(1)%k(m)
1841             de_dz(k,j,i) = 2.0_wp * sgs_wf_part *                             &
1842                           ( e(k,j,i) - e(k-1,j,i)   ) / ( zu(k) - zu(k-1) )
1843          ENDDO
1844
1845          de_dz(nzb,j,i)   = 0.0_wp
1846          de_dz(nzt,j,i)   = 0.0_wp
1847          de_dz(nzt+1,j,i) = 0.0_wp
1848       ENDDO
1849    ENDDO
1850!
1851!-- Ghost point exchange
1852    CALL exchange_horiz( de_dx, nbgp )
1853    CALL exchange_horiz( de_dy, nbgp )
1854    CALL exchange_horiz( de_dz, nbgp )
1855    CALL exchange_horiz( diss, nbgp  )
1856!
1857!-- Set boundary conditions at non-periodic boundaries. Note, at non-period
1858!-- boundaries zero-gradient boundary conditions are set for the subgrid TKE.
1859!-- Thus, TKE gradients normal to the respective lateral boundaries are zero,
1860!-- while tangetial TKE gradients then must be the same as within the prognostic
1861!-- domain. 
1862    IF ( bc_dirichlet_l )  THEN
1863       de_dx(:,:,-1) = 0.0_wp
1864       de_dy(:,:,-1) = de_dy(:,:,0) 
1865       de_dz(:,:,-1) = de_dz(:,:,0)
1866    ENDIF
1867    IF ( bc_dirichlet_r )  THEN
1868       de_dx(:,:,nxr+1) = 0.0_wp
1869       de_dy(:,:,nxr+1) = de_dy(:,:,nxr) 
1870       de_dz(:,:,nxr+1) = de_dz(:,:,nxr)
1871    ENDIF
1872    IF ( bc_dirichlet_n )  THEN
1873       de_dx(:,nyn+1,:) = de_dx(:,nyn,:)
1874       de_dy(:,nyn+1,:) = 0.0_wp 
1875       de_dz(:,nyn+1,:) = de_dz(:,nyn,:)
1876    ENDIF
1877    IF ( bc_dirichlet_s )  THEN
1878       de_dx(:,nys-1,:) = de_dx(:,nys,:)
1879       de_dy(:,nys-1,:) = 0.0_wp 
1880       de_dz(:,nys-1,:) = de_dz(:,nys,:)
1881    ENDIF 
1882!
1883!-- Calculate the horizontally averaged profiles of SGS TKE and resolved
1884!-- velocity variances (they may have been already calculated in routine
1885!-- flow_statistics).
1886    IF ( .NOT. flow_statistics_called )  THEN
1887
1888!
1889!--    First calculate horizontally averaged profiles of the horizontal
1890!--    velocities.
1891       sums_l(:,1,0) = 0.0_wp
1892       sums_l(:,2,0) = 0.0_wp
1893
1894       DO  i = nxl, nxr
1895          DO  j =  nys, nyn
1896             DO  k = nzb, nzt+1
1897!
1898!--             Flag indicating vicinity of wall
1899                flag1 = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_static_0(k,j,i), 24 ) )
1900
1901                sums_l(k,1,0)  = sums_l(k,1,0)  + u(k,j,i) * flag1
1902                sums_l(k,2,0)  = sums_l(k,2,0)  + v(k,j,i) * flag1
1903             ENDDO
1904          ENDDO
1905       ENDDO
1906
1907#if defined( __parallel )
1908!
1909!--    Compute total sum from local sums
1910       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1911       CALL MPI_ALLREDUCE( sums_l(nzb,1,0), sums(nzb,1), nzt+2-nzb, &
1912                           MPI_REAL, MPI_SUM, comm2d, ierr )
1913       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1914       CALL MPI_ALLREDUCE( sums_l(nzb,2,0), sums(nzb,2), nzt+2-nzb, &
1915                              MPI_REAL, MPI_SUM, comm2d, ierr )
1916#else
1917       sums(:,1) = sums_l(:,1,0)
1918       sums(:,2) = sums_l(:,2,0)
1919#endif
1920
1921!
1922!--    Final values are obtained by division by the total number of grid
1923!--    points used for the summation.
1924       hom(:,1,1,0) = sums(:,1) / ngp_2dh_outer(:,0)   ! u
1925       hom(:,1,2,0) = sums(:,2) / ngp_2dh_outer(:,0)   ! v
1926
1927!
1928!--    Now calculate the profiles of SGS TKE and the resolved-scale
1929!--    velocity variances
1930       sums_l(:,8,0)  = 0.0_wp
1931       sums_l(:,30,0) = 0.0_wp
1932       sums_l(:,31,0) = 0.0_wp
1933       sums_l(:,32,0) = 0.0_wp
1934       DO  i = nxl, nxr
1935          DO  j = nys, nyn
1936             DO  k = nzb, nzt+1
1937!
1938!--             Flag indicating vicinity of wall
1939                flag1 = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_static_0(k,j,i), 24 ) )
1940
1941                sums_l(k,8,0)  = sums_l(k,8,0)  + e(k,j,i)                       * flag1
1942                sums_l(k,30,0) = sums_l(k,30,0) + ( u(k,j,i) - hom(k,1,1,0) )**2 * flag1
1943                sums_l(k,31,0) = sums_l(k,31,0) + ( v(k,j,i) - hom(k,1,2,0) )**2 * flag1
1944                sums_l(k,32,0) = sums_l(k,32,0) + w(k,j,i)**2                    * flag1
1945             ENDDO
1946          ENDDO
1947       ENDDO
1948
1949#if defined( __parallel )
1950!
1951!--    Compute total sum from local sums
1952       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1953       CALL MPI_ALLREDUCE( sums_l(nzb,8,0), sums(nzb,8), nzt+2-nzb, &
1954                           MPI_REAL, MPI_SUM, comm2d, ierr )
1955       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1956       CALL MPI_ALLREDUCE( sums_l(nzb,30,0), sums(nzb,30), nzt+2-nzb, &
1957                           MPI_REAL, MPI_SUM, comm2d, ierr )
1958       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1959       CALL MPI_ALLREDUCE( sums_l(nzb,31,0), sums(nzb,31), nzt+2-nzb, &
1960                           MPI_REAL, MPI_SUM, comm2d, ierr )
1961       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1962       CALL MPI_ALLREDUCE( sums_l(nzb,32,0), sums(nzb,32), nzt+2-nzb, &
1963                           MPI_REAL, MPI_SUM, comm2d, ierr )
1964
1965#else
1966       sums(:,8)  = sums_l(:,8,0)
1967       sums(:,30) = sums_l(:,30,0)
1968       sums(:,31) = sums_l(:,31,0)
1969       sums(:,32) = sums_l(:,32,0)
1970#endif
1971
1972!
1973!--    Final values are obtained by division by the total number of grid
1974!--    points used for the summation.
1975       hom(:,1,8,0)  = sums(:,8)  / ngp_2dh_outer(:,0)   ! e
1976       hom(:,1,30,0) = sums(:,30) / ngp_2dh_outer(:,0)   ! u*2
1977       hom(:,1,31,0) = sums(:,31) / ngp_2dh_outer(:,0)   ! v*2
1978       hom(:,1,32,0) = sums(:,32) / ngp_2dh_outer(:,0)   ! w*2
1979
1980    ENDIF
1981
1982 END SUBROUTINE lpm_init_sgs_tke
1983 
1984 
1985!------------------------------------------------------------------------------!
1986! Description:
1987! ------------
1988!> Sobroutine control lpm actions, i.e. all actions during one time step.
1989!------------------------------------------------------------------------------! 
1990 SUBROUTINE lpm_actions( location )
1991
1992    CHARACTER (LEN=*), INTENT(IN) ::  location !< call location string
1993
1994    INTEGER(iwp)       ::  i                  !<
1995    INTEGER(iwp)       ::  ie                 !<
1996    INTEGER(iwp)       ::  is                 !<
1997    INTEGER(iwp)       ::  j                  !<
1998    INTEGER(iwp)       ::  je                 !<
1999    INTEGER(iwp)       ::  js                 !<
2000    INTEGER(iwp), SAVE ::  lpm_count = 0      !<
2001    INTEGER(iwp)       ::  k                  !<
2002    INTEGER(iwp)       ::  ke                 !<
2003    INTEGER(iwp)       ::  ks                 !<
2004    INTEGER(iwp)       ::  m                  !<
2005    INTEGER(iwp), SAVE ::  steps = 0          !<
2006
2007    LOGICAL            ::  first_loop_stride  !<
2008
2009
2010    SELECT CASE ( location )
2011
2012       CASE ( 'after_pressure_solver' )
2013!
2014!--       The particle model is executed if particle advection start is reached and only at the end
2015!--       of the intermediate time step loop.
2016          IF ( time_since_reference_point >= particle_advection_start   &
2017               .AND.  intermediate_timestep_count == intermediate_timestep_count_max )             &
2018          THEN
2019             CALL cpu_log( log_point(25), 'lpm', 'start' )
2020!
2021!--          Write particle data at current time on file.
2022!--          This has to be done here, before particles are further processed,
2023!--          because they may be deleted within this timestep (in case that
2024!--          dt_write_particle_data = dt_prel = particle_maximum_age).
2025             time_write_particle_data = time_write_particle_data + dt_3d
2026             IF ( time_write_particle_data >= dt_write_particle_data )  THEN
2027
2028                CALL lpm_data_output_particles
2029!
2030!--          The MOD function allows for changes in the output interval with restart
2031!--          runs.
2032                time_write_particle_data = MOD( time_write_particle_data, &
2033                                           MAX( dt_write_particle_data, dt_3d ) )
2034             ENDIF
2035
2036!
2037!--          Initialize arrays for marking those particles to be deleted after the
2038!--          (sub-) timestep
2039             deleted_particles = 0
2040
2041!
2042!--          Initialize variables used for accumulating the number of particles
2043!--          xchanged between the subdomains during all sub-timesteps (if sgs
2044!--          velocities are included). These data are output further below on the
2045!--          particle statistics file.
2046             trlp_count_sum      = 0
2047             trlp_count_recv_sum = 0
2048             trrp_count_sum      = 0
2049             trrp_count_recv_sum = 0
2050             trsp_count_sum      = 0
2051             trsp_count_recv_sum = 0
2052             trnp_count_sum      = 0
2053             trnp_count_recv_sum = 0
2054!
2055!--          Calculate exponential term used in case of particle inertia for each
2056!--          of the particle groups
2057             DO  m = 1, number_of_particle_groups
2058                IF ( particle_groups(m)%density_ratio /= 0.0_wp )  THEN
2059                   particle_groups(m)%exp_arg  =                                        &
2060                             4.5_wp * particle_groups(m)%density_ratio *                &
2061                             molecular_viscosity / ( particle_groups(m)%radius )**2
2062
2063                   particle_groups(m)%exp_term = EXP( -particle_groups(m)%exp_arg *     &
2064                             dt_3d )
2065                ENDIF
2066             ENDDO
2067!
2068!--          If necessary, release new set of particles
2069             IF ( ( simulated_time - last_particle_release_time ) >= dt_prel  .AND.     &
2070                    end_time_prel > simulated_time )  THEN
2071                DO WHILE ( ( simulated_time - last_particle_release_time ) >= dt_prel )
2072                   CALL lpm_create_particle( PHASE_RELEASE )
2073                   last_particle_release_time = last_particle_release_time + dt_prel
2074                ENDDO
2075             ENDIF
2076!
2077!--          Reset summation arrays
2078             IF ( cloud_droplets )  THEN
2079                ql_c  = 0.0_wp
2080                ql_v  = 0.0_wp
2081                ql_vp = 0.0_wp
2082             ENDIF
2083
2084             first_loop_stride = .TRUE.
2085             grid_particles(:,:,:)%time_loop_done = .TRUE.
2086!
2087!--          Timestep loop for particle advection.
2088!--          This loop has to be repeated until the advection time of every particle
2089!--          (within the total domain!) has reached the LES timestep (dt_3d).
2090!--          In case of including the SGS velocities, the particle timestep may be
2091!--          smaller than the LES timestep (because of the Lagrangian timescale
2092!--          restriction) and particles may require to undergo several particle
2093!--          timesteps, before the LES timestep is reached. Because the number of these
2094!--          particle timesteps to be carried out is unknown at first, these steps are
2095!--          carried out in the following infinite loop with exit condition.
2096             DO
2097                CALL cpu_log( log_point_s(44), 'lpm_advec', 'start' )
2098                CALL cpu_log( log_point_s(44), 'lpm_advec', 'pause' )
2099
2100!
2101!--             If particle advection includes SGS velocity components, calculate the
2102!--             required SGS quantities (i.e. gradients of the TKE, as well as
2103!--             horizontally averaged profiles of the SGS TKE and the resolved-scale
2104!--             velocity variances)
2105                IF ( use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
2106                   CALL lpm_init_sgs_tke
2107                ENDIF
2108!
2109!--             In case SGS-particle speed is considered, particles may carry out
2110!--             several particle timesteps. In order to prevent unnecessary
2111!--             treatment of particles that already reached the final time level,
2112!--             particles are sorted into contiguous blocks of finished and
2113!--             not-finished particles, in addition to their already sorting
2114!--             according to their sub-boxes.
2115                IF ( .NOT. first_loop_stride  .AND.  use_sgs_for_particles )            &
2116                   CALL lpm_sort_timeloop_done
2117                DO  i = nxl, nxr
2118                   DO  j = nys, nyn
2119                      DO  k = nzb+1, nzt
2120
2121                         number_of_particles = prt_count(k,j,i)
2122!
2123!--                      If grid cell gets empty, flag must be true
2124                         IF ( number_of_particles <= 0 )  THEN
2125                            grid_particles(k,j,i)%time_loop_done = .TRUE.
2126                            CYCLE
2127                         ENDIF
2128
2129                         IF ( .NOT. first_loop_stride  .AND.  &
2130                              grid_particles(k,j,i)%time_loop_done )  CYCLE
2131
2132                         particles => grid_particles(k,j,i)%particles(1:number_of_particles)
2133
2134                         particles(1:number_of_particles)%particle_mask = .TRUE.
2135!
2136!--                      Initialize the variable storing the total time that a particle
2137!--                      has advanced within the timestep procedure
2138                         IF ( first_loop_stride )  THEN
2139                            particles(1:number_of_particles)%dt_sum = 0.0_wp
2140                         ENDIF
2141!
2142!--                      Particle (droplet) growth by condensation/evaporation and
2143!--                      collision
2144                         IF ( cloud_droplets  .AND.  first_loop_stride)  THEN
2145!
2146!--                         Droplet growth by condensation / evaporation
2147                            CALL lpm_droplet_condensation(i,j,k)
2148!
2149!--                         Particle growth by collision
2150                            IF ( collision_kernel /= 'none' )  THEN
2151                               CALL lpm_droplet_collision(i,j,k)
2152                            ENDIF
2153
2154                         ENDIF
2155!
2156!--                      Initialize the switch used for the loop exit condition checked
2157!--                      at the end of this loop. If at least one particle has failed to
2158!--                      reach the LES timestep, this switch will be set false in
2159!--                      lpm_advec.
2160                         dt_3d_reached_l = .TRUE.
2161
2162!
2163!--                      Particle advection
2164                         CALL lpm_advec( i, j, k )
2165!
2166!--                      Particle reflection from walls. Only applied if the particles
2167!--                      are in the vertical range of the topography. (Here, some
2168!--                      optimization is still possible.)
2169                         IF ( topography /= 'flat'  .AND.  k < nzb_max + 2 )  THEN
2170                            CALL  lpm_boundary_conds( 'walls', i, j, k )
2171                         ENDIF
2172!
2173!--                      User-defined actions after the calculation of the new particle
2174!--                      position
2175                         CALL user_lpm_advec( i, j, k )
2176!
2177!--                      Apply boundary conditions to those particles that have crossed
2178!--                      the top or bottom boundary and delete those particles, which are
2179!--                      older than allowed
2180                         CALL lpm_boundary_conds( 'bottom/top', i, j, k )
2181!
2182!---                     If not all particles of the actual grid cell have reached the
2183!--                      LES timestep, this cell has to do another loop iteration. Due to
2184!--                      the fact that particles can move into neighboring grid cells,
2185!--                      these neighbor cells also have to perform another loop iteration.
2186!--                      Please note, this realization does not work properly if
2187!--                      particles move into another subdomain.
2188                         IF ( .NOT. dt_3d_reached_l )  THEN
2189                            ks = MAX(nzb+1,k-1)
2190                            ke = MIN(nzt,k+1)
2191                            js = MAX(nys,j-1)
2192                            je = MIN(nyn,j+1)
2193                            is = MAX(nxl,i-1)
2194                            ie = MIN(nxr,i+1)
2195                            grid_particles(ks:ke,js:je,is:ie)%time_loop_done = .FALSE.
2196                         ELSE
2197                            grid_particles(k,j,i)%time_loop_done = .TRUE.
2198                         ENDIF
2199
2200                      ENDDO
2201                   ENDDO
2202                ENDDO
2203                steps = steps + 1
2204                dt_3d_reached_l = ALL(grid_particles(:,:,:)%time_loop_done)
2205!
2206!--             Find out, if all particles on every PE have completed the LES timestep
2207!--             and set the switch corespondingly
2208#if defined( __parallel )
2209                IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2210                CALL MPI_ALLREDUCE( dt_3d_reached_l, dt_3d_reached, 1, MPI_LOGICAL, &
2211                                    MPI_LAND, comm2d, ierr )
2212#else
2213                dt_3d_reached = dt_3d_reached_l
2214#endif
2215                CALL cpu_log( log_point_s(44), 'lpm_advec', 'stop' )
2216
2217!
2218!--             Apply splitting and merging algorithm
2219                IF ( cloud_droplets )  THEN
2220                   IF ( splitting )  THEN
2221                      CALL lpm_splitting
2222                   ENDIF
2223                   IF ( merging )  THEN
2224                      CALL lpm_merging
2225                   ENDIF
2226                ENDIF
2227!
2228!--             Move Particles local to PE to a different grid cell
2229                CALL lpm_move_particle
2230!
2231!--             Horizontal boundary conditions including exchange between subdmains
2232                CALL lpm_exchange_horiz
2233
2234!
2235!--             IF .FALSE., lpm_sort_and_delete is done inside pcmp
2236                IF ( .NOT. dt_3d_reached  .OR.  .NOT. nested_run )   THEN
2237!
2238!--                Pack particles (eliminate those marked for deletion),
2239!--                determine new number of particles
2240                   CALL lpm_sort_and_delete
2241
2242!--                Initialize variables for the next (sub-) timestep, i.e., for marking
2243!--                those particles to be deleted after the timestep
2244                   deleted_particles = 0
2245                ENDIF
2246
2247                IF ( dt_3d_reached )  EXIT
2248
2249                first_loop_stride = .FALSE.
2250             ENDDO   ! timestep loop
2251!
2252!--          in case of nested runs do the transfer of particles after every full model time step
2253             IF ( nested_run )   THEN
2254                CALL particles_from_parent_to_child
2255                CALL particles_from_child_to_parent
2256                CALL pmcp_p_delete_particles_in_fine_grid_area
2257
2258                CALL lpm_sort_and_delete
2259
2260                deleted_particles = 0
2261             ENDIF
2262
2263!
2264!--          Calculate the new liquid water content for each grid box
2265             IF ( cloud_droplets )  CALL lpm_calc_liquid_water_content
2266
2267!
2268!--          At the end all arrays are exchanged
2269             IF ( cloud_droplets )  THEN
2270                CALL exchange_horiz( ql, nbgp )
2271                CALL exchange_horiz( ql_c, nbgp )
2272                CALL exchange_horiz( ql_v, nbgp )
2273                CALL exchange_horiz( ql_vp, nbgp )
2274             ENDIF
2275
2276!
2277!--          Deallocate unused memory
2278             IF ( deallocate_memory  .AND.  lpm_count == step_dealloc )  THEN
2279                CALL dealloc_particles_array
2280                lpm_count = 0
2281             ELSEIF ( deallocate_memory )  THEN
2282                lpm_count = lpm_count + 1
2283             ENDIF
2284
2285!
2286!--          Write particle statistics (in particular the number of particles
2287!--          exchanged between the subdomains) on file
2288             IF ( write_particle_statistics )  CALL lpm_write_exchange_statistics
2289!
2290!--          Execute Interactions of condnesation and evaporation to humidity and
2291!--          temperature field
2292             IF ( cloud_droplets )  THEN
2293                CALL lpm_interaction_droplets_ptq
2294                CALL exchange_horiz( pt, nbgp )
2295                CALL exchange_horiz( q, nbgp )
2296             ENDIF
2297
2298             CALL cpu_log( log_point(25), 'lpm', 'stop' )
2299
2300! !
2301! !--       Output of particle time series
2302!           IF ( particle_advection )  THEN
2303!              IF ( time_dopts >= dt_dopts  .OR.                                                        &
2304!                   ( time_since_reference_point >= particle_advection_start  .AND.                     &
2305!                    first_call_lpm ) )  THEN
2306!                 CALL lpm_data_output_ptseries
2307!                 time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
2308!              ENDIF
2309!           ENDIF
2310
2311!
2312!--           Set this switch to .false. @todo: maybe find better solution.
2313              first_call_lpm = .FALSE.
2314           ENDIF! ENDIF statement of lpm_actions('after_pressure_solver')
2315
2316       CASE ( 'after_integration' )
2317!
2318!--       Call at the end of timestep routine to save particle velocities fields
2319!--       for the next timestep
2320          CALL lpm_swap_timelevel_for_particle_advection
2321
2322       CASE DEFAULT
2323          CONTINUE
2324
2325    END SELECT
2326
2327 END SUBROUTINE lpm_actions
2328 
2329 
2330!------------------------------------------------------------------------------!
2331! Description:
2332! ------------
2333!
2334!------------------------------------------------------------------------------!
2335 SUBROUTINE particles_from_parent_to_child
2336    IMPLICIT NONE
2337
2338    CALL pmcp_c_get_particle_from_parent                         ! Child actions
2339    CALL pmcp_p_fill_particle_win                                ! Parent actions
2340
2341    RETURN
2342 END SUBROUTINE particles_from_parent_to_child
2343
2344 
2345!------------------------------------------------------------------------------!
2346! Description:
2347! ------------
2348!
2349!------------------------------------------------------------------------------!
2350 SUBROUTINE particles_from_child_to_parent
2351    IMPLICIT NONE
2352
2353    CALL pmcp_c_send_particle_to_parent                         ! Child actions
2354    CALL pmcp_p_empty_particle_win                              ! Parent actions
2355
2356    RETURN
2357 END SUBROUTINE particles_from_child_to_parent
2358 
2359!------------------------------------------------------------------------------!
2360! Description:
2361! ------------
2362!> This routine write exchange statistics of the lpm in a ascii file.
2363!------------------------------------------------------------------------------!
2364 SUBROUTINE lpm_write_exchange_statistics
2365
2366    INTEGER(iwp) ::  ip         !<
2367    INTEGER(iwp) ::  jp         !<
2368    INTEGER(iwp) ::  kp         !<
2369    INTEGER(iwp) ::  tot_number_of_particles !<
2370
2371!
2372!-- Determine the current number of particles
2373    number_of_particles         = 0
2374    DO  ip = nxl, nxr
2375       DO  jp = nys, nyn
2376          DO  kp = nzb+1, nzt
2377             number_of_particles = number_of_particles                         &
2378                                     + prt_count(kp,jp,ip)
2379          ENDDO
2380       ENDDO
2381    ENDDO
2382
2383    CALL check_open( 80 )
2384#if defined( __parallel )
2385    WRITE ( 80, 8000 )  current_timestep_number+1, simulated_time+dt_3d, &
2386                        number_of_particles, pleft, trlp_count_sum,      &
2387                        trlp_count_recv_sum, pright, trrp_count_sum,     &
2388                        trrp_count_recv_sum, psouth, trsp_count_sum,     &
2389                        trsp_count_recv_sum, pnorth, trnp_count_sum,     &
2390                        trnp_count_recv_sum
2391#else
2392    WRITE ( 80, 8000 )  current_timestep_number+1, simulated_time+dt_3d, &
2393                        number_of_particles
2394#endif
2395    CALL close_file( 80 )
2396
2397    IF ( number_of_particles > 0 )  THEN
2398        WRITE(9,*) 'number_of_particles ', number_of_particles,                &
2399                    current_timestep_number + 1, simulated_time + dt_3d
2400    ENDIF
2401
2402#if defined( __parallel )
2403    CALL MPI_ALLREDUCE( number_of_particles, tot_number_of_particles, 1,       &
2404                        MPI_INTEGER, MPI_SUM, comm2d, ierr )
2405#else
2406    tot_number_of_particles = number_of_particles
2407#endif
2408
2409    IF ( nested_run )  THEN
2410       CALL pmcp_g_print_number_of_particles( simulated_time+dt_3d,            &
2411                                              tot_number_of_particles)
2412    ENDIF
2413
2414!
2415!-- Formats
24168000 FORMAT (I6,1X,F7.2,4X,I10,5X,4(I3,1X,I4,'/',I4,2X),6X,I10)
2417
2418
2419 END SUBROUTINE lpm_write_exchange_statistics
2420 
2421
2422!------------------------------------------------------------------------------!
2423! Description:
2424! ------------
2425!> Write particle data in FORTRAN binary and/or netCDF format
2426!------------------------------------------------------------------------------!
2427 SUBROUTINE lpm_data_output_particles
2428 
2429    INTEGER(iwp) ::  ip !<
2430    INTEGER(iwp) ::  jp !<
2431    INTEGER(iwp) ::  kp !<
2432
2433    CALL cpu_log( log_point_s(40), 'lpm_data_output', 'start' )
2434
2435!
2436!-- Attention: change version number for unit 85 (in routine check_open)
2437!--            whenever the output format for this unit is changed!
2438    CALL check_open( 85 )
2439
2440    WRITE ( 85 )  simulated_time
2441    WRITE ( 85 )  prt_count
2442
2443    DO  ip = nxl, nxr
2444       DO  jp = nys, nyn
2445          DO  kp = nzb+1, nzt
2446             number_of_particles = prt_count(kp,jp,ip)
2447             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
2448             IF ( number_of_particles <= 0 )  CYCLE
2449             WRITE ( 85 )  particles
2450          ENDDO
2451       ENDDO
2452    ENDDO
2453
2454    CALL close_file( 85 )
2455
2456
2457#if defined( __netcdf )
2458! !
2459! !-- Output in netCDF format
2460!     CALL check_open( 108 )
2461!
2462! !
2463! !-- Update the NetCDF time axis
2464!     prt_time_count = prt_time_count + 1
2465!
2466!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_time_prt, &
2467!                             (/ simulated_time /),        &
2468!                             start = (/ prt_time_count /), count = (/ 1 /) )
2469!     CALL netcdf_handle_error( 'lpm_data_output_particles', 1 )
2470!
2471! !
2472! !-- Output the real number of particles used
2473!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_rnop_prt, &
2474!                             (/ number_of_particles /),   &
2475!                             start = (/ prt_time_count /), count = (/ 1 /) )
2476!     CALL netcdf_handle_error( 'lpm_data_output_particles', 2 )
2477!
2478! !
2479! !-- Output all particle attributes
2480!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(1), particles%age,      &
2481!                             start = (/ 1, prt_time_count /),               &
2482!                             count = (/ maximum_number_of_particles /) )
2483!     CALL netcdf_handle_error( 'lpm_data_output_particles', 3 )
2484!
2485!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(2), particles%user,     &
2486!                             start = (/ 1, prt_time_count /),               &
2487!                             count = (/ maximum_number_of_particles /) )
2488!     CALL netcdf_handle_error( 'lpm_data_output_particles', 4 )
2489!
2490!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(3), particles%origin_x, &
2491!                             start = (/ 1, prt_time_count /),               &
2492!                             count = (/ maximum_number_of_particles /) )
2493!     CALL netcdf_handle_error( 'lpm_data_output_particles', 5 )
2494!
2495!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(4), particles%origin_y, &
2496!                             start = (/ 1, prt_time_count /),               &
2497!                             count = (/ maximum_number_of_particles /) )
2498!     CALL netcdf_handle_error( 'lpm_data_output_particles', 6 )
2499!
2500!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(5), particles%origin_z, &
2501!                             start = (/ 1, prt_time_count /),               &
2502!                             count = (/ maximum_number_of_particles /) )
2503!     CALL netcdf_handle_error( 'lpm_data_output_particles', 7 )
2504!
2505!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(6), particles%radius,   &
2506!                             start = (/ 1, prt_time_count /),               &
2507!                             count = (/ maximum_number_of_particles /) )
2508!     CALL netcdf_handle_error( 'lpm_data_output_particles', 8 )
2509!
2510!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(7), particles%speed_x,  &
2511!                             start = (/ 1, prt_time_count /),               &
2512!                             count = (/ maximum_number_of_particles /) )
2513!     CALL netcdf_handle_error( 'lpm_data_output_particles', 9 )
2514!
2515!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(8), particles%speed_y,  &
2516!                             start = (/ 1, prt_time_count /),               &
2517!                             count = (/ maximum_number_of_particles /) )
2518!     CALL netcdf_handle_error( 'lpm_data_output_particles', 10 )
2519!
2520!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(9), particles%speed_z,  &
2521!                             start = (/ 1, prt_time_count /),               &
2522!                             count = (/ maximum_number_of_particles /) )
2523!     CALL netcdf_handle_error( 'lpm_data_output_particles', 11 )
2524!
2525!     nc_stat = NF90_PUT_VAR( id_set_prt,id_var_prt(10),                     &
2526!                             particles%weight_factor,                       &
2527!                             start = (/ 1, prt_time_count /),               &
2528!                             count = (/ maximum_number_of_particles /) )
2529!     CALL netcdf_handle_error( 'lpm_data_output_particles', 12 )
2530!
2531!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(11), particles%x,       &
2532!                             start = (/ 1, prt_time_count /),               &
2533!                             count = (/ maximum_number_of_particles /) )
2534!     CALL netcdf_handle_error( 'lpm_data_output_particles', 13 )
2535!
2536!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(12), particles%y,       &
2537!                             start = (/ 1, prt_time_count /),               &
2538!                             count = (/ maximum_number_of_particles /) )
2539!     CALL netcdf_handle_error( 'lpm_data_output_particles', 14 )
2540!
2541!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(13), particles%z,       &
2542!                             start = (/ 1, prt_time_count /),               &
2543!                             count = (/ maximum_number_of_particles /) )
2544!     CALL netcdf_handle_error( 'lpm_data_output_particles', 15 )
2545!
2546!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(14), particles%class,   &
2547!                             start = (/ 1, prt_time_count /),               &
2548!                             count = (/ maximum_number_of_particles /) )
2549!     CALL netcdf_handle_error( 'lpm_data_output_particles', 16 )
2550!
2551!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(15), particles%group,   &
2552!                             start = (/ 1, prt_time_count /),               &
2553!                             count = (/ maximum_number_of_particles /) )
2554!     CALL netcdf_handle_error( 'lpm_data_output_particles', 17 )
2555!
2556!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(16),                    &
2557!                             particles%id2,                                 &
2558!                             start = (/ 1, prt_time_count /),               &
2559!                             count = (/ maximum_number_of_particles /) )
2560!     CALL netcdf_handle_error( 'lpm_data_output_particles', 18 )
2561!
2562!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(17), particles%id1,     &
2563!                             start = (/ 1, prt_time_count /),               &
2564!                             count = (/ maximum_number_of_particles /) )
2565!     CALL netcdf_handle_error( 'lpm_data_output_particles', 19 )
2566!
2567#endif
2568
2569    CALL cpu_log( log_point_s(40), 'lpm_data_output', 'stop' )
2570
2571 END SUBROUTINE lpm_data_output_particles
2572 
2573!------------------------------------------------------------------------------!
2574! Description:
2575! ------------
2576!> This routine calculates and provide particle timeseries output.
2577!------------------------------------------------------------------------------!
2578 SUBROUTINE lpm_data_output_ptseries
2579 
2580    INTEGER(iwp) ::  i    !<
2581    INTEGER(iwp) ::  inum !<
2582    INTEGER(iwp) ::  j    !<
2583    INTEGER(iwp) ::  jg   !<
2584    INTEGER(iwp) ::  k    !<
2585    INTEGER(iwp) ::  n    !<
2586
2587    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pts_value   !<
2588    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pts_value_l !<
2589
2590
2591    CALL cpu_log( log_point(36), 'data_output_ptseries', 'start' )
2592
2593    IF ( myid == 0 )  THEN
2594!
2595!--    Open file for time series output in NetCDF format
2596       dopts_time_count = dopts_time_count + 1
2597       CALL check_open( 109 )
2598#if defined( __netcdf )
2599!
2600!--    Update the particle time series time axis
2601       nc_stat = NF90_PUT_VAR( id_set_pts, id_var_time_pts,      &
2602                               (/ time_since_reference_point /), &
2603                               start = (/ dopts_time_count /), count = (/ 1 /) )
2604       CALL netcdf_handle_error( 'data_output_ptseries', 391 )
2605#endif
2606
2607    ENDIF
2608
2609    ALLOCATE( pts_value(0:number_of_particle_groups,dopts_num), &
2610              pts_value_l(0:number_of_particle_groups,dopts_num) )
2611
2612    pts_value_l = 0.0_wp
2613    pts_value_l(:,16) = 9999999.9_wp    ! for calculation of minimum radius
2614
2615!
2616!-- Calculate or collect the particle time series quantities for all particles
2617!-- and seperately for each particle group (if there is more than one group)
2618    DO  i = nxl, nxr
2619       DO  j = nys, nyn
2620          DO  k = nzb, nzt
2621             number_of_particles = prt_count(k,j,i)
2622             IF (number_of_particles <= 0)  CYCLE
2623             particles => grid_particles(k,j,i)%particles(1:number_of_particles)
2624             DO  n = 1, number_of_particles
2625
2626                IF ( particles(n)%particle_mask )  THEN  ! Restrict analysis to active particles
2627
2628                   pts_value_l(0,1)  = pts_value_l(0,1) + 1.0_wp  ! total # of particles
2629                   pts_value_l(0,2)  = pts_value_l(0,2) +                      &
2630                          ( particles(n)%x - particles(n)%origin_x )  ! mean x
2631                   pts_value_l(0,3)  = pts_value_l(0,3) +                      &
2632                          ( particles(n)%y - particles(n)%origin_y )  ! mean y
2633                   pts_value_l(0,4)  = pts_value_l(0,4) +                      &
2634                          ( particles(n)%z - particles(n)%origin_z )  ! mean z
2635                   pts_value_l(0,5)  = pts_value_l(0,5) + particles(n)%z        ! mean z (absolute)
2636                   pts_value_l(0,6)  = pts_value_l(0,6) + particles(n)%speed_x  ! mean u
2637                   pts_value_l(0,7)  = pts_value_l(0,7) + particles(n)%speed_y  ! mean v
2638                   pts_value_l(0,8)  = pts_value_l(0,8) + particles(n)%speed_z  ! mean w
2639                   pts_value_l(0,9)  = pts_value_l(0,9)  + particles(n)%rvar1 ! mean sgsu
2640                   pts_value_l(0,10) = pts_value_l(0,10) + particles(n)%rvar2 ! mean sgsv
2641                   pts_value_l(0,11) = pts_value_l(0,11) + particles(n)%rvar3 ! mean sgsw
2642                   IF ( particles(n)%speed_z > 0.0_wp )  THEN
2643                      pts_value_l(0,12) = pts_value_l(0,12) + 1.0_wp  ! # of upward moving prts
2644                      pts_value_l(0,13) = pts_value_l(0,13) +                  &
2645                                              particles(n)%speed_z ! mean w upw.
2646                   ELSE
2647                      pts_value_l(0,14) = pts_value_l(0,14) +                  &
2648                                              particles(n)%speed_z ! mean w down
2649                   ENDIF
2650                   pts_value_l(0,15) = pts_value_l(0,15) + particles(n)%radius ! mean rad
2651                   pts_value_l(0,16) = MIN( pts_value_l(0,16), particles(n)%radius ) ! minrad
2652                   pts_value_l(0,17) = MAX( pts_value_l(0,17), particles(n)%radius ) ! maxrad
2653                   pts_value_l(0,18) = pts_value_l(0,18) + 1.0_wp
2654                   pts_value_l(0,19) = pts_value_l(0,18) + 1.0_wp
2655!
2656!--                Repeat the same for the respective particle group
2657                   IF ( number_of_particle_groups > 1 )  THEN
2658                      jg = particles(n)%group
2659
2660                      pts_value_l(jg,1)  = pts_value_l(jg,1) + 1.0_wp
2661                      pts_value_l(jg,2)  = pts_value_l(jg,2) +                   &
2662                           ( particles(n)%x - particles(n)%origin_x )
2663                      pts_value_l(jg,3)  = pts_value_l(jg,3) +                   &
2664                           ( particles(n)%y - particles(n)%origin_y )
2665                      pts_value_l(jg,4)  = pts_value_l(jg,4) +                   &
2666                           ( particles(n)%z - particles(n)%origin_z )
2667                      pts_value_l(jg,5)  = pts_value_l(jg,5) + particles(n)%z
2668                      pts_value_l(jg,6)  = pts_value_l(jg,6) + particles(n)%speed_x
2669                      pts_value_l(jg,7)  = pts_value_l(jg,7) + particles(n)%speed_y
2670                      pts_value_l(jg,8)  = pts_value_l(jg,8) + particles(n)%speed_z
2671                      pts_value_l(jg,9)  = pts_value_l(jg,9)  + particles(n)%rvar1
2672                      pts_value_l(jg,10) = pts_value_l(jg,10) + particles(n)%rvar2
2673                      pts_value_l(jg,11) = pts_value_l(jg,11) + particles(n)%rvar3
2674                      IF ( particles(n)%speed_z > 0.0_wp )  THEN
2675                         pts_value_l(jg,12) = pts_value_l(jg,12) + 1.0_wp
2676                         pts_value_l(jg,13) = pts_value_l(jg,13) + particles(n)%speed_z
2677                      ELSE
2678                         pts_value_l(jg,14) = pts_value_l(jg,14) + particles(n)%speed_z
2679                      ENDIF
2680                      pts_value_l(jg,15) = pts_value_l(jg,15) + particles(n)%radius
2681                      pts_value_l(jg,16) = MIN( pts_value_l(jg,16), particles(n)%radius )
2682                      pts_value_l(jg,17) = MAX( pts_value_l(jg,17), particles(n)%radius )
2683                      pts_value_l(jg,18) = pts_value_l(jg,18) + 1.0_wp
2684                      pts_value_l(jg,19) = pts_value_l(jg,19) + 1.0_wp
2685                   ENDIF
2686
2687                ENDIF
2688
2689             ENDDO
2690
2691          ENDDO
2692       ENDDO
2693    ENDDO
2694
2695
2696#if defined( __parallel )
2697!
2698!-- Sum values of the subdomains
2699    inum = number_of_particle_groups + 1
2700
2701    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2702    CALL MPI_ALLREDUCE( pts_value_l(0,1), pts_value(0,1), 15*inum, MPI_REAL, &
2703                        MPI_SUM, comm2d, ierr )
2704    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2705    CALL MPI_ALLREDUCE( pts_value_l(0,16), pts_value(0,16), inum, MPI_REAL, &
2706                        MPI_MIN, comm2d, ierr )
2707    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2708    CALL MPI_ALLREDUCE( pts_value_l(0,17), pts_value(0,17), inum, MPI_REAL, &
2709                        MPI_MAX, comm2d, ierr )
2710    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2711    CALL MPI_ALLREDUCE( pts_value_l(0,18), pts_value(0,18), inum, MPI_REAL, &
2712                        MPI_MAX, comm2d, ierr )
2713    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2714    CALL MPI_ALLREDUCE( pts_value_l(0,19), pts_value(0,19), inum, MPI_REAL, &
2715                        MPI_MIN, comm2d, ierr )
2716#else
2717    pts_value(:,1:19) = pts_value_l(:,1:19)
2718#endif
2719
2720!
2721!-- Normalize the above calculated quantities (except min/max values) with the
2722!-- total number of particles
2723    IF ( number_of_particle_groups > 1 )  THEN
2724       inum = number_of_particle_groups
2725    ELSE
2726       inum = 0
2727    ENDIF
2728
2729    DO  j = 0, inum
2730
2731       IF ( pts_value(j,1) > 0.0_wp )  THEN
2732
2733          pts_value(j,2:15) = pts_value(j,2:15) / pts_value(j,1)
2734          IF ( pts_value(j,12) > 0.0_wp  .AND.  pts_value(j,12) < 1.0_wp )  THEN
2735             pts_value(j,13) = pts_value(j,13) / pts_value(j,12)
2736             pts_value(j,14) = pts_value(j,14) / ( 1.0_wp - pts_value(j,12) )
2737          ELSEIF ( pts_value(j,12) == 0.0_wp )  THEN
2738             pts_value(j,13) = -1.0_wp
2739          ELSE
2740             pts_value(j,14) = -1.0_wp
2741          ENDIF
2742
2743       ENDIF
2744
2745    ENDDO
2746
2747!
2748!-- Calculate higher order moments of particle time series quantities,
2749!-- seperately for each particle group (if there is more than one group)
2750    DO  i = nxl, nxr
2751       DO  j = nys, nyn
2752          DO  k = nzb, nzt
2753             number_of_particles = prt_count(k,j,i)
2754             IF (number_of_particles <= 0)  CYCLE
2755             particles => grid_particles(k,j,i)%particles(1:number_of_particles)
2756             DO  n = 1, number_of_particles
2757
2758                pts_value_l(0,20) = pts_value_l(0,20) + ( particles(n)%x - &
2759                                    particles(n)%origin_x - pts_value(0,2) )**2 ! x*2
2760                pts_value_l(0,21) = pts_value_l(0,21) + ( particles(n)%y - &
2761                                    particles(n)%origin_y - pts_value(0,3) )**2 ! y*2
2762                pts_value_l(0,22) = pts_value_l(0,22) + ( particles(n)%z - &
2763                                    particles(n)%origin_z - pts_value(0,4) )**2 ! z*2
2764                pts_value_l(0,23) = pts_value_l(0,23) + ( particles(n)%speed_x - &
2765                                                         pts_value(0,6) )**2   ! u*2
2766                pts_value_l(0,24) = pts_value_l(0,24) + ( particles(n)%speed_y - &
2767                                                          pts_value(0,7) )**2   ! v*2
2768                pts_value_l(0,25) = pts_value_l(0,25) + ( particles(n)%speed_z - &
2769                                                          pts_value(0,8) )**2   ! w*2
2770                pts_value_l(0,26) = pts_value_l(0,26) + ( particles(n)%rvar1 - &
2771                                                          pts_value(0,9) )**2   ! u"2
2772                pts_value_l(0,27) = pts_value_l(0,27) + ( particles(n)%rvar2 - &
2773                                                          pts_value(0,10) )**2  ! v"2
2774                pts_value_l(0,28) = pts_value_l(0,28) + ( particles(n)%rvar3 - &
2775                                                          pts_value(0,11) )**2  ! w"2
2776!
2777!--             Repeat the same for the respective particle group
2778                IF ( number_of_particle_groups > 1 )  THEN
2779                   jg = particles(n)%group
2780
2781                   pts_value_l(jg,20) = pts_value_l(jg,20) + ( particles(n)%x - &
2782                                       particles(n)%origin_x - pts_value(jg,2) )**2
2783                   pts_value_l(jg,21) = pts_value_l(jg,21) + ( particles(n)%y - &
2784                                       particles(n)%origin_y - pts_value(jg,3) )**2
2785                   pts_value_l(jg,22) = pts_value_l(jg,22) + ( particles(n)%z - &
2786                                       particles(n)%origin_z - pts_value(jg,4) )**2
2787                   pts_value_l(jg,23) = pts_value_l(jg,23) + ( particles(n)%speed_x - &
2788                                                             pts_value(jg,6) )**2
2789                   pts_value_l(jg,24) = pts_value_l(jg,24) + ( particles(n)%speed_y - &
2790                                                             pts_value(jg,7) )**2
2791                   pts_value_l(jg,25) = pts_value_l(jg,25) + ( particles(n)%speed_z - &
2792                                                             pts_value(jg,8) )**2
2793                   pts_value_l(jg,26) = pts_value_l(jg,26) + ( particles(n)%rvar1 - &
2794                                                             pts_value(jg,9) )**2
2795                   pts_value_l(jg,27) = pts_value_l(jg,27) + ( particles(n)%rvar2 - &
2796                                                             pts_value(jg,10) )**2
2797                   pts_value_l(jg,28) = pts_value_l(jg,28) + ( particles(n)%rvar3 - &
2798                                                             pts_value(jg,11) )**2
2799                ENDIF
2800
2801             ENDDO
2802          ENDDO
2803       ENDDO
2804    ENDDO
2805
2806    pts_value_l(0,29) = ( number_of_particles - pts_value(0,1) / numprocs )**2
2807                                                 ! variance of particle numbers
2808    IF ( number_of_particle_groups > 1 )  THEN
2809       DO  j = 1, number_of_particle_groups
2810          pts_value_l(j,29) = ( pts_value_l(j,1) - &
2811                                pts_value(j,1) / numprocs )**2
2812       ENDDO
2813    ENDIF
2814
2815#if defined( __parallel )
2816!
2817!-- Sum values of the subdomains
2818    inum = number_of_particle_groups + 1
2819
2820    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2821    CALL MPI_ALLREDUCE( pts_value_l(0,20), pts_value(0,20), inum*10, MPI_REAL, &
2822                        MPI_SUM, comm2d, ierr )
2823#else
2824    pts_value(:,20:29) = pts_value_l(:,20:29)
2825#endif
2826
2827!
2828!-- Normalize the above calculated quantities with the total number of
2829!-- particles
2830    IF ( number_of_particle_groups > 1 )  THEN
2831       inum = number_of_particle_groups
2832    ELSE
2833       inum = 0
2834    ENDIF
2835
2836    DO  j = 0, inum
2837
2838       IF ( pts_value(j,1) > 0.0_wp )  THEN
2839          pts_value(j,20:28) = pts_value(j,20:28) / pts_value(j,1)
2840       ENDIF
2841       pts_value(j,29) = pts_value(j,29) / numprocs
2842
2843    ENDDO
2844
2845#if defined( __netcdf )
2846!
2847!-- Output particle time series quantities in NetCDF format
2848    IF ( myid == 0 )  THEN
2849       DO  j = 0, inum
2850          DO  i = 1, dopts_num
2851             nc_stat = NF90_PUT_VAR( id_set_pts, id_var_dopts(i,j),  &
2852                                     (/ pts_value(j,i) /),           &
2853                                     start = (/ dopts_time_count /), &
2854                                     count = (/ 1 /) )
2855             CALL netcdf_handle_error( 'data_output_ptseries', 392 )
2856          ENDDO
2857       ENDDO
2858    ENDIF
2859#endif
2860
2861    DEALLOCATE( pts_value, pts_value_l )
2862
2863    CALL cpu_log( log_point(36), 'data_output_ptseries', 'stop' )
2864
2865END SUBROUTINE lpm_data_output_ptseries
2866
2867 
2868!------------------------------------------------------------------------------!
2869! Description:
2870! ------------
2871!> This routine reads the respective restart data for the lpm.
2872!------------------------------------------------------------------------------!
2873 SUBROUTINE lpm_rrd_local_particles
2874
2875    CHARACTER (LEN=10) ::  particle_binary_version    !<
2876    CHARACTER (LEN=10) ::  version_on_file            !<
2877
2878    INTEGER(iwp) ::  alloc_size !<
2879    INTEGER(iwp) ::  ip         !<
2880    INTEGER(iwp) ::  jp         !<
2881    INTEGER(iwp) ::  kp         !<
2882
2883    TYPE(particle_type), DIMENSION(:), ALLOCATABLE ::  tmp_particles !<
2884
2885!
2886!-- Read particle data from previous model run.
2887!-- First open the input unit.
2888    IF ( myid_char == '' )  THEN
2889       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_IN'//myid_char,                  &
2890                  FORM='UNFORMATTED' )
2891    ELSE
2892       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_IN/'//myid_char,                 &
2893                  FORM='UNFORMATTED' )
2894    ENDIF
2895
2896!
2897!-- First compare the version numbers
2898    READ ( 90 )  version_on_file
2899    particle_binary_version = '4.0'
2900    IF ( TRIM( version_on_file ) /= TRIM( particle_binary_version ) )  THEN
2901       message_string = 'version mismatch concerning data from prior ' //      &
2902                        'run &version on file = "' //                          &
2903                                      TRIM( version_on_file ) //               &
2904                        '&version in program = "' //                           &
2905                                      TRIM( particle_binary_version ) // '"'
2906       CALL message( 'lpm_read_restart_file', 'PA0214', 1, 2, 0, 6, 0 )
2907    ENDIF
2908
2909!
2910!-- If less particles are stored on the restart file than prescribed by
2911!-- 1, the remainder is initialized by zero_particle to avoid
2912!-- errors.
2913    zero_particle = particle_type( 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2914                                   0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2915                                   0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2916                                   0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2917                                   0, 0, 0_idp, .FALSE., -1 )
2918!
2919!-- Read some particle parameters and the size of the particle arrays,
2920!-- allocate them and read their contents.
2921    READ ( 90 )  bc_par_b, bc_par_lr, bc_par_ns, bc_par_t,                     &
2922                 last_particle_release_time, number_of_particle_groups,        &
2923                 particle_groups, time_write_particle_data
2924
2925    ALLOCATE( prt_count(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                        &
2926              grid_particles(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2927
2928    READ ( 90 )  prt_count
2929
2930    DO  ip = nxl, nxr
2931       DO  jp = nys, nyn
2932          DO  kp = nzb+1, nzt
2933
2934             number_of_particles = prt_count(kp,jp,ip)
2935             IF ( number_of_particles > 0 )  THEN
2936                alloc_size = MAX( INT( number_of_particles *                   &
2937                             ( 1.0_wp + alloc_factor / 100.0_wp ) ),           &
2938                             1 )
2939             ELSE
2940                alloc_size = 1
2941             ENDIF
2942
2943             ALLOCATE( grid_particles(kp,jp,ip)%particles(1:alloc_size) )
2944
2945             IF ( number_of_particles > 0 )  THEN
2946                ALLOCATE( tmp_particles(1:number_of_particles) )
2947                READ ( 90 )  tmp_particles
2948                grid_particles(kp,jp,ip)%particles(1:number_of_particles) = tmp_particles
2949                DEALLOCATE( tmp_particles )
2950                IF ( number_of_particles < alloc_size )  THEN
2951                   grid_particles(kp,jp,ip)%particles(number_of_particles+1:alloc_size) &
2952                      = zero_particle
2953                ENDIF
2954             ELSE
2955                grid_particles(kp,jp,ip)%particles(1:alloc_size) = zero_particle
2956             ENDIF
2957
2958          ENDDO
2959       ENDDO
2960    ENDDO
2961
2962    CLOSE ( 90 )
2963!
2964!-- Must be called to sort particles into blocks, which is needed for a fast
2965!-- interpolation of the LES fields on the particle position.
2966    CALL lpm_sort_and_delete
2967
2968
2969 END SUBROUTINE lpm_rrd_local_particles
2970 
2971 
2972 SUBROUTINE lpm_rrd_local( k, nxlf, nxlc, nxl_on_file, nxrf, nxrc,          &
2973                              nxr_on_file, nynf, nync, nyn_on_file, nysf,  &
2974                              nysc, nys_on_file, tmp_3d, found )
2975
2976
2977   USE control_parameters,                                                 &
2978       ONLY: length, restart_string
2979
2980    INTEGER(iwp) ::  k               !<
2981    INTEGER(iwp) ::  nxlc            !<
2982    INTEGER(iwp) ::  nxlf            !<
2983    INTEGER(iwp) ::  nxl_on_file     !<
2984    INTEGER(iwp) ::  nxrc            !<
2985    INTEGER(iwp) ::  nxrf            !<
2986    INTEGER(iwp) ::  nxr_on_file     !<
2987    INTEGER(iwp) ::  nync            !<
2988    INTEGER(iwp) ::  nynf            !<
2989    INTEGER(iwp) ::  nyn_on_file     !<
2990    INTEGER(iwp) ::  nysc            !<
2991    INTEGER(iwp) ::  nysf            !<
2992    INTEGER(iwp) ::  nys_on_file     !<
2993
2994    LOGICAL, INTENT(OUT)  ::  found
2995
2996    REAL(wp), DIMENSION(nzb:nzt+1,nys_on_file-nbgp:nyn_on_file+nbgp,nxl_on_file-nbgp:nxr_on_file+nbgp) ::  tmp_3d   !<
2997
2998
2999    found = .TRUE.
3000
3001    SELECT CASE ( restart_string(1:length) )
3002
3003       CASE ( 'iran' ) ! matching random numbers is still unresolved issue
3004          IF ( k == 1 )  READ ( 13 )  iran, iran_part
3005
3006        CASE ( 'pc_av' )
3007           IF ( .NOT. ALLOCATED( pc_av ) )  THEN
3008              ALLOCATE( pc_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
3009           ENDIF
3010           IF ( k == 1 )  READ ( 13 )  tmp_3d
3011           pc_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =          &
3012              tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
3013
3014        CASE ( 'pr_av' )
3015           IF ( .NOT. ALLOCATED( pr_av ) )  THEN
3016              ALLOCATE( pr_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
3017           ENDIF
3018           IF ( k == 1 )  READ ( 13 )  tmp_3d
3019           pr_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =          &
3020              tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
3021 
3022         CASE ( 'ql_c_av' )
3023            IF ( .NOT. ALLOCATED( ql_c_av ) )  THEN
3024               ALLOCATE( ql_c_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
3025            ENDIF
3026            IF ( k == 1 )  READ ( 13 )  tmp_3d
3027            ql_c_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =        &
3028               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
3029
3030         CASE ( 'ql_v_av' )
3031            IF ( .NOT. ALLOCATED( ql_v_av ) )  THEN
3032               ALLOCATE( ql_v_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
3033            ENDIF
3034            IF ( k == 1 )  READ ( 13 )  tmp_3d
3035            ql_v_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =        &
3036               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
3037
3038         CASE ( 'ql_vp_av' )
3039            IF ( .NOT. ALLOCATED( ql_vp_av ) )  THEN
3040               ALLOCATE( ql_vp_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
3041            ENDIF
3042            IF ( k == 1 )  READ ( 13 )  tmp_3d
3043            ql_vp_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =       &
3044               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
3045
3046          CASE DEFAULT
3047
3048             found = .FALSE.
3049
3050       END SELECT
3051
3052
3053 END SUBROUTINE lpm_rrd_local
3054 
3055!------------------------------------------------------------------------------!
3056! Description:
3057! ------------
3058!> This routine writes the respective restart data for the lpm.
3059!------------------------------------------------------------------------------!
3060 SUBROUTINE lpm_wrd_local
3061 
3062    CHARACTER (LEN=10) ::  particle_binary_version   !<
3063
3064    INTEGER(iwp) ::  ip                              !<
3065    INTEGER(iwp) ::  jp                              !<
3066    INTEGER(iwp) ::  kp                              !<
3067!
3068!-- First open the output unit.
3069    IF ( myid_char == '' )  THEN
3070       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_OUT'//myid_char, &
3071                  FORM='UNFORMATTED')
3072    ELSE
3073       IF ( myid == 0 )  CALL local_system( 'mkdir PARTICLE_RESTART_DATA_OUT' )
3074#if defined( __parallel )
3075!
3076!--    Set a barrier in order to allow that thereafter all other processors
3077!--    in the directory created by PE0 can open their file
3078       CALL MPI_BARRIER( comm2d, ierr )
3079#endif
3080       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_OUT/'//myid_char, &
3081                  FORM='UNFORMATTED' )
3082    ENDIF
3083
3084!
3085!-- Write the version number of the binary format.
3086!-- Attention: After changes to the following output commands the version
3087!-- ---------  number of the variable particle_binary_version must be
3088!--            changed! Also, the version number and the list of arrays
3089!--            to be read in lpm_read_restart_file must be adjusted
3090!--            accordingly.
3091    particle_binary_version = '4.0'
3092    WRITE ( 90 )  particle_binary_version
3093
3094!
3095!-- Write some particle parameters, the size of the particle arrays
3096    WRITE ( 90 )  bc_par_b, bc_par_lr, bc_par_ns, bc_par_t,                    &
3097                  last_particle_release_time, number_of_particle_groups,       &
3098                  particle_groups, time_write_particle_data
3099
3100    WRITE ( 90 )  prt_count
3101         
3102    DO  ip = nxl, nxr
3103       DO  jp = nys, nyn
3104          DO  kp = nzb+1, nzt
3105             number_of_particles = prt_count(kp,jp,ip)
3106             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
3107             IF ( number_of_particles <= 0 )  CYCLE
3108             WRITE ( 90 )  particles
3109          ENDDO
3110       ENDDO
3111    ENDDO
3112
3113    CLOSE ( 90 )
3114
3115#if defined( __parallel )
3116       CALL MPI_BARRIER( comm2d, ierr )
3117#endif
3118
3119    CALL wrd_write_string( 'iran' ) 
3120    WRITE ( 14 )  iran, iran_part
3121
3122
3123 END SUBROUTINE lpm_wrd_local
3124
3125
3126!------------------------------------------------------------------------------!
3127! Description:
3128! ------------
3129!> This routine writes the respective restart data for the lpm.
3130!------------------------------------------------------------------------------!
3131 SUBROUTINE lpm_wrd_global
3132 
3133    CALL wrd_write_string( 'curvature_solution_effects' ) 
3134    WRITE ( 14 )  curvature_solution_effects
3135
3136    CALL wrd_write_string( 'interpolation_simple_corrector' )
3137    WRITE ( 14 )  interpolation_simple_corrector
3138
3139    CALL wrd_write_string( 'interpolation_simple_predictor' )
3140    WRITE ( 14 )  interpolation_simple_predictor
3141
3142    CALL wrd_write_string( 'interpolation_trilinear' )
3143    WRITE ( 14 )  interpolation_trilinear
3144
3145 END SUBROUTINE lpm_wrd_global
3146 
3147
3148!------------------------------------------------------------------------------!
3149! Description:
3150! ------------
3151!> This routine writes the respective restart data for the lpm.
3152!------------------------------------------------------------------------------!
3153 SUBROUTINE lpm_rrd_global( found )
3154 
3155    USE control_parameters,                            &
3156        ONLY: length, restart_string
3157
3158    LOGICAL, INTENT(OUT)  ::  found
3159
3160    found = .TRUE.
3161
3162    SELECT CASE ( restart_string(1:length) )
3163
3164       CASE ( 'curvature_solution_effects' )
3165          READ ( 13 )  curvature_solution_effects
3166
3167       CASE ( 'interpolation_simple_corrector' )
3168          READ ( 13 )  interpolation_simple_corrector
3169
3170       CASE ( 'interpolation_simple_predictor' )
3171          READ ( 13 )  interpolation_simple_predictor
3172
3173       CASE ( 'interpolation_trilinear' )
3174          READ ( 13 )  interpolation_trilinear
3175
3176!          CASE ( 'global_paramter' )
3177!             READ ( 13 )  global_parameter
3178!          CASE ( 'global_array' )
3179!             IF ( .NOT. ALLOCATED( global_array ) )  ALLOCATE( global_array(1:10) )
3180!             READ ( 13 )  global_array
3181
3182       CASE DEFAULT
3183
3184          found = .FALSE.
3185
3186    END SELECT
3187   
3188 END SUBROUTINE lpm_rrd_global
3189
3190
3191!------------------------------------------------------------------------------!
3192! Description:
3193! ------------
3194!> This is a submodule of the lagrangian particle model. It contains all
3195!> dynamic processes of the lpm. This includes the advection (resolved and sub-
3196!> grid scale) as well as the boundary conditions of particles. As a next step
3197!> this submodule should be excluded as an own file.
3198!------------------------------------------------------------------------------!
3199 SUBROUTINE lpm_advec (ip,jp,kp)
3200
3201    LOGICAL ::  subbox_at_wall !< flag to see if the current subgridbox is adjacent to a wall
3202
3203    INTEGER(iwp) ::  i                           !< index variable along x
3204    INTEGER(iwp) ::  i_next                      !< index variable along x
3205    INTEGER(iwp) ::  ip                          !< index variable along x
3206    INTEGER(iwp) ::  iteration_steps = 1         !< amount of iterations steps for corrector step
3207    INTEGER(iwp) ::  j                           !< index variable along y
3208    INTEGER(iwp) ::  j_next                      !< index variable along y
3209    INTEGER(iwp) ::  jp                          !< index variable along y
3210    INTEGER(iwp) ::  k                           !< index variable along z
3211    INTEGER(iwp) ::  k_wall                      !< vertical index of topography top
3212    INTEGER(iwp) ::  kp                          !< index variable along z
3213    INTEGER(iwp) ::  k_next                      !< index variable along z
3214    INTEGER(iwp) ::  kw                          !< index variable along z
3215    INTEGER(iwp) ::  kkw                         !< index variable along z
3216    INTEGER(iwp) ::  n                           !< loop variable over all particles in a grid box
3217    INTEGER(iwp) ::  nb                          !< block number particles are sorted in
3218    INTEGER(iwp) ::  particle_end                !< end index for partilce loop
3219    INTEGER(iwp) ::  particle_start              !< start index for particle loop
3220    INTEGER(iwp) ::  surf_start                  !< Index on surface data-type for current grid box
3221    INTEGER(iwp) ::  subbox_end                  !< end index for loop over subboxes in particle advection
3222    INTEGER(iwp) ::  subbox_start                !< start index for loop over subboxes in particle advection
3223    INTEGER(iwp) ::  nn                          !< loop variable over iterations steps
3224
3225    INTEGER(iwp), DIMENSION(0:7) ::  start_index !< start particle index for current block
3226    INTEGER(iwp), DIMENSION(0:7) ::  end_index   !< start particle index for current block
3227
3228    REAL(wp) ::  aa                 !< dummy argument for horizontal particle interpolation
3229    REAL(wp) ::  alpha              !< interpolation facor for x-direction
3230
3231    REAL(wp) ::  bb                 !< dummy argument for horizontal particle interpolation
3232    REAL(wp) ::  beta               !< interpolation facor for y-direction
3233    REAL(wp) ::  cc                 !< dummy argument for horizontal particle interpolation
3234    REAL(wp) ::  d_z_p_z0           !< inverse of interpolation length for logarithmic interpolation
3235    REAL(wp) ::  dd                 !< dummy argument for horizontal particle interpolation
3236    REAL(wp) ::  de_dx_int_l        !< x/y-interpolated TKE gradient (x) at particle position at lower vertical level
3237    REAL(wp) ::  de_dx_int_u        !< x/y-interpolated TKE gradient (x) at particle position at upper vertical level
3238    REAL(wp) ::  de_dy_int_l        !< x/y-interpolated TKE gradient (y) at particle position at lower vertical level
3239    REAL(wp) ::  de_dy_int_u        !< x/y-interpolated TKE gradient (y) at particle position at upper vertical level
3240    REAL(wp) ::  de_dt              !< temporal derivative of TKE experienced by the particle
3241    REAL(wp) ::  de_dt_min          !< lower level for temporal TKE derivative
3242    REAL(wp) ::  de_dz_int_l        !< x/y-interpolated TKE gradient (z) at particle position at lower vertical level
3243    REAL(wp) ::  de_dz_int_u        !< x/y-interpolated TKE gradient (z) at particle position at upper vertical level
3244    REAL(wp) ::  diameter           !< diamter of droplet
3245    REAL(wp) ::  diss_int_l         !< x/y-interpolated dissipation at particle position at lower vertical level
3246    REAL(wp) ::  diss_int_u         !< x/y-interpolated dissipation at particle position at upper vertical level
3247    REAL(wp) ::  dt_particle_m      !< previous particle time step
3248    REAL(wp) ::  dz_temp            !< dummy for the vertical grid spacing
3249    REAL(wp) ::  e_int_l            !< x/y-interpolated TKE at particle position at lower vertical level
3250    REAL(wp) ::  e_int_u            !< x/y-interpolated TKE at particle position at upper vertical level
3251    REAL(wp) ::  e_mean_int         !< horizontal mean TKE at particle height
3252    REAL(wp) ::  exp_arg            !< argument in the exponent - particle radius
3253    REAL(wp) ::  exp_term           !< exponent term
3254    REAL(wp) ::  gamma              !< interpolation facor for z-direction
3255    REAL(wp) ::  gg                 !< dummy argument for horizontal particle interpolation
3256    REAL(wp) ::  height_p           !< dummy argument for logarithmic interpolation
3257    REAL(wp) ::  log_z_z0_int       !< logarithmus used for surface_layer interpolation
3258    REAL(wp) ::  random_gauss       !< Gaussian-distributed random number used for SGS particle advection
3259    REAL(wp) ::  RL                 !< Lagrangian autocorrelation coefficient
3260    REAL(wp) ::  rg1                !< Gaussian distributed random number
3261    REAL(wp) ::  rg2                !< Gaussian distributed random number
3262    REAL(wp) ::  rg3                !< Gaussian distributed random number
3263    REAL(wp) ::  sigma              !< velocity standard deviation
3264    REAL(wp) ::  u_int_l            !< x/y-interpolated u-component at particle position at lower vertical level
3265    REAL(wp) ::  u_int_u            !< x/y-interpolated u-component at particle position at upper vertical level
3266    REAL(wp) ::  unext              !< calculated particle u-velocity of corrector step
3267    REAL(wp) ::  us_int             !< friction velocity at particle grid box
3268    REAL(wp) ::  usws_int           !< surface momentum flux (u component) at particle grid box
3269    REAL(wp) ::  v_int_l            !< x/y-interpolated v-component at particle position at lower vertical level
3270    REAL(wp) ::  v_int_u            !< x/y-interpolated v-component at particle position at upper vertical level
3271    REAL(wp) ::  vsws_int           !< surface momentum flux (u component) at particle grid box
3272    REAL(wp) ::  vnext              !< calculated particle v-velocity of corrector step
3273    REAL(wp) ::  vv_int             !< dummy to compute interpolated mean SGS TKE, used to scale SGS advection
3274    REAL(wp) ::  w_int_l            !< x/y-interpolated w-component at particle position at lower vertical level
3275    REAL(wp) ::  w_int_u            !< x/y-interpolated w-component at particle position at upper vertical level
3276    REAL(wp) ::  wnext              !< calculated particle w-velocity of corrector step
3277    REAL(wp) ::  w_s                !< terminal velocity of droplets
3278    REAL(wp) ::  x                  !< dummy argument for horizontal particle interpolation
3279    REAL(wp) ::  xp                 !< calculated particle position in x of predictor step
3280    REAL(wp) ::  y                  !< dummy argument for horizontal particle interpolation
3281    REAL(wp) ::  yp                 !< calculated particle position in y of predictor step
3282    REAL(wp) ::  z_p                !< surface layer height (0.5 dz)
3283    REAL(wp) ::  zp                 !< calculated particle position in z of predictor step
3284
3285    REAL(wp), PARAMETER ::  a_rog = 9.65_wp      !< parameter for fall velocity
3286    REAL(wp), PARAMETER ::  b_rog = 10.43_wp     !< parameter for fall velocity
3287    REAL(wp), PARAMETER ::  c_rog = 0.6_wp       !< parameter for fall velocity
3288    REAL(wp), PARAMETER ::  k_cap_rog = 4.0_wp   !< parameter for fall velocity
3289    REAL(wp), PARAMETER ::  k_low_rog = 12.0_wp  !< parameter for fall velocity
3290    REAL(wp), PARAMETER ::  d0_rog = 0.745_wp    !< separation diameter
3291
3292    REAL(wp), DIMENSION(number_of_particles) ::  term_1_2       !< flag to communicate whether a particle is near topography or not
3293    REAL(wp), DIMENSION(number_of_particles) ::  dens_ratio     !< ratio between the density of the fluid and the density of the particles
3294    REAL(wp), DIMENSION(number_of_particles) ::  de_dx_int      !< horizontal TKE gradient along x at particle position
3295    REAL(wp), DIMENSION(number_of_particles) ::  de_dy_int      !< horizontal TKE gradient along y at particle position
3296    REAL(wp), DIMENSION(number_of_particles) ::  de_dz_int      !< horizontal TKE gradient along z at particle position
3297    REAL(wp), DIMENSION(number_of_particles) ::  diss_int       !< dissipation at particle position
3298    REAL(wp), DIMENSION(number_of_particles) ::  dt_gap         !< remaining time until particle time integration reaches LES time
3299    REAL(wp), DIMENSION(number_of_particles) ::  dt_particle    !< particle time step
3300    REAL(wp), DIMENSION(number_of_particles) ::  e_int          !< TKE at particle position
3301    REAL(wp), DIMENSION(number_of_particles) ::  fs_int         !< weighting factor for subgrid-scale particle speed
3302    REAL(wp), DIMENSION(number_of_particles) ::  lagr_timescale !< Lagrangian timescale
3303    REAL(wp), DIMENSION(number_of_particles) ::  rvar1_temp     !< SGS particle velocity - u-component
3304    REAL(wp), DIMENSION(number_of_particles) ::  rvar2_temp     !< SGS particle velocity - v-component
3305    REAL(wp), DIMENSION(number_of_particles) ::  rvar3_temp     !< SGS particle velocity - w-component
3306    REAL(wp), DIMENSION(number_of_particles) ::  u_int          !< u-component of particle speed
3307    REAL(wp), DIMENSION(number_of_particles) ::  v_int          !< v-component of particle speed
3308    REAL(wp), DIMENSION(number_of_particles) ::  w_int          !< w-component of particle speed
3309    REAL(wp), DIMENSION(number_of_particles) ::  xv             !< x-position
3310    REAL(wp), DIMENSION(number_of_particles) ::  yv             !< y-position
3311    REAL(wp), DIMENSION(number_of_particles) ::  zv             !< z-position
3312
3313    REAL(wp), DIMENSION(number_of_particles, 3) ::  rg !< vector of Gaussian distributed random numbers
3314
3315    CALL cpu_log( log_point_s(44), 'lpm_advec', 'continue' )
3316!
3317!-- Determine height of Prandtl layer and distance between Prandtl-layer
3318!-- height and horizontal mean roughness height, which are required for
3319!-- vertical logarithmic interpolation of horizontal particle speeds
3320!-- (for particles below first vertical grid level).
3321    z_p      = zu(nzb+1) - zw(nzb)
3322    d_z_p_z0 = 1.0_wp / ( z_p - z0_av_global )
3323
3324    xv = particles(1:number_of_particles)%x
3325    yv = particles(1:number_of_particles)%y
3326    zv = particles(1:number_of_particles)%z
3327    dt_particle = dt_3d
3328
3329!
3330!-- This case uses a simple interpolation method for the particle velocites,
3331!-- and applying a predictor-corrector method. @note the current time divergence
3332!-- free time step is denoted with u_t etc.; the velocities of the time level of
3333!-- t+1 wit u,v, and w, as the model is called after swap timelevel
3334!-- @attention: for the corrector step the velocities of t(n+1) are required.
3335!-- Therefore the particle code is executed at the end of the time intermediate
3336!-- timestep routine. This interpolation method is described in more detail
3337!-- in Grabowski et al., 2018 (GMD).
3338    IF ( interpolation_simple_corrector )  THEN
3339!
3340!--    Predictor step
3341       kkw = kp - 1
3342       DO  n = 1, number_of_particles
3343
3344          alpha = MAX( MIN( ( particles(n)%x - ip * dx ) * ddx, 1.0_wp ), 0.0_wp )
3345          u_int(n) = u_t(kp,jp,ip) * ( 1.0_wp - alpha ) + u_t(kp,jp,ip+1) * alpha
3346
3347          beta  = MAX( MIN( ( particles(n)%y - jp * dy ) * ddy, 1.0_wp ), 0.0_wp )
3348          v_int(n) = v_t(kp,jp,ip) * ( 1.0_wp - beta ) + v_t(kp,jp+1,ip) * beta
3349
3350          gamma = MAX( MIN( ( particles(n)%z - zw(kkw) ) /                   &
3351                            ( zw(kkw+1) - zw(kkw) ), 1.0_wp ), 0.0_wp )
3352          w_int(n) = w_t(kkw,jp,ip) * ( 1.0_wp - gamma ) + w_t(kkw+1,jp,ip) * gamma
3353
3354       ENDDO
3355!
3356!--    Corrector step
3357       DO  n = 1, number_of_particles
3358
3359          IF ( .NOT. particles(n)%particle_mask )  CYCLE
3360
3361          DO  nn = 1, iteration_steps
3362
3363!
3364!--          Guess new position
3365             xp = particles(n)%x + u_int(n) * dt_particle(n)
3366             yp = particles(n)%y + v_int(n) * dt_particle(n)
3367             zp = particles(n)%z + w_int(n) * dt_particle(n)
3368!
3369!--          x direction
3370             i_next = FLOOR( xp * ddx , KIND=iwp)
3371             alpha  = MAX( MIN( ( xp - i_next * dx ) * ddx, 1.0_wp ), 0.0_wp )
3372!
3373!--          y direction
3374             j_next = FLOOR( yp * ddy )
3375             beta   = MAX( MIN( ( yp - j_next * dy ) * ddy, 1.0_wp ), 0.0_wp )
3376!
3377!--          z_direction
3378             k_next = MAX( MIN( FLOOR( zp / (zw(kkw+1)-zw(kkw)) + offset_ocean_nzt ), nzt ), 0)
3379             gamma = MAX( MIN( ( zp - zw(k_next) ) /                      &
3380                               ( zw(k_next+1) - zw(k_next) ), 1.0_wp ), 0.0_wp )
3381!
3382!--          Calculate part of the corrector step
3383             unext = u(k_next+1, j_next, i_next) * ( 1.0_wp - alpha ) +    &
3384                     u(k_next+1, j_next,   i_next+1) * alpha
3385
3386             vnext = v(k_next+1, j_next, i_next) * ( 1.0_wp - beta  ) +    &
3387                     v(k_next+1, j_next+1, i_next  ) * beta
3388
3389             wnext = w(k_next,   j_next, i_next) * ( 1.0_wp - gamma ) +    &
3390                     w(k_next+1, j_next, i_next  ) * gamma
3391
3392!
3393!--          Calculate interpolated particle velocity with predictor
3394!--          corrector step. u_int, v_int and w_int describes the part of
3395!--          the predictor step. unext, vnext and wnext is the part of the
3396!--          corrector step. The resulting new position is set below. The
3397!--          implementation is based on Grabowski et al., 2018 (GMD).
3398             u_int(n) = 0.5_wp * ( u_int(n) + unext )
3399             v_int(n) = 0.5_wp * ( v_int(n) + vnext )
3400             w_int(n) = 0.5_wp * ( w_int(n) + wnext )
3401
3402          ENDDO
3403       ENDDO
3404!
3405!-- This case uses a simple interpolation method for the particle velocites,
3406!-- and applying a predictor.
3407    ELSEIF ( interpolation_simple_predictor )  THEN
3408!
3409!--    The particle position for the w velociy is based on the value of kp and kp-1
3410       kkw = kp - 1
3411       DO  n = 1, number_of_particles
3412          IF ( .NOT. particles(n)%particle_mask )  CYCLE
3413
3414          alpha    = MAX( MIN( ( particles(n)%x - ip * dx ) * ddx, 1.0_wp ), 0.0_wp )
3415          u_int(n) = u(kp,jp,ip) * ( 1.0_wp - alpha ) + u(kp,jp,ip+1) * alpha
3416
3417          beta     = MAX( MIN( ( particles(n)%y - jp * dy ) * ddy, 1.0_wp ), 0.0_wp )
3418          v_int(n) = v(kp,jp,ip) * ( 1.0_wp - beta ) + v(kp,jp+1,ip) * beta
3419
3420          gamma    = MAX( MIN( ( particles(n)%z - zw(kkw) ) /                   &
3421                               ( zw(kkw+1) - zw(kkw) ), 1.0_wp ), 0.0_wp )
3422          w_int(n) = w(kkw,jp,ip) * ( 1.0_wp - gamma ) + w(kkw+1,jp,ip) * gamma
3423       ENDDO
3424!
3425!-- The trilinear interpolation.
3426    ELSEIF ( interpolation_trilinear )  THEN
3427
3428       start_index = grid_particles(kp,jp,ip)%start_index
3429       end_index   = grid_particles(kp,jp,ip)%end_index
3430
3431       DO  nb = 0, 7
3432!
3433!--       Interpolate u velocity-component
3434          i = ip
3435          j = jp + block_offset(nb)%j_off
3436          k = kp + block_offset(nb)%k_off
3437
3438          DO  n = start_index(nb), end_index(nb)
3439!
3440!--          Interpolation of the u velocity component onto particle position.
3441!--          Particles are interpolation bi-linearly in the horizontal and a
3442!--          linearly in the vertical. An exception is made for particles below
3443!--          the first vertical grid level in case of a prandtl layer. In this
3444!--          case the horizontal particle velocity components are determined using
3445!--          Monin-Obukhov relations (if branch).
3446!--          First, check if particle is located below first vertical grid level
3447!--          above topography (Prandtl-layer height)
3448!--          Determine vertical index of topography top
3449             k_wall = topo_top_ind(jp,ip,0)
3450
3451             IF ( constant_flux_layer  .AND.  zv(n) - zw(k_wall) < z_p )  THEN
3452!
3453!--             Resolved-scale horizontal particle velocity is zero below z0.
3454                IF ( zv(n) - zw(k_wall) < z0_av_global )  THEN
3455                   u_int(n) = 0.0_wp
3456                ELSE
3457!
3458!--                Determine the sublayer. Further used as index.
3459                   height_p = ( zv(n) - zw(k_wall) - z0_av_global ) &
3460                                        * REAL( number_of_sublayers, KIND=wp )    &
3461                                        * d_z_p_z0
3462!
3463!--                Calculate LOG(z/z0) for exact particle height. Therefore,
3464!--                interpolate linearly between precalculated logarithm.
3465                   log_z_z0_int = log_z_z0(INT(height_p))                         &
3466                                    + ( height_p - INT(height_p) )                &
3467                                    * ( log_z_z0(INT(height_p)+1)                 &
3468                                         - log_z_z0(INT(height_p))                &
3469                                      )
3470!
3471!--                Get friction velocity and momentum flux from new surface data
3472!--                types.
3473                   IF ( surf_def_h(0)%start_index(jp,ip) <=                   &
3474                        surf_def_h(0)%end_index(jp,ip) )  THEN
3475                      surf_start = surf_def_h(0)%start_index(jp,ip)
3476!--                   Limit friction velocity. In narrow canyons or holes the
3477!--                   friction velocity can become very small, resulting in a too
3478!--                   large particle speed.
3479                      us_int    = MAX( surf_def_h(0)%us(surf_start), 0.01_wp )
3480                      usws_int  = surf_def_h(0)%usws(surf_start)
3481                   ELSEIF ( surf_lsm_h%start_index(jp,ip) <=                  &
3482                            surf_lsm_h%end_index(jp,ip) )  THEN
3483                      surf_start = surf_lsm_h%start_index(jp,ip)
3484                      us_int    = MAX( surf_lsm_h%us(surf_start), 0.01_wp )
3485                      usws_int  = surf_lsm_h%usws(surf_start)
3486                   ELSEIF ( surf_usm_h%start_index(jp,ip) <=                  &
3487                            surf_usm_h%end_index(jp,ip) )  THEN
3488                      surf_start = surf_usm_h%start_index(jp,ip)
3489                      us_int    = MAX( surf_usm_h%us(surf_start), 0.01_wp )
3490                      usws_int  = surf_usm_h%usws(surf_start)
3491                   ENDIF
3492!
3493!--                Neutral solution is applied for all situations, e.g. also for
3494!--                unstable and stable situations. Even though this is not exact
3495!--                this saves a lot of CPU time since several calls of intrinsic
3496!--                FORTRAN procedures (LOG, ATAN) are avoided, This is justified
3497!--                as sensitivity studies revealed no significant effect of
3498!--                using the neutral solution also for un/stable situations.
3499                   u_int(n) = -usws_int / ( us_int * kappa + 1E-10_wp )           &
3500                               * log_z_z0_int - u_gtrans
3501                ENDIF
3502!
3503!--          Particle above the first grid level. Bi-linear interpolation in the
3504!--          horizontal and linear interpolation in the vertical direction.
3505             ELSE
3506                = xv(n) - i * dx
3507                y  = yv(n) + ( 0.5_wp - j ) * dy
3508                aa = x**2          + y**2
3509                bb = ( dx - x )**2 + y**2
3510                cc = x**2          + ( dy - y )**2
3511                dd = ( dx - x )**2 + ( dy - y )**2
3512                gg = aa + bb + cc + dd
3513
3514                u_int_l = ( ( gg - aa ) * u(k,j,i)   + ( gg - bb ) * u(k,j,i+1)   &
3515                            + ( gg - cc ) * u(k,j+1,i) + ( gg - dd ) *            &
3516                            u(k,j+1,i+1) ) / ( 3.0_wp * gg ) - u_gtrans
3517
3518                IF ( k == nzt )  THEN
3519                   u_int(n) = u_int_l
3520                ELSE
3521                   u_int_u = ( ( gg-aa ) * u(k+1,j,i) + ( gg-bb ) * u(k+1,j,i+1)  &
3522                               + ( gg-cc ) * u(k+1,j+1,i) + ( gg-dd ) *           &
3523                               u(k+1,j+1,i+1) ) / ( 3.0_wp * gg ) - u_gtrans
3524                   u_int(n) = u_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *            &
3525                              ( u_int_u - u_int_l )
3526                ENDIF
3527             ENDIF
3528          ENDDO
3529!
3530!--       Same procedure for interpolation of the v velocity-component
3531          i = ip + block_offset(nb)%i_off
3532          j = jp
3533          k = kp + block_offset(nb)%k_off
3534
3535          DO  n = start_index(nb), end_index(nb)
3536!
3537!--          Determine vertical index of topography top
3538             k_wall = topo_top_ind(jp,ip,0)
3539
3540             IF ( constant_flux_layer  .AND.  zv(n) - zw(k_wall) < z_p )  THEN
3541                IF ( zv(n) - zw(k_wall) < z0_av_global )  THEN
3542!
3543!--                Resolved-scale horizontal particle velocity is zero below z0.
3544                   v_int(n) = 0.0_wp
3545                ELSE
3546!
3547!--                Determine the sublayer. Further used as index. Please note,
3548!--                logarithmus can not be reused from above, as in in case of
3549!--                topography particle on u-grid can be above surface-layer height,
3550!--                whereas it can be below on v-grid.
3551                   height_p = ( zv(n) - zw(k_wall) - z0_av_global ) &
3552                                     * REAL( number_of_sublayers, KIND=wp )       &
3553                                     * d_z_p_z0
3554!
3555!--                Calculate LOG(z/z0) for exact particle height. Therefore,
3556!--                interpolate linearly between precalculated logarithm.
3557                   log_z_z0_int = log_z_z0(INT(height_p))                         &
3558                                    + ( height_p - INT(height_p) )                &
3559                                    * ( log_z_z0(INT(height_p)+1)                 &
3560                                         - log_z_z0(INT(height_p))                &
3561                                      )
3562!
3563!--                Get friction velocity and momentum flux from new surface data
3564!--                types.
3565                   IF ( surf_def_h(0)%start_index(jp,ip) <=                   &
3566                        surf_def_h(0)%end_index(jp,ip) )  THEN
3567                      surf_start = surf_def_h(0)%start_index(jp,ip)
3568!--                   Limit friction velocity. In narrow canyons or holes the
3569!--                   friction velocity can become very small, resulting in a too
3570!--                   large particle speed.
3571                      us_int    = MAX( surf_def_h(0)%us(surf_start), 0.01_wp )
3572                      vsws_int  = surf_def_h(0)%vsws(surf_start)
3573                   ELSEIF ( surf_lsm_h%start_index(jp,ip) <=                  &
3574                            surf_lsm_h%end_index(jp,ip) )  THEN
3575                      surf_start = surf_lsm_h%start_index(jp,ip)
3576                      us_int    = MAX( surf_lsm_h%us(surf_start), 0.01_wp )
3577                      vsws_int  = surf_lsm_h%vsws(surf_start)
3578                   ELSEIF ( surf_usm_h%start_index(jp,ip) <=                  &
3579                            surf_usm_h%end_index(jp,ip) )  THEN
3580                      surf_start = surf_usm_h%start_index(jp,ip)
3581                      us_int    = MAX( surf_usm_h%us(surf_start), 0.01_wp )
3582                      vsws_int  = surf_usm_h%vsws(surf_start)
3583                   ENDIF
3584!
3585!--                Neutral solution is applied for all situations, e.g. also for
3586!--                unstable and stable situations. Even though this is not exact
3587!--                this saves a lot of CPU time since several calls of intrinsic
3588!--                FORTRAN procedures (LOG, ATAN) are avoided, This is justified
3589!--                as sensitivity studies revealed no significant effect of
3590!--                using the neutral solution also for un/stable situations.
3591                   v_int(n) = -vsws_int / ( us_int * kappa + 1E-10_wp )           &
3592                            * log_z_z0_int - v_gtrans
3593
3594                ENDIF
3595             ELSE
3596                = xv(n) + ( 0.5_wp - i ) * dx
3597                y  = yv(n) - j * dy
3598                aa = x**2          + y**2
3599                bb = ( dx - x )**2 + y**2
3600                cc = x**2          + ( dy - y )**2
3601                dd = ( dx - x )**2 + ( dy - y )**2
3602                gg = aa + bb + cc + dd
3603
3604                v_int_l = ( ( gg - aa ) * v(k,j,i)   + ( gg - bb ) * v(k,j,i+1)   &
3605                          + ( gg - cc ) * v(k,j+1,i) + ( gg - dd ) * v(k,j+1,i+1) &
3606                          ) / ( 3.0_wp * gg ) - v_gtrans
3607
3608                IF ( k == nzt )  THEN
3609                   v_int(n) = v_int_l
3610                ELSE
3611                   v_int_u = ( ( gg-aa ) * v(k+1,j,i)   + ( gg-bb ) * v(k+1,j,i+1)   &
3612                             + ( gg-cc ) * v(k+1,j+1,i) + ( gg-dd ) * v(k+1,j+1,i+1) &
3613                             ) / ( 3.0_wp * gg ) - v_gtrans
3614                   v_int(n) = v_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *               &
3615                                     ( v_int_u - v_int_l )
3616                ENDIF
3617             ENDIF
3618          ENDDO
3619!
3620!--       Same procedure for interpolation of the w velocity-component
3621          i = ip + block_offset(nb)%i_off
3622          j = jp + block_offset(nb)%j_off
3623          k = kp - 1
3624
3625          DO  n = start_index(nb), end_index(nb)
3626             IF ( vertical_particle_advection(particles(n)%group) )  THEN
3627                = xv(n) + ( 0.5_wp - i ) * dx
3628                y  = yv(n) + ( 0.5_wp - j ) * dy
3629                aa = x**2          + y**2
3630                bb = ( dx - x )**2 + y**2
3631                cc = x**2          + ( dy - y )**2
3632                dd = ( dx - x )**2 + ( dy - y )**2
3633                gg = aa + bb + cc + dd
3634
3635                w_int_l = ( ( gg - aa ) * w(k,j,i)   + ( gg - bb ) * w(k,j,i+1)   &
3636                          + ( gg - cc ) * w(k,j+1,i) + ( gg - dd ) * w(k,j+1,i+1) &
3637                          ) / ( 3.0_wp * gg )
3638
3639                IF ( k == nzt )  THEN
3640                   w_int(n) = w_int_l
3641                ELSE
3642                   w_int_u = ( ( gg-aa ) * w(k+1,j,i)   + &
3643                               ( gg-bb ) * w(k+1,j,i+1) + &
3644                               ( gg-cc ) * w(k+1,j+1,i) + &
3645                               ( gg-dd ) * w(k+1,j+1,i+1) &
3646                             ) / ( 3.0_wp * gg )
3647                   w_int(n) = w_int_l + ( zv(n) - zw(k) ) / dzw(k+1) *               &
3648                              ( w_int_u - w_int_l )
3649                ENDIF
3650             ELSE
3651                w_int(n) = 0.0_wp
3652             ENDIF
3653          ENDDO
3654       ENDDO
3655    ENDIF
3656
3657!-- Interpolate and calculate quantities needed for calculating the SGS
3658!-- velocities
3659    IF ( use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
3660
3661       DO  nb = 0,7
3662
3663          subbox_at_wall = .FALSE.
3664!
3665!--       In case of topography check if subbox is adjacent to a wall
3666          IF ( .NOT. topography == 'flat' )  THEN
3667             i = ip + MERGE( -1_iwp , 1_iwp, BTEST( nb, 2 ) )
3668             j = jp + MERGE( -1_iwp , 1_iwp, BTEST( nb, 1 ) )
3669             k = kp + MERGE( -1_iwp , 1_iwp, BTEST( nb, 0 ) )
3670             IF ( .NOT. BTEST(wall_flags_static_0(k,  jp, ip), 0) .OR.                &
3671                  .NOT. BTEST(wall_flags_static_0(kp, j,  ip), 0) .OR.                &
3672                  .NOT. BTEST(wall_flags_static_0(kp, jp, i ), 0) )                   &
3673             THEN
3674                subbox_at_wall = .TRUE.
3675             ENDIF
3676          ENDIF
3677          IF ( subbox_at_wall )  THEN
3678             e_int(start_index(nb):end_index(nb))     = e(kp,jp,ip) 
3679             diss_int(start_index(nb):end_index(nb))  = diss(kp,jp,ip)
3680             de_dx_int(start_index(nb):end_index(nb)) = de_dx(kp,jp,ip)
3681             de_dy_int(start_index(nb):end_index(nb)) = de_dy(kp,jp,ip)
3682             de_dz_int(start_index(nb):end_index(nb)) = de_dz(kp,jp,ip)
3683!
3684!--          Set flag for stochastic equation.
3685             term_1_2(start_index(nb):end_index(nb)) = 0.0_wp
3686          ELSE
3687             i = ip + block_offset(nb)%i_off
3688             j = jp + block_offset(nb)%j_off
3689             k = kp + block_offset(nb)%k_off
3690
3691             DO  n = start_index(nb), end_index(nb)
3692!
3693!--             Interpolate TKE
3694                x  = xv(n) + ( 0.5_wp - i ) * dx
3695                y  = yv(n) + ( 0.5_wp - j ) * dy
3696                aa = x**2          + y**2
3697                bb = ( dx - x )**2 + y**2
3698                cc = x**2          + ( dy - y )**2
3699                dd = ( dx - x )**2 + ( dy - y )**2
3700                gg = aa + bb + cc + dd
3701
3702                e_int_l = ( ( gg-aa ) * e(k,j,i)   + ( gg-bb ) * e(k,j,i+1)   &
3703                          + ( gg-cc ) * e(k,j+1,i) + ( gg-dd ) * e(k,j+1,i+1) &
3704                          ) / ( 3.0_wp * gg )
3705
3706                IF ( k+1 == nzt+1 )  THEN
3707                   e_int(n) = e_int_l
3708                ELSE
3709                   e_int_u = ( ( gg - aa ) * e(k+1,j,i)   + &
3710                               ( gg - bb ) * e(k+1,j,i+1) + &
3711                               ( gg - cc ) * e(k+1,j+1,i) + &
3712                               ( gg - dd ) * e(k+1,j+1,i+1) &
3713                            ) / ( 3.0_wp * gg )
3714                   e_int(n) = e_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *            &
3715                                     ( e_int_u - e_int_l )
3716                ENDIF
3717!
3718!--             Needed to avoid NaN particle velocities (this might not be
3719!--             required any more)
3720                IF ( e_int(n) <= 0.0_wp )  THEN
3721                   e_int(n) = 1.0E-20_wp
3722                ENDIF
3723!
3724!--             Interpolate the TKE gradient along x (adopt incides i,j,k and
3725!--             all position variables from above (TKE))
3726                de_dx_int_l = ( ( gg - aa ) * de_dx(k,j,i)   + &
3727                                ( gg - bb ) * de_dx(k,j,i+1) + &
3728                                ( gg - cc ) * de_dx(k,j+1,i) + &
3729                                ( gg - dd ) * de_dx(k,j+1,i+1) &
3730                               ) / ( 3.0_wp * gg )
3731
3732                IF ( ( k+1 == nzt+1 )  .OR.  ( k == nzb ) )  THEN
3733                   de_dx_int(n) = de_dx_int_l
3734                ELSE
3735                   de_dx_int_u = ( ( gg - aa ) * de_dx(k+1,j,i)   + &
3736                                   ( gg - bb ) * de_dx(k+1,j,i+1) + &
3737                                   ( gg - cc ) * de_dx(k+1,j+1,i) + &
3738                                   ( gg - dd ) * de_dx(k+1,j+1,i+1) &
3739                                  ) / ( 3.0_wp * gg )
3740                   de_dx_int(n) = de_dx_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *    &
3741                                              ( de_dx_int_u - de_dx_int_l )
3742                ENDIF
3743!
3744!--             Interpolate the TKE gradient along y
3745                de_dy_int_l = ( ( gg - aa ) * de_dy(k,j,i)   + &
3746                                ( gg - bb ) * de_dy(k,j,i+1) + &
3747                                ( gg - cc ) * de_dy(k,j+1,i) + &
3748                                ( gg - dd ) * de_dy(k,j+1,i+1) &
3749                               ) / ( 3.0_wp * gg )
3750                IF ( ( k+1 == nzt+1 )  .OR.  ( k == nzb ) )  THEN
3751                   de_dy_int(n) = de_dy_int_l
3752                ELSE
3753                   de_dy_int_u = ( ( gg - aa ) * de_dy(k+1,j,i)   + &
3754                                   ( gg - bb ) * de_dy(k+1,j,i+1) + &
3755                                   ( gg - cc ) * de_dy(k+1,j+1,i) + &
3756                                   ( gg - dd ) * de_dy(k+1,j+1,i+1) &
3757                                  ) / ( 3.0_wp * gg )
3758                      de_dy_int(n) = de_dy_int_l + ( zv(n) - zu(k) ) / dzw(k+1) * &
3759                                                 ( de_dy_int_u - de_dy_int_l )
3760                ENDIF
3761
3762!
3763!--             Interpolate the TKE gradient along z
3764                IF ( zv(n) < 0.5_wp * dz(1) )  THEN
3765                   de_dz_int(n) = 0.0_wp
3766                ELSE
3767                   de_dz_int_l = ( ( gg - aa ) * de_dz(k,j,i)   + &
3768                                   ( gg - bb ) * de_dz(k,j,i+1) + &
3769                                   ( gg - cc ) * de_dz(k,j+1,i) + &
3770                                   ( gg - dd ) * de_dz(k,j+1,i+1) &
3771                                  ) / ( 3.0_wp * gg )
3772
3773                   IF ( ( k+1 == nzt+1 )  .OR.  ( k == nzb ) )  THEN
3774                      de_dz_int(n) = de_dz_int_l
3775                   ELSE
3776                      de_dz_int_u = ( ( gg - aa ) * de_dz(k+1,j,i)   + &
3777                                      ( gg - bb ) * de_dz(k+1,j,i+1) + &
3778                                      ( gg - cc ) * de_dz(k+1,j+1,i) + &
3779                                      ( gg - dd ) * de_dz(k+1,j+1,i+1) &
3780                                     ) / ( 3.0_wp * gg )
3781                      de_dz_int(n) = de_dz_int_l + ( zv(n) - zu(k) ) / dzw(k+1) * &
3782                                                 ( de_dz_int_u - de_dz_int_l )
3783                   ENDIF
3784                ENDIF
3785
3786!
3787!--             Interpolate the dissipation of TKE
3788                diss_int_l = ( ( gg - aa ) * diss(k,j,i)   + &
3789                               ( gg - bb ) * diss(k,j,i+1) + &
3790                               ( gg - cc ) * diss(k,j+1,i) + &
3791                               ( gg - dd ) * diss(k,j+1,i+1) &
3792                               ) / ( 3.0_wp * gg )
3793
3794                IF ( k == nzt )  THEN
3795                   diss_int(n) = diss_int_l
3796                ELSE
3797                   diss_int_u = ( ( gg - aa ) * diss(k+1,j,i)   + &
3798                                  ( gg - bb ) * diss(k+1,j,i+1) + &
3799                                  ( gg - cc ) * diss(k+1,j+1,i) + &
3800                                  ( gg - dd ) * diss(k+1,j+1,i+1) &
3801                                 ) / ( 3.0_wp * gg )
3802                   diss_int(n) = diss_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *      &
3803                                            ( diss_int_u - diss_int_l )
3804                ENDIF
3805
3806!
3807!--             Set flag for stochastic equation.
3808                term_1_2(n) = 1.0_wp
3809             ENDDO
3810          ENDIF
3811       ENDDO
3812
3813       DO  nb = 0,7
3814          i = ip + block_offset(nb)%i_off
3815          j = jp + block_offset(nb)%j_off
3816          k = kp + block_offset(nb)%k_off
3817
3818          DO  n = start_index(nb), end_index(nb)
3819!
3820!--          Vertical interpolation of the horizontally averaged SGS TKE and
3821!--          resolved-scale velocity variances and use the interpolated values
3822!--          to calculate the coefficient fs, which is a measure of the ratio
3823!--          of the subgrid-scale turbulent kinetic energy to the total amount
3824!--          of turbulent kinetic energy.
3825             IF ( k == 0 )  THEN
3826                e_mean_int = hom(0,1,8,0)
3827             ELSE
3828                e_mean_int = hom(k,1,8,0) +                                    &
3829                                           ( hom(k+1,1,8,0) - hom(k,1,8,0) ) / &
3830                                           ( zu(k+1) - zu(k) ) *               &
3831                                           ( zv(n) - zu(k) )
3832             ENDIF
3833
3834             kw = kp - 1
3835
3836             IF ( k == 0 )  THEN
3837                aa  = hom(k+1,1,30,0)  * ( zv(n) / &
3838                                         ( 0.5_wp * ( zu(k+1) - zu(k) ) ) )
3839                bb  = hom(k+1,1,31,0)  * ( zv(n) / &
3840                                         ( 0.5_wp * ( zu(k+1) - zu(k) ) ) )
3841                cc  = hom(kw+1,1,32,0) * ( zv(n) / &
3842                                         ( 1.0_wp * ( zw(kw+1) - zw(kw) ) ) )
3843             ELSE
3844                aa  = hom(k,1,30,0) + ( hom(k+1,1,30,0) - hom(k,1,30,0) ) *    &
3845                           ( ( zv(n) - zu(k) ) / ( zu(k+1) - zu(k) ) )
3846                bb  = hom(k,1,31,0) + ( hom(k+1,1,31,0) - hom(k,1,31,0) ) *    &
3847                           ( ( zv(n) - zu(k) ) / ( zu(k+1) - zu(k) ) )
3848                cc  = hom(kw,1,32,0) + ( hom(kw+1,1,32,0)-hom(kw,1,32,0) ) *   &
3849                           ( ( zv(n) - zw(kw) ) / ( zw(kw+1)-zw(kw) ) )
3850             ENDIF
3851
3852             vv_int = ( 1.0_wp / 3.0_wp ) * ( aa + bb + cc )
3853!
3854!--          Needed to avoid NaN particle velocities. The value of 1.0 is just
3855!--          an educated guess for the given case.
3856             IF ( vv_int + ( 2.0_wp / 3.0_wp ) * e_mean_int == 0.0_wp )  THEN
3857                fs_int(n) = 1.0_wp
3858             ELSE
3859                fs_int(n) = ( 2.0_wp / 3.0_wp ) * e_mean_int /                 &
3860                            ( vv_int + ( 2.0_wp / 3.0_wp ) * e_mean_int )
3861             ENDIF
3862
3863          ENDDO
3864       ENDDO
3865
3866       DO  nb = 0, 7
3867          DO  n = start_index(nb), end_index(nb)
3868             rg(n,1) = random_gauss( iran_part, 5.0_wp )
3869             rg(n,2) = random_gauss( iran_part, 5.0_wp )
3870             rg(n,3) = random_gauss( iran_part, 5.0_wp )
3871          ENDDO
3872       ENDDO
3873
3874       DO  nb = 0, 7
3875          DO  n = start_index(nb), end_index(nb)
3876
3877!
3878!--          Calculate the Lagrangian timescale according to Weil et al. (2004).
3879             lagr_timescale(n) = ( 4.0_wp * e_int(n) + 1E-20_wp ) / &
3880                              ( 3.0_wp * fs_int(n) * c_0 * diss_int(n) + 1E-20_wp )
3881
3882!
3883!--          Calculate the next particle timestep. dt_gap is the time needed to
3884!--          complete the current LES timestep.
3885             dt_gap(n) = dt_3d - particles(n)%dt_sum
3886             dt_particle(n) = MIN( dt_3d, 0.025_wp * lagr_timescale(n), dt_gap(n) )
3887             particles(n)%aux1 = lagr_timescale(n)
3888             particles(n)%aux2 = dt_gap(n)
3889!
3890!--          The particle timestep should not be too small in order to prevent
3891!--          the number of particle timesteps of getting too large
3892             IF ( dt_particle(n) < dt_min_part )  THEN
3893                IF ( dt_min_part < dt_gap(n) )  THEN
3894                   dt_particle(n) = dt_min_part
3895                ELSE
3896                   dt_particle(n) = dt_gap(n)
3897                ENDIF
3898             ENDIF
3899             rvar1_temp(n) = particles(n)%rvar1
3900             rvar2_temp(n) = particles(n)%rvar2
3901             rvar3_temp(n) = particles(n)%rvar3
3902!
3903!--          Calculate the SGS velocity components
3904             IF ( particles(n)%age == 0.0_wp )  THEN
3905!
3906!--             For new particles the SGS components are derived from the SGS
3907!--             TKE. Limit the Gaussian random number to the interval
3908!--             [-5.0*sigma, 5.0*sigma] in order to prevent the SGS velocities
3909!--             from becoming unrealistically large.
3910                rvar1_temp(n) = SQRT( 2.0_wp * sgs_wf_part * e_int(n)          &
3911                                          + 1E-20_wp ) * ( rg(n,1) - 1.0_wp )
3912                rvar2_temp(n) = SQRT( 2.0_wp * sgs_wf_part * e_int(n)          &
3913                                          + 1E-20_wp ) * ( rg(n,2) - 1.0_wp )
3914                rvar3_temp(n) = SQRT( 2.0_wp * sgs_wf_part * e_int(n)          &
3915                                          + 1E-20_wp ) * ( rg(n,3) - 1.0_wp )
3916
3917             ELSE
3918!
3919!--             Restriction of the size of the new timestep: compared to the
3920!--             previous timestep the increase must not exceed 200%. First,
3921!--             check if age > age_m, in order to prevent that particles get zero
3922!--             timestep.
3923                dt_particle_m = MERGE( dt_particle(n),                         &
3924                                       particles(n)%age - particles(n)%age_m,  &
3925                                       particles(n)%age - particles(n)%age_m < &
3926                                       1E-8_wp )
3927                IF ( dt_particle(n) > 2.0_wp * dt_particle_m )  THEN
3928                   dt_particle(n) = 2.0_wp * dt_particle_m
3929                ENDIF
3930
3931!--             For old particles the SGS components are correlated with the
3932!--             values from the previous timestep. Random numbers have also to
3933!--             be limited (see above).
3934!--             As negative values for the subgrid TKE are not allowed, the
3935!--             change of the subgrid TKE with time cannot be smaller than
3936!--             -e_int(n)/dt_particle. This value is used as a lower boundary
3937!--             value for the change of TKE
3938                de_dt_min = - e_int(n) / dt_particle(n)
3939
3940                de_dt = ( e_int(n) - particles(n)%e_m ) / dt_particle_m
3941
3942                IF ( de_dt < de_dt_min )  THEN
3943                   de_dt = de_dt_min
3944                ENDIF
3945
3946                CALL weil_stochastic_eq( rvar1_temp(n), fs_int(n), e_int(n),    &
3947                                        de_dx_int(n), de_dt, diss_int(n),       &
3948                                        dt_particle(n), rg(n,1), term_1_2(n) )
3949
3950                CALL weil_stochastic_eq( rvar2_temp(n), fs_int(n), e_int(n),    &
3951                                        de_dy_int(n), de_dt, diss_int(n),       &
3952                                        dt_particle(n), rg(n,2), term_1_2(n) )
3953
3954                CALL weil_stochastic_eq( rvar3_temp(n), fs_int(n), e_int(n),    &
3955                                        de_dz_int(n), de_dt, diss_int(n),       &
3956                                        dt_particle(n), rg(n,3), term_1_2(n) )
3957
3958             ENDIF
3959
3960          ENDDO
3961       ENDDO
3962!
3963!--    Check if the added SGS velocities result in a violation of the CFL-
3964!--    criterion. If yes choose a smaller timestep based on the new velocities
3965!--    and calculate SGS velocities again
3966       dz_temp = zw(kp)-zw(kp-1)
3967
3968       DO  nb = 0, 7
3969          DO  n = start_index(nb), end_index(nb)
3970             IF ( .NOT. particles(n)%age == 0.0_wp .AND.                       &
3971                (ABS( u_int(n) + rvar1_temp(n) ) > (dx/dt_particle(n))  .OR.   &
3972                 ABS( v_int(n) + rvar2_temp(n) ) > (dy/dt_particle(n))  .OR.   &
3973                 ABS( w_int(n) + rvar3_temp(n) ) > (dz_temp/dt_particle(n))))  THEN
3974
3975                dt_particle(n) = 0.9_wp * MIN(                                 &
3976                                 ( dx / ABS( u_int(n) + rvar1_temp(n) ) ),     &
3977                                 ( dy / ABS( v_int(n) + rvar2_temp(n) ) ),     &
3978                                 ( dz_temp / ABS( w_int(n) + rvar3_temp(n) ) ) )
3979
3980!
3981!--             Reset temporary SGS velocites to "current" ones
3982                rvar1_temp(n) = particles(n)%rvar1
3983                rvar2_temp(n) = particles(n)%rvar2
3984                rvar3_temp(n) = particles(n)%rvar3
3985
3986                de_dt_min = - e_int(n) / dt_particle(n)
3987
3988                de_dt = ( e_int(n) - particles(n)%e_m ) / dt_particle_m
3989
3990                IF ( de_dt < de_dt_min )  THEN
3991                   de_dt = de_dt_min
3992                ENDIF
3993
3994                CALL weil_stochastic_eq( rvar1_temp(n), fs_int(n), e_int(n),    &
3995                                        de_dx_int(n), de_dt, diss_int(n),       &
3996                                        dt_particle(n), rg(n,1), term_1_2(n) )
3997
3998                CALL weil_stochastic_eq( rvar2_temp(n), fs_int(n), e_int(n),    &
3999                                        de_dy_int(n), de_dt, diss_int(n),       &
4000                                        dt_particle(n), rg(n,2), term_1_2(n) )
4001
4002                CALL weil_stochastic_eq( rvar3_temp(n), fs_int(n), e_int(n),    &
4003                                        de_dz_int(n), de_dt, diss_int(n),       &
4004                                        dt_particle(n), rg(n,3), term_1_2(n) )
4005             ENDIF
4006
4007!
4008!--          Update particle velocites
4009             particles(n)%rvar1 = rvar1_temp(n)
4010             particles(n)%rvar2 = rvar2_temp(n)
4011             particles(n)%rvar3 = rvar3_temp(n)
4012             u_int(n) = u_int(n) + particles(n)%rvar1
4013             v_int(n) = v_int(n) + particles(n)%rvar2
4014             w_int(n) = w_int(n) + particles(n)%rvar3
4015!
4016!--          Store the SGS TKE of the current timelevel which is needed for
4017!--          for calculating the SGS particle velocities at the next timestep
4018             particles(n)%e_m = e_int(n)
4019          ENDDO
4020       ENDDO
4021
4022    ELSE
4023!
4024!--    If no SGS velocities are used, only the particle timestep has to
4025!--    be set
4026       dt_particle = dt_3d
4027
4028    ENDIF
4029
4030    dens_ratio = particle_groups(particles(1:number_of_particles)%group)%density_ratio
4031    IF ( ANY( dens_ratio == 0.0_wp ) )  THEN
4032!
4033!--    Decide whether the particle loop runs over the subboxes or only over 1,
4034!--    number_of_particles. This depends on the selected interpolation method.
4035!--    If particle interpolation method is not trilinear, then the sorting within
4036!--    subboxes is not required. However, therefore the index start_index(nb) and
4037!--    end_index(nb) are not defined and the loops are still over
4038!--    number_of_particles. @todo find a more generic way to write this loop or
4039!--    delete trilinear interpolation
4040       IF ( interpolation_trilinear )  THEN
4041          subbox_start = 0
4042          subbox_end   = 7
4043       ELSE
4044          subbox_start = 1
4045          subbox_end   = 1
4046       ENDIF
4047!
4048!--    loop over subboxes. In case of simple interpolation scheme no subboxes
4049!--    are introduced, as they are not required. Accordingly, this loops goes
4050!--    from 1 to 1.
4051       DO  nb = subbox_start, subbox_end
4052          IF ( interpolation_trilinear )  THEN
4053             particle_start = start_index(nb)
4054             particle_end   = end_index(nb)
4055          ELSE
4056             particle_start = 1
4057             particle_end   = number_of_particles
4058          ENDIF
4059!
4060!--         Loop from particle start to particle end
4061            DO  n = particle_start, particle_end
4062
4063!
4064!--          Particle advection
4065             IF ( dens_ratio(n) == 0.0_wp )  THEN
4066!
4067!--             Pure passive transport (without particle inertia)
4068                particles(n)%x = xv(n) + u_int(n) * dt_particle(n)
4069                particles(n)%y = yv(n) + v_int(n) * dt_particle(n)
4070                particles(n)%z = zv(n) + w_int(n) * dt_particle(n)
4071
4072                particles(n)%speed_x = u_int(n)
4073                particles(n)%speed_y = v_int(n)
4074                particles(n)%speed_z = w_int(n)
4075
4076             ELSE
4077!
4078!--             Transport of particles with inertia
4079                particles(n)%x = particles(n)%x + particles(n)%speed_x * &
4080                                                  dt_particle(n)
4081                particles(n)%y = particles(n)%y + particles(n)%speed_y * &
4082                                                  dt_particle(n)
4083                particles(n)%z = particles(n)%z + particles(n)%speed_z * &
4084                                                  dt_particle(n)
4085
4086!
4087!--             Update of the particle velocity
4088                IF ( cloud_droplets )  THEN
4089!
4090!--                Terminal velocity is computed for vertical direction (Rogers et
4091!--                al., 1993, J. Appl. Meteorol.)
4092                   diameter = particles(n)%radius * 2000.0_wp !diameter in mm
4093                   IF ( diameter <= d0_rog )  THEN
4094                      w_s = k_cap_rog * diameter * ( 1.0_wp - EXP( -k_low_rog * diameter ) )
4095                   ELSE
4096                      w_s = a_rog - b_rog * EXP( -c_rog * diameter )
4097                   ENDIF
4098
4099!
4100!--                If selected, add random velocities following Soelch and Kaercher
4101!--                (2010, Q. J. R. Meteorol. Soc.)
4102                   IF ( use_sgs_for_particles )  THEN
4103                      lagr_timescale(n) = km(kp,jp,ip) / MAX( e(kp,jp,ip), 1.0E-20_wp )
4104                      RL             = EXP( -1.0_wp * dt_3d / MAX( lagr_timescale(n), &
4105                                             1.0E-20_wp ) )
4106                      sigma          = SQRT( e(kp,jp,ip) )
4107
4108                      rg1 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4109                      rg2 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4110                      rg3 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4111
4112                      particles(n)%rvar1 = RL * particles(n)%rvar1 +              &
4113                                           SQRT( 1.0_wp - RL**2 ) * sigma * rg1
4114                      particles(n)%rvar2 = RL * particles(n)%rvar2 +              &
4115                                           SQRT( 1.0_wp - RL**2 ) * sigma * rg2
4116                      particles(n)%rvar3 = RL * particles(n)%rvar3 +              &
4117                                           SQRT( 1.0_wp - RL**2 ) * sigma * rg3
4118
4119                      particles(n)%speed_x = u_int(n) + particles(n)%rvar1
4120                      particles(n)%speed_y = v_int(n) + particles(n)%rvar2
4121                      particles(n)%speed_z = w_int(n) + particles(n)%rvar3 - w_s
4122                   ELSE
4123                      particles(n)%speed_x = u_int(n)
4124                      particles(n)%speed_y = v_int(n)
4125                      particles(n)%speed_z = w_int(n) - w_s
4126                   ENDIF
4127
4128                ELSE
4129
4130                   IF ( use_sgs_for_particles )  THEN
4131                      exp_arg  = particle_groups(particles(n)%group)%exp_arg
4132                      exp_term = EXP( -exp_arg * dt_particle(n) )
4133                   ELSE
4134                      exp_arg  = particle_groups(particles(n)%group)%exp_arg
4135                      exp_term = particle_groups(particles(n)%group)%exp_term
4136                   ENDIF
4137                   particles(n)%speed_x = particles(n)%speed_x * exp_term +         &
4138                                          u_int(n) * ( 1.0_wp - exp_term )
4139                   particles(n)%speed_y = particles(n)%speed_y * exp_term +         &
4140                                          v_int(n) * ( 1.0_wp - exp_term )
4141                   particles(n)%speed_z = particles(n)%speed_z * exp_term +         &
4142                                          ( w_int(n) - ( 1.0_wp - dens_ratio(n) ) * &
4143                                          g / exp_arg ) * ( 1.0_wp - exp_term )
4144                ENDIF
4145
4146             ENDIF
4147          ENDDO
4148       ENDDO
4149
4150    ELSE
4151!
4152!--    Decide whether the particle loop runs over the subboxes or only over 1,
4153!--    number_of_particles. This depends on the selected interpolation method.
4154       IF ( interpolation_trilinear )  THEN
4155          subbox_start = 0
4156          subbox_end   = 7
4157       ELSE
4158          subbox_start = 1
4159          subbox_end   = 1
4160       ENDIF
4161!--    loop over subboxes. In case of simple interpolation scheme no subboxes
4162!--    are introduced, as they are not required. Accordingly, this loops goes
4163!--    from 1 to 1.
4164       DO  nb = subbox_start, subbox_end
4165          IF ( interpolation_trilinear )  THEN
4166             particle_start = start_index(nb)
4167             particle_end   = end_index(nb)
4168          ELSE
4169             particle_start = 1
4170             particle_end   = number_of_particles
4171          ENDIF
4172!
4173!--         Loop from particle start to particle end
4174            DO  n = particle_start, particle_end
4175
4176!
4177!--          Transport of particles with inertia
4178             particles(n)%x = xv(n) + particles(n)%speed_x * dt_particle(n)
4179             particles(n)%y = yv(n) + particles(n)%speed_y * dt_particle(n)
4180             particles(n)%z = zv(n) + particles(n)%speed_z * dt_particle(n)
4181!
4182!--          Update of the particle velocity
4183             IF ( cloud_droplets )  THEN
4184!
4185!--             Terminal velocity is computed for vertical direction (Rogers et al.,
4186!--             1993, J. Appl. Meteorol.)
4187                diameter = particles(n)%radius * 2000.0_wp !diameter in mm
4188                IF ( diameter <= d0_rog )  THEN
4189                   w_s = k_cap_rog * diameter * ( 1.0_wp - EXP( -k_low_rog * diameter ) )
4190                ELSE
4191                   w_s = a_rog - b_rog * EXP( -c_rog * diameter )
4192                ENDIF
4193
4194!
4195!--             If selected, add random velocities following Soelch and Kaercher
4196!--             (2010, Q. J. R. Meteorol. Soc.)
4197                IF ( use_sgs_for_particles )  THEN
4198                    lagr_timescale(n) = km(kp,jp,ip) / MAX( e(kp,jp,ip), 1.0E-20_wp )
4199                     RL             = EXP( -1.0_wp * dt_3d / MAX( lagr_timescale(n), &
4200                                             1.0E-20_wp ) )
4201                    sigma          = SQRT( e(kp,jp,ip) )
4202
4203                    rg1 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4204                    rg2 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4205                    rg3 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4206
4207                    particles(n)%rvar1 = RL * particles(n)%rvar1 +                &
4208                                         SQRT( 1.0_wp - RL**2 ) * sigma * rg1
4209                    particles(n)%rvar2 = RL * particles(n)%rvar2 +                &
4210                                         SQRT( 1.0_wp - RL**2 ) * sigma * rg2
4211                    particles(n)%rvar3 = RL * particles(n)%rvar3 +                &
4212                                         SQRT( 1.0_wp - RL**2 ) * sigma * rg3
4213
4214                    particles(n)%speed_x = u_int(n) + particles(n)%rvar1
4215                    particles(n)%speed_y = v_int(n) + particles(n)%rvar2
4216                    particles(n)%speed_z = w_int(n) + particles(n)%rvar3 - w_s
4217                ELSE
4218                    particles(n)%speed_x = u_int(n)
4219                    particles(n)%speed_y = v_int(n)
4220                    particles(n)%speed_z = w_int(n) - w_s
4221                ENDIF
4222
4223             ELSE
4224
4225                IF ( use_sgs_for_particles )  THEN
4226                   exp_arg  = particle_groups(particles(n)%group)%exp_arg
4227                   exp_term = EXP( -exp_arg * dt_particle(n) )
4228                ELSE
4229                   exp_arg  = particle_groups(particles(n)%group)%exp_arg
4230                   exp_term = particle_groups(particles(n)%group)%exp_term
4231                ENDIF
4232                particles(n)%speed_x = particles(n)%speed_x * exp_term +             &
4233                                       u_int(n) * ( 1.0_wp - exp_term )
4234                particles(n)%speed_y = particles(n)%speed_y * exp_term +             &
4235                                       v_int(n) * ( 1.0_wp - exp_term )
4236                particles(n)%speed_z = particles(n)%speed_z * exp_term +             &
4237                                       ( w_int(n) - ( 1.0_wp - dens_ratio(n) ) * g / &
4238                                       exp_arg ) * ( 1.0_wp - exp_term )
4239             ENDIF
4240          ENDDO
4241       ENDDO
4242
4243    ENDIF
4244
4245!
4246!-- Store the old age of the particle ( needed to prevent that a
4247!-- particle crosses several PEs during one timestep, and for the
4248!-- evaluation of the subgrid particle velocity fluctuations )
4249    particles(1:number_of_particles)%age_m = particles(1:number_of_particles)%age
4250
4251!
4252!--    loop over subboxes. In case of simple interpolation scheme no subboxes
4253!--    are introduced, as they are not required. Accordingly, this loops goes
4254!--    from 1 to 1.
4255!
4256!-- Decide whether the particle loop runs over the subboxes or only over 1,
4257!-- number_of_particles. This depends on the selected interpolation method.
4258    IF ( interpolation_trilinear )  THEN
4259       subbox_start = 0
4260       subbox_end   = 7
4261    ELSE
4262       subbox_start = 1
4263       subbox_end   = 1
4264    ENDIF
4265    DO  nb = subbox_start, subbox_end
4266       IF ( interpolation_trilinear )  THEN
4267          particle_start = start_index(nb)
4268          particle_end   = end_index(nb)
4269       ELSE
4270          particle_start = 1
4271          particle_end   = number_of_particles
4272       ENDIF
4273!
4274!--    Loop from particle start to particle end
4275       DO  n = particle_start, particle_end
4276!
4277!--       Increment the particle age and the total time that the particle
4278!--       has advanced within the particle timestep procedure
4279          particles(n)%age    = particles(n)%age    + dt_particle(n)
4280          particles(n)%dt_sum = particles(n)%dt_sum + dt_particle(n)
4281
4282!
4283!--       Check whether there is still a particle that has not yet completed
4284!--       the total LES timestep
4285          IF ( ( dt_3d - particles(n)%dt_sum ) > 1E-8_wp )  THEN
4286             dt_3d_reached_l = .FALSE.
4287          ENDIF
4288
4289       ENDDO
4290    ENDDO
4291
4292    CALL cpu_log( log_point_s(44), 'lpm_advec', 'pause' )
4293
4294
4295 END SUBROUTINE lpm_advec
4296
4297 
4298!------------------------------------------------------------------------------! 
4299! Description:
4300! ------------
4301!> Calculation of subgrid-scale particle speed using the stochastic model
4302!> of Weil et al. (2004, JAS, 61, 2877-2887).
4303!------------------------------------------------------------------------------!
4304 SUBROUTINE weil_stochastic_eq( v_sgs, fs_n, e_n, dedxi_n, dedt_n, diss_n,     &
4305                                dt_n, rg_n, fac )
4306
4307    REAL(wp) ::  a1      !< dummy argument
4308    REAL(wp) ::  dedt_n  !< time derivative of TKE at particle position
4309    REAL(wp) ::  dedxi_n !< horizontal derivative of TKE at particle position
4310    REAL(wp) ::  diss_n  !< dissipation at particle position
4311    REAL(wp) ::  dt_n    !< particle timestep
4312    REAL(wp) ::  e_n     !< TKE at particle position
4313    REAL(wp) ::  fac     !< flag to identify adjacent topography
4314    REAL(wp) ::  fs_n    !< weighting factor to prevent that subgrid-scale particle speed becomes too large
4315    REAL(wp) ::  rg_n    !< random number
4316    REAL(wp) ::  term1   !< memory term
4317    REAL(wp) ::  term2   !< drift correction term
4318    REAL(wp) ::  term3   !< random term
4319    REAL(wp) ::  v_sgs   !< subgrid-scale velocity component
4320
4321!-- At first, limit TKE to a small non-zero number, in order to prevent
4322!-- the occurrence of extremely large SGS-velocities in case TKE is zero,
4323!-- (could occur at the simulation begin).
4324    e_n = MAX( e_n, 1E-20_wp )
4325!
4326!-- Please note, terms 1 and 2 (drift and memory term, respectively) are
4327!-- multiplied by a flag to switch of both terms near topography.
4328!-- This is necessary, as both terms may cause a subgrid-scale velocity build up
4329!-- if particles are trapped in regions with very small TKE, e.g. in narrow street
4330!-- canyons resolved by only a few grid points. Hence, term 1 and term 2 are
4331!-- disabled if one of the adjacent grid points belongs to topography.
4332!-- Moreover, in this case, the  previous subgrid-scale component is also set
4333!-- to zero.
4334
4335    a1 = fs_n * c_0 * diss_n
4336!
4337!-- Memory term
4338    term1 = - a1 * v_sgs * dt_n / ( 4.0_wp * sgs_wf_part * e_n + 1E-20_wp )    &
4339                 * fac
4340!
4341!-- Drift correction term
4342    term2 = ( ( dedt_n * v_sgs / e_n ) + dedxi_n ) * 0.5_wp * dt_n              &
4343                 * fac
4344!
4345!-- Random term
4346    term3 = SQRT( MAX( a1, 1E-20_wp ) ) * ( rg_n - 1.0_wp ) * SQRT( dt_n )
4347!
4348!-- In cese one of the adjacent grid-boxes belongs to topograhy, the previous
4349!-- subgrid-scale velocity component is set to zero, in order to prevent a
4350!-- velocity build-up.
4351!-- This case, set also previous subgrid-scale component to zero.
4352    v_sgs = v_sgs * fac + term1 + term2 + term3
4353
4354 END SUBROUTINE weil_stochastic_eq
4355
4356
4357!------------------------------------------------------------------------------!
4358! Description:
4359! ------------
4360!> swap timelevel in case of particle advection interpolation 'simple-corrector'
4361!> This routine is called at the end of one timestep, the velocities are then
4362!> used for the next timestep
4363!------------------------------------------------------------------------------!
4364 SUBROUTINE lpm_swap_timelevel_for_particle_advection
4365
4366!
4367!-- save the divergence free velocites of t+1 to use them at the end of the
4368!-- next time step
4369    u_t = u
4370    v_t = v
4371    w_t = w
4372
4373 END SUBROUTINE lpm_swap_timelevel_for_particle_advection
4374
4375
4376!------------------------------------------------------------------------------! 
4377! Description:
4378! ------------
4379!> Boundary conditions for the Lagrangian particles.
4380!> The routine consists of two different parts. One handles the bottom (flat)
4381!> and top boundary. In this part, also particles which exceeded their lifetime
4382!> are deleted.
4383!> The other part handles the reflection of particles from vertical walls.
4384!> This part was developed by Jin Zhang during 2006-2007.
4385!>
4386!> To do: Code structure for finding the t_index values and for checking the
4387!> -----  reflection conditions is basically the same for all four cases, so it
4388!>        should be possible to further simplify/shorten it.
4389!>
4390!> THE WALLS PART OF THIS ROUTINE HAS NOT BEEN TESTED FOR OCEAN RUNS SO FAR!!!!
4391!> (see offset_ocean_*)
4392!------------------------------------------------------------------------------!
4393 SUBROUTINE lpm_boundary_conds( location_bc , i, j, k )
4394
4395    CHARACTER (LEN=*), INTENT(IN) ::  location_bc !< general mode: boundary conditions at bottom/top of the model domain
4396                                   !< or at vertical surfaces (buildings, terrain steps)   
4397    INTEGER(iwp), INTENT(IN) ::  i !< grid index of particle box along x
4398    INTEGER(iwp), INTENT(IN) ::  j !< grid index of particle box along y
4399    INTEGER(iwp), INTENT(IN) ::  k !< grid index of particle box along z
4400
4401    INTEGER(iwp) ::  inc            !< dummy for sorting algorithmus
4402    INTEGER(iwp) ::  ir             !< dummy for sorting algorithmus
4403    INTEGER(iwp) ::  i1             !< grid index (x) of old particle position
4404    INTEGER(iwp) ::  i2             !< grid index (x) of current particle position
4405    INTEGER(iwp) ::  i3             !< grid index (x) of intermediate particle position
4406    INTEGER(iwp) ::  index_reset    !< index reset height
4407    INTEGER(iwp) ::  jr             !< dummy for sorting algorithmus
4408    INTEGER(iwp) ::  j1             !< grid index (y) of old particle position
4409    INTEGER(iwp) ::  j2             !< grid index (y) of current particle position
4410    INTEGER(iwp) ::  j3             !< grid index (y) of intermediate particle position
4411    INTEGER(iwp) ::  k1             !< grid index (z) of old particle position
4412    INTEGER(iwp) ::  k2             !< grid index (z) of current particle position
4413    INTEGER(iwp) ::  k3             !< grid index (z) of intermediate particle position
4414    INTEGER(iwp) ::  n              !< particle number
4415    INTEGER(iwp) ::  particles_top  !< maximum reset height
4416    INTEGER(iwp) ::  t_index        !< running index for intermediate particle timesteps in reflection algorithmus
4417    INTEGER(iwp) ::  t_index_number !< number of intermediate particle timesteps in reflection algorithmus
4418    INTEGER(iwp) ::  tmp_x          !< dummy for sorting algorithm
4419    INTEGER(iwp) ::  tmp_y          !< dummy for sorting algorithm
4420    INTEGER(iwp) ::  tmp_z          !< dummy for sorting algorithm
4421
4422    INTEGER(iwp), DIMENSION(0:10) ::  x_ind(0:10) = 0 !< index array (x) of intermediate particle positions
4423    INTEGER(iwp), DIMENSION(0:10) ::  y_ind(0:10) = 0 !< index array (y) of intermediate particle positions
4424    INTEGER(iwp), DIMENSION(0:10) ::  z_ind(0:10) = 0 !< index array (z) of intermediate particle positions
4425
4426    LOGICAL  ::  cross_wall_x    !< flag to check if particle reflection along x is necessary
4427    LOGICAL  ::  cross_wall_y    !< flag to check if particle reflection along y is necessary
4428    LOGICAL  ::  cross_wall_z    !< flag to check if particle reflection along z is necessary
4429    LOGICAL  ::  reflect_x       !< flag to check if particle is already reflected along x
4430    LOGICAL  ::  reflect_y       !< flag to check if particle is already reflected along y
4431    LOGICAL  ::  reflect_z       !< flag to check if particle is already reflected along z
4432    LOGICAL  ::  tmp_reach_x     !< dummy for sorting algorithmus
4433    LOGICAL  ::  tmp_reach_y     !< dummy for sorting algorithmus
4434    LOGICAL  ::  tmp_reach_z     !< dummy for sorting algorithmus
4435    LOGICAL  ::  x_wall_reached  !< flag to check if particle has already reached wall
4436    LOGICAL  ::  y_wall_reached  !< flag to check if particle has already reached wall
4437    LOGICAL  ::  z_wall_reached  !< flag to check if particle has already reached wall
4438
4439    LOGICAL, DIMENSION(0:10) ::  reach_x  !< flag to check if particle is at a yz-wall
4440    LOGICAL, DIMENSION(0:10) ::  reach_y  !< flag to check if particle is at a xz-wall
4441    LOGICAL, DIMENSION(0:10) ::  reach_z  !< flag to check if particle is at a xy-wall
4442
4443    REAL(wp) ::  dt_particle    !< particle timestep
4444    REAL(wp) ::  eps = 1E-10_wp !< security number to check if particle has reached a wall
4445    REAL(wp) ::  pos_x          !< intermediate particle position (x)
4446    REAL(wp) ::  pos_x_old      !< particle position (x) at previous particle timestep
4447    REAL(wp) ::  pos_y          !< intermediate particle position (y)
4448    REAL(wp) ::  pos_y_old      !< particle position (y) at previous particle timestep
4449    REAL(wp) ::  pos_z          !< intermediate particle position (z)
4450    REAL(wp) ::  pos_z_old      !< particle position (z) at previous particle timestep
4451    REAL(wp) ::  prt_x          !< current particle position (x)
4452    REAL(wp) ::  prt_y          !< current particle position (y)
4453    REAL(wp) ::  prt_z          !< current particle position (z)
4454    REAL(wp) ::  ran_val        !< location of wall in z
4455    REAL(wp) ::  reset_top      !< location of wall in z
4456    REAL(wp) ::  t_old          !< previous reflection time
4457    REAL(wp) ::  tmp_t          !< dummy for sorting algorithmus
4458    REAL(wp) ::  xwall          !< location of wall in x
4459    REAL(wp) ::  ywall          !< location of wall in y
4460    REAL(wp) ::  zwall          !< location of wall in z
4461
4462    REAL(wp), DIMENSION(0:10) ::  t  !< reflection time
4463
4464    SELECT CASE ( location_bc )
4465
4466       CASE ( 'bottom/top' )
4467
4468!
4469!--    Apply boundary conditions to those particles that have crossed the top or
4470!--    bottom boundary and delete those particles, which are older than allowed
4471       DO  n = 1, number_of_particles
4472
4473!
4474!--       Stop if particles have moved further than the length of one
4475!--       PE subdomain (newly released particles have age = age_m!)
4476          IF ( particles(n)%age /= particles(n)%age_m )  THEN
4477             IF ( ABS(particles(n)%speed_x) >                                  &
4478                  ((nxr-nxl+2)*dx)/(particles(n)%age-particles(n)%age_m)  .OR. &
4479                  ABS(particles(n)%speed_y) >                                  &
4480                  ((nyn-nys+2)*dy)/(particles(n)%age-particles(n)%age_m) )  THEN
4481
4482                  WRITE( message_string, * )  'particle too fast.  n = ',  n
4483                  CALL message( 'lpm_boundary_conds', 'PA0148', 2, 2, -1, 6, 1 )
4484             ENDIF
4485          ENDIF
4486
4487          IF ( particles(n)%age > particle_maximum_age  .AND.  &
4488               particles(n)%particle_mask )                              &
4489          THEN
4490             particles(n)%particle_mask  = .FALSE.
4491             deleted_particles = deleted_particles + 1
4492          ENDIF
4493
4494          IF ( particles(n)%z >= zw(nz)  .AND.  particles(n)%particle_mask )  THEN
4495             IF ( ibc_par_t == 1 )  THEN
4496!
4497!--             Particle absorption
4498                particles(n)%particle_mask  = .FALSE.
4499                deleted_particles = deleted_particles + 1
4500             ELSEIF ( ibc_par_t == 2 )  THEN
4501!
4502!--             Particle reflection
4503                particles(n)%z       = 2.0_wp * zw(nz) - particles(n)%z
4504                particles(n)%speed_z = -particles(n)%speed_z
4505                IF ( use_sgs_for_particles  .AND. &
4506                     particles(n)%rvar3 > 0.0_wp )  THEN
4507                   particles(n)%rvar3 = -particles(n)%rvar3
4508                ENDIF
4509             ENDIF
4510          ENDIF
4511
4512          IF ( particles(n)%z < zw(0)  .AND.  particles(n)%particle_mask )  THEN
4513             IF ( ibc_par_b == 1 )  THEN
4514!
4515!--             Particle absorption
4516                particles(n)%particle_mask  = .FALSE.
4517                deleted_particles = deleted_particles + 1
4518             ELSEIF ( ibc_par_b == 2 )  THEN
4519!
4520!--             Particle reflection
4521                particles(n)%z       = 2.0_wp * zw(0) - particles(n)%z
4522                particles(n)%speed_z = -particles(n)%speed_z
4523                IF ( use_sgs_for_particles  .AND. &
4524                     particles(n)%rvar3 < 0.0_wp )  THEN
4525                   particles(n)%rvar3 = -particles(n)%rvar3
4526                ENDIF
4527             ELSEIF ( ibc_par_b == 3 )  THEN
4528!
4529!--             Find reset height. @note this works only in non-strechted cases
4530                particles_top = INT( pst(1) / dz(1) )
4531                index_reset = MINLOC( prt_count(nzb+1:particles_top,j,i), DIM = 1 )
4532                reset_top = zu(index_reset)
4533                iran_part = iran_part + myid
4534                ran_val = random_function( iran_part )
4535                particles(n)%z       = reset_top *  ( 1.0  + ( ran_val / 10.0_wp) )
4536                particles(n)%speed_z = 0.0_wp
4537                IF ( curvature_solution_effects )  THEN
4538                   particles(n)%radius = particles(n)%aux1
4539                ELSE
4540                   particles(n)%radius = 1.0E-8
4541                ENDIF
4542             ENDIF
4543          ENDIF
4544       ENDDO
4545
4546      CASE ( 'walls' )
4547
4548       CALL cpu_log( log_point_s(48), 'lpm_wall_reflect', 'start' )
4549
4550       DO  n = 1, number_of_particles
4551!
4552!--       Recalculate particle timestep
4553          dt_particle = particles(n)%age - particles(n)%age_m
4554!
4555!--       Obtain x/y indices for current particle position
4556          i2 = particles(n)%x * ddx
4557          j2 = particles(n)%y * ddy
4558          IF ( zw(k)   < particles(n)%z ) k2 = k + 1
4559          IF ( zw(k)   > particles(n)%.AND.  zw(k-1) < particles(n)%z ) k2 = k
4560          IF ( zw(k-1) > particles(n)%z ) k2 = k - 1
4561!
4562!--       Save current particle positions
4563          prt_x = particles(n)%x
4564          prt_y = particles(n)%y
4565          prt_z = particles(n)%z
4566!
4567!--       Recalculate old particle positions
4568          pos_x_old = particles(n)%x - particles(n)%speed_x * dt_particle
4569          pos_y_old = particles(n)%y - particles(n)%speed_y * dt_particle
4570          pos_z_old = particles(n)%z - particles(n)%speed_z * dt_particle
4571!
4572!--       Obtain x/y indices for old particle positions
4573          i1 = i
4574          j1 = j
4575          k1 = k
4576!
4577!--       Determine horizontal as well as vertical walls at which particle can
4578!--       be potentially reflected.
4579!--       Start with walls aligned in yz layer.
4580!--       Wall to the right
4581          IF ( prt_x > pos_x_old )  THEN
4582             xwall = ( i1 + 1 ) * dx
4583!
4584!--       Wall to the left
4585          ELSE
4586             xwall = i1 * dx
4587          ENDIF
4588!
4589!--       Walls aligned in xz layer
4590!--       Wall to the north
4591          IF ( prt_y > pos_y_old )  THEN
4592             ywall = ( j1 + 1 ) * dy
4593!--       Wall to the south
4594          ELSE
4595             ywall = j1 * dy
4596          ENDIF
4597
4598          IF ( prt_z > pos_z_old )  THEN
4599             zwall = zw(k)
4600          ELSE
4601             zwall = zw(k-1)
4602          ENDIF
4603!
4604!--       Initialize flags to check if particle reflection is necessary
4605          cross_wall_x = .FALSE.
4606          cross_wall_y = .FALSE.
4607          cross_wall_z = .FALSE.
4608!
4609!--       Initialize flags to check if a wall is reached
4610          reach_x      = .FALSE.
4611          reach_y      = .FALSE.
4612          reach_z      = .FALSE.
4613!
4614!--       Initialize flags to check if a particle was already reflected
4615          reflect_x    = .FALSE.
4616          reflect_y    = .FALSE.
4617          reflect_z    = .FALSE.
4618!
4619!--       Initialize flags to check if a wall is already crossed.
4620!--       ( Required to obtain correct indices. )
4621          x_wall_reached = .FALSE.
4622          y_wall_reached = .FALSE.
4623          z_wall_reached = .FALSE.
4624!
4625!--       Initialize time array
4626          t     = 0.0_wp
4627!
4628!--       Check if particle can reach any wall. This case, calculate the
4629!--       fractional time needed to reach this wall. Store this fractional
4630!--       timestep in array t. Moreover, store indices for these grid
4631!--       boxes where the respective wall belongs to. 
4632!--       Start with x-direction.
4633          t_index    = 1
4634          t(t_index) = ( xwall - pos_x_old )                                   &
4635                     / MERGE( MAX( prt_x - pos_x_old,  1E-30_wp ),             &
4636                              MIN( prt_x - pos_x_old, -1E-30_wp ),             &
4637                              prt_x > pos_x_old )
4638          x_ind(t_index)   = i2
4639          y_ind(t_index)   = j1
4640          z_ind(t_index)   = k1
4641          reach_x(t_index) = .TRUE.
4642          reach_y(t_index) = .FALSE.
4643          reach_z(t_index) = .FALSE.
4644!
4645!--       Store these values only if particle really reaches any wall. t must
4646!--       be in a interval between [0:1].
4647          IF ( t(t_index) <= 1.0_wp  .AND.  t(t_index) >= 0.0_wp )  THEN
4648             t_index      = t_index + 1
4649             cross_wall_x = .TRUE.
4650          ENDIF
4651!
4652!--       y-direction
4653          t(t_index) = ( ywall - pos_y_old )                                   &
4654                     / MERGE( MAX( prt_y - pos_y_old,  1E-30_wp ),             &
4655                              MIN( prt_y - pos_y_old, -1E-30_wp ),             &
4656                              prt_y > pos_y_old )
4657          x_ind(t_index)   = i1
4658          y_ind(t_index)   = j2
4659          z_ind(t_index)   = k1
4660          reach_x(t_index) = .FALSE.
4661          reach_y(t_index) = .TRUE.
4662          reach_z(t_index) = .FALSE.
4663          IF ( t(t_index) <= 1.0_wp  .AND.  t(t_index) >= 0.0_wp )  THEN
4664             t_index      = t_index + 1
4665             cross_wall_y = .TRUE.
4666          ENDIF
4667!
4668!--       z-direction
4669          t(t_index) = (zwall - pos_z_old )                                    &
4670                     / MERGE( MAX( prt_z - pos_z_old,  1E-30_wp ),             &
4671                              MIN( prt_z - pos_z_old, -1E-30_wp ),             &
4672                              prt_z > pos_z_old )
4673
4674          x_ind(t_index)   = i1
4675          y_ind(t_index)   = j1
4676          z_ind(t_index)   = k2
4677          reach_x(t_index) = .FALSE.
4678          reach_y(t_index) = .FALSE.
4679          reach_z(t_index) = .TRUE.
4680          IF( t(t_index) <= 1.0_wp  .AND.  t(t_index) >= 0.0_wp)  THEN
4681             t_index      = t_index + 1
4682             cross_wall_z = .TRUE.
4683          ENDIF
4684
4685          t_index_number = t_index - 1
4686!
4687!--       Carry out reflection only if particle reaches any wall
4688          IF ( cross_wall_x  .OR.  cross_wall_y  .OR.  cross_wall_z )  THEN
4689!
4690!--          Sort fractional timesteps in ascending order. Also sort the
4691!--          corresponding indices and flag according to the time interval a 
4692!--          particle reaches the respective wall.
4693             inc = 1
4694             jr  = 1
4695             DO WHILE ( inc <= t_index_number )
4696                inc = 3 * inc + 1
4697             ENDDO
4698
4699             DO WHILE ( inc > 1 )
4700                inc = inc / 3
4701                DO  ir = inc+1, t_index_number
4702                   tmp_t       = t(ir)
4703                   tmp_x       = x_ind(ir)
4704                   tmp_y       = y_ind(ir)
4705                   tmp_z       = z_ind(ir)
4706                   tmp_reach_x = reach_x(ir)
4707                   tmp_reach_y = reach_y(ir)
4708                   tmp_reach_z = reach_z(ir)
4709                   jr    = ir
4710                   DO WHILE ( t(jr-inc) > tmp_t )
4711                      t(jr)       = t(jr-inc)
4712                      x_ind(jr)   = x_ind(jr-inc)
4713                      y_ind(jr)   = y_ind(jr-inc)
4714                      z_ind(jr)   = z_ind(jr-inc)
4715                      reach_x(jr) = reach_x(jr-inc)
4716                      reach_y(jr) = reach_y(jr-inc)
4717                      reach_z(jr) = reach_z(jr-inc)
4718                      jr    = jr - inc
4719                      IF ( jr <= inc )  EXIT
4720                   ENDDO
4721                   t(jr)       = tmp_t
4722                   x_ind(jr)   = tmp_x
4723                   y_ind(jr)   = tmp_y
4724                   z_ind(jr)   = tmp_z
4725                   reach_x(jr) = tmp_reach_x
4726                   reach_y(jr) = tmp_reach_y
4727                   reach_z(jr) = tmp_reach_z
4728                ENDDO
4729             ENDDO
4730!
4731!--          Initialize temporary particle positions
4732             pos_x = pos_x_old
4733             pos_y = pos_y_old
4734             pos_z = pos_z_old
4735!
4736!--          Loop over all times a particle possibly moves into a new grid box
4737             t_old = 0.0_wp
4738             DO t_index = 1, t_index_number
4739!
4740!--             Calculate intermediate particle position according to the
4741!--             timesteps a particle reaches any wall.
4742                pos_x = pos_x + ( t(t_index) - t_old ) * dt_particle           &
4743                                                       * particles(n)%speed_x
4744                pos_y = pos_y + ( t(t_index) - t_old ) * dt_particle           &
4745                                                       * particles(n)%speed_y
4746                pos_z = pos_z + ( t(t_index) - t_old ) * dt_particle           &
4747                                                       * particles(n)%speed_z
4748!
4749!--             Obtain x/y grid indices for intermediate particle position from
4750!--             sorted index array
4751                i3 = x_ind(t_index)
4752                j3 = y_ind(t_index)
4753                k3 = z_ind(t_index)
4754!
4755!--             Check which wall is already reached
4756                IF ( .NOT. x_wall_reached )  x_wall_reached = reach_x(t_index) 
4757                IF ( .NOT. y_wall_reached )  y_wall_reached = reach_y(t_index)
4758                IF ( .NOT. z_wall_reached )  z_wall_reached = reach_z(t_index)
4759!
4760!--             Check if a particle needs to be reflected at any yz-wall. If
4761!--             necessary, carry out reflection. Please note, a security
4762!--             constant is required, as the particle position does not
4763!--             necessarily exactly match the wall location due to rounding
4764!--             errors.
4765                IF ( reach_x(t_index)                      .AND.               & 
4766                     ABS( pos_x - xwall ) < eps            .AND.               &
4767                     .NOT. BTEST(wall_flags_static_0(k3,j3,i3),0) .AND.               &
4768                     .NOT. reflect_x )  THEN
4769!
4770!
4771!--                Reflection in x-direction.
4772!--                Ensure correct reflection by MIN/MAX functions, depending on
4773!--                direction of particle transport.
4774!--                Due to rounding errors pos_x does not exactly match the wall
4775!--                location, leading to erroneous reflection.             
4776                   pos_x = MERGE( MIN( 2.0_wp * xwall - pos_x, xwall ),        &
4777                                  MAX( 2.0_wp * xwall - pos_x, xwall ),        &
4778                                  particles(n)%x > xwall )
4779!
4780!--                Change sign of particle speed                     
4781                   particles(n)%speed_x = - particles(n)%speed_x
4782!
4783!--                Also change sign of subgrid-scale particle speed
4784                   particles(n)%rvar1 = - particles(n)%rvar1
4785!
4786!--                Set flag that reflection along x is already done
4787                   reflect_x          = .TRUE.
4788!
4789!--                As the particle does not cross any further yz-wall during
4790!--                this timestep, set further x-indices to the current one.
4791                   x_ind(t_index:t_index_number) = i1
4792!
4793!--             If particle already reached the wall but was not reflected,
4794!--             set further x-indices to the new one.
4795                ELSEIF ( x_wall_reached .AND. .NOT. reflect_x )  THEN
4796                    x_ind(t_index:t_index_number) = i2
4797                ENDIF !particle reflection in x direction done
4798
4799!
4800!--             Check if a particle needs to be reflected at any xz-wall. If
4801!--             necessary, carry out reflection. Please note, a security
4802!--             constant is required, as the particle position does not
4803!--             necessarily exactly match the wall location due to rounding
4804!--             errors.
4805                IF ( reach_y(t_index)                      .AND.               & 
4806                     ABS( pos_y - ywall ) < eps            .AND.               &
4807                     .NOT. BTEST(wall_flags_static_0(k3,j3,i3),0) .AND.               &
4808                     .NOT. reflect_y )  THEN
4809!
4810!
4811!--                Reflection in y-direction.
4812!--                Ensure correct reflection by MIN/MAX functions, depending on
4813!--                direction of particle transport.
4814!--                Due to rounding errors pos_y does not exactly match the wall
4815!--                location, leading to erroneous reflection.             
4816                   pos_y = MERGE( MIN( 2.0_wp * ywall - pos_y, ywall ),        &
4817                                  MAX( 2.0_wp * ywall - pos_y, ywall ),        &
4818                                  particles(n)%y > ywall )
4819!
4820!--                Change sign of particle speed                     
4821                   particles(n)%speed_y = - particles(n)%speed_y
4822!
4823!--                Also change sign of subgrid-scale particle speed
4824                   particles(n)%rvar2 = - particles(n)%rvar2
4825!
4826!--                Set flag that reflection along y is already done
4827                   reflect_y          = .TRUE.
4828!
4829!--                As the particle does not cross any further xz-wall during
4830!--                this timestep, set further y-indices to the current one.
4831                   y_ind(t_index:t_index_number) = j1
4832!
4833!--             If particle already reached the wall but was not reflected,
4834!--             set further y-indices to the new one.
4835                ELSEIF ( y_wall_reached .AND. .NOT. reflect_y )  THEN
4836                    y_ind(t_index:t_index_number) = j2
4837                ENDIF !particle reflection in y direction done
4838
4839!
4840!--             Check if a particle needs to be reflected at any xy-wall. If
4841!--             necessary, carry out reflection. Please note, a security
4842!--             constant is required, as the particle position does not
4843!--             necessarily exactly match the wall location due to rounding
4844!--             errors.
4845                IF ( reach_z(t_index)                      .AND.               & 
4846                     ABS( pos_z - zwall ) < eps            .AND.               &
4847                     .NOT. BTEST(wall_flags_static_0(k3,j3,i3),0) .AND.               &
4848                     .NOT. reflect_z )  THEN
4849!
4850!
4851!--                Reflection in z-direction.
4852!--                Ensure correct reflection by MIN/MAX functions, depending on
4853!--                direction of particle transport.
4854!--                Due to rounding errors pos_z does not exactly match the wall
4855!--                location, leading to erroneous reflection.             
4856                   pos_z = MERGE( MIN( 2.0_wp * zwall - pos_z, zwall ),        &
4857                                  MAX( 2.0_wp * zwall - pos_z, zwall ),        &
4858                                  particles(n)%z > zwall )
4859!
4860!--                Change sign of particle speed                     
4861                   particles(n)%speed_z = - particles(n)%speed_z
4862!
4863!--                Also change sign of subgrid-scale particle speed
4864                   particles(n)%rvar3 = - particles(n)%rvar3
4865!
4866!--                Set flag that reflection along z is already done
4867                   reflect_z          = .TRUE.
4868!
4869!--                As the particle does not cross any further xy-wall during
4870!--                this timestep, set further z-indices to the current one.
4871                   z_ind(t_index:t_index_number) = k1
4872!
4873!--             If particle already reached the wall but was not reflected,
4874!--             set further z-indices to the new one.
4875                ELSEIF ( z_wall_reached .AND. .NOT. reflect_z )  THEN
4876                    z_ind(t_index:t_index_number) = k2
4877                ENDIF !particle reflection in z direction done               
4878
4879!
4880!--             Swap time
4881                t_old = t(t_index)
4882
4883             ENDDO
4884!
4885!--          If a particle was reflected, calculate final position from last
4886!--          intermediate position.
4887             IF ( reflect_x  .OR.  reflect_y  .OR.  reflect_z )  THEN
4888
4889                particles(n)%x = pos_x + ( 1.0_wp - t_old ) * dt_particle      &
4890                                                         * particles(n)%speed_x
4891                particles(n)%y = pos_y + ( 1.0_wp - t_old ) * dt_particle      &
4892                                                         * particles(n)%speed_y
4893                particles(n)%z = pos_z + ( 1.0_wp - t_old ) * dt_particle      &
4894                                                         * particles(n)%speed_z
4895
4896             ENDIF
4897
4898          ENDIF
4899
4900       ENDDO
4901
4902       CALL cpu_log( log_point_s(48), 'lpm_wall_reflect', 'stop' )
4903
4904       CASE DEFAULT
4905          CONTINUE
4906
4907    END SELECT
4908
4909 END SUBROUTINE lpm_boundary_conds
4910
4911
4912!------------------------------------------------------------------------------!
4913! Description:
4914! ------------
4915!> Calculates change in droplet radius by condensation/evaporation, using
4916!> either an analytic formula or by numerically integrating the radius growth
4917!> equation including curvature and solution effects using Rosenbrocks method
4918!> (see Numerical recipes in FORTRAN, 2nd edition, p. 731).
4919!> The analytical formula and growth equation follow those given in
4920!> Rogers and Yau (A short course in cloud physics, 3rd edition, p. 102/103).
4921!------------------------------------------------------------------------------!
4922 SUBROUTINE lpm_droplet_condensation (i,j,k)
4923
4924    INTEGER(iwp), INTENT(IN) ::  i              !<
4925    INTEGER(iwp), INTENT(IN) ::  j              !<
4926    INTEGER(iwp), INTENT(IN) ::  k              !<
4927    INTEGER(iwp) ::  n                          !<
4928
4929    REAL(wp) ::  afactor                       !< curvature effects
4930    REAL(wp) ::  arg                           !<
4931    REAL(wp) ::  bfactor                       !< solute effects
4932    REAL(wp) ::  ddenom                        !<
4933    REAL(wp) ::  delta_r                       !<
4934    REAL(wp) ::  diameter                      !< diameter of cloud droplets
4935    REAL(wp) ::  diff_coeff                    !< diffusivity for water vapor
4936    REAL(wp) ::  drdt                          !<
4937    REAL(wp