source: palm/trunk/SOURCE/lagrangian_particle_model_mod.f90 @ 4180

Last change on this file since 4180 was 4180, checked in by scharf, 22 months ago

removed comments in 'Former revisions' section that are older than 01.01.2019

  • Property svn:keywords set to Id
File size: 349.1 KB
Line 
1!> @file lagrangian_particle_model_mod.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2019 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: lagrangian_particle_model_mod.f90 4180 2019-08-21 14:37:54Z scharf $
27! Replace function get_topography_top_index by topo_top_ind
28!
29! 4145 2019-08-06 09:55:22Z schwenkel
30! Some reformatting
31!
32! 4144 2019-08-06 09:11:47Z raasch
33! relational operators .EQ., .NE., etc. replaced by ==, /=, etc.
34!
35! 4143 2019-08-05 15:14:53Z schwenkel
36! Rename variable and change select case to if statement
37!
38! 4122 2019-07-26 13:11:56Z schwenkel
39! Implement reset method as bottom boundary condition
40!
41! 4121 2019-07-26 10:01:22Z schwenkel
42! Implementation of an simple method for interpolating the velocities to
43! particle position
44!
45! 4114 2019-07-23 14:09:27Z schwenkel
46! Bugfix: Added working precision for if statement
47!
48! 4054 2019-06-27 07:42:18Z raasch
49! bugfix for calculating the minimum particle time step
50!
51! 4044 2019-06-19 12:28:27Z schwenkel
52! Bugfix in case of grid strecting: corrected calculation of k-Index
53!
54! 4043 2019-06-18 16:59:00Z schwenkel
55! Remove min_nr_particle, Add lpm_droplet_interactions_ptq into module
56!
57! 4028 2019-06-13 12:21:37Z schwenkel
58! Further modularization of particle code components
59!
60! 4020 2019-06-06 14:57:48Z schwenkel
61! Removing submodules
62!
63! 4018 2019-06-06 13:41:50Z eckhard
64! Bugfix for former revision
65!
66! 4017 2019-06-06 12:16:46Z schwenkel
67! Modularization of all lagrangian particle model code components
68!
69! 3655 2019-01-07 16:51:22Z knoop
70! bugfix to guarantee correct particle releases in case that the release
71! interval is smaller than the model timestep
72!
73!
74! Description:
75! ------------
76!> The embedded LPM allows for studying transport and dispersion processes within
77!> turbulent flows. This model including passive particles that do not show any
78!> feedback on the turbulent flow. Further also particles with inertia and
79!> cloud droplets ca be simulated explicitly.
80!>
81!> @todo test lcm
82!>       implement simple interpolation method for subgrid scale velocites
83!> @note <Enter notes on the module>
84!> @bug  <Enter bug on the module>
85!------------------------------------------------------------------------------!
86 MODULE lagrangian_particle_model_mod
87
88    USE, INTRINSIC ::  ISO_C_BINDING
89
90    USE arrays_3d,                                                             &
91        ONLY:  de_dx, de_dy, de_dz, dzw, zu, zw,  ql_c, ql_v, ql_vp, hyp,      &
92               pt, q, exner, ql, diss, e, u, v, w, km, ql_1, ql_2, pt_p, q_p,  &
93               d_exner, u_p, v_p, w_p
94 
95    USE averaging,                                                             &
96        ONLY:  ql_c_av, pr_av, pc_av, ql_vp_av, ql_v_av
97
98    USE basic_constants_and_equations_mod,                                     &
99        ONLY: molecular_weight_of_solute, molecular_weight_of_water, magnus,   &
100              pi, rd_d_rv, rho_l, r_v, rho_s, vanthoff, l_v, kappa, g, lv_d_cp
101
102    USE control_parameters,                                                    &
103        ONLY:  bc_dirichlet_l, bc_dirichlet_n, bc_dirichlet_r, bc_dirichlet_s, &
104               cloud_droplets, constant_flux_layer, current_timestep_number,   &
105               dt_3d, dt_3d_reached, humidity,                                 &
106               dt_3d_reached_l, dt_dopts, dz, initializing_actions,            &
107               message_string, molecular_viscosity, ocean_mode,                &
108               particle_maximum_age, iran,                                     & 
109               simulated_time, topography, dopts_time_count,                   &
110               time_since_reference_point, rho_surface, u_gtrans, v_gtrans,    &
111               dz_stretch_level, dz_stretch_level_start
112
113    USE cpulog,                                                                &
114        ONLY:  cpu_log, log_point, log_point_s
115
116    USE indices,                                                               &
117        ONLY:  nx, nxl, nxlg, nxrg, nxr, ny, nyn, nys, nyng, nysg, nz, nzb,    &
118               nzb_max, nzt,nbgp, ngp_2dh_outer,                               &
119               topo_top_ind,                                                   &
120               wall_flags_0
121
122    USE kinds
123
124    USE pegrid
125
126    USE particle_attributes
127
128    USE pmc_particle_interface,                                                &
129        ONLY: pmcp_c_get_particle_from_parent, pmcp_p_fill_particle_win,       &
130              pmcp_c_send_particle_to_parent, pmcp_p_empty_particle_win,       &
131              pmcp_p_delete_particles_in_fine_grid_area, pmcp_g_init,          &
132              pmcp_g_print_number_of_particles
133
134    USE pmc_interface,                                                         &
135        ONLY: nested_run
136
137    USE grid_variables,                                                        &
138        ONLY:  ddx, dx, ddy, dy
139
140    USE netcdf_interface,                                                      &
141        ONLY:  netcdf_data_format, netcdf_deflate, dopts_num, id_set_pts,      &
142               id_var_dopts, id_var_time_pts, nc_stat,                         &
143               netcdf_handle_error
144
145    USE random_function_mod,                                                   &
146        ONLY:  random_function
147
148    USE statistics,                                                            &
149        ONLY:  hom
150
151    USE surface_mod,                                                           &
152        ONLY:  bc_h,                                                           &
153               surf_def_h,                                                     &
154               surf_lsm_h,                                                     &
155               surf_usm_h
156
157#if defined( __parallel )  &&  !defined( __mpifh )
158    USE MPI
159#endif
160
161#if defined( __parallel )  &&  defined( __mpifh )
162    INCLUDE "mpif.h"
163#endif     
164
165#if defined( __netcdf )
166    USE NETCDF
167#endif
168
169    IMPLICIT NONE
170
171    CHARACTER(LEN=15) ::  aero_species = 'nacl'                   !< aerosol species
172    CHARACTER(LEN=15) ::  aero_type    = 'maritime'               !< aerosol type
173    CHARACTER(LEN=15) ::  bc_par_lr    = 'cyclic'                 !< left/right boundary condition
174    CHARACTER(LEN=15) ::  bc_par_ns    = 'cyclic'                 !< north/south boundary condition
175    CHARACTER(LEN=15) ::  bc_par_b     = 'reflect'                !< bottom boundary condition
176    CHARACTER(LEN=15) ::  bc_par_t     = 'absorb'                 !< top boundary condition
177    CHARACTER(LEN=15) ::  collision_kernel   = 'none'             !< collision kernel
178
179    CHARACTER(LEN=5)  ::  splitting_function = 'gamma'            !< function for calculation critical weighting factor
180    CHARACTER(LEN=5)  ::  splitting_mode     = 'const'            !< splitting mode
181
182    CHARACTER(LEN=25) ::  particle_advection_interpolation = 'trilinear' !< interpolation method for calculatin the particle
183
184    INTEGER(iwp) ::  deleted_particles = 0                        !< number of deleted particles per time step   
185    INTEGER(iwp) ::  i_splitting_mode                             !< dummy for splitting mode
186    INTEGER(iwp) ::  iran_part = -1234567                         !< number for random generator   
187    INTEGER(iwp) ::  max_number_particles_per_gridbox = 100       !< namelist parameter (see documentation)
188    INTEGER(iwp) ::  isf                                          !< dummy for splitting function
189    INTEGER(iwp) ::  number_particles_per_gridbox = -1            !< namelist parameter (see documentation)
190    INTEGER(iwp) ::  number_of_sublayers = 20                     !< number of sublayers for particle velocities betwenn surface and first grid level
191    INTEGER(iwp) ::  offset_ocean_nzt = 0                         !< in case of oceans runs, the vertical index calculations need an offset
192    INTEGER(iwp) ::  offset_ocean_nzt_m1 = 0                      !< in case of oceans runs, the vertical index calculations need an offset
193    INTEGER(iwp) ::  particles_per_point = 1                      !< namelist parameter (see documentation)
194    INTEGER(iwp) ::  radius_classes = 20                          !< namelist parameter (see documentation)
195    INTEGER(iwp) ::  splitting_factor = 2                         !< namelist parameter (see documentation)
196    INTEGER(iwp) ::  splitting_factor_max = 5                     !< namelist parameter (see documentation)
197    INTEGER(iwp) ::  step_dealloc = 100                           !< namelist parameter (see documentation)
198    INTEGER(iwp) ::  total_number_of_particles                    !< total number of particles in the whole model domain
199    INTEGER(iwp) ::  trlp_count_sum                               !< parameter for particle exchange of PEs
200    INTEGER(iwp) ::  trlp_count_recv_sum                          !< parameter for particle exchange of PEs
201    INTEGER(iwp) ::  trrp_count_sum                               !< parameter for particle exchange of PEs
202    INTEGER(iwp) ::  trrp_count_recv_sum                          !< parameter for particle exchange of PEs
203    INTEGER(iwp) ::  trsp_count_sum                               !< parameter for particle exchange of PEs
204    INTEGER(iwp) ::  trsp_count_recv_sum                          !< parameter for particle exchange of PEs
205    INTEGER(iwp) ::  trnp_count_sum                               !< parameter for particle exchange of PEs
206    INTEGER(iwp) ::  trnp_count_recv_sum                          !< parameter for particle exchange of PEs
207
208    LOGICAL ::  lagrangian_particle_model = .FALSE.       !< namelist parameter (see documentation)
209    LOGICAL ::  curvature_solution_effects = .FALSE.      !< namelist parameter (see documentation)
210    LOGICAL ::  deallocate_memory = .TRUE.                !< namelist parameter (see documentation)
211    LOGICAL ::  hall_kernel = .FALSE.                     !< flag for collision kernel
212    LOGICAL ::  merging = .FALSE.                         !< namelist parameter (see documentation)
213    LOGICAL ::  random_start_position = .FALSE.           !< namelist parameter (see documentation)
214    LOGICAL ::  read_particles_from_restartfile = .TRUE.  !< namelist parameter (see documentation)
215    LOGICAL ::  seed_follows_topography = .FALSE.         !< namelist parameter (see documentation)
216    LOGICAL ::  splitting = .FALSE.                       !< namelist parameter (see documentation)
217    LOGICAL ::  use_kernel_tables = .FALSE.               !< parameter, which turns on the use of precalculated collision kernels
218    LOGICAL ::  write_particle_statistics = .FALSE.       !< namelist parameter (see documentation)
219    LOGICAL ::  interpolation_simple_predictor = .FALSE.  !< flag for simple particle advection interpolation with predictor step
220    LOGICAL ::  interpolation_simple_corrector = .FALSE.  !< flag for simple particle advection interpolation with corrector step
221    LOGICAL ::  interpolation_trilinear = .FALSE.         !< flag for trilinear particle advection interpolation
222
223    LOGICAL, DIMENSION(max_number_of_particle_groups) ::   vertical_particle_advection = .TRUE. !< Switch for vertical particle transport
224
225    REAL(wp) ::  aero_weight = 1.0_wp                      !< namelist parameter (see documentation)
226    REAL(wp) ::  dt_min_part = 0.0002_wp                   !< minimum particle time step when SGS velocities are used (s)
227    REAL(wp) ::  dt_prel = 9999999.9_wp                    !< namelist parameter (see documentation)
228    REAL(wp) ::  dt_write_particle_data = 9999999.9_wp     !< namelist parameter (see documentation)
229    REAL(wp) ::  end_time_prel = 9999999.9_wp              !< namelist parameter (see documentation)
230    REAL(wp) ::  initial_weighting_factor = 1.0_wp         !< namelist parameter (see documentation)
231    REAL(wp) ::  last_particle_release_time = 0.0_wp       !< last time of particle release
232    REAL(wp) ::  log_sigma(3) = 1.0_wp                     !< namelist parameter (see documentation)
233    REAL(wp) ::  na(3) = 0.0_wp                            !< namelist parameter (see documentation)
234    REAL(wp) ::  number_concentration = -1.0_wp            !< namelist parameter (see documentation)
235    REAL(wp) ::  radius_merge = 1.0E-7_wp                  !< namelist parameter (see documentation)
236    REAL(wp) ::  radius_split = 40.0E-6_wp                 !< namelist parameter (see documentation)
237    REAL(wp) ::  rm(3) = 1.0E-6_wp                         !< namelist parameter (see documentation)
238    REAL(wp) ::  sgs_wf_part                               !< parameter for sgs
239    REAL(wp) ::  time_write_particle_data = 0.0_wp         !< write particle data at current time on file
240    REAL(wp) ::  weight_factor_merge = -1.0_wp             !< namelist parameter (see documentation)
241    REAL(wp) ::  weight_factor_split = -1.0_wp             !< namelist parameter (see documentation)
242    REAL(wp) ::  z0_av_global                              !< horizontal mean value of z0
243
244    REAL(wp) ::  rclass_lbound !<
245    REAL(wp) ::  rclass_ubound !<
246
247    REAL(wp), PARAMETER ::  c_0 = 3.0_wp         !< parameter for lagrangian timescale
248
249    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  density_ratio = 9999999.9_wp  !< namelist parameter (see documentation)
250    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pdx = 9999999.9_wp            !< namelist parameter (see documentation)
251    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pdy = 9999999.9_wp            !< namelist parameter (see documentation)
252    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pdz = 9999999.9_wp            !< namelist parameter (see documentation)
253    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psb = 9999999.9_wp            !< namelist parameter (see documentation)
254    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psl = 9999999.9_wp            !< namelist parameter (see documentation)
255    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psn = 9999999.9_wp            !< namelist parameter (see documentation)
256    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  psr = 9999999.9_wp            !< namelist parameter (see documentation)
257    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pss = 9999999.9_wp            !< namelist parameter (see documentation)
258    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  pst = 9999999.9_wp            !< namelist parameter (see documentation).
259    REAL(wp), DIMENSION(max_number_of_particle_groups) ::  radius = 9999999.9_wp         !< namelist parameter (see documentation)
260
261    REAL(wp), DIMENSION(:), ALLOCATABLE     ::  log_z_z0   !< Precalculate LOG(z/z0) 
262
263    INTEGER(iwp), PARAMETER ::  NR_2_direction_move = 10000 !<
264    INTEGER(iwp)            ::  nr_move_north               !<
265    INTEGER(iwp)            ::  nr_move_south               !<
266
267    TYPE(particle_type), DIMENSION(:), ALLOCATABLE ::  move_also_north
268    TYPE(particle_type), DIMENSION(:), ALLOCATABLE ::  move_also_south
269
270    REAL(wp) ::  epsilon_collision !<
271    REAL(wp) ::  urms              !<
272
273    REAL(wp), DIMENSION(:),   ALLOCATABLE ::  epsclass  !< dissipation rate class
274    REAL(wp), DIMENSION(:),   ALLOCATABLE ::  radclass  !< radius class
275    REAL(wp), DIMENSION(:),   ALLOCATABLE ::  winf      !<
276
277    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  ec        !<
278    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  ecf       !<
279    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  gck       !<
280    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  hkernel   !<
281    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  hwratio   !<
282
283    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  ckernel !<
284
285    INTEGER(iwp), PARAMETER         ::  PHASE_INIT    = 1  !<
286    INTEGER(iwp), PARAMETER, PUBLIC ::  PHASE_RELEASE = 2  !<
287
288    SAVE
289
290    PRIVATE
291
292    PUBLIC lpm_parin,     &
293           lpm_header,    &
294           lpm_init_arrays,&
295           lpm_init,      &
296           lpm_actions,   &
297           lpm_data_output_ptseries, &
298           lpm_interaction_droplets_ptq, &
299           lpm_rrd_local_particles, &
300           lpm_wrd_local, &
301           lpm_rrd_global, &
302           lpm_wrd_global, &
303           lpm_rrd_local, &
304           lpm_check_parameters
305
306    PUBLIC lagrangian_particle_model
307
308    INTERFACE lpm_check_parameters
309       MODULE PROCEDURE lpm_check_parameters
310    END INTERFACE lpm_check_parameters
311
312    INTERFACE lpm_parin
313       MODULE PROCEDURE lpm_parin
314    END INTERFACE lpm_parin
315
316    INTERFACE lpm_header
317       MODULE PROCEDURE lpm_header
318    END INTERFACE lpm_header
319
320    INTERFACE lpm_init_arrays
321       MODULE PROCEDURE lpm_init_arrays
322    END INTERFACE lpm_init_arrays
323 
324    INTERFACE lpm_init
325       MODULE PROCEDURE lpm_init
326    END INTERFACE lpm_init
327
328    INTERFACE lpm_actions
329       MODULE PROCEDURE lpm_actions
330    END INTERFACE lpm_actions
331
332    INTERFACE lpm_data_output_ptseries
333       MODULE PROCEDURE lpm_data_output_ptseries
334    END INTERFACE
335
336    INTERFACE lpm_rrd_local_particles
337       MODULE PROCEDURE lpm_rrd_local_particles
338    END INTERFACE lpm_rrd_local_particles
339
340    INTERFACE lpm_rrd_global
341       MODULE PROCEDURE lpm_rrd_global
342    END INTERFACE lpm_rrd_global
343
344    INTERFACE lpm_rrd_local
345       MODULE PROCEDURE lpm_rrd_local
346    END INTERFACE lpm_rrd_local
347
348    INTERFACE lpm_wrd_local
349       MODULE PROCEDURE lpm_wrd_local
350    END INTERFACE lpm_wrd_local
351
352    INTERFACE lpm_wrd_global
353       MODULE PROCEDURE lpm_wrd_global
354    END INTERFACE lpm_wrd_global
355
356    INTERFACE lpm_advec
357       MODULE PROCEDURE lpm_advec
358    END INTERFACE lpm_advec
359
360    INTERFACE lpm_calc_liquid_water_content
361       MODULE PROCEDURE lpm_calc_liquid_water_content
362    END INTERFACE
363
364    INTERFACE lpm_interaction_droplets_ptq
365       MODULE PROCEDURE lpm_interaction_droplets_ptq
366       MODULE PROCEDURE lpm_interaction_droplets_ptq_ij
367    END INTERFACE lpm_interaction_droplets_ptq
368
369    INTERFACE lpm_boundary_conds
370       MODULE PROCEDURE lpm_boundary_conds
371    END INTERFACE lpm_boundary_conds
372
373    INTERFACE lpm_droplet_condensation
374       MODULE PROCEDURE lpm_droplet_condensation
375    END INTERFACE
376
377    INTERFACE lpm_droplet_collision
378       MODULE PROCEDURE lpm_droplet_collision
379    END INTERFACE lpm_droplet_collision
380
381    INTERFACE lpm_init_kernels
382       MODULE PROCEDURE lpm_init_kernels
383    END INTERFACE lpm_init_kernels
384
385    INTERFACE lpm_splitting
386       MODULE PROCEDURE lpm_splitting
387    END INTERFACE lpm_splitting
388
389    INTERFACE lpm_merging
390       MODULE PROCEDURE lpm_merging
391    END INTERFACE lpm_merging
392
393    INTERFACE lpm_exchange_horiz
394       MODULE PROCEDURE lpm_exchange_horiz
395    END INTERFACE lpm_exchange_horiz
396
397    INTERFACE lpm_move_particle
398       MODULE PROCEDURE lpm_move_particle
399    END INTERFACE lpm_move_particle
400
401    INTERFACE realloc_particles_array
402       MODULE PROCEDURE realloc_particles_array
403    END INTERFACE realloc_particles_array
404
405    INTERFACE dealloc_particles_array
406       MODULE PROCEDURE dealloc_particles_array
407    END INTERFACE dealloc_particles_array
408
409    INTERFACE lpm_sort_and_delete
410       MODULE PROCEDURE lpm_sort_and_delete
411    END INTERFACE lpm_sort_and_delete
412
413    INTERFACE lpm_sort_timeloop_done
414       MODULE PROCEDURE lpm_sort_timeloop_done
415    END INTERFACE lpm_sort_timeloop_done
416
417    INTERFACE lpm_pack
418       MODULE PROCEDURE lpm_pack
419    END INTERFACE lpm_pack
420
421 CONTAINS
422 
423
424!------------------------------------------------------------------------------!
425! Description:
426! ------------
427!> Parin for &particle_parameters for the Lagrangian particle model
428!------------------------------------------------------------------------------!
429 SUBROUTINE lpm_parin
430 
431    CHARACTER (LEN=80) ::  line  !<
432
433    NAMELIST /particles_par/ &
434       aero_species, &
435       aero_type, &
436       aero_weight, &
437       alloc_factor, &
438       bc_par_b, &
439       bc_par_lr, &
440       bc_par_ns, &
441       bc_par_t, &
442       collision_kernel, &
443       curvature_solution_effects, &
444       deallocate_memory, &
445       density_ratio, &
446       dissipation_classes, &
447       dt_dopts, &
448       dt_min_part, &
449       dt_prel, &
450       dt_write_particle_data, &
451       end_time_prel, &
452       initial_weighting_factor, &
453       log_sigma, &
454       max_number_particles_per_gridbox, &
455       merging, &
456       na, &
457       number_concentration, &
458       number_of_particle_groups, &
459       number_particles_per_gridbox, &
460       particles_per_point, &
461       particle_advection_start, &
462       particle_advection_interpolation, &
463       particle_maximum_age, &
464       pdx, &
465       pdy, &
466       pdz, &
467       psb, &
468       psl, &
469       psn, &
470       psr, &
471       pss, &
472       pst, &
473       radius, &
474       radius_classes, &
475       radius_merge, &
476       radius_split, &
477       random_start_position, &
478       read_particles_from_restartfile, &
479       rm, &
480       seed_follows_topography, &
481       splitting, &
482       splitting_factor, &
483       splitting_factor_max, &
484       splitting_function, &
485       splitting_mode, &
486       step_dealloc, &
487       use_sgs_for_particles, &
488       vertical_particle_advection, &
489       weight_factor_merge, &
490       weight_factor_split, &
491       write_particle_statistics
492
493       NAMELIST /particle_parameters/ &
494       aero_species, &
495       aero_type, &
496       aero_weight, &
497       alloc_factor, &
498       bc_par_b, &
499       bc_par_lr, &
500       bc_par_ns, &
501       bc_par_t, &
502       collision_kernel, &
503       curvature_solution_effects, &
504       deallocate_memory, &
505       density_ratio, &
506       dissipation_classes, &
507       dt_dopts, &
508       dt_min_part, &
509       dt_prel, &
510       dt_write_particle_data, &
511       end_time_prel, &
512       initial_weighting_factor, &
513       log_sigma, &
514       max_number_particles_per_gridbox, &
515       merging, &
516       na, &
517       number_concentration, &
518       number_of_particle_groups, &
519       number_particles_per_gridbox, &
520       particles_per_point, &
521       particle_advection_start, &
522       particle_advection_interpolation, &
523       particle_maximum_age, &
524       pdx, &
525       pdy, &
526       pdz, &
527       psb, &
528       psl, &
529       psn, &
530       psr, &
531       pss, &
532       pst, &
533       radius, &
534       radius_classes, &
535       radius_merge, &
536       radius_split, &
537       random_start_position, &
538       read_particles_from_restartfile, &
539       rm, &
540       seed_follows_topography, &
541       splitting, &
542       splitting_factor, &
543       splitting_factor_max, &
544       splitting_function, &
545       splitting_mode, &
546       step_dealloc, &
547       use_sgs_for_particles, &
548       vertical_particle_advection, &
549       weight_factor_merge, &
550       weight_factor_split, &
551       write_particle_statistics
552
553!
554!-- Position the namelist-file at the beginning (it was already opened in
555!-- parin), search for the namelist-group of the package and position the
556!-- file at this line. Do the same for each optionally used package.
557    line = ' '
558   
559!
560!-- Try to find particles package
561    REWIND ( 11 )
562    line = ' '
563    DO   WHILE ( INDEX( line, '&particle_parameters' ) == 0 )
564       READ ( 11, '(A)', END=12 )  line
565    ENDDO
566    BACKSPACE ( 11 )
567!
568!-- Read user-defined namelist
569    READ ( 11, particle_parameters, ERR = 10 )
570!
571!-- Set flag that indicates that particles are switched on
572    particle_advection = .TRUE.
573   
574    GOTO 14
575
57610  BACKSPACE( 11 )
577    READ( 11 , '(A)') line
578    CALL parin_fail_message( 'particle_parameters', line )
579!
580!-- Try to find particles package (old namelist)
58112  REWIND ( 11 )
582    line = ' '
583    DO WHILE ( INDEX( line, '&particles_par' ) == 0 )
584       READ ( 11, '(A)', END=14 )  line
585    ENDDO
586    BACKSPACE ( 11 )
587!
588!-- Read user-defined namelist
589    READ ( 11, particles_par, ERR = 13, END = 14 )
590
591    message_string = 'namelist particles_par is deprecated and will be ' //    &
592                     'removed in near future. Please use namelist ' //         &
593                     'particle_parameters instead'
594    CALL message( 'package_parin', 'PA0487', 0, 1, 0, 6, 0 )
595
596!
597!-- Set flag that indicates that particles are switched on
598    particle_advection = .TRUE.
599
600    GOTO 14
601
60213    BACKSPACE( 11 )
603       READ( 11 , '(A)') line
604       CALL parin_fail_message( 'particles_par', line )
605
60614 CONTINUE
607
608 END SUBROUTINE lpm_parin
609 
610!------------------------------------------------------------------------------!
611! Description:
612! ------------
613!> Writes used particle attributes in header file.
614!------------------------------------------------------------------------------!
615 SUBROUTINE lpm_header ( io )
616
617    CHARACTER (LEN=40) ::  output_format       !< netcdf format
618 
619    INTEGER(iwp) ::  i               !<
620    INTEGER(iwp), INTENT(IN) ::  io  !< Unit of the output file
621
622 
623     IF ( humidity  .AND.  cloud_droplets )  THEN
624       WRITE ( io, 433 )
625       IF ( curvature_solution_effects )  WRITE ( io, 434 )
626       IF ( collision_kernel /= 'none' )  THEN
627          WRITE ( io, 435 )  TRIM( collision_kernel )
628          IF ( collision_kernel(6:9) == 'fast' )  THEN
629             WRITE ( io, 436 )  radius_classes, dissipation_classes
630          ENDIF
631       ELSE
632          WRITE ( io, 437 )
633       ENDIF
634    ENDIF
635 
636    IF ( particle_advection )  THEN
637!
638!--    Particle attributes
639       WRITE ( io, 480 )  particle_advection_start, dt_prel, bc_par_lr, &
640                          bc_par_ns, bc_par_b, bc_par_t, particle_maximum_age, &
641                          end_time_prel
642       IF ( use_sgs_for_particles )  WRITE ( io, 488 )  dt_min_part
643       IF ( random_start_position )  WRITE ( io, 481 )
644       IF ( seed_follows_topography )  WRITE ( io, 496 )
645       IF ( particles_per_point > 1 )  WRITE ( io, 489 )  particles_per_point
646       WRITE ( io, 495 )  total_number_of_particles
647       IF ( dt_write_particle_data /= 9999999.9_wp )  THEN
648          WRITE ( io, 485 )  dt_write_particle_data
649          IF ( netcdf_data_format > 1 )  THEN
650             output_format = 'netcdf (64 bit offset) and binary'
651          ELSE
652             output_format = 'netcdf and binary'
653          ENDIF
654          IF ( netcdf_deflate == 0 )  THEN
655             WRITE ( io, 344 )  output_format
656          ELSE
657             WRITE ( io, 354 )  TRIM( output_format ), netcdf_deflate
658          ENDIF
659       ENDIF
660       IF ( dt_dopts /= 9999999.9_wp )  WRITE ( io, 494 )  dt_dopts
661       IF ( write_particle_statistics )  WRITE ( io, 486 )
662
663       WRITE ( io, 487 )  number_of_particle_groups
664
665       DO  i = 1, number_of_particle_groups
666          IF ( i == 1  .AND.  density_ratio(i) == 9999999.9_wp )  THEN
667             WRITE ( io, 490 )  i, 0.0_wp
668             WRITE ( io, 492 )
669          ELSE
670             WRITE ( io, 490 )  i, radius(i)
671             IF ( density_ratio(i) /= 0.0_wp )  THEN
672                WRITE ( io, 491 )  density_ratio(i)
673             ELSE
674                WRITE ( io, 492 )
675             ENDIF
676          ENDIF
677          WRITE ( io, 493 )  psl(i), psr(i), pss(i), psn(i), psb(i), pst(i), &
678                             pdx(i), pdy(i), pdz(i)
679          IF ( .NOT. vertical_particle_advection(i) )  WRITE ( io, 482 )
680       ENDDO
681
682    ENDIF
683   
684344 FORMAT ('       Output format: ',A/)
685354 FORMAT ('       Output format: ',A, '   compressed with level: ',I1/)
686
687433 FORMAT ('    Cloud droplets treated explicitly using the Lagrangian part', &
688                 'icle model')
689434 FORMAT ('    Curvature and solution effecs are considered for growth of', &
690                 ' droplets < 1.0E-6 m')
691435 FORMAT ('    Droplet collision is handled by ',A,'-kernel')
692436 FORMAT ('       Fast kernel with fixed radius- and dissipation classes ', &
693                    'are used'/ &
694            '          number of radius classes:       ',I3,'    interval ', &
695                       '[1.0E-6,2.0E-4] m'/ &
696            '          number of dissipation classes:   ',I2,'    interval ', &
697                       '[0,1000] cm**2/s**3')
698437 FORMAT ('    Droplet collision is switched off')
699
700480 FORMAT ('    Particles:'/ &
701            '    ---------'// &
702            '       Particle advection is active (switched on at t = ', F7.1, &
703                    ' s)'/ &
704            '       Start of new particle generations every  ',F6.1,' s'/ &
705            '       Boundary conditions: left/right: ', A, ' north/south: ', A/&
706            '                            bottom:     ', A, ' top:         ', A/&
707            '       Maximum particle age:                 ',F9.1,' s'/ &
708            '       Advection stopped at t = ',F9.1,' s'/)
709481 FORMAT ('       Particles have random start positions'/)
710482 FORMAT ('          Particles are advected only horizontally'/)
711485 FORMAT ('       Particle data are written on file every ', F9.1, ' s')
712486 FORMAT ('       Particle statistics are written on file'/)
713487 FORMAT ('       Number of particle groups: ',I2/)
714488 FORMAT ('       SGS velocity components are used for particle advection'/ &
715            '          minimum timestep for advection:', F8.5/)
716489 FORMAT ('       Number of particles simultaneously released at each ', &
717                    'point: ', I5/)
718490 FORMAT ('       Particle group ',I2,':'/ &
719            '          Particle radius: ',E10.3, 'm')
720491 FORMAT ('          Particle inertia is activated'/ &
721            '             density_ratio (rho_fluid/rho_particle) =',F6.3/)
722492 FORMAT ('          Particles are advected only passively (no inertia)'/)
723493 FORMAT ('          Boundaries of particle source: x:',F8.1,' - ',F8.1,' m'/&
724            '                                         y:',F8.1,' - ',F8.1,' m'/&
725            '                                         z:',F8.1,' - ',F8.1,' m'/&
726            '          Particle distances:  dx = ',F8.1,' m  dy = ',F8.1, &
727                       ' m  dz = ',F8.1,' m'/)
728494 FORMAT ('       Output of particle time series in NetCDF format every ', &
729                    F8.2,' s'/)
730495 FORMAT ('       Number of particles in total domain: ',I10/)
731496 FORMAT ('       Initial vertical particle positions are interpreted ', &
732                    'as relative to the given topography')
733   
734 END SUBROUTINE lpm_header
735 
736!------------------------------------------------------------------------------!
737! Description:
738! ------------
739!> Writes used particle attributes in header file.
740!------------------------------------------------------------------------------! 
741 SUBROUTINE lpm_check_parameters
742 
743!
744!-- Collision kernels:
745    SELECT CASE ( TRIM( collision_kernel ) )
746
747       CASE ( 'hall', 'hall_fast' )
748          hall_kernel = .TRUE.
749
750       CASE ( 'wang', 'wang_fast' )
751          wang_kernel = .TRUE.
752
753       CASE ( 'none' )
754
755
756       CASE DEFAULT
757          message_string = 'unknown collision kernel: collision_kernel = "' // &
758                           TRIM( collision_kernel ) // '"'
759          CALL message( 'check_parameters', 'PA0350', 1, 2, 0, 6, 0 )
760
761    END SELECT
762    IF ( collision_kernel(6:9) == 'fast' )  use_kernel_tables = .TRUE.
763
764!
765!-- Subgrid scale velocites with the simple interpolation method for resolved
766!-- velocites is not implemented for passive particles. However, for cloud
767!-- it can be combined as the sgs-velocites for active particles are
768!-- calculated differently, i.e. no subboxes are needed.
769    IF ( .NOT. TRIM( particle_advection_interpolation ) == 'trilinear'  .AND.  &
770       use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
771          message_string = 'subrgrid scale velocities in combination with ' // &
772                           'simple interpolation method is not '            // &
773                           'implemented'
774          CALL message( 'check_parameters', 'PA0659', 1, 2, 0, 6, 0 )
775    ENDIF
776
777 END SUBROUTINE
778 
779!------------------------------------------------------------------------------!
780! Description:
781! ------------
782!> Initialize arrays for lpm
783!------------------------------------------------------------------------------!   
784 SUBROUTINE lpm_init_arrays
785 
786    IF ( cloud_droplets )  THEN
787!
788!--    Liquid water content, change in liquid water content
789       ALLOCATE ( ql_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                      &
790                  ql_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
791!
792!--    Real volume of particles (with weighting), volume of particles
793       ALLOCATE ( ql_v(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                      &
794                     ql_vp(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
795    ENDIF
796   
797!
798!--    Initial assignment of the pointers   
799    IF ( cloud_droplets )  THEN
800       ql   => ql_1
801       ql_c => ql_2
802    ENDIF
803   
804 END SUBROUTINE lpm_init_arrays
805 
806!------------------------------------------------------------------------------!
807! Description:
808! ------------
809!> Initialize Lagrangian particle model
810!------------------------------------------------------------------------------!
811 SUBROUTINE lpm_init
812
813    INTEGER(iwp) ::  i                           !<
814    INTEGER(iwp) ::  j                           !<
815    INTEGER(iwp) ::  k                           !<
816
817    REAL(wp) ::  div                             !<
818    REAL(wp) ::  height_int                      !<
819    REAL(wp) ::  height_p                        !<
820    REAL(wp) ::  z_p                             !<
821    REAL(wp) ::  z0_av_local                     !<
822
823!
824!-- In case of oceans runs, the vertical index calculations need an offset,
825!-- because otherwise the k indices will become negative
826    IF ( ocean_mode )  THEN
827       offset_ocean_nzt    = nzt
828       offset_ocean_nzt_m1 = nzt - 1
829    ENDIF
830
831!
832!-- Define block offsets for dividing a gridcell in 8 sub cells
833!-- See documentation for List of subgrid boxes
834!-- See pack_and_sort in lpm_pack_arrays.f90 for assignment of the subgrid boxes
835    block_offset(0) = block_offset_def ( 0, 0, 0)
836    block_offset(1) = block_offset_def ( 0, 0,-1)
837    block_offset(2) = block_offset_def ( 0,-1, 0)
838    block_offset(3) = block_offset_def ( 0,-1,-1)
839    block_offset(4) = block_offset_def (-1, 0, 0)
840    block_offset(5) = block_offset_def (-1, 0,-1)
841    block_offset(6) = block_offset_def (-1,-1, 0)
842    block_offset(7) = block_offset_def (-1,-1,-1)
843!
844!-- Check the number of particle groups.
845    IF ( number_of_particle_groups > max_number_of_particle_groups )  THEN
846       WRITE( message_string, * ) 'max_number_of_particle_groups =',           &
847                                  max_number_of_particle_groups ,              &
848                                  '&number_of_particle_groups reset to ',      &
849                                  max_number_of_particle_groups
850       CALL message( 'lpm_init', 'PA0213', 0, 1, 0, 6, 0 )
851       number_of_particle_groups = max_number_of_particle_groups
852    ENDIF
853!
854!-- Check if downward-facing walls exist. This case, reflection boundary
855!-- conditions (as well as subgrid-scale velocities) may do not work
856!-- propably (not realized so far).
857    IF ( surf_def_h(1)%ns >= 1 )  THEN
858       WRITE( message_string, * ) 'Overhanging topography do not work '//      &
859                                  'with particles'
860       CALL message( 'lpm_init', 'PA0212', 0, 1, 0, 6, 0 )
861
862    ENDIF
863
864!
865!-- Set default start positions, if necessary
866    IF ( psl(1) == 9999999.9_wp )  psl(1) = 0.0_wp
867    IF ( psr(1) == 9999999.9_wp )  psr(1) = ( nx +1 ) * dx
868    IF ( pss(1) == 9999999.9_wp )  pss(1) = 0.0_wp
869    IF ( psn(1) == 9999999.9_wp )  psn(1) = ( ny +1 ) * dy
870    IF ( psb(1) == 9999999.9_wp )  psb(1) = zu(nz/2)
871    IF ( pst(1) == 9999999.9_wp )  pst(1) = psb(1)
872
873    IF ( pdx(1) == 9999999.9_wp  .OR.  pdx(1) == 0.0_wp )  pdx(1) = dx
874    IF ( pdy(1) == 9999999.9_wp  .OR.  pdy(1) == 0.0_wp )  pdy(1) = dy
875    IF ( pdz(1) == 9999999.9_wp  .OR.  pdz(1) == 0.0_wp )  pdz(1) = zu(2) - zu(1)
876
877!
878!-- If number_particles_per_gridbox is set, the parametres pdx, pdy and pdz are
879!-- calculated diagnostically. Therfore an isotropic distribution is prescribed.
880    IF ( number_particles_per_gridbox /= -1 .AND.   &
881         number_particles_per_gridbox >= 1 )    THEN
882       pdx(1) = (( dx * dy * ( zu(2) - zu(1) ) ) /  &
883             REAL(number_particles_per_gridbox))**0.3333333_wp
884!
885!--    Ensure a smooth value (two significant digits) of distance between
886!--    particles (pdx, pdy, pdz).
887       div = 1000.0_wp
888       DO  WHILE ( pdx(1) < div )
889          div = div / 10.0_wp
890       ENDDO
891       pdx(1) = NINT( pdx(1) * 100.0_wp / div ) * div / 100.0_wp
892       pdy(1) = pdx(1)
893       pdz(1) = pdx(1)
894
895    ENDIF
896
897    DO  j = 2, number_of_particle_groups
898       IF ( psl(j) == 9999999.9_wp )  psl(j) = psl(j-1)
899       IF ( psr(j) == 9999999.9_wp )  psr(j) = psr(j-1)
900       IF ( pss(j) == 9999999.9_wp )  pss(j) = pss(j-1)
901       IF ( psn(j) == 9999999.9_wp )  psn(j) = psn(j-1)
902       IF ( psb(j) == 9999999.9_wp )  psb(j) = psb(j-1)
903       IF ( pst(j) == 9999999.9_wp )  pst(j) = pst(j-1)
904       IF ( pdx(j) == 9999999.9_wp  .OR.  pdx(j) == 0.0_wp )  pdx(j) = pdx(j-1)
905       IF ( pdy(j) == 9999999.9_wp  .OR.  pdy(j) == 0.0_wp )  pdy(j) = pdy(j-1)
906       IF ( pdz(j) == 9999999.9_wp  .OR.  pdz(j) == 0.0_wp )  pdz(j) = pdz(j-1)
907    ENDDO
908
909!
910!-- Allocate arrays required for calculating particle SGS velocities.
911!-- Initialize prefactor required for stoachastic Weil equation.
912    IF ( use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
913       ALLOCATE( de_dx(nzb:nzt+1,nysg:nyng,nxlg:nxrg), &
914                 de_dy(nzb:nzt+1,nysg:nyng,nxlg:nxrg), &
915                 de_dz(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
916
917       de_dx = 0.0_wp
918       de_dy = 0.0_wp
919       de_dz = 0.0_wp
920
921       sgs_wf_part = 1.0_wp / 3.0_wp
922    ENDIF
923
924!
925!-- Allocate array required for logarithmic vertical interpolation of
926!-- horizontal particle velocities between the surface and the first vertical
927!-- grid level. In order to avoid repeated CPU cost-intensive CALLS of
928!-- intrinsic FORTRAN procedure LOG(z/z0), LOG(z/z0) is precalculated for
929!-- several heights. Splitting into 20 sublayers turned out to be sufficient.
930!-- To obtain exact height levels of particles, linear interpolation is applied
931!-- (see lpm_advec.f90).
932    IF ( constant_flux_layer )  THEN
933
934       ALLOCATE ( log_z_z0(0:number_of_sublayers) )
935       z_p = zu(nzb+1) - zw(nzb)
936
937!
938!--    Calculate horizontal mean value of z0 used for logartihmic
939!--    interpolation. Note: this is not exact for heterogeneous z0.
940!--    However, sensitivity studies showed that the effect is
941!--    negligible.
942       z0_av_local  = SUM( surf_def_h(0)%z0 ) + SUM( surf_lsm_h%z0 ) +         &
943                      SUM( surf_usm_h%z0 )
944       z0_av_global = 0.0_wp
945
946#if defined( __parallel )
947       CALL MPI_ALLREDUCE(z0_av_local, z0_av_global, 1, MPI_REAL, MPI_SUM, &
948                          comm2d, ierr )
949#else
950       z0_av_global = z0_av_local
951#endif
952
953       z0_av_global = z0_av_global  / ( ( ny + 1 ) * ( nx + 1 ) )
954!
955!--    Horizontal wind speed is zero below and at z0
956       log_z_z0(0) = 0.0_wp
957!
958!--    Calculate vertical depth of the sublayers
959       height_int  = ( z_p - z0_av_global ) / REAL( number_of_sublayers, KIND=wp )
960!
961!--    Precalculate LOG(z/z0)
962       height_p    = z0_av_global
963       DO  k = 1, number_of_sublayers
964
965          height_p    = height_p + height_int
966          log_z_z0(k) = LOG( height_p / z0_av_global )
967
968       ENDDO
969
970    ENDIF
971
972!
973!-- Check which particle interpolation method should be used
974    IF ( TRIM( particle_advection_interpolation )  ==  'trilinear' )  THEN
975       interpolation_simple_corrector = .FALSE.
976       interpolation_simple_predictor = .FALSE.
977       interpolation_trilinear        = .TRUE.
978    ELSEIF ( TRIM( particle_advection_interpolation )  ==  'simple_corrector' )  THEN
979       interpolation_simple_corrector = .TRUE.
980       interpolation_simple_predictor = .FALSE.
981       interpolation_trilinear        = .FALSE.
982    ELSEIF ( TRIM( particle_advection_interpolation )  ==  'simple_predictor' )  THEN
983       interpolation_simple_corrector = .FALSE.
984       interpolation_simple_predictor = .TRUE.
985       interpolation_trilinear        = .FALSE.
986    ENDIF
987
988!
989!-- Check boundary condition and set internal variables
990    SELECT CASE ( bc_par_b )
991
992       CASE ( 'absorb' )
993          ibc_par_b = 1
994
995       CASE ( 'reflect' )
996          ibc_par_b = 2
997
998       CASE ( 'reset' )
999          ibc_par_b = 3
1000
1001       CASE DEFAULT
1002          WRITE( message_string, * )  'unknown boundary condition ',           &
1003                                       'bc_par_b = "', TRIM( bc_par_b ), '"'
1004          CALL message( 'lpm_init', 'PA0217', 1, 2, 0, 6, 0 )
1005
1006    END SELECT
1007    SELECT CASE ( bc_par_t )
1008
1009       CASE ( 'absorb' )
1010          ibc_par_t = 1
1011
1012       CASE ( 'reflect' )
1013          ibc_par_t = 2
1014
1015       CASE ( 'nested' )
1016          ibc_par_t = 3
1017
1018       CASE DEFAULT
1019          WRITE( message_string, * ) 'unknown boundary condition ',            &
1020                                     'bc_par_t = "', TRIM( bc_par_t ), '"'
1021          CALL message( 'lpm_init', 'PA0218', 1, 2, 0, 6, 0 )
1022
1023    END SELECT
1024    SELECT CASE ( bc_par_lr )
1025
1026       CASE ( 'cyclic' )
1027          ibc_par_lr = 0
1028
1029       CASE ( 'absorb' )
1030          ibc_par_lr = 1
1031
1032       CASE ( 'reflect' )
1033          ibc_par_lr = 2
1034
1035       CASE ( 'nested' )
1036          ibc_par_lr = 3
1037
1038       CASE DEFAULT
1039          WRITE( message_string, * ) 'unknown boundary condition ',   &
1040                                     'bc_par_lr = "', TRIM( bc_par_lr ), '"'
1041          CALL message( 'lpm_init', 'PA0219', 1, 2, 0, 6, 0 )
1042
1043    END SELECT
1044    SELECT CASE ( bc_par_ns )
1045
1046       CASE ( 'cyclic' )
1047          ibc_par_ns = 0
1048
1049       CASE ( 'absorb' )
1050          ibc_par_ns = 1
1051
1052       CASE ( 'reflect' )
1053          ibc_par_ns = 2
1054
1055       CASE ( 'nested' )
1056          ibc_par_ns = 3
1057
1058       CASE DEFAULT
1059          WRITE( message_string, * ) 'unknown boundary condition ',   &
1060                                     'bc_par_ns = "', TRIM( bc_par_ns ), '"'
1061          CALL message( 'lpm_init', 'PA0220', 1, 2, 0, 6, 0 )
1062
1063    END SELECT
1064    SELECT CASE ( splitting_mode )
1065
1066       CASE ( 'const' )
1067          i_splitting_mode = 1
1068
1069       CASE ( 'cl_av' )
1070          i_splitting_mode = 2
1071
1072       CASE ( 'gb_av' )
1073          i_splitting_mode = 3
1074
1075       CASE DEFAULT
1076          WRITE( message_string, * )  'unknown splitting_mode = "',            &
1077                                      TRIM( splitting_mode ), '"'
1078          CALL message( 'lpm_init', 'PA0146', 1, 2, 0, 6, 0 )
1079
1080    END SELECT
1081    SELECT CASE ( splitting_function )
1082
1083       CASE ( 'gamma' )
1084          isf = 1
1085
1086       CASE ( 'log' )
1087          isf = 2
1088
1089       CASE ( 'exp' )
1090          isf = 3
1091
1092       CASE DEFAULT
1093          WRITE( message_string, * )  'unknown splitting function = "',        &
1094                                       TRIM( splitting_function ), '"'
1095          CALL message( 'lpm_init', 'PA0147', 1, 2, 0, 6, 0 )
1096
1097    END SELECT
1098!
1099!-- Initialize collision kernels
1100    IF ( collision_kernel /= 'none' )  CALL lpm_init_kernels
1101!
1102!-- For the first model run of a possible job chain initialize the
1103!-- particles, otherwise read the particle data from restart file.
1104    IF ( TRIM( initializing_actions ) == 'read_restart_data'  &
1105         .AND.  read_particles_from_restartfile )  THEN
1106       CALL lpm_rrd_local_particles
1107    ELSE
1108!
1109!--    Allocate particle arrays and set attributes of the initial set of
1110!--    particles, which can be also periodically released at later times.
1111       ALLOCATE( prt_count(nzb:nzt+1,nysg:nyng,nxlg:nxrg), &
1112                 grid_particles(nzb+1:nzt,nys:nyn,nxl:nxr) )
1113
1114       number_of_particles = 0
1115       prt_count           = 0
1116!
1117!--    initialize counter for particle IDs
1118       grid_particles%id_counter = 1
1119!
1120!--    Initialize all particles with dummy values (otherwise errors may
1121!--    occur within restart runs). The reason for this is still not clear
1122!--    and may be presumably caused by errors in the respective user-interface.
1123       zero_particle = particle_type( 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1124                                      0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1125                                      0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1126                                      0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,  &
1127                                      0, 0, 0_idp, .FALSE., -1 )
1128
1129       particle_groups = particle_groups_type( 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp )
1130!
1131!--    Set values for the density ratio and radius for all particle
1132!--    groups, if necessary
1133       IF ( density_ratio(1) == 9999999.9_wp )  density_ratio(1) = 0.0_wp
1134       IF ( radius(1)        == 9999999.9_wp )  radius(1) = 0.0_wp
1135       DO  i = 2, number_of_particle_groups
1136          IF ( density_ratio(i) == 9999999.9_wp )  THEN
1137             density_ratio(i) = density_ratio(i-1)
1138          ENDIF
1139          IF ( radius(i) == 9999999.9_wp )  radius(i) = radius(i-1)
1140       ENDDO
1141
1142       DO  i = 1, number_of_particle_groups
1143          IF ( density_ratio(i) /= 0.0_wp  .AND.  radius(i) == 0 )  THEN
1144             WRITE( message_string, * ) 'particle group #', i, ' has a',       &
1145                                        'density ratio /= 0 but radius = 0'
1146             CALL message( 'lpm_init', 'PA0215', 1, 2, 0, 6, 0 )
1147          ENDIF
1148          particle_groups(i)%density_ratio = density_ratio(i)
1149          particle_groups(i)%radius        = radius(i)
1150       ENDDO
1151!
1152!--    Set a seed value for the random number generator to be exclusively
1153!--    used for the particle code. The generated random numbers should be
1154!--    different on the different PEs.
1155       iran_part = iran_part + myid
1156!
1157!--    Create the particle set, and set the initial particles
1158       CALL lpm_create_particle( phase_init )
1159       last_particle_release_time = particle_advection_start
1160!
1161!--    User modification of initial particles
1162       CALL user_lpm_init
1163!
1164!--    Open file for statistical informations about particle conditions
1165       IF ( write_particle_statistics )  THEN
1166          CALL check_open( 80 )
1167          WRITE ( 80, 8000 )  current_timestep_number, simulated_time,         &
1168                              number_of_particles
1169          CALL close_file( 80 )
1170       ENDIF
1171
1172    ENDIF
1173
1174    IF ( nested_run )  CALL pmcp_g_init
1175!
1176!-- To avoid programm abort, assign particles array to the local version of
1177!-- first grid cell
1178    number_of_particles = prt_count(nzb+1,nys,nxl)
1179    particles => grid_particles(nzb+1,nys,nxl)%particles(1:number_of_particles)
1180!
1181!-- Formats
11828000 FORMAT (I6,1X,F7.2,4X,I10,71X,I10)
1183
1184 END SUBROUTINE lpm_init
1185 
1186!------------------------------------------------------------------------------!
1187! Description:
1188! ------------
1189!> Create Lagrangian particles
1190!------------------------------------------------------------------------------! 
1191 SUBROUTINE lpm_create_particle (phase)
1192
1193    INTEGER(iwp)               ::  alloc_size  !< relative increase of allocated memory for particles
1194    INTEGER(iwp)               ::  i           !< loop variable ( particle groups )
1195    INTEGER(iwp)               ::  ip          !< index variable along x
1196    INTEGER(iwp)               ::  j           !< loop variable ( particles per point )
1197    INTEGER(iwp)               ::  jp          !< index variable along y
1198    INTEGER(iwp)               ::  k           !< index variable along z
1199    INTEGER(iwp)               ::  k_surf      !< index of surface grid point
1200    INTEGER(iwp)               ::  kp          !< index variable along z
1201    INTEGER(iwp)               ::  loop_stride !< loop variable for initialization
1202    INTEGER(iwp)               ::  n           !< loop variable ( number of particles )
1203    INTEGER(iwp)               ::  new_size    !< new size of allocated memory for particles
1204
1205    INTEGER(iwp), INTENT(IN)   ::  phase       !< mode of inititialization
1206
1207    INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  local_count !< start address of new particle
1208    INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  local_start !< start address of new particle
1209
1210    LOGICAL                    ::  first_stride !< flag for initialization
1211
1212    REAL(wp)                   ::  pos_x      !< increment for particle position in x
1213    REAL(wp)                   ::  pos_y      !< increment for particle position in y
1214    REAL(wp)                   ::  pos_z      !< increment for particle position in z
1215    REAL(wp)                   ::  rand_contr !< dummy argument for random position
1216
1217    TYPE(particle_type),TARGET ::  tmp_particle !< temporary particle used for initialization
1218
1219!
1220!-- Calculate particle positions and store particle attributes, if
1221!-- particle is situated on this PE
1222    DO  loop_stride = 1, 2
1223       first_stride = (loop_stride == 1)
1224       IF ( first_stride )   THEN
1225          local_count = 0           ! count number of particles
1226       ELSE
1227          local_count = prt_count   ! Start address of new particles
1228       ENDIF
1229
1230!
1231!--    Calculate initial_weighting_factor diagnostically
1232       IF ( number_concentration /= -1.0_wp  .AND.  number_concentration > 0.0_wp )  THEN
1233          initial_weighting_factor =  number_concentration  *                           &
1234                                      pdx(1) * pdy(1) * pdz(1)
1235       END IF
1236
1237       n = 0
1238       DO  i = 1, number_of_particle_groups
1239          pos_z = psb(i)
1240          DO WHILE ( pos_z <= pst(i) )
1241             IF ( pos_z >= zw(0) .AND.  pos_z < zw(nzt) )  THEN
1242                pos_y = pss(i)
1243                DO WHILE ( pos_y <= psn(i) )
1244                   IF ( pos_y >= nys * dy  .AND.                  &
1245                        pos_y <  ( nyn + 1 ) * dy  )  THEN
1246                      pos_x = psl(i)
1247               xloop: DO WHILE ( pos_x <= psr(i) )
1248                         IF ( pos_x >= nxl * dx  .AND.            &
1249                              pos_x <  ( nxr + 1) * dx )  THEN
1250                            DO  j = 1, particles_per_point
1251                               n = n + 1
1252                               tmp_particle%x             = pos_x
1253                               tmp_particle%y             = pos_y
1254                               tmp_particle%z             = pos_z
1255                               tmp_particle%age           = 0.0_wp
1256                               tmp_particle%age_m         = 0.0_wp
1257                               tmp_particle%dt_sum        = 0.0_wp
1258                               tmp_particle%e_m           = 0.0_wp
1259                               tmp_particle%rvar1         = 0.0_wp
1260                               tmp_particle%rvar2         = 0.0_wp
1261                               tmp_particle%rvar3         = 0.0_wp
1262                               tmp_particle%speed_x       = 0.0_wp
1263                               tmp_particle%speed_y       = 0.0_wp
1264                               tmp_particle%speed_z       = 0.0_wp
1265                               tmp_particle%origin_x      = pos_x
1266                               tmp_particle%origin_y      = pos_y
1267                               tmp_particle%origin_z      = pos_z
1268                               IF ( curvature_solution_effects )  THEN
1269                                  tmp_particle%aux1      = 0.0_wp    ! dry aerosol radius
1270                                  tmp_particle%aux2      = dt_3d     ! last Rosenbrock timestep
1271                               ELSE
1272                                  tmp_particle%aux1      = 0.0_wp    ! free to use
1273                                  tmp_particle%aux2      = 0.0_wp    ! free to use
1274                               ENDIF
1275                               tmp_particle%radius        = particle_groups(i)%radius
1276                               tmp_particle%weight_factor = initial_weighting_factor
1277                               tmp_particle%class         = 1
1278                               tmp_particle%group         = i
1279                               tmp_particle%id            = 0_idp
1280                               tmp_particle%particle_mask = .TRUE.
1281                               tmp_particle%block_nr      = -1
1282!
1283!--                            Determine the grid indices of the particle position
1284                               ip = INT( tmp_particle%x * ddx )
1285                               jp = INT( tmp_particle%y * ddy )
1286!
1287!--                            In case of stretching the actual k index is found iteratively
1288                               IF ( dz_stretch_level /= -9999999.9_wp  .OR.           &
1289                                    dz_stretch_level_start(1) /= -9999999.9_wp )  THEN
1290                                  kp = MINLOC( ABS( tmp_particle%z - zu ), DIM = 1 ) - 1
1291                               ELSE
1292                                  kp = INT( tmp_particle%z / dz(1) + 1 + offset_ocean_nzt )
1293                               ENDIF
1294!
1295!--                            Determine surface level. Therefore, check for
1296!--                            upward-facing wall on w-grid.
1297                               k_surf = topo_top_ind(jp,ip,3)
1298                               IF ( seed_follows_topography )  THEN
1299!
1300!--                               Particle height is given relative to topography
1301                                  kp = kp + k_surf
1302                                  tmp_particle%z = tmp_particle%z + zw(k_surf)
1303!--                               Skip particle release if particle position is
1304!--                               above model top, or within topography in case
1305!--                               of overhanging structures.
1306                                  IF ( kp > nzt  .OR.                          &
1307                                 .NOT. BTEST( wall_flags_0(kp,jp,ip), 0 ) )  THEN
1308                                     pos_x = pos_x + pdx(i)
1309                                     CYCLE xloop
1310                                  ENDIF
1311!
1312!--                            Skip particle release if particle position is
1313!--                            below surface, or within topography in case
1314!--                            of overhanging structures.
1315                               ELSEIF ( .NOT. seed_follows_topography .AND.    &
1316                                         tmp_particle%z <= zw(k_surf)  .OR.    &
1317                                        .NOT. BTEST( wall_flags_0(kp,jp,ip), 0 ) )&
1318                               THEN
1319                                  pos_x = pos_x + pdx(i)
1320                                  CYCLE xloop
1321                               ENDIF
1322
1323                               local_count(kp,jp,ip) = local_count(kp,jp,ip) + 1
1324
1325                               IF ( .NOT. first_stride )  THEN
1326                                  IF ( ip < nxl  .OR.  jp < nys  .OR.  kp < nzb+1 )  THEN
1327                                     write(6,*) 'xl ',ip,jp,kp,nxl,nys,nzb+1
1328                                  ENDIF
1329                                  IF ( ip > nxr  .OR.  jp > nyn  .OR.  kp > nzt )  THEN
1330                                     write(6,*) 'xu ',ip,jp,kp,nxr,nyn,nzt
1331                                  ENDIF
1332                                  grid_particles(kp,jp,ip)%particles(local_count(kp,jp,ip)) = tmp_particle
1333                               ENDIF
1334                            ENDDO
1335                         ENDIF
1336                         pos_x = pos_x + pdx(i)
1337                      ENDDO xloop
1338                   ENDIF
1339                   pos_y = pos_y + pdy(i)
1340                ENDDO
1341             ENDIF
1342
1343             pos_z = pos_z + pdz(i)
1344          ENDDO
1345       ENDDO
1346
1347       IF ( first_stride )  THEN
1348          DO  ip = nxl, nxr
1349             DO  jp = nys, nyn
1350                DO  kp = nzb+1, nzt
1351                   IF ( phase == PHASE_INIT )  THEN
1352                      IF ( local_count(kp,jp,ip) > 0 )  THEN
1353                         alloc_size = MAX( INT( local_count(kp,jp,ip) *        &
1354                            ( 1.0_wp + alloc_factor / 100.0_wp ) ),            &
1355                            1 )
1356                      ELSE
1357                         alloc_size = 1
1358                      ENDIF
1359                      ALLOCATE(grid_particles(kp,jp,ip)%particles(1:alloc_size))
1360                      DO  n = 1, alloc_size
1361                         grid_particles(kp,jp,ip)%particles(n) = zero_particle
1362                      ENDDO
1363                   ELSEIF ( phase == PHASE_RELEASE )  THEN
1364                      IF ( local_count(kp,jp,ip) > 0 )  THEN
1365                         new_size   = local_count(kp,jp,ip) + prt_count(kp,jp,ip)
1366                         alloc_size = MAX( INT( new_size * ( 1.0_wp +          &
1367                            alloc_factor / 100.0_wp ) ), 1 )
1368                         IF( alloc_size > SIZE( grid_particles(kp,jp,ip)%particles) )  THEN
1369                            CALL realloc_particles_array( ip, jp, kp, alloc_size )
1370                         ENDIF
1371                      ENDIF
1372                   ENDIF
1373                ENDDO
1374             ENDDO
1375          ENDDO
1376       ENDIF
1377
1378    ENDDO
1379
1380    local_start = prt_count+1
1381    prt_count   = local_count
1382!
1383!-- Calculate particle IDs
1384    DO  ip = nxl, nxr
1385       DO  jp = nys, nyn
1386          DO  kp = nzb+1, nzt
1387             number_of_particles = prt_count(kp,jp,ip)
1388             IF ( number_of_particles <= 0 )  CYCLE
1389             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1390
1391             DO  n = local_start(kp,jp,ip), number_of_particles  !only new particles
1392
1393                particles(n)%id = 10000_idp**3 * grid_particles(kp,jp,ip)%id_counter + &
1394                                  10000_idp**2 * kp + 10000_idp * jp + ip
1395!
1396!--             Count the number of particles that have been released before
1397                grid_particles(kp,jp,ip)%id_counter =                          &
1398                                         grid_particles(kp,jp,ip)%id_counter + 1
1399
1400             ENDDO
1401
1402          ENDDO
1403       ENDDO
1404    ENDDO
1405!
1406!-- Initialize aerosol background spectrum
1407    IF ( curvature_solution_effects )  THEN
1408       CALL lpm_init_aerosols( local_start )
1409    ENDIF
1410!
1411!-- Add random fluctuation to particle positions.
1412    IF ( random_start_position )  THEN
1413       DO  ip = nxl, nxr
1414          DO  jp = nys, nyn
1415             DO  kp = nzb+1, nzt
1416                number_of_particles = prt_count(kp,jp,ip)
1417                IF ( number_of_particles <= 0 )  CYCLE
1418                particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1419!
1420!--             Move only new particles. Moreover, limit random fluctuation
1421!--             in order to prevent that particles move more than one grid box,
1422!--             which would lead to problems concerning particle exchange
1423!--             between processors in case pdx/pdy are larger than dx/dy,
1424!--             respectively.
1425                DO  n = local_start(kp,jp,ip), number_of_particles
1426                   IF ( psl(particles(n)%group) /= psr(particles(n)%group) )  THEN
1427                      rand_contr = ( random_function( iran_part ) - 0.5_wp ) * &
1428                                     pdx(particles(n)%group)
1429                      particles(n)%x = particles(n)%x +                        &
1430                              MERGE( rand_contr, SIGN( dx, rand_contr ),       &
1431                                     ABS( rand_contr ) < dx                    &
1432                                   )
1433                   ENDIF
1434                   IF ( pss(particles(n)%group) /= psn(particles(n)%group) )  THEN
1435                      rand_contr = ( random_function( iran_part ) - 0.5_wp ) * &
1436                                     pdy(particles(n)%group)
1437                      particles(n)%y = particles(n)%y +                        &
1438                              MERGE( rand_contr, SIGN( dy, rand_contr ),       &
1439                                     ABS( rand_contr ) < dy                    &
1440                                   )
1441                   ENDIF
1442                   IF ( psb(particles(n)%group) /= pst(particles(n)%group) )  THEN
1443                      rand_contr = ( random_function( iran_part ) - 0.5_wp ) * &
1444                                     pdz(particles(n)%group)
1445                      particles(n)%z = particles(n)%z +                        &
1446                              MERGE( rand_contr, SIGN( dzw(kp), rand_contr ),  &
1447                                     ABS( rand_contr ) < dzw(kp)               &
1448                                   )
1449                   ENDIF
1450                ENDDO
1451!
1452!--             Identify particles located outside the model domain and reflect
1453!--             or absorb them if necessary.
1454                CALL lpm_boundary_conds( 'bottom/top', i, j, k )
1455!
1456!--             Furthermore, remove particles located in topography. Note, as
1457!--             the particle speed is still zero at this point, wall
1458!--             reflection boundary conditions will not work in this case.
1459                particles =>                                                   &
1460                       grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1461                DO  n = local_start(kp,jp,ip), number_of_particles
1462                   i = particles(n)%x * ddx
1463                   j = particles(n)%y * ddy
1464                   k = particles(n)%z / dz(1) + 1 + offset_ocean_nzt
1465                   DO WHILE( zw(k) < particles(n)%z )
1466                      k = k + 1
1467                   ENDDO
1468                   DO WHILE( zw(k-1) > particles(n)%z )
1469                      k = k - 1
1470                   ENDDO
1471!
1472!--                Check if particle is within topography
1473                   IF ( .NOT. BTEST( wall_flags_0(k,j,i), 0 ) )  THEN
1474                      particles(n)%particle_mask = .FALSE.
1475                      deleted_particles = deleted_particles + 1
1476                   ENDIF
1477
1478                ENDDO
1479             ENDDO
1480          ENDDO
1481       ENDDO
1482!
1483!--    Exchange particles between grid cells and processors
1484       CALL lpm_move_particle
1485       CALL lpm_exchange_horiz
1486
1487    ENDIF
1488!
1489!-- In case of random_start_position, delete particles identified by
1490!-- lpm_exchange_horiz and lpm_boundary_conds. Then sort particles into blocks,
1491!-- which is needed for a fast interpolation of the LES fields on the particle
1492!-- position.
1493    CALL lpm_sort_and_delete
1494!
1495!-- Determine the current number of particles
1496    DO  ip = nxl, nxr
1497       DO  jp = nys, nyn
1498          DO  kp = nzb+1, nzt
1499             number_of_particles         = number_of_particles                 &
1500                                           + prt_count(kp,jp,ip)
1501          ENDDO
1502       ENDDO
1503    ENDDO
1504!
1505!-- Calculate the number of particles of the total domain
1506#if defined( __parallel )
1507    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1508    CALL MPI_ALLREDUCE( number_of_particles, total_number_of_particles, 1, &
1509    MPI_INTEGER, MPI_SUM, comm2d, ierr )
1510#else
1511    total_number_of_particles = number_of_particles
1512#endif
1513
1514    RETURN
1515
1516 END SUBROUTINE lpm_create_particle
1517 
1518 
1519!------------------------------------------------------------------------------!
1520! Description:
1521! ------------
1522!> This routine initialize the particles as aerosols with physio-chemical
1523!> properties.
1524!------------------------------------------------------------------------------!   
1525 SUBROUTINE lpm_init_aerosols(local_start)
1526
1527    REAL(wp) ::  afactor            !< curvature effects
1528    REAL(wp) ::  bfactor            !< solute effects
1529    REAL(wp) ::  dlogr              !< logarithmic width of radius bin
1530    REAL(wp) ::  e_a                !< vapor pressure
1531    REAL(wp) ::  e_s                !< saturation vapor pressure
1532    REAL(wp) ::  rmin = 0.005e-6_wp !< minimum aerosol radius
1533    REAL(wp) ::  rmax = 10.0e-6_wp  !< maximum aerosol radius
1534    REAL(wp) ::  r_mid              !< mean radius of bin
1535    REAL(wp) ::  r_l                !< left radius of bin
1536    REAL(wp) ::  r_r                !< right radius of bin
1537    REAL(wp) ::  sigma              !< surface tension
1538    REAL(wp) ::  t_int              !< temperature
1539
1540    INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg), INTENT(IN) ::  local_start !<
1541
1542    INTEGER(iwp) ::  n              !<
1543    INTEGER(iwp) ::  ip             !<
1544    INTEGER(iwp) ::  jp             !<
1545    INTEGER(iwp) ::  kp             !<
1546
1547!
1548!-- Set constants for different aerosol species
1549    IF ( TRIM( aero_species ) == 'nacl' )  THEN
1550       molecular_weight_of_solute = 0.05844_wp 
1551       rho_s                      = 2165.0_wp
1552       vanthoff                   = 2.0_wp
1553    ELSEIF ( TRIM( aero_species ) == 'c3h4o4' )  THEN
1554       molecular_weight_of_solute = 0.10406_wp 
1555       rho_s                      = 1600.0_wp
1556       vanthoff                   = 1.37_wp
1557    ELSEIF ( TRIM( aero_species ) == 'nh4o3' )  THEN
1558       molecular_weight_of_solute = 0.08004_wp 
1559       rho_s                      = 1720.0_wp
1560       vanthoff                   = 2.31_wp
1561    ELSE
1562       WRITE( message_string, * ) 'unknown aerosol species ',   &
1563                                'aero_species = "', TRIM( aero_species ), '"'
1564       CALL message( 'lpm_init', 'PA0470', 1, 2, 0, 6, 0 )
1565    ENDIF
1566!
1567!-- The following typical aerosol spectra are taken from Jaenicke (1993):
1568!-- Tropospheric aerosols. Published in Aerosol-Cloud-Climate Interactions.
1569    IF ( TRIM( aero_type ) == 'polar' )  THEN
1570       na        = (/ 2.17e1, 1.86e-1, 3.04e-4 /) * 1.0E6_wp
1571       rm        = (/ 0.0689, 0.375, 4.29 /) * 1.0E-6_wp
1572       log_sigma = (/ 0.245, 0.300, 0.291 /)
1573    ELSEIF ( TRIM( aero_type ) == 'background' )  THEN
1574       na        = (/ 1.29e2, 5.97e1, 6.35e1 /) * 1.0E6_wp
1575       rm        = (/ 0.0036, 0.127, 0.259 /) * 1.0E-6_wp
1576       log_sigma = (/ 0.645, 0.253, 0.425 /)
1577    ELSEIF ( TRIM( aero_type ) == 'maritime' )  THEN
1578       na        = (/ 1.33e2, 6.66e1, 3.06e0 /) * 1.0E6_wp
1579       rm        = (/ 0.0039, 0.133, 0.29 /) * 1.0E-6_wp
1580       log_sigma = (/ 0.657, 0.210, 0.396 /)
1581    ELSEIF ( TRIM( aero_type ) == 'continental' )  THEN
1582       na        = (/ 3.20e3, 2.90e3, 3.00e-1 /) * 1.0E6_wp
1583       rm        = (/ 0.01, 0.058, 0.9 /) * 1.0E-6_wp
1584       log_sigma = (/ 0.161, 0.217, 0.380 /)
1585    ELSEIF ( TRIM( aero_type ) == 'desert' )  THEN
1586       na        = (/ 7.26e2, 1.14e3, 1.78e-1 /) * 1.0E6_wp
1587       rm        = (/ 0.001, 0.0188, 10.8 /) * 1.0E-6_wp
1588       log_sigma = (/ 0.247, 0.770, 0.438 /)
1589    ELSEIF ( TRIM( aero_type ) == 'rural' )  THEN
1590       na        = (/ 6.65e3, 1.47e2, 1.99e3 /) * 1.0E6_wp
1591       rm        = (/ 0.00739, 0.0269, 0.0419 /) * 1.0E-6_wp
1592       log_sigma = (/ 0.225, 0.557, 0.266 /)
1593    ELSEIF ( TRIM( aero_type ) == 'urban' )  THEN
1594       na        = (/ 9.93e4, 1.11e3, 3.64e4 /) * 1.0E6_wp
1595       rm        = (/ 0.00651, 0.00714, 0.0248 /) * 1.0E-6_wp
1596       log_sigma = (/ 0.245, 0.666, 0.337 /)
1597    ELSEIF ( TRIM( aero_type ) == 'user' )  THEN
1598       CONTINUE
1599    ELSE
1600       WRITE( message_string, * ) 'unknown aerosol type ',   &
1601                                'aero_type = "', TRIM( aero_type ), '"'
1602       CALL message( 'lpm_init', 'PA0459', 1, 2, 0, 6, 0 )
1603    ENDIF
1604
1605    DO  ip = nxl, nxr
1606       DO  jp = nys, nyn
1607          DO  kp = nzb+1, nzt
1608
1609             number_of_particles = prt_count(kp,jp,ip)
1610             IF ( number_of_particles <= 0 )  CYCLE
1611             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
1612
1613             dlogr   = ( LOG10(rmax) - LOG10(rmin) ) / ( number_of_particles - local_start(kp,jp,ip) + 1 )
1614!
1615!--          Initialize the aerosols with a predefined spectral distribution
1616!--          of the dry radius (logarithmically increasing bins) and a varying
1617!--          weighting factor
1618             DO  n = local_start(kp,jp,ip), number_of_particles  !only new particles
1619
1620                r_l   = 10.0**( LOG10( rmin ) + (n-1) * dlogr )
1621                r_r   = 10.0**( LOG10( rmin ) + n * dlogr )
1622                r_mid = SQRT( r_l * r_r )
1623
1624                particles(n)%aux1          = r_mid
1625                particles(n)%weight_factor =                                           &
1626                   ( na(1) / ( SQRT( 2.0_wp * pi ) * log_sigma(1) ) *                     &
1627                     EXP( - LOG10( r_mid / rm(1) )**2 / ( 2.0_wp * log_sigma(1)**2 ) ) +  &
1628                     na(2) / ( SQRT( 2.0_wp * pi ) * log_sigma(2) ) *                     &
1629                     EXP( - LOG10( r_mid / rm(2) )**2 / ( 2.0_wp * log_sigma(2)**2 ) ) +  &
1630                     na(3) / ( SQRT( 2.0_wp * pi ) * log_sigma(3) ) *                     &
1631                     EXP( - LOG10( r_mid / rm(3) )**2 / ( 2.0_wp * log_sigma(3)**2 ) )    &
1632                   ) * ( LOG10(r_r) - LOG10(r_l) ) * ( dx * dy * dzw(kp) )
1633
1634!
1635!--             Multiply weight_factor with the namelist parameter aero_weight
1636!--             to increase or decrease the number of simulated aerosols
1637                particles(n)%weight_factor = particles(n)%weight_factor * aero_weight
1638
1639                IF ( particles(n)%weight_factor - FLOOR(particles(n)%weight_factor,KIND=wp) &
1640                     > random_function( iran_part ) )  THEN
1641                   particles(n)%weight_factor = FLOOR(particles(n)%weight_factor,KIND=wp) + 1.0_wp
1642                ELSE
1643                   particles(n)%weight_factor = FLOOR(particles(n)%weight_factor,KIND=wp)
1644                ENDIF
1645!
1646!--             Unnecessary particles will be deleted
1647                IF ( particles(n)%weight_factor <= 0.0_wp )  particles(n)%particle_mask = .FALSE.
1648
1649             ENDDO
1650!
1651!--          Set particle radius to equilibrium radius based on the environmental
1652!--          supersaturation (Khvorostyanov and Curry, 2007, JGR). This avoids
1653!--          the sometimes lengthy growth toward their equilibrium radius within
1654!--          the simulation.
1655             t_int  = pt(kp,jp,ip) * exner(kp)
1656
1657             e_s = magnus( t_int )
1658             e_a = q(kp,jp,ip) * hyp(kp) / ( q(kp,jp,ip) + rd_d_rv )
1659
1660             sigma   = 0.0761_wp - 0.000155_wp * ( t_int - 273.15_wp )
1661             afactor = 2.0_wp * sigma / ( rho_l * r_v * t_int )
1662
1663             bfactor = vanthoff * molecular_weight_of_water *    &
1664                       rho_s / ( molecular_weight_of_solute * rho_l )
1665!
1666!--          The formula is only valid for subsaturated environments. For
1667!--          supersaturations higher than -5 %, the supersaturation is set to -5%.
1668             IF ( e_a / e_s >= 0.95_wp )  e_a = 0.95_wp * e_s
1669
1670             DO  n = local_start(kp,jp,ip), number_of_particles  !only new particles
1671!
1672!--             For details on this equation, see Eq. (14) of Khvorostyanov and
1673!--             Curry (2007, JGR)
1674                particles(n)%radius = bfactor**0.3333333_wp *                  &
1675                   particles(n)%aux1 / ( 1.0_wp - e_a / e_s )**0.3333333_wp / &
1676                   ( 1.0_wp + ( afactor / ( 3.0_wp * bfactor**0.3333333_wp *   &
1677                     particles(n)%aux1 ) ) /                                  &
1678                     ( 1.0_wp - e_a / e_s )**0.6666666_wp                      &
1679                   )
1680
1681             ENDDO
1682
1683          ENDDO
1684       ENDDO
1685    ENDDO
1686
1687 END SUBROUTINE lpm_init_aerosols
1688
1689
1690!------------------------------------------------------------------------------!
1691! Description:
1692! ------------
1693!> Calculates quantities required for considering the SGS velocity fluctuations
1694!> in the particle transport by a stochastic approach. The respective
1695!> quantities are: SGS-TKE gradients and horizontally averaged profiles of the
1696!> SGS TKE and the resolved-scale velocity variances.
1697!------------------------------------------------------------------------------!
1698 SUBROUTINE lpm_init_sgs_tke
1699
1700    USE statistics,                                                            &
1701        ONLY:  flow_statistics_called, hom, sums, sums_l
1702
1703    INTEGER(iwp) ::  i      !< index variable along x
1704    INTEGER(iwp) ::  j      !< index variable along y
1705    INTEGER(iwp) ::  k      !< index variable along z
1706    INTEGER(iwp) ::  m      !< running index for the surface elements
1707
1708    REAL(wp) ::  flag1      !< flag to mask topography
1709
1710!
1711!-- TKE gradient along x and y
1712    DO  i = nxl, nxr
1713       DO  j = nys, nyn
1714          DO  k = nzb, nzt+1
1715
1716             IF ( .NOT. BTEST( wall_flags_0(k,j,i-1), 0 )  .AND.               &
1717                        BTEST( wall_flags_0(k,j,i), 0   )  .AND.               &
1718                        BTEST( wall_flags_0(k,j,i+1), 0 ) )                    &
1719             THEN
1720                de_dx(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1721                               ( e(k,j,i+1) - e(k,j,i) ) * ddx
1722             ELSEIF ( BTEST( wall_flags_0(k,j,i-1), 0 )  .AND.                 &
1723                      BTEST( wall_flags_0(k,j,i), 0   )  .AND.                 &
1724                .NOT. BTEST( wall_flags_0(k,j,i+1), 0 ) )                      &
1725             THEN
1726                de_dx(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1727                               ( e(k,j,i) - e(k,j,i-1) ) * ddx
1728             ELSEIF ( .NOT. BTEST( wall_flags_0(k,j,i), 22   )  .AND.          &
1729                      .NOT. BTEST( wall_flags_0(k,j,i+1), 22 ) )               &   
1730             THEN
1731                de_dx(k,j,i) = 0.0_wp
1732             ELSEIF ( .NOT. BTEST( wall_flags_0(k,j,i-1), 22 )  .AND.          &
1733                      .NOT. BTEST( wall_flags_0(k,j,i), 22   ) )               &
1734             THEN
1735                de_dx(k,j,i) = 0.0_wp
1736             ELSE
1737                de_dx(k,j,i) = sgs_wf_part * ( e(k,j,i+1) - e(k,j,i-1) ) * ddx
1738             ENDIF
1739
1740             IF ( .NOT. BTEST( wall_flags_0(k,j-1,i), 0 )  .AND.               &
1741                        BTEST( wall_flags_0(k,j,i), 0   )  .AND.               &
1742                        BTEST( wall_flags_0(k,j+1,i), 0 ) )                    &
1743             THEN
1744                de_dy(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1745                               ( e(k,j+1,i) - e(k,j,i) ) * ddy
1746             ELSEIF ( BTEST( wall_flags_0(k,j-1,i), 0 )  .AND.                 &
1747                      BTEST( wall_flags_0(k,j,i), 0   )  .AND.                 &
1748                .NOT. BTEST( wall_flags_0(k,j+1,i), 0 ) )                      &
1749             THEN
1750                de_dy(k,j,i) = 2.0_wp * sgs_wf_part *                          &
1751                               ( e(k,j,i) - e(k,j-1,i) ) * ddy
1752             ELSEIF ( .NOT. BTEST( wall_flags_0(k,j,i), 22   )  .AND.          &
1753                      .NOT. BTEST( wall_flags_0(k,j+1,i), 22 ) )               &   
1754             THEN
1755                de_dy(k,j,i) = 0.0_wp
1756             ELSEIF ( .NOT. BTEST( wall_flags_0(k,j-1,i), 22 )  .AND.          &
1757                      .NOT. BTEST( wall_flags_0(k,j,i), 22   ) )               &
1758             THEN
1759                de_dy(k,j,i) = 0.0_wp
1760             ELSE
1761                de_dy(k,j,i) = sgs_wf_part * ( e(k,j+1,i) - e(k,j-1,i) ) * ddy
1762             ENDIF
1763
1764          ENDDO
1765       ENDDO
1766    ENDDO
1767
1768!
1769!-- TKE gradient along z at topograhy and  including bottom and top boundary conditions
1770    DO  i = nxl, nxr
1771       DO  j = nys, nyn
1772          DO  k = nzb+1, nzt-1
1773!
1774!--          Flag to mask topography
1775             flag1 = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0  ) )
1776
1777             de_dz(k,j,i) = 2.0_wp * sgs_wf_part *                             &
1778                           ( e(k+1,j,i) - e(k-1,j,i) ) / ( zu(k+1) - zu(k-1) ) &
1779                                                 * flag1
1780          ENDDO
1781!
1782!--       upward-facing surfaces
1783          DO  m = bc_h(0)%start_index(j,i), bc_h(0)%end_index(j,i)
1784             k            = bc_h(0)%k(m)
1785             de_dz(k,j,i) = 2.0_wp * sgs_wf_part *                             &
1786                           ( e(k+1,j,i) - e(k,j,i)   ) / ( zu(k+1) - zu(k) )
1787          ENDDO
1788!
1789!--       downward-facing surfaces
1790          DO  m = bc_h(1)%start_index(j,i), bc_h(1)%end_index(j,i)
1791             k            = bc_h(1)%k(m)
1792             de_dz(k,j,i) = 2.0_wp * sgs_wf_part *                             &
1793                           ( e(k,j,i) - e(k-1,j,i)   ) / ( zu(k) - zu(k-1) )
1794          ENDDO
1795
1796          de_dz(nzb,j,i)   = 0.0_wp
1797          de_dz(nzt,j,i)   = 0.0_wp
1798          de_dz(nzt+1,j,i) = 0.0_wp
1799       ENDDO
1800    ENDDO
1801!
1802!-- Ghost point exchange
1803    CALL exchange_horiz( de_dx, nbgp )
1804    CALL exchange_horiz( de_dy, nbgp )
1805    CALL exchange_horiz( de_dz, nbgp )
1806    CALL exchange_horiz( diss, nbgp  )
1807!
1808!-- Set boundary conditions at non-periodic boundaries. Note, at non-period
1809!-- boundaries zero-gradient boundary conditions are set for the subgrid TKE.
1810!-- Thus, TKE gradients normal to the respective lateral boundaries are zero,
1811!-- while tangetial TKE gradients then must be the same as within the prognostic
1812!-- domain. 
1813    IF ( bc_dirichlet_l )  THEN
1814       de_dx(:,:,-1) = 0.0_wp
1815       de_dy(:,:,-1) = de_dy(:,:,0) 
1816       de_dz(:,:,-1) = de_dz(:,:,0)
1817    ENDIF
1818    IF ( bc_dirichlet_r )  THEN
1819       de_dx(:,:,nxr+1) = 0.0_wp
1820       de_dy(:,:,nxr+1) = de_dy(:,:,nxr) 
1821       de_dz(:,:,nxr+1) = de_dz(:,:,nxr)
1822    ENDIF
1823    IF ( bc_dirichlet_n )  THEN
1824       de_dx(:,nyn+1,:) = de_dx(:,nyn,:)
1825       de_dy(:,nyn+1,:) = 0.0_wp 
1826       de_dz(:,nyn+1,:) = de_dz(:,nyn,:)
1827    ENDIF
1828    IF ( bc_dirichlet_s )  THEN
1829       de_dx(:,nys-1,:) = de_dx(:,nys,:)
1830       de_dy(:,nys-1,:) = 0.0_wp 
1831       de_dz(:,nys-1,:) = de_dz(:,nys,:)
1832    ENDIF 
1833!
1834!-- Calculate the horizontally averaged profiles of SGS TKE and resolved
1835!-- velocity variances (they may have been already calculated in routine
1836!-- flow_statistics).
1837    IF ( .NOT. flow_statistics_called )  THEN
1838
1839!
1840!--    First calculate horizontally averaged profiles of the horizontal
1841!--    velocities.
1842       sums_l(:,1,0) = 0.0_wp
1843       sums_l(:,2,0) = 0.0_wp
1844
1845       DO  i = nxl, nxr
1846          DO  j =  nys, nyn
1847             DO  k = nzb, nzt+1
1848!
1849!--             Flag indicating vicinity of wall
1850                flag1 = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 24 ) )
1851
1852                sums_l(k,1,0)  = sums_l(k,1,0)  + u(k,j,i) * flag1
1853                sums_l(k,2,0)  = sums_l(k,2,0)  + v(k,j,i) * flag1
1854             ENDDO
1855          ENDDO
1856       ENDDO
1857
1858#if defined( __parallel )
1859!
1860!--    Compute total sum from local sums
1861       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1862       CALL MPI_ALLREDUCE( sums_l(nzb,1,0), sums(nzb,1), nzt+2-nzb, &
1863                           MPI_REAL, MPI_SUM, comm2d, ierr )
1864       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1865       CALL MPI_ALLREDUCE( sums_l(nzb,2,0), sums(nzb,2), nzt+2-nzb, &
1866                              MPI_REAL, MPI_SUM, comm2d, ierr )
1867#else
1868       sums(:,1) = sums_l(:,1,0)
1869       sums(:,2) = sums_l(:,2,0)
1870#endif
1871
1872!
1873!--    Final values are obtained by division by the total number of grid
1874!--    points used for the summation.
1875       hom(:,1,1,0) = sums(:,1) / ngp_2dh_outer(:,0)   ! u
1876       hom(:,1,2,0) = sums(:,2) / ngp_2dh_outer(:,0)   ! v
1877
1878!
1879!--    Now calculate the profiles of SGS TKE and the resolved-scale
1880!--    velocity variances
1881       sums_l(:,8,0)  = 0.0_wp
1882       sums_l(:,30,0) = 0.0_wp
1883       sums_l(:,31,0) = 0.0_wp
1884       sums_l(:,32,0) = 0.0_wp
1885       DO  i = nxl, nxr
1886          DO  j = nys, nyn
1887             DO  k = nzb, nzt+1
1888!
1889!--             Flag indicating vicinity of wall
1890                flag1 = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 24 ) )
1891
1892                sums_l(k,8,0)  = sums_l(k,8,0)  + e(k,j,i)                       * flag1
1893                sums_l(k,30,0) = sums_l(k,30,0) + ( u(k,j,i) - hom(k,1,1,0) )**2 * flag1
1894                sums_l(k,31,0) = sums_l(k,31,0) + ( v(k,j,i) - hom(k,1,2,0) )**2 * flag1
1895                sums_l(k,32,0) = sums_l(k,32,0) + w(k,j,i)**2                    * flag1
1896             ENDDO
1897          ENDDO
1898       ENDDO
1899
1900#if defined( __parallel )
1901!
1902!--    Compute total sum from local sums
1903       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1904       CALL MPI_ALLREDUCE( sums_l(nzb,8,0), sums(nzb,8), nzt+2-nzb, &
1905                           MPI_REAL, MPI_SUM, comm2d, ierr )
1906       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1907       CALL MPI_ALLREDUCE( sums_l(nzb,30,0), sums(nzb,30), nzt+2-nzb, &
1908                           MPI_REAL, MPI_SUM, comm2d, ierr )
1909       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1910       CALL MPI_ALLREDUCE( sums_l(nzb,31,0), sums(nzb,31), nzt+2-nzb, &
1911                           MPI_REAL, MPI_SUM, comm2d, ierr )
1912       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1913       CALL MPI_ALLREDUCE( sums_l(nzb,32,0), sums(nzb,32), nzt+2-nzb, &
1914                           MPI_REAL, MPI_SUM, comm2d, ierr )
1915
1916#else
1917       sums(:,8)  = sums_l(:,8,0)
1918       sums(:,30) = sums_l(:,30,0)
1919       sums(:,31) = sums_l(:,31,0)
1920       sums(:,32) = sums_l(:,32,0)
1921#endif
1922
1923!
1924!--    Final values are obtained by division by the total number of grid
1925!--    points used for the summation.
1926       hom(:,1,8,0)  = sums(:,8)  / ngp_2dh_outer(:,0)   ! e
1927       hom(:,1,30,0) = sums(:,30) / ngp_2dh_outer(:,0)   ! u*2
1928       hom(:,1,31,0) = sums(:,31) / ngp_2dh_outer(:,0)   ! v*2
1929       hom(:,1,32,0) = sums(:,32) / ngp_2dh_outer(:,0)   ! w*2
1930
1931    ENDIF
1932
1933 END SUBROUTINE lpm_init_sgs_tke
1934 
1935 
1936!------------------------------------------------------------------------------!
1937! Description:
1938! ------------
1939!> Sobroutine control lpm actions, i.e. all actions during one time step.
1940!------------------------------------------------------------------------------! 
1941 SUBROUTINE lpm_actions( location )
1942
1943    CHARACTER (LEN=*), INTENT(IN) ::  location !< call location string
1944
1945    INTEGER(iwp)       ::  i                  !<
1946    INTEGER(iwp)       ::  ie                 !<
1947    INTEGER(iwp)       ::  is                 !<
1948    INTEGER(iwp)       ::  j                  !<
1949    INTEGER(iwp)       ::  je                 !<
1950    INTEGER(iwp)       ::  js                 !<
1951    INTEGER(iwp), SAVE ::  lpm_count = 0      !<
1952    INTEGER(iwp)       ::  k                  !<
1953    INTEGER(iwp)       ::  ke                 !<
1954    INTEGER(iwp)       ::  ks                 !<
1955    INTEGER(iwp)       ::  m                  !<
1956    INTEGER(iwp), SAVE ::  steps = 0          !<
1957
1958    LOGICAL            ::  first_loop_stride  !<
1959
1960
1961    SELECT CASE ( location )
1962
1963       CASE ( 'after_prognostic_equations' )
1964
1965          CALL cpu_log( log_point(25), 'lpm', 'start' )
1966!
1967!--       Write particle data at current time on file.
1968!--       This has to be done here, before particles are further processed,
1969!--       because they may be deleted within this timestep (in case that
1970!--       dt_write_particle_data = dt_prel = particle_maximum_age).
1971          time_write_particle_data = time_write_particle_data + dt_3d
1972          IF ( time_write_particle_data >= dt_write_particle_data )  THEN
1973
1974             CALL lpm_data_output_particles
1975!
1976!--       The MOD function allows for changes in the output interval with restart
1977!--       runs.
1978             time_write_particle_data = MOD( time_write_particle_data, &
1979                                        MAX( dt_write_particle_data, dt_3d ) )
1980          ENDIF
1981
1982!
1983!--       Initialize arrays for marking those particles to be deleted after the
1984!--       (sub-) timestep
1985          deleted_particles = 0
1986
1987!
1988!--       Initialize variables used for accumulating the number of particles
1989!--       xchanged between the subdomains during all sub-timesteps (if sgs
1990!--       velocities are included). These data are output further below on the
1991!--       particle statistics file.
1992          trlp_count_sum      = 0
1993          trlp_count_recv_sum = 0
1994          trrp_count_sum      = 0
1995          trrp_count_recv_sum = 0
1996          trsp_count_sum      = 0
1997          trsp_count_recv_sum = 0
1998          trnp_count_sum      = 0
1999          trnp_count_recv_sum = 0
2000!
2001!--       Calculate exponential term used in case of particle inertia for each
2002!--       of the particle groups
2003          DO  m = 1, number_of_particle_groups
2004             IF ( particle_groups(m)%density_ratio /= 0.0_wp )  THEN
2005                particle_groups(m)%exp_arg  =                                        &
2006                          4.5_wp * particle_groups(m)%density_ratio *                &
2007                          molecular_viscosity / ( particle_groups(m)%radius )**2
2008
2009                particle_groups(m)%exp_term = EXP( -particle_groups(m)%exp_arg *     &
2010                          dt_3d )
2011             ENDIF
2012          ENDDO
2013!
2014!--       If necessary, release new set of particles
2015          IF ( ( simulated_time - last_particle_release_time ) >= dt_prel  .AND.     &
2016                 end_time_prel > simulated_time )  THEN
2017             DO WHILE ( ( simulated_time - last_particle_release_time ) >= dt_prel )
2018                CALL lpm_create_particle( PHASE_RELEASE )
2019                last_particle_release_time = last_particle_release_time + dt_prel
2020             ENDDO
2021          ENDIF
2022!
2023!--       Reset summation arrays
2024          IF ( cloud_droplets )  THEN
2025             ql_c  = 0.0_wp
2026             ql_v  = 0.0_wp
2027             ql_vp = 0.0_wp
2028          ENDIF
2029
2030          first_loop_stride = .TRUE.
2031          grid_particles(:,:,:)%time_loop_done = .TRUE.
2032!
2033!--       Timestep loop for particle advection.
2034!--       This loop has to be repeated until the advection time of every particle
2035!--       (within the total domain!) has reached the LES timestep (dt_3d).
2036!--       In case of including the SGS velocities, the particle timestep may be
2037!--       smaller than the LES timestep (because of the Lagrangian timescale
2038!--       restriction) and particles may require to undergo several particle
2039!--       timesteps, before the LES timestep is reached. Because the number of these
2040!--       particle timesteps to be carried out is unknown at first, these steps are
2041!--       carried out in the following infinite loop with exit condition.
2042          DO
2043             CALL cpu_log( log_point_s(44), 'lpm_advec', 'start' )
2044             CALL cpu_log( log_point_s(44), 'lpm_advec', 'pause' )
2045
2046!
2047!--          If particle advection includes SGS velocity components, calculate the
2048!--          required SGS quantities (i.e. gradients of the TKE, as well as
2049!--          horizontally averaged profiles of the SGS TKE and the resolved-scale
2050!--          velocity variances)
2051             IF ( use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
2052                CALL lpm_init_sgs_tke
2053             ENDIF
2054!
2055!--          In case SGS-particle speed is considered, particles may carry out
2056!--          several particle timesteps. In order to prevent unnecessary
2057!--          treatment of particles that already reached the final time level,
2058!--          particles are sorted into contiguous blocks of finished and
2059!--          not-finished particles, in addition to their already sorting
2060!--          according to their sub-boxes.
2061             IF ( .NOT. first_loop_stride  .AND.  use_sgs_for_particles )            &
2062                CALL lpm_sort_timeloop_done
2063             DO  i = nxl, nxr
2064                DO  j = nys, nyn
2065                   DO  k = nzb+1, nzt
2066
2067                      number_of_particles = prt_count(k,j,i)
2068!
2069!--                   If grid cell gets empty, flag must be true
2070                      IF ( number_of_particles <= 0 )  THEN
2071                         grid_particles(k,j,i)%time_loop_done = .TRUE.
2072                         CYCLE
2073                      ENDIF
2074
2075                      IF ( .NOT. first_loop_stride  .AND.  &
2076                           grid_particles(k,j,i)%time_loop_done )  CYCLE
2077
2078                      particles => grid_particles(k,j,i)%particles(1:number_of_particles)
2079
2080                      particles(1:number_of_particles)%particle_mask = .TRUE.
2081!
2082!--                   Initialize the variable storing the total time that a particle
2083!--                   has advanced within the timestep procedure
2084                      IF ( first_loop_stride )  THEN
2085                         particles(1:number_of_particles)%dt_sum = 0.0_wp
2086                      ENDIF
2087!
2088!--                   Particle (droplet) growth by condensation/evaporation and
2089!--                   collision
2090                      IF ( cloud_droplets  .AND.  first_loop_stride)  THEN
2091!
2092!--                      Droplet growth by condensation / evaporation
2093                         CALL lpm_droplet_condensation(i,j,k)
2094!
2095!--                      Particle growth by collision
2096                         IF ( collision_kernel /= 'none' )  THEN
2097                            CALL lpm_droplet_collision(i,j,k)
2098                         ENDIF
2099
2100                      ENDIF
2101!
2102!--                   Initialize the switch used for the loop exit condition checked
2103!--                   at the end of this loop. If at least one particle has failed to
2104!--                   reach the LES timestep, this switch will be set false in
2105!--                   lpm_advec.
2106                      dt_3d_reached_l = .TRUE.
2107
2108!
2109!--                   Particle advection
2110                      CALL lpm_advec( i, j, k )
2111!
2112!--                   Particle reflection from walls. Only applied if the particles
2113!--                   are in the vertical range of the topography. (Here, some
2114!--                   optimization is still possible.)
2115                      IF ( topography /= 'flat'  .AND.  k < nzb_max + 2 )  THEN
2116                         CALL  lpm_boundary_conds( 'walls', i, j, k )
2117                      ENDIF
2118!
2119!--                   User-defined actions after the calculation of the new particle
2120!--                   position
2121                      CALL user_lpm_advec( i, j, k )
2122!
2123!--                   Apply boundary conditions to those particles that have crossed
2124!--                   the top or bottom boundary and delete those particles, which are
2125!--                   older than allowed
2126                      CALL lpm_boundary_conds( 'bottom/top', i, j, k )
2127!
2128!---                  If not all particles of the actual grid cell have reached the
2129!--                   LES timestep, this cell has to do another loop iteration. Due to
2130!--                   the fact that particles can move into neighboring grid cells,
2131!--                   these neighbor cells also have to perform another loop iteration.
2132!--                   Please note, this realization does not work properly if
2133!--                   particles move into another subdomain.
2134                      IF ( .NOT. dt_3d_reached_l )  THEN
2135                         ks = MAX(nzb+1,k-1)
2136                         ke = MIN(nzt,k+1)
2137                         js = MAX(nys,j-1)
2138                         je = MIN(nyn,j+1)
2139                         is = MAX(nxl,i-1)
2140                         ie = MIN(nxr,i+1)
2141                         grid_particles(ks:ke,js:je,is:ie)%time_loop_done = .FALSE.
2142                      ELSE
2143                         grid_particles(k,j,i)%time_loop_done = .TRUE.
2144                      ENDIF
2145
2146                   ENDDO
2147                ENDDO
2148             ENDDO
2149             steps = steps + 1
2150             dt_3d_reached_l = ALL(grid_particles(:,:,:)%time_loop_done)
2151!
2152!--          Find out, if all particles on every PE have completed the LES timestep
2153!--          and set the switch corespondingly
2154#if defined( __parallel )
2155             IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2156             CALL MPI_ALLREDUCE( dt_3d_reached_l, dt_3d_reached, 1, MPI_LOGICAL, &
2157                                 MPI_LAND, comm2d, ierr )
2158#else
2159             dt_3d_reached = dt_3d_reached_l
2160#endif
2161             CALL cpu_log( log_point_s(44), 'lpm_advec', 'stop' )
2162
2163!
2164!--          Apply splitting and merging algorithm
2165             IF ( cloud_droplets )  THEN
2166                IF ( splitting )  THEN
2167                   CALL lpm_splitting
2168                ENDIF
2169                IF ( merging )  THEN
2170                   CALL lpm_merging
2171                ENDIF
2172             ENDIF
2173!
2174!--          Move Particles local to PE to a different grid cell
2175             CALL lpm_move_particle
2176!
2177!--          Horizontal boundary conditions including exchange between subdmains
2178             CALL lpm_exchange_horiz
2179
2180!
2181!--          IF .FALSE., lpm_sort_and_delete is done inside pcmp
2182             IF ( .NOT. dt_3d_reached  .OR.  .NOT. nested_run )   THEN
2183!
2184!--             Pack particles (eliminate those marked for deletion),
2185!--             determine new number of particles
2186                CALL lpm_sort_and_delete
2187
2188!--             Initialize variables for the next (sub-) timestep, i.e., for marking
2189!--             those particles to be deleted after the timestep
2190                deleted_particles = 0
2191             ENDIF
2192
2193             IF ( dt_3d_reached )  EXIT
2194
2195             first_loop_stride = .FALSE.
2196          ENDDO   ! timestep loop
2197!
2198!--       in case of nested runs do the transfer of particles after every full model time step
2199          IF ( nested_run )   THEN
2200             CALL particles_from_parent_to_child
2201             CALL particles_from_child_to_parent
2202             CALL pmcp_p_delete_particles_in_fine_grid_area
2203
2204             CALL lpm_sort_and_delete
2205
2206             deleted_particles = 0
2207          ENDIF
2208
2209!
2210!--       Calculate the new liquid water content for each grid box
2211          IF ( cloud_droplets )  CALL lpm_calc_liquid_water_content
2212
2213!
2214!--       Deallocate unused memory
2215          IF ( deallocate_memory  .AND.  lpm_count == step_dealloc )  THEN
2216             CALL dealloc_particles_array
2217             lpm_count = 0
2218          ELSEIF ( deallocate_memory )  THEN
2219             lpm_count = lpm_count + 1
2220          ENDIF
2221
2222!
2223!--       Write particle statistics (in particular the number of particles
2224!--       exchanged between the subdomains) on file
2225          IF ( write_particle_statistics )  CALL lpm_write_exchange_statistics
2226
2227          CALL cpu_log( log_point(25), 'lpm', 'stop' )
2228
2229! !
2230! !--       Output of particle time series
2231!           IF ( particle_advection )  THEN
2232!              IF ( time_dopts >= dt_dopts  .OR.                                                        &
2233!                   ( time_since_reference_point >= particle_advection_start  .AND.                     &
2234!                    first_call_lpm ) )  THEN
2235!                 CALL lpm_data_output_ptseries
2236!                 time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
2237!              ENDIF
2238!           ENDIF
2239
2240       CASE DEFAULT
2241          CONTINUE
2242
2243    END SELECT
2244
2245 END SUBROUTINE lpm_actions
2246 
2247 
2248!------------------------------------------------------------------------------!
2249! Description:
2250! ------------
2251!
2252!------------------------------------------------------------------------------!
2253 SUBROUTINE particles_from_parent_to_child
2254    IMPLICIT NONE
2255
2256    CALL pmcp_c_get_particle_from_parent                         ! Child actions
2257    CALL pmcp_p_fill_particle_win                                ! Parent actions
2258
2259    RETURN
2260 END SUBROUTINE particles_from_parent_to_child
2261
2262 
2263!------------------------------------------------------------------------------!
2264! Description:
2265! ------------
2266!
2267!------------------------------------------------------------------------------!
2268 SUBROUTINE particles_from_child_to_parent
2269    IMPLICIT NONE
2270
2271    CALL pmcp_c_send_particle_to_parent                         ! Child actions
2272    CALL pmcp_p_empty_particle_win                              ! Parent actions
2273
2274    RETURN
2275 END SUBROUTINE particles_from_child_to_parent
2276 
2277!------------------------------------------------------------------------------!
2278! Description:
2279! ------------
2280!> This routine write exchange statistics of the lpm in a ascii file.
2281!------------------------------------------------------------------------------!
2282 SUBROUTINE lpm_write_exchange_statistics
2283
2284    INTEGER(iwp) ::  ip         !<
2285    INTEGER(iwp) ::  jp         !<
2286    INTEGER(iwp) ::  kp         !<
2287    INTEGER(iwp) ::  tot_number_of_particles !<
2288
2289!
2290!-- Determine the current number of particles
2291    number_of_particles         = 0
2292    DO  ip = nxl, nxr
2293       DO  jp = nys, nyn
2294          DO  kp = nzb+1, nzt
2295             number_of_particles = number_of_particles                         &
2296                                     + prt_count(kp,jp,ip)
2297          ENDDO
2298       ENDDO
2299    ENDDO
2300
2301    CALL check_open( 80 )
2302#if defined( __parallel )
2303    WRITE ( 80, 8000 )  current_timestep_number+1, simulated_time+dt_3d, &
2304                        number_of_particles, pleft, trlp_count_sum,      &
2305                        trlp_count_recv_sum, pright, trrp_count_sum,     &
2306                        trrp_count_recv_sum, psouth, trsp_count_sum,     &
2307                        trsp_count_recv_sum, pnorth, trnp_count_sum,     &
2308                        trnp_count_recv_sum
2309#else
2310    WRITE ( 80, 8000 )  current_timestep_number+1, simulated_time+dt_3d, &
2311                        number_of_particles
2312#endif
2313    CALL close_file( 80 )
2314
2315    IF ( number_of_particles > 0 )  THEN
2316        WRITE(9,*) 'number_of_particles ', number_of_particles,                &
2317                    current_timestep_number + 1, simulated_time + dt_3d
2318    ENDIF
2319
2320#if defined( __parallel )
2321    CALL MPI_ALLREDUCE( number_of_particles, tot_number_of_particles, 1,       &
2322                        MPI_INTEGER, MPI_SUM, comm2d, ierr )
2323#else
2324    tot_number_of_particles = number_of_particles
2325#endif
2326
2327    IF ( nested_run )  THEN
2328       CALL pmcp_g_print_number_of_particles( simulated_time+dt_3d,            &
2329                                              tot_number_of_particles)
2330    ENDIF
2331
2332!
2333!-- Formats
23348000 FORMAT (I6,1X,F7.2,4X,I10,5X,4(I3,1X,I4,'/',I4,2X),6X,I10)
2335
2336
2337 END SUBROUTINE lpm_write_exchange_statistics
2338 
2339
2340!------------------------------------------------------------------------------!
2341! Description:
2342! ------------
2343!> Write particle data in FORTRAN binary and/or netCDF format
2344!------------------------------------------------------------------------------!
2345 SUBROUTINE lpm_data_output_particles
2346 
2347    INTEGER(iwp) ::  ip !<
2348    INTEGER(iwp) ::  jp !<
2349    INTEGER(iwp) ::  kp !<
2350
2351    CALL cpu_log( log_point_s(40), 'lpm_data_output', 'start' )
2352
2353!
2354!-- Attention: change version number for unit 85 (in routine check_open)
2355!--            whenever the output format for this unit is changed!
2356    CALL check_open( 85 )
2357
2358    WRITE ( 85 )  simulated_time
2359    WRITE ( 85 )  prt_count
2360
2361    DO  ip = nxl, nxr
2362       DO  jp = nys, nyn
2363          DO  kp = nzb+1, nzt
2364             number_of_particles = prt_count(kp,jp,ip)
2365             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
2366             IF ( number_of_particles <= 0 )  CYCLE
2367             WRITE ( 85 )  particles
2368          ENDDO
2369       ENDDO
2370    ENDDO
2371
2372    CALL close_file( 85 )
2373
2374
2375#if defined( __netcdf )
2376! !
2377! !-- Output in netCDF format
2378!     CALL check_open( 108 )
2379!
2380! !
2381! !-- Update the NetCDF time axis
2382!     prt_time_count = prt_time_count + 1
2383!
2384!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_time_prt, &
2385!                             (/ simulated_time /),        &
2386!                             start = (/ prt_time_count /), count = (/ 1 /) )
2387!     CALL netcdf_handle_error( 'lpm_data_output_particles', 1 )
2388!
2389! !
2390! !-- Output the real number of particles used
2391!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_rnop_prt, &
2392!                             (/ number_of_particles /),   &
2393!                             start = (/ prt_time_count /), count = (/ 1 /) )
2394!     CALL netcdf_handle_error( 'lpm_data_output_particles', 2 )
2395!
2396! !
2397! !-- Output all particle attributes
2398!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(1), particles%age,      &
2399!                             start = (/ 1, prt_time_count /),               &
2400!                             count = (/ maximum_number_of_particles /) )
2401!     CALL netcdf_handle_error( 'lpm_data_output_particles', 3 )
2402!
2403!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(2), particles%user,     &
2404!                             start = (/ 1, prt_time_count /),               &
2405!                             count = (/ maximum_number_of_particles /) )
2406!     CALL netcdf_handle_error( 'lpm_data_output_particles', 4 )
2407!
2408!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(3), particles%origin_x, &
2409!                             start = (/ 1, prt_time_count /),               &
2410!                             count = (/ maximum_number_of_particles /) )
2411!     CALL netcdf_handle_error( 'lpm_data_output_particles', 5 )
2412!
2413!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(4), particles%origin_y, &
2414!                             start = (/ 1, prt_time_count /),               &
2415!                             count = (/ maximum_number_of_particles /) )
2416!     CALL netcdf_handle_error( 'lpm_data_output_particles', 6 )
2417!
2418!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(5), particles%origin_z, &
2419!                             start = (/ 1, prt_time_count /),               &
2420!                             count = (/ maximum_number_of_particles /) )
2421!     CALL netcdf_handle_error( 'lpm_data_output_particles', 7 )
2422!
2423!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(6), particles%radius,   &
2424!                             start = (/ 1, prt_time_count /),               &
2425!                             count = (/ maximum_number_of_particles /) )
2426!     CALL netcdf_handle_error( 'lpm_data_output_particles', 8 )
2427!
2428!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(7), particles%speed_x,  &
2429!                             start = (/ 1, prt_time_count /),               &
2430!                             count = (/ maximum_number_of_particles /) )
2431!     CALL netcdf_handle_error( 'lpm_data_output_particles', 9 )
2432!
2433!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(8), particles%speed_y,  &
2434!                             start = (/ 1, prt_time_count /),               &
2435!                             count = (/ maximum_number_of_particles /) )
2436!     CALL netcdf_handle_error( 'lpm_data_output_particles', 10 )
2437!
2438!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(9), particles%speed_z,  &
2439!                             start = (/ 1, prt_time_count /),               &
2440!                             count = (/ maximum_number_of_particles /) )
2441!     CALL netcdf_handle_error( 'lpm_data_output_particles', 11 )
2442!
2443!     nc_stat = NF90_PUT_VAR( id_set_prt,id_var_prt(10),                     &
2444!                             particles%weight_factor,                       &
2445!                             start = (/ 1, prt_time_count /),               &
2446!                             count = (/ maximum_number_of_particles /) )
2447!     CALL netcdf_handle_error( 'lpm_data_output_particles', 12 )
2448!
2449!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(11), particles%x,       &
2450!                             start = (/ 1, prt_time_count /),               &
2451!                             count = (/ maximum_number_of_particles /) )
2452!     CALL netcdf_handle_error( 'lpm_data_output_particles', 13 )
2453!
2454!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(12), particles%y,       &
2455!                             start = (/ 1, prt_time_count /),               &
2456!                             count = (/ maximum_number_of_particles /) )
2457!     CALL netcdf_handle_error( 'lpm_data_output_particles', 14 )
2458!
2459!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(13), particles%z,       &
2460!                             start = (/ 1, prt_time_count /),               &
2461!                             count = (/ maximum_number_of_particles /) )
2462!     CALL netcdf_handle_error( 'lpm_data_output_particles', 15 )
2463!
2464!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(14), particles%class,   &
2465!                             start = (/ 1, prt_time_count /),               &
2466!                             count = (/ maximum_number_of_particles /) )
2467!     CALL netcdf_handle_error( 'lpm_data_output_particles', 16 )
2468!
2469!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(15), particles%group,   &
2470!                             start = (/ 1, prt_time_count /),               &
2471!                             count = (/ maximum_number_of_particles /) )
2472!     CALL netcdf_handle_error( 'lpm_data_output_particles', 17 )
2473!
2474!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(16),                    &
2475!                             particles%id2,                                 &
2476!                             start = (/ 1, prt_time_count /),               &
2477!                             count = (/ maximum_number_of_particles /) )
2478!     CALL netcdf_handle_error( 'lpm_data_output_particles', 18 )
2479!
2480!     nc_stat = NF90_PUT_VAR( id_set_prt, id_var_prt(17), particles%id1,     &
2481!                             start = (/ 1, prt_time_count /),               &
2482!                             count = (/ maximum_number_of_particles /) )
2483!     CALL netcdf_handle_error( 'lpm_data_output_particles', 19 )
2484!
2485#endif
2486
2487    CALL cpu_log( log_point_s(40), 'lpm_data_output', 'stop' )
2488
2489 END SUBROUTINE lpm_data_output_particles
2490 
2491!------------------------------------------------------------------------------!
2492! Description:
2493! ------------
2494!> This routine calculates and provide particle timeseries output.
2495!------------------------------------------------------------------------------!
2496 SUBROUTINE lpm_data_output_ptseries
2497 
2498    INTEGER(iwp) ::  i    !<
2499    INTEGER(iwp) ::  inum !<
2500    INTEGER(iwp) ::  j    !<
2501    INTEGER(iwp) ::  jg   !<
2502    INTEGER(iwp) ::  k    !<
2503    INTEGER(iwp) ::  n    !<
2504
2505    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pts_value   !<
2506    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pts_value_l !<
2507
2508
2509    CALL cpu_log( log_point(36), 'data_output_ptseries', 'start' )
2510
2511    IF ( myid == 0 )  THEN
2512!
2513!--    Open file for time series output in NetCDF format
2514       dopts_time_count = dopts_time_count + 1
2515       CALL check_open( 109 )
2516#if defined( __netcdf )
2517!
2518!--    Update the particle time series time axis
2519       nc_stat = NF90_PUT_VAR( id_set_pts, id_var_time_pts,      &
2520                               (/ time_since_reference_point /), &
2521                               start = (/ dopts_time_count /), count = (/ 1 /) )
2522       CALL netcdf_handle_error( 'data_output_ptseries', 391 )
2523#endif
2524
2525    ENDIF
2526
2527    ALLOCATE( pts_value(0:number_of_particle_groups,dopts_num), &
2528              pts_value_l(0:number_of_particle_groups,dopts_num) )
2529
2530    pts_value_l = 0.0_wp
2531    pts_value_l(:,16) = 9999999.9_wp    ! for calculation of minimum radius
2532
2533!
2534!-- Calculate or collect the particle time series quantities for all particles
2535!-- and seperately for each particle group (if there is more than one group)
2536    DO  i = nxl, nxr
2537       DO  j = nys, nyn
2538          DO  k = nzb, nzt
2539             number_of_particles = prt_count(k,j,i)
2540             IF (number_of_particles <= 0)  CYCLE
2541             particles => grid_particles(k,j,i)%particles(1:number_of_particles)
2542             DO  n = 1, number_of_particles
2543
2544                IF ( particles(n)%particle_mask )  THEN  ! Restrict analysis to active particles
2545
2546                   pts_value_l(0,1)  = pts_value_l(0,1) + 1.0_wp  ! total # of particles
2547                   pts_value_l(0,2)  = pts_value_l(0,2) +                      &
2548                          ( particles(n)%x - particles(n)%origin_x )  ! mean x
2549                   pts_value_l(0,3)  = pts_value_l(0,3) +                      &
2550                          ( particles(n)%y - particles(n)%origin_y )  ! mean y
2551                   pts_value_l(0,4)  = pts_value_l(0,4) +                      &
2552                          ( particles(n)%z - particles(n)%origin_z )  ! mean z
2553                   pts_value_l(0,5)  = pts_value_l(0,5) + particles(n)%z        ! mean z (absolute)
2554                   pts_value_l(0,6)  = pts_value_l(0,6) + particles(n)%speed_x  ! mean u
2555                   pts_value_l(0,7)  = pts_value_l(0,7) + particles(n)%speed_y  ! mean v
2556                   pts_value_l(0,8)  = pts_value_l(0,8) + particles(n)%speed_z  ! mean w
2557                   pts_value_l(0,9)  = pts_value_l(0,9)  + particles(n)%rvar1 ! mean sgsu
2558                   pts_value_l(0,10) = pts_value_l(0,10) + particles(n)%rvar2 ! mean sgsv
2559                   pts_value_l(0,11) = pts_value_l(0,11) + particles(n)%rvar3 ! mean sgsw
2560                   IF ( particles(n)%speed_z > 0.0_wp )  THEN
2561                      pts_value_l(0,12) = pts_value_l(0,12) + 1.0_wp  ! # of upward moving prts
2562                      pts_value_l(0,13) = pts_value_l(0,13) +                  &
2563                                              particles(n)%speed_z ! mean w upw.
2564                   ELSE
2565                      pts_value_l(0,14) = pts_value_l(0,14) +                  &
2566                                              particles(n)%speed_z ! mean w down
2567                   ENDIF
2568                   pts_value_l(0,15) = pts_value_l(0,15) + particles(n)%radius ! mean rad
2569                   pts_value_l(0,16) = MIN( pts_value_l(0,16), particles(n)%radius ) ! minrad
2570                   pts_value_l(0,17) = MAX( pts_value_l(0,17), particles(n)%radius ) ! maxrad
2571                   pts_value_l(0,18) = pts_value_l(0,18) + 1.0_wp
2572                   pts_value_l(0,19) = pts_value_l(0,18) + 1.0_wp
2573!
2574!--                Repeat the same for the respective particle group
2575                   IF ( number_of_particle_groups > 1 )  THEN
2576                      jg = particles(n)%group
2577
2578                      pts_value_l(jg,1)  = pts_value_l(jg,1) + 1.0_wp
2579                      pts_value_l(jg,2)  = pts_value_l(jg,2) +                   &
2580                           ( particles(n)%x - particles(n)%origin_x )
2581                      pts_value_l(jg,3)  = pts_value_l(jg,3) +                   &
2582                           ( particles(n)%y - particles(n)%origin_y )
2583                      pts_value_l(jg,4)  = pts_value_l(jg,4) +                   &
2584                           ( particles(n)%z - particles(n)%origin_z )
2585                      pts_value_l(jg,5)  = pts_value_l(jg,5) + particles(n)%z
2586                      pts_value_l(jg,6)  = pts_value_l(jg,6) + particles(n)%speed_x
2587                      pts_value_l(jg,7)  = pts_value_l(jg,7) + particles(n)%speed_y
2588                      pts_value_l(jg,8)  = pts_value_l(jg,8) + particles(n)%speed_z
2589                      pts_value_l(jg,9)  = pts_value_l(jg,9)  + particles(n)%rvar1
2590                      pts_value_l(jg,10) = pts_value_l(jg,10) + particles(n)%rvar2
2591                      pts_value_l(jg,11) = pts_value_l(jg,11) + particles(n)%rvar3
2592                      IF ( particles(n)%speed_z > 0.0_wp )  THEN
2593                         pts_value_l(jg,12) = pts_value_l(jg,12) + 1.0_wp
2594                         pts_value_l(jg,13) = pts_value_l(jg,13) + particles(n)%speed_z
2595                      ELSE
2596                         pts_value_l(jg,14) = pts_value_l(jg,14) + particles(n)%speed_z
2597                      ENDIF
2598                      pts_value_l(jg,15) = pts_value_l(jg,15) + particles(n)%radius
2599                      pts_value_l(jg,16) = MIN( pts_value(jg,16), particles(n)%radius )
2600                      pts_value_l(jg,17) = MAX( pts_value(jg,17), particles(n)%radius )
2601                      pts_value_l(jg,18) = pts_value_l(jg,18) + 1.0_wp
2602                      pts_value_l(jg,19) = pts_value_l(jg,19) + 1.0_wp
2603                   ENDIF
2604
2605                ENDIF
2606
2607             ENDDO
2608
2609          ENDDO
2610       ENDDO
2611    ENDDO
2612
2613
2614#if defined( __parallel )
2615!
2616!-- Sum values of the subdomains
2617    inum = number_of_particle_groups + 1
2618
2619    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2620    CALL MPI_ALLREDUCE( pts_value_l(0,1), pts_value(0,1), 15*inum, MPI_REAL, &
2621                        MPI_SUM, comm2d, ierr )
2622    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2623    CALL MPI_ALLREDUCE( pts_value_l(0,16), pts_value(0,16), inum, MPI_REAL, &
2624                        MPI_MIN, comm2d, ierr )
2625    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2626    CALL MPI_ALLREDUCE( pts_value_l(0,17), pts_value(0,17), inum, MPI_REAL, &
2627                        MPI_MAX, comm2d, ierr )
2628    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2629    CALL MPI_ALLREDUCE( pts_value_l(0,18), pts_value(0,18), inum, MPI_REAL, &
2630                        MPI_MAX, comm2d, ierr )
2631    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2632    CALL MPI_ALLREDUCE( pts_value_l(0,19), pts_value(0,19), inum, MPI_REAL, &
2633                        MPI_MIN, comm2d, ierr )
2634#else
2635    pts_value(:,1:19) = pts_value_l(:,1:19)
2636#endif
2637
2638!
2639!-- Normalize the above calculated quantities (except min/max values) with the
2640!-- total number of particles
2641    IF ( number_of_particle_groups > 1 )  THEN
2642       inum = number_of_particle_groups
2643    ELSE
2644       inum = 0
2645    ENDIF
2646
2647    DO  j = 0, inum
2648
2649       IF ( pts_value(j,1) > 0.0_wp )  THEN
2650
2651          pts_value(j,2:15) = pts_value(j,2:15) / pts_value(j,1)
2652          IF ( pts_value(j,12) > 0.0_wp  .AND.  pts_value(j,12) < 1.0_wp )  THEN
2653             pts_value(j,13) = pts_value(j,13) / pts_value(j,12)
2654             pts_value(j,14) = pts_value(j,14) / ( 1.0_wp - pts_value(j,12) )
2655          ELSEIF ( pts_value(j,12) == 0.0_wp )  THEN
2656             pts_value(j,13) = -1.0_wp
2657          ELSE
2658             pts_value(j,14) = -1.0_wp
2659          ENDIF
2660
2661       ENDIF
2662
2663    ENDDO
2664
2665!
2666!-- Calculate higher order moments of particle time series quantities,
2667!-- seperately for each particle group (if there is more than one group)
2668    DO  i = nxl, nxr
2669       DO  j = nys, nyn
2670          DO  k = nzb, nzt
2671             number_of_particles = prt_count(k,j,i)
2672             IF (number_of_particles <= 0)  CYCLE
2673             particles => grid_particles(k,j,i)%particles(1:number_of_particles)
2674             DO  n = 1, number_of_particles
2675
2676                pts_value_l(0,20) = pts_value_l(0,20) + ( particles(n)%x - &
2677                                    particles(n)%origin_x - pts_value(0,2) )**2 ! x*2
2678                pts_value_l(0,21) = pts_value_l(0,21) + ( particles(n)%y - &
2679                                    particles(n)%origin_y - pts_value(0,3) )**2 ! y*2
2680                pts_value_l(0,22) = pts_value_l(0,22) + ( particles(n)%z - &
2681                                    particles(n)%origin_z - pts_value(0,4) )**2 ! z*2
2682                pts_value_l(0,23) = pts_value_l(0,23) + ( particles(n)%speed_x - &
2683                                                         pts_value(0,6) )**2   ! u*2
2684                pts_value_l(0,24) = pts_value_l(0,24) + ( particles(n)%speed_y - &
2685                                                          pts_value(0,7) )**2   ! v*2
2686                pts_value_l(0,25) = pts_value_l(0,25) + ( particles(n)%speed_z - &
2687                                                          pts_value(0,8) )**2   ! w*2
2688                pts_value_l(0,26) = pts_value_l(0,26) + ( particles(n)%rvar1 - &
2689                                                          pts_value(0,9) )**2   ! u"2
2690                pts_value_l(0,27) = pts_value_l(0,27) + ( particles(n)%rvar2 - &
2691                                                          pts_value(0,10) )**2  ! v"2
2692                pts_value_l(0,28) = pts_value_l(0,28) + ( particles(n)%rvar3 - &
2693                                                          pts_value(0,11) )**2  ! w"2
2694!
2695!--             Repeat the same for the respective particle group
2696                IF ( number_of_particle_groups > 1 )  THEN
2697                   jg = particles(n)%group
2698
2699                   pts_value_l(jg,20) = pts_value_l(jg,20) + ( particles(n)%x - &
2700                                       particles(n)%origin_x - pts_value(jg,2) )**2
2701                   pts_value_l(jg,21) = pts_value_l(jg,21) + ( particles(n)%y - &
2702                                       particles(n)%origin_y - pts_value(jg,3) )**2
2703                   pts_value_l(jg,22) = pts_value_l(jg,22) + ( particles(n)%z - &
2704                                       particles(n)%origin_z - pts_value(jg,4) )**2
2705                   pts_value_l(jg,23) = pts_value_l(jg,23) + ( particles(n)%speed_x - &
2706                                                             pts_value(jg,6) )**2
2707                   pts_value_l(jg,24) = pts_value_l(jg,24) + ( particles(n)%speed_y - &
2708                                                             pts_value(jg,7) )**2
2709                   pts_value_l(jg,25) = pts_value_l(jg,25) + ( particles(n)%speed_z - &
2710                                                             pts_value(jg,8) )**2
2711                   pts_value_l(jg,26) = pts_value_l(jg,26) + ( particles(n)%rvar1 - &
2712                                                             pts_value(jg,9) )**2
2713                   pts_value_l(jg,27) = pts_value_l(jg,27) + ( particles(n)%rvar2 - &
2714                                                             pts_value(jg,10) )**2
2715                   pts_value_l(jg,28) = pts_value_l(jg,28) + ( particles(n)%rvar3 - &
2716                                                             pts_value(jg,11) )**2
2717                ENDIF
2718
2719             ENDDO
2720          ENDDO
2721       ENDDO
2722    ENDDO
2723
2724    pts_value_l(0,29) = ( number_of_particles - pts_value(0,1) / numprocs )**2
2725                                                 ! variance of particle numbers
2726    IF ( number_of_particle_groups > 1 )  THEN
2727       DO  j = 1, number_of_particle_groups
2728          pts_value_l(j,29) = ( pts_value_l(j,1) - &
2729                                pts_value(j,1) / numprocs )**2
2730       ENDDO
2731    ENDIF
2732
2733#if defined( __parallel )
2734!
2735!-- Sum values of the subdomains
2736    inum = number_of_particle_groups + 1
2737
2738    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
2739    CALL MPI_ALLREDUCE( pts_value_l(0,20), pts_value(0,20), inum*10, MPI_REAL, &
2740                        MPI_SUM, comm2d, ierr )
2741#else
2742    pts_value(:,20:29) = pts_value_l(:,20:29)
2743#endif
2744
2745!
2746!-- Normalize the above calculated quantities with the total number of
2747!-- particles
2748    IF ( number_of_particle_groups > 1 )  THEN
2749       inum = number_of_particle_groups
2750    ELSE
2751       inum = 0
2752    ENDIF
2753
2754    DO  j = 0, inum
2755
2756       IF ( pts_value(j,1) > 0.0_wp )  THEN
2757          pts_value(j,20:28) = pts_value(j,20:28) / pts_value(j,1)
2758       ENDIF
2759       pts_value(j,29) = pts_value(j,29) / numprocs
2760
2761    ENDDO
2762
2763#if defined( __netcdf )
2764!
2765!-- Output particle time series quantities in NetCDF format
2766    IF ( myid == 0 )  THEN
2767       DO  j = 0, inum
2768          DO  i = 1, dopts_num
2769             nc_stat = NF90_PUT_VAR( id_set_pts, id_var_dopts(i,j),  &
2770                                     (/ pts_value(j,i) /),           &
2771                                     start = (/ dopts_time_count /), &
2772                                     count = (/ 1 /) )
2773             CALL netcdf_handle_error( 'data_output_ptseries', 392 )
2774          ENDDO
2775       ENDDO
2776    ENDIF
2777#endif
2778
2779    DEALLOCATE( pts_value, pts_value_l )
2780
2781    CALL cpu_log( log_point(36), 'data_output_ptseries', 'stop' )
2782
2783END SUBROUTINE lpm_data_output_ptseries
2784
2785 
2786!------------------------------------------------------------------------------!
2787! Description:
2788! ------------
2789!> This routine reads the respective restart data for the lpm.
2790!------------------------------------------------------------------------------!
2791 SUBROUTINE lpm_rrd_local_particles
2792
2793    CHARACTER (LEN=10) ::  particle_binary_version    !<
2794    CHARACTER (LEN=10) ::  version_on_file            !<
2795
2796    INTEGER(iwp) ::  alloc_size !<
2797    INTEGER(iwp) ::  ip         !<
2798    INTEGER(iwp) ::  jp         !<
2799    INTEGER(iwp) ::  kp         !<
2800
2801    TYPE(particle_type), DIMENSION(:), ALLOCATABLE ::  tmp_particles !<
2802
2803!
2804!-- Read particle data from previous model run.
2805!-- First open the input unit.
2806    IF ( myid_char == '' )  THEN
2807       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_IN'//myid_char,                  &
2808                  FORM='UNFORMATTED' )
2809    ELSE
2810       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_IN/'//myid_char,                 &
2811                  FORM='UNFORMATTED' )
2812    ENDIF
2813
2814!
2815!-- First compare the version numbers
2816    READ ( 90 )  version_on_file
2817    particle_binary_version = '4.0'
2818    IF ( TRIM( version_on_file ) /= TRIM( particle_binary_version ) )  THEN
2819       message_string = 'version mismatch concerning data from prior ' //      &
2820                        'run &version on file = "' //                          &
2821                                      TRIM( version_on_file ) //               &
2822                        '&version in program = "' //                           &
2823                                      TRIM( particle_binary_version ) // '"'
2824       CALL message( 'lpm_read_restart_file', 'PA0214', 1, 2, 0, 6, 0 )
2825    ENDIF
2826
2827!
2828!-- If less particles are stored on the restart file than prescribed by
2829!-- 1, the remainder is initialized by zero_particle to avoid
2830!-- errors.
2831    zero_particle = particle_type( 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2832                                   0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2833                                   0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2834                                   0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp,     &
2835                                   0, 0, 0_idp, .FALSE., -1 )
2836!
2837!-- Read some particle parameters and the size of the particle arrays,
2838!-- allocate them and read their contents.
2839    READ ( 90 )  bc_par_b, bc_par_lr, bc_par_ns, bc_par_t,                     &
2840                 last_particle_release_time, number_of_particle_groups,        &
2841                 particle_groups, time_write_particle_data
2842
2843    ALLOCATE( prt_count(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                        &
2844              grid_particles(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2845
2846    READ ( 90 )  prt_count
2847
2848    DO  ip = nxl, nxr
2849       DO  jp = nys, nyn
2850          DO  kp = nzb+1, nzt
2851
2852             number_of_particles = prt_count(kp,jp,ip)
2853             IF ( number_of_particles > 0 )  THEN
2854                alloc_size = MAX( INT( number_of_particles *                   &
2855                             ( 1.0_wp + alloc_factor / 100.0_wp ) ),           &
2856                             1 )
2857             ELSE
2858                alloc_size = 1
2859             ENDIF
2860
2861             ALLOCATE( grid_particles(kp,jp,ip)%particles(1:alloc_size) )
2862
2863             IF ( number_of_particles > 0 )  THEN
2864                ALLOCATE( tmp_particles(1:number_of_particles) )
2865                READ ( 90 )  tmp_particles
2866                grid_particles(kp,jp,ip)%particles(1:number_of_particles) = tmp_particles
2867                DEALLOCATE( tmp_particles )
2868                IF ( number_of_particles < alloc_size )  THEN
2869                   grid_particles(kp,jp,ip)%particles(number_of_particles+1:alloc_size) &
2870                      = zero_particle
2871                ENDIF
2872             ELSE
2873                grid_particles(kp,jp,ip)%particles(1:alloc_size) = zero_particle
2874             ENDIF
2875
2876          ENDDO
2877       ENDDO
2878    ENDDO
2879
2880    CLOSE ( 90 )
2881!
2882!-- Must be called to sort particles into blocks, which is needed for a fast
2883!-- interpolation of the LES fields on the particle position.
2884    CALL lpm_sort_and_delete
2885
2886
2887 END SUBROUTINE lpm_rrd_local_particles
2888 
2889 
2890 SUBROUTINE lpm_rrd_local( k, nxlf, nxlc, nxl_on_file, nxrf, nxrc,          &
2891                              nxr_on_file, nynf, nync, nyn_on_file, nysf,  &
2892                              nysc, nys_on_file, tmp_3d, found )
2893
2894
2895   USE control_parameters,                                                 &
2896       ONLY: length, restart_string
2897
2898    INTEGER(iwp) ::  k               !<
2899    INTEGER(iwp) ::  nxlc            !<
2900    INTEGER(iwp) ::  nxlf            !<
2901    INTEGER(iwp) ::  nxl_on_file     !<
2902    INTEGER(iwp) ::  nxrc            !<
2903    INTEGER(iwp) ::  nxrf            !<
2904    INTEGER(iwp) ::  nxr_on_file     !<
2905    INTEGER(iwp) ::  nync            !<
2906    INTEGER(iwp) ::  nynf            !<
2907    INTEGER(iwp) ::  nyn_on_file     !<
2908    INTEGER(iwp) ::  nysc            !<
2909    INTEGER(iwp) ::  nysf            !<
2910    INTEGER(iwp) ::  nys_on_file     !<
2911
2912    LOGICAL, INTENT(OUT)  ::  found
2913
2914    REAL(wp), DIMENSION(nzb:nzt+1,nys_on_file-nbgp:nyn_on_file+nbgp,nxl_on_file-nbgp:nxr_on_file+nbgp) ::  tmp_3d   !<
2915
2916
2917    found = .TRUE.
2918
2919    SELECT CASE ( restart_string(1:length) )
2920
2921       CASE ( 'iran' ) ! matching random numbers is still unresolved issue
2922          IF ( k == 1 )  READ ( 13 )  iran, iran_part
2923
2924        CASE ( 'pc_av' )
2925           IF ( .NOT. ALLOCATED( pc_av ) )  THEN
2926              ALLOCATE( pc_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2927           ENDIF
2928           IF ( k == 1 )  READ ( 13 )  tmp_3d
2929           pc_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =          &
2930              tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2931
2932        CASE ( 'pr_av' )
2933           IF ( .NOT. ALLOCATED( pr_av ) )  THEN
2934              ALLOCATE( pr_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2935           ENDIF
2936           IF ( k == 1 )  READ ( 13 )  tmp_3d
2937           pr_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =          &
2938              tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2939 
2940         CASE ( 'ql_c_av' )
2941            IF ( .NOT. ALLOCATED( ql_c_av ) )  THEN
2942               ALLOCATE( ql_c_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2943            ENDIF
2944            IF ( k == 1 )  READ ( 13 )  tmp_3d
2945            ql_c_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =        &
2946               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2947
2948         CASE ( 'ql_v_av' )
2949            IF ( .NOT. ALLOCATED( ql_v_av ) )  THEN
2950               ALLOCATE( ql_v_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2951            ENDIF
2952            IF ( k == 1 )  READ ( 13 )  tmp_3d
2953            ql_v_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =        &
2954               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2955
2956         CASE ( 'ql_vp_av' )
2957            IF ( .NOT. ALLOCATED( ql_vp_av ) )  THEN
2958               ALLOCATE( ql_vp_av(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2959            ENDIF
2960            IF ( k == 1 )  READ ( 13 )  tmp_3d
2961            ql_vp_av(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =       &
2962               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2963
2964          CASE DEFAULT
2965
2966             found = .FALSE.
2967
2968       END SELECT
2969               
2970
2971 END SUBROUTINE lpm_rrd_local
2972 
2973!------------------------------------------------------------------------------!
2974! Description:
2975! ------------
2976!> This routine writes the respective restart data for the lpm.
2977!------------------------------------------------------------------------------!
2978 SUBROUTINE lpm_wrd_local
2979 
2980    CHARACTER (LEN=10) ::  particle_binary_version   !<
2981
2982    INTEGER(iwp) ::  ip                              !<
2983    INTEGER(iwp) ::  jp                              !<
2984    INTEGER(iwp) ::  kp                              !<
2985!
2986!-- First open the output unit.
2987    IF ( myid_char == '' )  THEN
2988       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_OUT'//myid_char, &
2989                  FORM='UNFORMATTED')
2990    ELSE
2991       IF ( myid == 0 )  CALL local_system( 'mkdir PARTICLE_RESTART_DATA_OUT' )
2992#if defined( __parallel )
2993!
2994!--    Set a barrier in order to allow that thereafter all other processors
2995!--    in the directory created by PE0 can open their file
2996       CALL MPI_BARRIER( comm2d, ierr )
2997#endif
2998       OPEN ( 90, FILE='PARTICLE_RESTART_DATA_OUT/'//myid_char, &
2999                  FORM='UNFORMATTED' )
3000    ENDIF
3001
3002!
3003!-- Write the version number of the binary format.
3004!-- Attention: After changes to the following output commands the version
3005!-- ---------  number of the variable particle_binary_version must be
3006!--            changed! Also, the version number and the list of arrays
3007!--            to be read in lpm_read_restart_file must be adjusted
3008!--            accordingly.
3009    particle_binary_version = '4.0'
3010    WRITE ( 90 )  particle_binary_version
3011
3012!
3013!-- Write some particle parameters, the size of the particle arrays
3014    WRITE ( 90 )  bc_par_b, bc_par_lr, bc_par_ns, bc_par_t,                    &
3015                  last_particle_release_time, number_of_particle_groups,       &
3016                  particle_groups, time_write_particle_data
3017
3018    WRITE ( 90 )  prt_count
3019         
3020    DO  ip = nxl, nxr
3021       DO  jp = nys, nyn
3022          DO  kp = nzb+1, nzt
3023             number_of_particles = prt_count(kp,jp,ip)
3024             particles => grid_particles(kp,jp,ip)%particles(1:number_of_particles)
3025             IF ( number_of_particles <= 0 )  CYCLE
3026             WRITE ( 90 )  particles
3027          ENDDO
3028       ENDDO
3029    ENDDO
3030
3031    CLOSE ( 90 )
3032
3033#if defined( __parallel )
3034       CALL MPI_BARRIER( comm2d, ierr )
3035#endif
3036
3037    CALL wrd_write_string( 'iran' ) 
3038    WRITE ( 14 )  iran, iran_part
3039
3040
3041 END SUBROUTINE lpm_wrd_local
3042
3043
3044!------------------------------------------------------------------------------!
3045! Description:
3046! ------------
3047!> This routine writes the respective restart data for the lpm.
3048!------------------------------------------------------------------------------!
3049 SUBROUTINE lpm_wrd_global
3050 
3051    CALL wrd_write_string( 'curvature_solution_effects' ) 
3052    WRITE ( 14 )  curvature_solution_effects
3053
3054    CALL wrd_write_string( 'interpolation_simple_corrector' )
3055    WRITE ( 14 )  interpolation_simple_corrector
3056
3057    CALL wrd_write_string( 'interpolation_simple_predictor' )
3058    WRITE ( 14 )  interpolation_simple_predictor
3059
3060    CALL wrd_write_string( 'interpolation_trilinear' )
3061    WRITE ( 14 )  interpolation_trilinear
3062
3063 END SUBROUTINE lpm_wrd_global
3064 
3065
3066!------------------------------------------------------------------------------!
3067! Description:
3068! ------------
3069!> This routine writes the respective restart data for the lpm.
3070!------------------------------------------------------------------------------!
3071 SUBROUTINE lpm_rrd_global( found )
3072 
3073    USE control_parameters,                            &
3074        ONLY: length, restart_string
3075
3076    LOGICAL, INTENT(OUT)  ::  found
3077
3078    found = .TRUE.
3079
3080    SELECT CASE ( restart_string(1:length) )
3081
3082       CASE ( 'curvature_solution_effects' )
3083          READ ( 13 )  curvature_solution_effects
3084
3085       CASE ( 'interpolation_simple_corrector' )
3086          READ ( 13 )  interpolation_simple_corrector
3087
3088       CASE ( 'interpolation_simple_predictor' )
3089          READ ( 13 )  interpolation_simple_predictor
3090
3091       CASE ( 'interpolation_trilinear' )
3092          READ ( 13 )  interpolation_trilinear
3093
3094!          CASE ( 'global_paramter' )
3095!             READ ( 13 )  global_parameter
3096!          CASE ( 'global_array' )
3097!             IF ( .NOT. ALLOCATED( global_array ) )  ALLOCATE( global_array(1:10) )
3098!             READ ( 13 )  global_array
3099
3100       CASE DEFAULT
3101
3102          found = .FALSE.
3103
3104    END SELECT
3105   
3106 END SUBROUTINE lpm_rrd_global
3107
3108
3109!------------------------------------------------------------------------------!
3110! Description:
3111! ------------
3112!> This is a submodule of the lagrangian particle model. It contains all
3113!> dynamic processes of the lpm. This includes the advection (resolved and sub-
3114!> grid scale) as well as the boundary conditions of particles. As a next step
3115!> this submodule should be excluded as an own file.
3116!------------------------------------------------------------------------------!
3117 SUBROUTINE lpm_advec (ip,jp,kp)
3118
3119    LOGICAL ::  subbox_at_wall !< flag to see if the current subgridbox is adjacent to a wall
3120
3121    INTEGER(iwp) ::  i                           !< index variable along x
3122    INTEGER(iwp) ::  i_next                      !< index variable along x
3123    INTEGER(iwp) ::  ip                          !< index variable along x
3124    INTEGER(iwp) ::  iteration_steps = 1         !< amount of iterations steps for corrector step
3125    INTEGER(iwp) ::  j                           !< index variable along y
3126    INTEGER(iwp) ::  j_next                      !< index variable along y
3127    INTEGER(iwp) ::  jp                          !< index variable along y
3128    INTEGER(iwp) ::  k                           !< index variable along z
3129    INTEGER(iwp) ::  k_wall                      !< vertical index of topography top
3130    INTEGER(iwp) ::  kp                          !< index variable along z
3131    INTEGER(iwp) ::  k_next                      !< index variable along z
3132    INTEGER(iwp) ::  kw                          !< index variable along z
3133    INTEGER(iwp) ::  kkw                         !< index variable along z
3134    INTEGER(iwp) ::  n                           !< loop variable over all particles in a grid box
3135    INTEGER(iwp) ::  nb                          !< block number particles are sorted in
3136    INTEGER(iwp) ::  particle_end                !< end index for partilce loop
3137    INTEGER(iwp) ::  particle_start              !< start index for particle loop
3138    INTEGER(iwp) ::  surf_start                  !< Index on surface data-type for current grid box
3139    INTEGER(iwp) ::  subbox_end                  !< end index for loop over subboxes in particle advection
3140    INTEGER(iwp) ::  subbox_start                !< start index for loop over subboxes in particle advection
3141    INTEGER(iwp) ::  nn                          !< loop variable over iterations steps
3142
3143    INTEGER(iwp), DIMENSION(0:7) ::  start_index !< start particle index for current block
3144    INTEGER(iwp), DIMENSION(0:7) ::  end_index   !< start particle index for current block
3145
3146    REAL(wp) ::  aa                 !< dummy argument for horizontal particle interpolation
3147    REAL(wp) ::  alpha              !< interpolation facor for x-direction
3148
3149    REAL(wp) ::  bb                 !< dummy argument for horizontal particle interpolation
3150    REAL(wp) ::  beta               !< interpolation facor for y-direction
3151    REAL(wp) ::  cc                 !< dummy argument for horizontal particle interpolation
3152    REAL(wp) ::  d_z_p_z0           !< inverse of interpolation length for logarithmic interpolation
3153    REAL(wp) ::  dd                 !< dummy argument for horizontal particle interpolation
3154    REAL(wp) ::  de_dx_int_l        !< x/y-interpolated TKE gradient (x) at particle position at lower vertical level
3155    REAL(wp) ::  de_dx_int_u        !< x/y-interpolated TKE gradient (x) at particle position at upper vertical level
3156    REAL(wp) ::  de_dy_int_l        !< x/y-interpolated TKE gradient (y) at particle position at lower vertical level
3157    REAL(wp) ::  de_dy_int_u        !< x/y-interpolated TKE gradient (y) at particle position at upper vertical level
3158    REAL(wp) ::  de_dt              !< temporal derivative of TKE experienced by the particle
3159    REAL(wp) ::  de_dt_min          !< lower level for temporal TKE derivative
3160    REAL(wp) ::  de_dz_int_l        !< x/y-interpolated TKE gradient (z) at particle position at lower vertical level
3161    REAL(wp) ::  de_dz_int_u        !< x/y-interpolated TKE gradient (z) at particle position at upper vertical level
3162    REAL(wp) ::  diameter           !< diamter of droplet
3163    REAL(wp) ::  diss_int_l         !< x/y-interpolated dissipation at particle position at lower vertical level
3164    REAL(wp) ::  diss_int_u         !< x/y-interpolated dissipation at particle position at upper vertical level
3165    REAL(wp) ::  dt_particle_m      !< previous particle time step
3166    REAL(wp) ::  dz_temp            !< dummy for the vertical grid spacing
3167    REAL(wp) ::  e_int_l            !< x/y-interpolated TKE at particle position at lower vertical level
3168    REAL(wp) ::  e_int_u            !< x/y-interpolated TKE at particle position at upper vertical level
3169    REAL(wp) ::  e_mean_int         !< horizontal mean TKE at particle height
3170    REAL(wp) ::  exp_arg            !< argument in the exponent - particle radius
3171    REAL(wp) ::  exp_term           !< exponent term
3172    REAL(wp) ::  gamma              !< interpolation facor for z-direction
3173    REAL(wp) ::  gg                 !< dummy argument for horizontal particle interpolation
3174    REAL(wp) ::  height_p           !< dummy argument for logarithmic interpolation
3175    REAL(wp) ::  log_z_z0_int       !< logarithmus used for surface_layer interpolation
3176    REAL(wp) ::  random_gauss       !< Gaussian-distributed random number used for SGS particle advection
3177    REAL(wp) ::  RL                 !< Lagrangian autocorrelation coefficient
3178    REAL(wp) ::  rg1                !< Gaussian distributed random number
3179    REAL(wp) ::  rg2                !< Gaussian distributed random number
3180    REAL(wp) ::  rg3                !< Gaussian distributed random number
3181    REAL(wp) ::  sigma              !< velocity standard deviation
3182    REAL(wp) ::  u_int_l            !< x/y-interpolated u-component at particle position at lower vertical level
3183    REAL(wp) ::  u_int_u            !< x/y-interpolated u-component at particle position at upper vertical level
3184    REAL(wp) ::  unext              !< calculated particle u-velocity of corrector step
3185    REAL(wp) ::  us_int             !< friction velocity at particle grid box
3186    REAL(wp) ::  usws_int           !< surface momentum flux (u component) at particle grid box
3187    REAL(wp) ::  v_int_l            !< x/y-interpolated v-component at particle position at lower vertical level
3188    REAL(wp) ::  v_int_u            !< x/y-interpolated v-component at particle position at upper vertical level
3189    REAL(wp) ::  vsws_int           !< surface momentum flux (u component) at particle grid box
3190    REAL(wp) ::  vnext              !< calculated particle v-velocity of corrector step
3191    REAL(wp) ::  vv_int             !< dummy to compute interpolated mean SGS TKE, used to scale SGS advection
3192    REAL(wp) ::  w_int_l            !< x/y-interpolated w-component at particle position at lower vertical level
3193    REAL(wp) ::  w_int_u            !< x/y-interpolated w-component at particle position at upper vertical level
3194    REAL(wp) ::  wnext              !< calculated particle w-velocity of corrector step
3195    REAL(wp) ::  w_s                !< terminal velocity of droplets
3196    REAL(wp) ::  x                  !< dummy argument for horizontal particle interpolation
3197    REAL(wp) ::  xp                 !< calculated particle position in x of predictor step
3198    REAL(wp) ::  y                  !< dummy argument for horizontal particle interpolation
3199    REAL(wp) ::  yp                 !< calculated particle position in y of predictor step
3200    REAL(wp) ::  z_p                !< surface layer height (0.5 dz)
3201    REAL(wp) ::  zp                 !< calculated particle position in z of predictor step
3202
3203    REAL(wp), PARAMETER ::  a_rog = 9.65_wp      !< parameter for fall velocity
3204    REAL(wp), PARAMETER ::  b_rog = 10.43_wp     !< parameter for fall velocity
3205    REAL(wp), PARAMETER ::  c_rog = 0.6_wp       !< parameter for fall velocity
3206    REAL(wp), PARAMETER ::  k_cap_rog = 4.0_wp   !< parameter for fall velocity
3207    REAL(wp), PARAMETER ::  k_low_rog = 12.0_wp  !< parameter for fall velocity
3208    REAL(wp), PARAMETER ::  d0_rog = 0.745_wp    !< separation diameter
3209
3210    REAL(wp), DIMENSION(number_of_particles) ::  term_1_2       !< flag to communicate whether a particle is near topography or not
3211    REAL(wp), DIMENSION(number_of_particles) ::  dens_ratio     !< ratio between the density of the fluid and the density of the particles
3212    REAL(wp), DIMENSION(number_of_particles) ::  de_dx_int      !< horizontal TKE gradient along x at particle position
3213    REAL(wp), DIMENSION(number_of_particles) ::  de_dy_int      !< horizontal TKE gradient along y at particle position
3214    REAL(wp), DIMENSION(number_of_particles) ::  de_dz_int      !< horizontal TKE gradient along z at particle position
3215    REAL(wp), DIMENSION(number_of_particles) ::  diss_int       !< dissipation at particle position
3216    REAL(wp), DIMENSION(number_of_particles) ::  dt_gap         !< remaining time until particle time integration reaches LES time
3217    REAL(wp), DIMENSION(number_of_particles) ::  dt_particle    !< particle time step
3218    REAL(wp), DIMENSION(number_of_particles) ::  e_int          !< TKE at particle position
3219    REAL(wp), DIMENSION(number_of_particles) ::  fs_int         !< weighting factor for subgrid-scale particle speed
3220    REAL(wp), DIMENSION(number_of_particles) ::  lagr_timescale !< Lagrangian timescale
3221    REAL(wp), DIMENSION(number_of_particles) ::  rvar1_temp     !< SGS particle velocity - u-component
3222    REAL(wp), DIMENSION(number_of_particles) ::  rvar2_temp     !< SGS particle velocity - v-component
3223    REAL(wp), DIMENSION(number_of_particles) ::  rvar3_temp     !< SGS particle velocity - w-component
3224    REAL(wp), DIMENSION(number_of_particles) ::  u_int          !< u-component of particle speed
3225    REAL(wp), DIMENSION(number_of_particles) ::  v_int          !< v-component of particle speed
3226    REAL(wp), DIMENSION(number_of_particles) ::  w_int          !< w-component of particle speed
3227    REAL(wp), DIMENSION(number_of_particles) ::  xv             !< x-position
3228    REAL(wp), DIMENSION(number_of_particles) ::  yv             !< y-position
3229    REAL(wp), DIMENSION(number_of_particles) ::  zv             !< z-position
3230
3231    REAL(wp), DIMENSION(number_of_particles, 3) ::  rg !< vector of Gaussian distributed random numbers
3232
3233    CALL cpu_log( log_point_s(44), 'lpm_advec', 'continue' )
3234!
3235!-- Determine height of Prandtl layer and distance between Prandtl-layer
3236!-- height and horizontal mean roughness height, which are required for
3237!-- vertical logarithmic interpolation of horizontal particle speeds
3238!-- (for particles below first vertical grid level).
3239    z_p      = zu(nzb+1) - zw(nzb)
3240    d_z_p_z0 = 1.0_wp / ( z_p - z0_av_global )
3241
3242    xv = particles(1:number_of_particles)%x
3243    yv = particles(1:number_of_particles)%y
3244    zv = particles(1:number_of_particles)%z
3245    dt_particle = dt_3d
3246
3247!
3248!-- This case uses a simple interpolation method for the particle velocites,
3249!-- and applying a predictor-corrector method. @attention: for the corrector
3250!-- step the velocities of t(n+1) are required. However, at this moment of
3251!-- the time integration they are not free of divergence. This interpolation
3252!-- method is described in more detail in Grabowski et al., 2018 (GMD).
3253    IF ( interpolation_simple_corrector )  THEN
3254!
3255!--    Predictor step
3256       kkw = kp - 1
3257       DO  n = 1, number_of_particles
3258
3259          alpha = MAX( MIN( ( particles(n)%x - ip * dx ) * ddx, 1.0_wp ), 0.0_wp )
3260          u_int(n) = u(kp,jp,ip) * ( 1.0_wp - alpha ) + u(kp,jp,ip+1) * alpha
3261
3262          beta  = MAX( MIN( ( particles(n)%y - jp * dy ) * ddy, 1.0_wp ), 0.0_wp )
3263          v_int(n) = v(kp,jp,ip) * ( 1.0_wp - beta ) + v(kp,jp+1,ip) * beta
3264
3265          gamma = MAX( MIN( ( particles(n)%z - zw(kkw) ) /                   &
3266                            ( zw(kkw+1) - zw(kkw) ), 1.0_wp ), 0.0_wp )
3267          w_int(n) = w(kkw,jp,ip) * ( 1.0_wp - gamma ) + w(kkw+1,jp,ip) * gamma
3268
3269       ENDDO
3270!
3271!--    Corrector step
3272       DO  n = 1, number_of_particles
3273
3274          IF ( .NOT. particles(n)%particle_mask )  CYCLE
3275
3276          DO  nn = 1, iteration_steps
3277
3278!
3279!--          Guess new position
3280             xp = particles(n)%x + u_int(n) * dt_particle(n)
3281             yp = particles(n)%y + v_int(n) * dt_particle(n)
3282             zp = particles(n)%z + w_int(n) * dt_particle(n)
3283!
3284!--          x direction
3285             i_next = FLOOR( xp * ddx , KIND=iwp)
3286             alpha  = MAX( MIN( ( xp - i_next * dx ) * ddx, 1.0_wp ), 0.0_wp )
3287!
3288!--          y direction
3289             j_next = FLOOR( yp * ddy )
3290             beta   = MAX( MIN( ( yp - j_next * dy ) * ddy, 1.0_wp ), 0.0_wp )
3291!
3292!--          z_direction
3293             k_next = MAX( MIN( FLOOR( zp / (zw(kkw+1)-zw(kkw)) ), nzt ), 0)
3294             gamma = MAX( MIN( ( zp - zw(k_next) ) /                      &
3295                               ( zw(k_next+1) - zw(k_next) ), 1.0_wp ), 0.0_wp )
3296!
3297!--          Calculate part of the corrector step
3298             unext = u_p(k_next+1, j_next, i_next) * ( 1.0_wp - alpha ) +    &
3299                     u_p(k_next+1, j_next,   i_next+1) * alpha
3300
3301             vnext = v_p(k_next+1, j_next, i_next) * ( 1.0_wp - beta  ) +    &
3302                     v_p(k_next+1, j_next+1, i_next  ) * beta
3303
3304             wnext = w_p(k_next,   j_next, i_next) * ( 1.0_wp - gamma ) +    &
3305                     w_p(k_next+1, j_next, i_next  ) * gamma
3306
3307!
3308!--          Calculate interpolated particle velocity with predictor
3309!--          corrector step. u_int, v_int and w_int describes the part of
3310!--          the predictor step. unext, vnext and wnext is the part of the
3311!--          corrector step. The resulting new position is set below. The
3312!--          implementation is based on Grabowski et al., 2018 (GMD).
3313             u_int(n) = 0.5_wp * ( u_int(n) + unext )
3314             v_int(n) = 0.5_wp * ( v_int(n) + vnext )
3315             w_int(n) = 0.5_wp * ( w_int(n) + wnext )
3316
3317          ENDDO
3318       ENDDO
3319!
3320!-- This case uses a simple interpolation method for the particle velocites,
3321!-- and applying a predictor.
3322    ELSEIF ( interpolation_simple_predictor )  THEN
3323!
3324!--    The particle position for the w velociy is based on the value of kp and kp-1
3325       kkw = kp - 1
3326       DO  n = 1, number_of_particles
3327          IF ( .NOT. particles(n)%particle_mask )  CYCLE
3328
3329          alpha    = MAX( MIN( ( particles(n)%x - ip * dx ) * ddx, 1.0_wp ), 0.0_wp )
3330          u_int(n) = u(kp,jp,ip) * ( 1.0_wp - alpha ) + u(kp,jp,ip+1) * alpha
3331
3332          beta     = MAX( MIN( ( particles(n)%y - jp * dy ) * ddy, 1.0_wp ), 0.0_wp )
3333          v_int(n) = v(kp,jp,ip) * ( 1.0_wp - beta ) + v(kp,jp+1,ip) * beta
3334
3335          gamma    = MAX( MIN( ( particles(n)%z - zw(kkw) ) /                   &
3336                               ( zw(kkw+1) - zw(kkw) ), 1.0_wp ), 0.0_wp )
3337          w_int(n) = w(kkw,jp,ip) * ( 1.0_wp - gamma ) + w(kkw+1,jp,ip) * gamma
3338       ENDDO
3339!
3340!-- The trilinear interpolation.
3341    ELSEIF ( interpolation_trilinear )  THEN
3342
3343       start_index = grid_particles(kp,jp,ip)%start_index
3344       end_index   = grid_particles(kp,jp,ip)%end_index
3345
3346       DO  nb = 0, 7
3347!
3348!--       Interpolate u velocity-component
3349          i = ip
3350          j = jp + block_offset(nb)%j_off
3351          k = kp + block_offset(nb)%k_off
3352
3353          DO  n = start_index(nb), end_index(nb)
3354!
3355!--          Interpolation of the u velocity component onto particle position.
3356!--          Particles are interpolation bi-linearly in the horizontal and a
3357!--          linearly in the vertical. An exception is made for particles below
3358!--          the first vertical grid level in case of a prandtl layer. In this
3359!--          case the horizontal particle velocity components are determined using
3360!--          Monin-Obukhov relations (if branch).
3361!--          First, check if particle is located below first vertical grid level
3362!--          above topography (Prandtl-layer height)
3363!--          Determine vertical index of topography top
3364             k_wall = topo_top_ind(jp,ip,0)
3365
3366             IF ( constant_flux_layer  .AND.  zv(n) - zw(k_wall) < z_p )  THEN
3367!
3368!--             Resolved-scale horizontal particle velocity is zero below z0.
3369                IF ( zv(n) - zw(k_wall) < z0_av_global )  THEN
3370                   u_int(n) = 0.0_wp
3371                ELSE
3372!
3373!--                Determine the sublayer. Further used as index.
3374                   height_p = ( zv(n) - zw(k_wall) - z0_av_global ) &
3375                                        * REAL( number_of_sublayers, KIND=wp )    &
3376                                        * d_z_p_z0
3377!
3378!--                Calculate LOG(z/z0) for exact particle height. Therefore,
3379!--                interpolate linearly between precalculated logarithm.
3380                   log_z_z0_int = log_z_z0(INT(height_p))                         &
3381                                    + ( height_p - INT(height_p) )                &
3382                                    * ( log_z_z0(INT(height_p)+1)                 &
3383                                         - log_z_z0(INT(height_p))                &
3384                                      )
3385!
3386!--                Get friction velocity and momentum flux from new surface data
3387!--                types.
3388                   IF ( surf_def_h(0)%start_index(jp,ip) <=                   &
3389                        surf_def_h(0)%end_index(jp,ip) )  THEN
3390                      surf_start = surf_def_h(0)%start_index(jp,ip)
3391!--                   Limit friction velocity. In narrow canyons or holes the
3392!--                   friction velocity can become very small, resulting in a too
3393!--                   large particle speed.
3394                      us_int    = MAX( surf_def_h(0)%us(surf_start), 0.01_wp )
3395                      usws_int  = surf_def_h(0)%usws(surf_start)
3396                   ELSEIF ( surf_lsm_h%start_index(jp,ip) <=                  &
3397                            surf_lsm_h%end_index(jp,ip) )  THEN
3398                      surf_start = surf_lsm_h%start_index(jp,ip)
3399                      us_int    = MAX( surf_lsm_h%us(surf_start), 0.01_wp )
3400                      usws_int  = surf_lsm_h%usws(surf_start)
3401                   ELSEIF ( surf_usm_h%start_index(jp,ip) <=                  &
3402                            surf_usm_h%end_index(jp,ip) )  THEN
3403                      surf_start = surf_usm_h%start_index(jp,ip)
3404                      us_int    = MAX( surf_usm_h%us(surf_start), 0.01_wp )
3405                      usws_int  = surf_usm_h%usws(surf_start)
3406                   ENDIF
3407!
3408!--                Neutral solution is applied for all situations, e.g. also for
3409!--                unstable and stable situations. Even though this is not exact
3410!--                this saves a lot of CPU time since several calls of intrinsic
3411!--                FORTRAN procedures (LOG, ATAN) are avoided, This is justified
3412!--                as sensitivity studies revealed no significant effect of
3413!--                using the neutral solution also for un/stable situations.
3414                   u_int(n) = -usws_int / ( us_int * kappa + 1E-10_wp )           &
3415                               * log_z_z0_int - u_gtrans
3416                ENDIF
3417!
3418!--          Particle above the first grid level. Bi-linear interpolation in the
3419!--          horizontal and linear interpolation in the vertical direction.
3420             ELSE
3421                = xv(n) - i * dx
3422                y  = yv(n) + ( 0.5_wp - j ) * dy
3423                aa = x**2          + y**2
3424                bb = ( dx - x )**2 + y**2
3425                cc = x**2          + ( dy - y )**2
3426                dd = ( dx - x )**2 + ( dy - y )**2
3427                gg = aa + bb + cc + dd
3428
3429                u_int_l = ( ( gg - aa ) * u(k,j,i)   + ( gg - bb ) * u(k,j,i+1)   &
3430                            + ( gg - cc ) * u(k,j+1,i) + ( gg - dd ) *            &
3431                            u(k,j+1,i+1) ) / ( 3.0_wp * gg ) - u_gtrans
3432
3433                IF ( k == nzt )  THEN
3434                   u_int(n) = u_int_l
3435                ELSE
3436                   u_int_u = ( ( gg-aa ) * u(k+1,j,i) + ( gg-bb ) * u(k+1,j,i+1)  &
3437                               + ( gg-cc ) * u(k+1,j+1,i) + ( gg-dd ) *           &
3438                               u(k+1,j+1,i+1) ) / ( 3.0_wp * gg ) - u_gtrans
3439                   u_int(n) = u_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *            &
3440                              ( u_int_u - u_int_l )
3441                ENDIF
3442             ENDIF
3443          ENDDO
3444!
3445!--       Same procedure for interpolation of the v velocity-component
3446          i = ip + block_offset(nb)%i_off
3447          j = jp
3448          k = kp + block_offset(nb)%k_off
3449
3450          DO  n = start_index(nb), end_index(nb)
3451!
3452!--          Determine vertical index of topography top
3453             k_wall = topo_top_ind(jp,ip,0)
3454
3455             IF ( constant_flux_layer  .AND.  zv(n) - zw(k_wall) < z_p )  THEN
3456                IF ( zv(n) - zw(k_wall) < z0_av_global )  THEN
3457!
3458!--                Resolved-scale horizontal particle velocity is zero below z0.
3459                   v_int(n) = 0.0_wp
3460                ELSE
3461!
3462!--                Determine the sublayer. Further used as index. Please note,
3463!--                logarithmus can not be reused from above, as in in case of
3464!--                topography particle on u-grid can be above surface-layer height,
3465!--                whereas it can be below on v-grid.
3466                   height_p = ( zv(n) - zw(k_wall) - z0_av_global ) &
3467                                     * REAL( number_of_sublayers, KIND=wp )       &
3468                                     * d_z_p_z0
3469!
3470!--                Calculate LOG(z/z0) for exact particle height. Therefore,
3471!--                interpolate linearly between precalculated logarithm.
3472                   log_z_z0_int = log_z_z0(INT(height_p))                         &
3473                                    + ( height_p - INT(height_p) )                &
3474                                    * ( log_z_z0(INT(height_p)+1)                 &
3475                                         - log_z_z0(INT(height_p))                &
3476                                      )
3477!
3478!--                Get friction velocity and momentum flux from new surface data
3479!--                types.
3480                   IF ( surf_def_h(0)%start_index(jp,ip) <=                   &
3481                        surf_def_h(0)%end_index(jp,ip) )  THEN
3482                      surf_start = surf_def_h(0)%start_index(jp,ip)
3483!--                   Limit friction velocity. In narrow canyons or holes the
3484!--                   friction velocity can become very small, resulting in a too
3485!--                   large particle speed.
3486                      us_int    = MAX( surf_def_h(0)%us(surf_start), 0.01_wp )
3487                      vsws_int  = surf_def_h(0)%vsws(surf_start)
3488                   ELSEIF ( surf_lsm_h%start_index(jp,ip) <=                  &
3489                            surf_lsm_h%end_index(jp,ip) )  THEN
3490                      surf_start = surf_lsm_h%start_index(jp,ip)
3491                      us_int    = MAX( surf_lsm_h%us(surf_start), 0.01_wp )
3492                      vsws_int  = surf_lsm_h%vsws(surf_start)
3493                   ELSEIF ( surf_usm_h%start_index(jp,ip) <=                  &
3494                            surf_usm_h%end_index(jp,ip) )  THEN
3495                      surf_start = surf_usm_h%start_index(jp,ip)
3496                      us_int    = MAX( surf_usm_h%us(surf_start), 0.01_wp )
3497                      vsws_int  = surf_usm_h%vsws(surf_start)
3498                   ENDIF
3499!
3500!--                Neutral solution is applied for all situations, e.g. also for
3501!--                unstable and stable situations. Even though this is not exact
3502!--                this saves a lot of CPU time since several calls of intrinsic
3503!--                FORTRAN procedures (LOG, ATAN) are avoided, This is justified
3504!--                as sensitivity studies revealed no significant effect of
3505!--                using the neutral solution also for un/stable situations.
3506                   v_int(n) = -vsws_int / ( us_int * kappa + 1E-10_wp )           &
3507                            * log_z_z0_int - v_gtrans
3508
3509                ENDIF
3510             ELSE
3511                = xv(n) + ( 0.5_wp - i ) * dx
3512                y  = yv(n) - j * dy
3513                aa = x**2          + y**2
3514                bb = ( dx - x )**2 + y**2
3515                cc = x**2          + ( dy - y )**2
3516                dd = ( dx - x )**2 + ( dy - y )**2
3517                gg = aa + bb + cc + dd
3518
3519                v_int_l = ( ( gg - aa ) * v(k,j,i)   + ( gg - bb ) * v(k,j,i+1)   &
3520                          + ( gg - cc ) * v(k,j+1,i) + ( gg - dd ) * v(k,j+1,i+1) &
3521                          ) / ( 3.0_wp * gg ) - v_gtrans
3522
3523                IF ( k == nzt )  THEN
3524                   v_int(n) = v_int_l
3525                ELSE
3526                   v_int_u = ( ( gg-aa ) * v(k+1,j,i)   + ( gg-bb ) * v(k+1,j,i+1)   &
3527                             + ( gg-cc ) * v(k+1,j+1,i) + ( gg-dd ) * v(k+1,j+1,i+1) &
3528                             ) / ( 3.0_wp * gg ) - v_gtrans
3529                   v_int(n) = v_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *               &
3530                                     ( v_int_u - v_int_l )
3531                ENDIF
3532             ENDIF
3533          ENDDO
3534!
3535!--       Same procedure for interpolation of the w velocity-component
3536          i = ip + block_offset(nb)%i_off
3537          j = jp + block_offset(nb)%j_off
3538          k = kp - 1
3539
3540          DO  n = start_index(nb), end_index(nb)
3541             IF ( vertical_particle_advection(particles(n)%group) )  THEN
3542                = xv(n) + ( 0.5_wp - i ) * dx
3543                y  = yv(n) + ( 0.5_wp - j ) * dy
3544                aa = x**2          + y**2
3545                bb = ( dx - x )**2 + y**2
3546                cc = x**2          + ( dy - y )**2
3547                dd = ( dx - x )**2 + ( dy - y )**2
3548                gg = aa + bb + cc + dd
3549
3550                w_int_l = ( ( gg - aa ) * w(k,j,i)   + ( gg - bb ) * w(k,j,i+1)   &
3551                          + ( gg - cc ) * w(k,j+1,i) + ( gg - dd ) * w(k,j+1,i+1) &
3552                          ) / ( 3.0_wp * gg )
3553
3554                IF ( k == nzt )  THEN
3555                   w_int(n) = w_int_l
3556                ELSE
3557                   w_int_u = ( ( gg-aa ) * w(k+1,j,i)   + &
3558                               ( gg-bb ) * w(k+1,j,i+1) + &
3559                               ( gg-cc ) * w(k+1,j+1,i) + &
3560                               ( gg-dd ) * w(k+1,j+1,i+1) &
3561                             ) / ( 3.0_wp * gg )
3562                   w_int(n) = w_int_l + ( zv(n) - zw(k) ) / dzw(k+1) *               &
3563                              ( w_int_u - w_int_l )
3564                ENDIF
3565             ELSE
3566                w_int(n) = 0.0_wp
3567             ENDIF
3568          ENDDO
3569       ENDDO
3570    ENDIF
3571
3572!-- Interpolate and calculate quantities needed for calculating the SGS
3573!-- velocities
3574    IF ( use_sgs_for_particles  .AND.  .NOT. cloud_droplets )  THEN
3575
3576       DO  nb = 0,7
3577
3578          subbox_at_wall = .FALSE.
3579!
3580!--       In case of topography check if subbox is adjacent to a wall
3581          IF ( .NOT. topography == 'flat' )  THEN
3582             i = ip + MERGE( -1_iwp , 1_iwp, BTEST( nb, 2 ) )
3583             j = jp + MERGE( -1_iwp , 1_iwp, BTEST( nb, 1 ) )
3584             k = kp + MERGE( -1_iwp , 1_iwp, BTEST( nb, 0 ) )
3585             IF ( .NOT. BTEST(wall_flags_0(k,  jp, ip), 0) .OR.                &
3586                  .NOT. BTEST(wall_flags_0(kp, j,  ip), 0) .OR.                &
3587                  .NOT. BTEST(wall_flags_0(kp, jp, i ), 0) )                   &
3588             THEN
3589                subbox_at_wall = .TRUE.
3590             ENDIF
3591          ENDIF
3592          IF ( subbox_at_wall )  THEN
3593             e_int(start_index(nb):end_index(nb))     = e(kp,jp,ip) 
3594             diss_int(start_index(nb):end_index(nb))  = diss(kp,jp,ip)
3595             de_dx_int(start_index(nb):end_index(nb)) = de_dx(kp,jp,ip)
3596             de_dy_int(start_index(nb):end_index(nb)) = de_dy(kp,jp,ip)
3597             de_dz_int(start_index(nb):end_index(nb)) = de_dz(kp,jp,ip)
3598!
3599!--          Set flag for stochastic equation.
3600             term_1_2(start_index(nb):end_index(nb)) = 0.0_wp
3601          ELSE
3602             i = ip + block_offset(nb)%i_off
3603             j = jp + block_offset(nb)%j_off
3604             k = kp + block_offset(nb)%k_off
3605
3606             DO  n = start_index(nb), end_index(nb)
3607!
3608!--             Interpolate TKE
3609                x  = xv(n) + ( 0.5_wp - i ) * dx
3610                y  = yv(n) + ( 0.5_wp - j ) * dy
3611                aa = x**2          + y**2
3612                bb = ( dx - x )**2 + y**2
3613                cc = x**2          + ( dy - y )**2
3614                dd = ( dx - x )**2 + ( dy - y )**2
3615                gg = aa + bb + cc + dd
3616
3617                e_int_l = ( ( gg-aa ) * e(k,j,i)   + ( gg-bb ) * e(k,j,i+1)   &
3618                          + ( gg-cc ) * e(k,j+1,i) + ( gg-dd ) * e(k,j+1,i+1) &
3619                          ) / ( 3.0_wp * gg )
3620
3621                IF ( k+1 == nzt+1 )  THEN
3622                   e_int(n) = e_int_l
3623                ELSE
3624                   e_int_u = ( ( gg - aa ) * e(k+1,j,i)   + &
3625                               ( gg - bb ) * e(k+1,j,i+1) + &
3626                               ( gg - cc ) * e(k+1,j+1,i) + &
3627                               ( gg - dd ) * e(k+1,j+1,i+1) &
3628                            ) / ( 3.0_wp * gg )
3629                   e_int(n) = e_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *            &
3630                                     ( e_int_u - e_int_l )
3631                ENDIF
3632!
3633!--             Needed to avoid NaN particle velocities (this might not be
3634!--             required any more)
3635                IF ( e_int(n) <= 0.0_wp )  THEN
3636                   e_int(n) = 1.0E-20_wp
3637                ENDIF
3638!
3639!--             Interpolate the TKE gradient along x (adopt incides i,j,k and
3640!--             all position variables from above (TKE))
3641                de_dx_int_l = ( ( gg - aa ) * de_dx(k,j,i)   + &
3642                                ( gg - bb ) * de_dx(k,j,i+1) + &
3643                                ( gg - cc ) * de_dx(k,j+1,i) + &
3644                                ( gg - dd ) * de_dx(k,j+1,i+1) &
3645                               ) / ( 3.0_wp * gg )
3646
3647                IF ( ( k+1 == nzt+1 )  .OR.  ( k == nzb ) )  THEN
3648                   de_dx_int(n) = de_dx_int_l
3649                ELSE
3650                   de_dx_int_u = ( ( gg - aa ) * de_dx(k+1,j,i)   + &
3651                                   ( gg - bb ) * de_dx(k+1,j,i+1) + &
3652                                   ( gg - cc ) * de_dx(k+1,j+1,i) + &
3653                                   ( gg - dd ) * de_dx(k+1,j+1,i+1) &
3654                                  ) / ( 3.0_wp * gg )
3655                   de_dx_int(n) = de_dx_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *    &
3656                                              ( de_dx_int_u - de_dx_int_l )
3657                ENDIF
3658!
3659!--             Interpolate the TKE gradient along y
3660                de_dy_int_l = ( ( gg - aa ) * de_dy(k,j,i)   + &
3661                                ( gg - bb ) * de_dy(k,j,i+1) + &
3662                                ( gg - cc ) * de_dy(k,j+1,i) + &
3663                                ( gg - dd ) * de_dy(k,j+1,i+1) &
3664                               ) / ( 3.0_wp * gg )
3665                IF ( ( k+1 == nzt+1 )  .OR.  ( k == nzb ) )  THEN
3666                   de_dy_int(n) = de_dy_int_l
3667                ELSE
3668                   de_dy_int_u = ( ( gg - aa ) * de_dy(k+1,j,i)   + &
3669                                   ( gg - bb ) * de_dy(k+1,j,i+1) + &
3670                                   ( gg - cc ) * de_dy(k+1,j+1,i) + &
3671                                   ( gg - dd ) * de_dy(k+1,j+1,i+1) &
3672                                  ) / ( 3.0_wp * gg )
3673                      de_dy_int(n) = de_dy_int_l + ( zv(n) - zu(k) ) / dzw(k+1) * &
3674                                                 ( de_dy_int_u - de_dy_int_l )
3675                ENDIF
3676
3677!
3678!--             Interpolate the TKE gradient along z
3679                IF ( zv(n) < 0.5_wp * dz(1) )  THEN
3680                   de_dz_int(n) = 0.0_wp
3681                ELSE
3682                   de_dz_int_l = ( ( gg - aa ) * de_dz(k,j,i)   + &
3683                                   ( gg - bb ) * de_dz(k,j,i+1) + &
3684                                   ( gg - cc ) * de_dz(k,j+1,i) + &
3685                                   ( gg - dd ) * de_dz(k,j+1,i+1) &
3686                                  ) / ( 3.0_wp * gg )
3687
3688                   IF ( ( k+1 == nzt+1 )  .OR.  ( k == nzb ) )  THEN
3689                      de_dz_int(n) = de_dz_int_l
3690                   ELSE
3691                      de_dz_int_u = ( ( gg - aa ) * de_dz(k+1,j,i)   + &
3692                                      ( gg - bb ) * de_dz(k+1,j,i+1) + &
3693                                      ( gg - cc ) * de_dz(k+1,j+1,i) + &
3694                                      ( gg - dd ) * de_dz(k+1,j+1,i+1) &
3695                                     ) / ( 3.0_wp * gg )
3696                      de_dz_int(n) = de_dz_int_l + ( zv(n) - zu(k) ) / dzw(k+1) * &
3697                                                 ( de_dz_int_u - de_dz_int_l )
3698                   ENDIF
3699                ENDIF
3700
3701!
3702!--             Interpolate the dissipation of TKE
3703                diss_int_l = ( ( gg - aa ) * diss(k,j,i)   + &
3704                               ( gg - bb ) * diss(k,j,i+1) + &
3705                               ( gg - cc ) * diss(k,j+1,i) + &
3706                               ( gg - dd ) * diss(k,j+1,i+1) &
3707                               ) / ( 3.0_wp * gg )
3708
3709                IF ( k == nzt )  THEN
3710                   diss_int(n) = diss_int_l
3711                ELSE
3712                   diss_int_u = ( ( gg - aa ) * diss(k+1,j,i)   + &
3713                                  ( gg - bb ) * diss(k+1,j,i+1) + &
3714                                  ( gg - cc ) * diss(k+1,j+1,i) + &
3715                                  ( gg - dd ) * diss(k+1,j+1,i+1) &
3716                                 ) / ( 3.0_wp * gg )
3717                   diss_int(n) = diss_int_l + ( zv(n) - zu(k) ) / dzw(k+1) *      &
3718                                            ( diss_int_u - diss_int_l )
3719                ENDIF
3720
3721!
3722!--             Set flag for stochastic equation.
3723                term_1_2(n) = 1.0_wp
3724             ENDDO
3725          ENDIF
3726       ENDDO
3727
3728       DO  nb = 0,7
3729          i = ip + block_offset(nb)%i_off
3730          j = jp + block_offset(nb)%j_off
3731          k = kp + block_offset(nb)%k_off
3732
3733          DO  n = start_index(nb), end_index(nb)
3734!
3735!--          Vertical interpolation of the horizontally averaged SGS TKE and
3736!--          resolved-scale velocity variances and use the interpolated values
3737!--          to calculate the coefficient fs, which is a measure of the ratio
3738!--          of the subgrid-scale turbulent kinetic energy to the total amount
3739!--          of turbulent kinetic energy.
3740             IF ( k == 0 )  THEN
3741                e_mean_int = hom(0,1,8,0)
3742             ELSE
3743                e_mean_int = hom(k,1,8,0) +                                    &
3744                                           ( hom(k+1,1,8,0) - hom(k,1,8,0) ) / &
3745                                           ( zu(k+1) - zu(k) ) *               &
3746                                           ( zv(n) - zu(k) )
3747             ENDIF
3748
3749             kw = kp - 1
3750
3751             IF ( k == 0 )  THEN
3752                aa  = hom(k+1,1,30,0)  * ( zv(n) / &
3753                                         ( 0.5_wp * ( zu(k+1) - zu(k) ) ) )
3754                bb  = hom(k+1,1,31,0)  * ( zv(n) / &
3755                                         ( 0.5_wp * ( zu(k+1) - zu(k) ) ) )
3756                cc  = hom(kw+1,1,32,0) * ( zv(n) / &
3757                                         ( 1.0_wp * ( zw(kw+1) - zw(kw) ) ) )
3758             ELSE
3759                aa  = hom(k,1,30,0) + ( hom(k+1,1,30,0) - hom(k,1,30,0) ) *    &
3760                           ( ( zv(n) - zu(k) ) / ( zu(k+1) - zu(k) ) )
3761                bb  = hom(k,1,31,0) + ( hom(k+1,1,31,0) - hom(k,1,31,0) ) *    &
3762                           ( ( zv(n) - zu(k) ) / ( zu(k+1) - zu(k) ) )
3763                cc  = hom(kw,1,32,0) + ( hom(kw+1,1,32,0)-hom(kw,1,32,0) ) *   &
3764                           ( ( zv(n) - zw(kw) ) / ( zw(kw+1)-zw(kw) ) )
3765             ENDIF
3766
3767             vv_int = ( 1.0_wp / 3.0_wp ) * ( aa + bb + cc )
3768!
3769!--          Needed to avoid NaN particle velocities. The value of 1.0 is just
3770!--          an educated guess for the given case.
3771             IF ( vv_int + ( 2.0_wp / 3.0_wp ) * e_mean_int == 0.0_wp )  THEN
3772                fs_int(n) = 1.0_wp
3773             ELSE
3774                fs_int(n) = ( 2.0_wp / 3.0_wp ) * e_mean_int /                 &
3775                            ( vv_int + ( 2.0_wp / 3.0_wp ) * e_mean_int )
3776             ENDIF
3777
3778          ENDDO
3779       ENDDO
3780
3781       DO  nb = 0, 7
3782          DO  n = start_index(nb), end_index(nb)
3783             rg(n,1) = random_gauss( iran_part, 5.0_wp )
3784             rg(n,2) = random_gauss( iran_part, 5.0_wp )
3785             rg(n,3) = random_gauss( iran_part, 5.0_wp )
3786          ENDDO
3787       ENDDO
3788
3789       DO  nb = 0, 7
3790          DO  n = start_index(nb), end_index(nb)
3791
3792!
3793!--          Calculate the Lagrangian timescale according to Weil et al. (2004).
3794             lagr_timescale(n) = ( 4.0_wp * e_int(n) + 1E-20_wp ) / &
3795                              ( 3.0_wp * fs_int(n) * c_0 * diss_int(n) + 1E-20_wp )
3796
3797!
3798!--          Calculate the next particle timestep. dt_gap is the time needed to
3799!--          complete the current LES timestep.
3800             dt_gap(n) = dt_3d - particles(n)%dt_sum
3801             dt_particle(n) = MIN( dt_3d, 0.025_wp * lagr_timescale(n), dt_gap(n) )
3802             particles(n)%aux1 = lagr_timescale(n)
3803             particles(n)%aux2 = dt_gap(n)
3804!
3805!--          The particle timestep should not be too small in order to prevent
3806!--          the number of particle timesteps of getting too large
3807             IF ( dt_particle(n) < dt_min_part )  THEN
3808                IF ( dt_min_part < dt_gap(n) )  THEN
3809                   dt_particle(n) = dt_min_part
3810                ELSE
3811                   dt_particle(n) = dt_gap(n)
3812                ENDIF
3813             ENDIF
3814             rvar1_temp(n) = particles(n)%rvar1
3815             rvar2_temp(n) = particles(n)%rvar2
3816             rvar3_temp(n) = particles(n)%rvar3
3817!
3818!--          Calculate the SGS velocity components
3819             IF ( particles(n)%age == 0.0_wp )  THEN
3820!
3821!--             For new particles the SGS components are derived from the SGS
3822!--             TKE. Limit the Gaussian random number to the interval
3823!--             [-5.0*sigma, 5.0*sigma] in order to prevent the SGS velocities
3824!--             from becoming unrealistically large.
3825                rvar1_temp(n) = SQRT( 2.0_wp * sgs_wf_part * e_int(n)          &
3826                                          + 1E-20_wp ) * ( rg(n,1) - 1.0_wp )
3827                rvar2_temp(n) = SQRT( 2.0_wp * sgs_wf_part * e_int(n)          &
3828                                          + 1E-20_wp ) * ( rg(n,2) - 1.0_wp )
3829                rvar3_temp(n) = SQRT( 2.0_wp * sgs_wf_part * e_int(n)          &
3830                                          + 1E-20_wp ) * ( rg(n,3) - 1.0_wp )
3831
3832             ELSE
3833!
3834!--             Restriction of the size of the new timestep: compared to the
3835!--             previous timestep the increase must not exceed 200%. First,
3836!--             check if age > age_m, in order to prevent that particles get zero
3837!--             timestep.
3838                dt_particle_m = MERGE( dt_particle(n),                         &
3839                                       particles(n)%age - particles(n)%age_m,  &
3840                                       particles(n)%age - particles(n)%age_m < &
3841                                       1E-8_wp )
3842                IF ( dt_particle(n) > 2.0_wp * dt_particle_m )  THEN
3843                   dt_particle(n) = 2.0_wp * dt_particle_m
3844                ENDIF
3845
3846!--             For old particles the SGS components are correlated with the
3847!--             values from the previous timestep. Random numbers have also to
3848!--             be limited (see above).
3849!--             As negative values for the subgrid TKE are not allowed, the
3850!--             change of the subgrid TKE with time cannot be smaller than
3851!--             -e_int(n)/dt_particle. This value is used as a lower boundary
3852!--             value for the change of TKE
3853                de_dt_min = - e_int(n) / dt_particle(n)
3854
3855                de_dt = ( e_int(n) - particles(n)%e_m ) / dt_particle_m
3856
3857                IF ( de_dt < de_dt_min )  THEN
3858                   de_dt = de_dt_min
3859                ENDIF
3860
3861                CALL weil_stochastic_eq( rvar1_temp(n), fs_int(n), e_int(n),    &
3862                                        de_dx_int(n), de_dt, diss_int(n),       &
3863                                        dt_particle(n), rg(n,1), term_1_2(n) )
3864
3865                CALL weil_stochastic_eq( rvar2_temp(n), fs_int(n), e_int(n),    &
3866                                        de_dy_int(n), de_dt, diss_int(n),       &
3867                                        dt_particle(n), rg(n,2), term_1_2(n) )
3868
3869                CALL weil_stochastic_eq( rvar3_temp(n), fs_int(n), e_int(n),    &
3870                                        de_dz_int(n), de_dt, diss_int(n),       &
3871                                        dt_particle(n), rg(n,3), term_1_2(n) )
3872
3873             ENDIF
3874
3875          ENDDO
3876       ENDDO
3877!
3878!--    Check if the added SGS velocities result in a violation of the CFL-
3879!--    criterion. If yes choose a smaller timestep based on the new velocities
3880!--    and calculate SGS velocities again
3881       dz_temp = zw(kp)-zw(kp-1)
3882
3883       DO  nb = 0, 7
3884          DO  n = start_index(nb), end_index(nb)
3885             IF ( .NOT. particles(n)%age == 0.0_wp .AND.                       &
3886                (ABS( u_int(n) + rvar1_temp(n) ) > (dx/dt_particle(n))  .OR.   &
3887                 ABS( v_int(n) + rvar2_temp(n) ) > (dy/dt_particle(n))  .OR.   &
3888                 ABS( w_int(n) + rvar3_temp(n) ) > (dz_temp/dt_particle(n))))  THEN
3889
3890                dt_particle(n) = 0.9_wp * MIN(                                 &
3891                                 ( dx / ABS( u_int(n) + rvar1_temp(n) ) ),     &
3892                                 ( dy / ABS( v_int(n) + rvar2_temp(n) ) ),     &
3893                                 ( dz_temp / ABS( w_int(n) + rvar3_temp(n) ) ) )
3894
3895!
3896!--             Reset temporary SGS velocites to "current" ones
3897                rvar1_temp(n) = particles(n)%rvar1
3898                rvar2_temp(n) = particles(n)%rvar2
3899                rvar3_temp(n) = particles(n)%rvar3
3900
3901                de_dt_min = - e_int(n) / dt_particle(n)
3902
3903                de_dt = ( e_int(n) - particles(n)%e_m ) / dt_particle_m
3904
3905                IF ( de_dt < de_dt_min )  THEN
3906                   de_dt = de_dt_min
3907                ENDIF
3908
3909                CALL weil_stochastic_eq( rvar1_temp(n), fs_int(n), e_int(n),    &
3910                                        de_dx_int(n), de_dt, diss_int(n),       &
3911                                        dt_particle(n), rg(n,1), term_1_2(n) )
3912
3913                CALL weil_stochastic_eq( rvar2_temp(n), fs_int(n), e_int(n),    &
3914                                        de_dy_int(n), de_dt, diss_int(n),       &
3915                                        dt_particle(n), rg(n,2), term_1_2(n) )
3916
3917                CALL weil_stochastic_eq( rvar3_temp(n), fs_int(n), e_int(n),    &
3918                                        de_dz_int(n), de_dt, diss_int(n),       &
3919                                        dt_particle(n), rg(n,3), term_1_2(n) )
3920             ENDIF
3921
3922!
3923!--          Update particle velocites
3924             particles(n)%rvar1 = rvar1_temp(n)
3925             particles(n)%rvar2 = rvar2_temp(n)
3926             particles(n)%rvar3 = rvar3_temp(n)
3927             u_int(n) = u_int(n) + particles(n)%rvar1
3928             v_int(n) = v_int(n) + particles(n)%rvar2
3929             w_int(n) = w_int(n) + particles(n)%rvar3
3930!
3931!--          Store the SGS TKE of the current timelevel which is needed for
3932!--          for calculating the SGS particle velocities at the next timestep
3933             particles(n)%e_m = e_int(n)
3934          ENDDO
3935       ENDDO
3936
3937    ELSE
3938!
3939!--    If no SGS velocities are used, only the particle timestep has to
3940!--    be set
3941       dt_particle = dt_3d
3942
3943    ENDIF
3944
3945    dens_ratio = particle_groups(particles(1:number_of_particles)%group)%density_ratio
3946    IF ( ANY( dens_ratio == 0.0_wp ) )  THEN
3947!
3948!--    Decide whether the particle loop runs over the subboxes or only over 1,
3949!--    number_of_particles. This depends on the selected interpolation method.
3950!--    If particle interpolation method is not trilinear, then the sorting within
3951!--    subboxes is not required. However, therefore the index start_index(nb) and
3952!--    end_index(nb) are not defined and the loops are still over
3953!--    number_of_particles. @todo find a more generic way to write this loop or
3954!--    delete trilinear interpolation
3955       IF ( interpolation_trilinear )  THEN
3956          subbox_start = 0
3957          subbox_end   = 7
3958       ELSE
3959          subbox_start = 1
3960          subbox_end   = 1
3961       ENDIF
3962!
3963!--    loop over subboxes. In case of simple interpolation scheme no subboxes
3964!--    are introduced, as they are not required. Accordingly, this loops goes
3965!--    from 1 to 1.
3966       DO  nb = subbox_start, subbox_end
3967          IF ( interpolation_trilinear )  THEN
3968             particle_start = start_index(nb)
3969             particle_end   = end_index(nb)
3970          ELSE
3971             particle_start = 1
3972             particle_end   = number_of_particles
3973          ENDIF
3974!
3975!--         Loop from particle start to particle end
3976            DO  n = particle_start, particle_end
3977
3978!
3979!--          Particle advection
3980             IF ( dens_ratio(n) == 0.0_wp )  THEN
3981!
3982!--             Pure passive transport (without particle inertia)
3983                particles(n)%x = xv(n) + u_int(n) * dt_particle(n)
3984                particles(n)%y = yv(n) + v_int(n) * dt_particle(n)
3985                particles(n)%z = zv(n) + w_int(n) * dt_particle(n)
3986
3987                particles(n)%speed_x = u_int(n)
3988                particles(n)%speed_y = v_int(n)
3989                particles(n)%speed_z = w_int(n)
3990
3991             ELSE
3992!
3993!--             Transport of particles with inertia
3994                particles(n)%x = particles(n)%x + particles(n)%speed_x * &
3995                                                  dt_particle(n)
3996                particles(n)%y = particles(n)%y + particles(n)%speed_y * &
3997                                                  dt_particle(n)
3998                particles(n)%z = particles(n)%z + particles(n)%speed_z * &
3999                                                  dt_particle(n)
4000
4001!
4002!--             Update of the particle velocity
4003                IF ( cloud_droplets )  THEN
4004!
4005!--                Terminal velocity is computed for vertical direction (Rogers et
4006!--                al., 1993, J. Appl. Meteorol.)
4007                   diameter = particles(n)%radius * 2000.0_wp !diameter in mm
4008                   IF ( diameter <= d0_rog )  THEN
4009                      w_s = k_cap_rog * diameter * ( 1.0_wp - EXP( -k_low_rog * diameter ) )
4010                   ELSE
4011                      w_s = a_rog - b_rog * EXP( -c_rog * diameter )
4012                   ENDIF
4013
4014!
4015!--                If selected, add random velocities following Soelch and Kaercher
4016!--                (2010, Q. J. R. Meteorol. Soc.)
4017                   IF ( use_sgs_for_particles )  THEN
4018                      lagr_timescale(n) = km(kp,jp,ip) / MAX( e(kp,jp,ip), 1.0E-20_wp )
4019                      RL             = EXP( -1.0_wp * dt_3d / MAX( lagr_timescale(n), &
4020                                             1.0E-20_wp ) )
4021                      sigma          = SQRT( e(kp,jp,ip) )
4022
4023                      rg1 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4024                      rg2 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4025                      rg3 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4026
4027                      particles(n)%rvar1 = RL * particles(n)%rvar1 +              &
4028                                           SQRT( 1.0_wp - RL**2 ) * sigma * rg1
4029                      particles(n)%rvar2 = RL * particles(n)%rvar2 +              &
4030                                           SQRT( 1.0_wp - RL**2 ) * sigma * rg2
4031                      particles(n)%rvar3 = RL * particles(n)%rvar3 +              &
4032                                           SQRT( 1.0_wp - RL**2 ) * sigma * rg3
4033
4034                      particles(n)%speed_x = u_int(n) + particles(n)%rvar1
4035                      particles(n)%speed_y = v_int(n) + particles(n)%rvar2
4036                      particles(n)%speed_z = w_int(n) + particles(n)%rvar3 - w_s
4037                   ELSE
4038                      particles(n)%speed_x = u_int(n)
4039                      particles(n)%speed_y = v_int(n)
4040                      particles(n)%speed_z = w_int(n) - w_s
4041                   ENDIF
4042
4043                ELSE
4044
4045                   IF ( use_sgs_for_particles )  THEN
4046                      exp_arg  = particle_groups(particles(n)%group)%exp_arg
4047                      exp_term = EXP( -exp_arg * dt_particle(n) )
4048                   ELSE
4049                      exp_arg  = particle_groups(particles(n)%group)%exp_arg
4050                      exp_term = particle_groups(particles(n)%group)%exp_term
4051                   ENDIF
4052                   particles(n)%speed_x = particles(n)%speed_x * exp_term +         &
4053                                          u_int(n) * ( 1.0_wp - exp_term )
4054                   particles(n)%speed_y = particles(n)%speed_y * exp_term +         &
4055                                          v_int(n) * ( 1.0_wp - exp_term )
4056                   particles(n)%speed_z = particles(n)%speed_z * exp_term +         &
4057                                          ( w_int(n) - ( 1.0_wp - dens_ratio(n) ) * &
4058                                          g / exp_arg ) * ( 1.0_wp - exp_term )
4059                ENDIF
4060
4061             ENDIF
4062          ENDDO
4063       ENDDO
4064
4065    ELSE
4066!
4067!--    Decide whether the particle loop runs over the subboxes or only over 1,
4068!--    number_of_particles. This depends on the selected interpolation method.
4069       IF ( interpolation_trilinear )  THEN
4070          subbox_start = 0
4071          subbox_end   = 7
4072       ELSE
4073          subbox_start = 1
4074          subbox_end   = 1
4075       ENDIF
4076!--    loop over subboxes. In case of simple interpolation scheme no subboxes
4077!--    are introduced, as they are not required. Accordingly, this loops goes
4078!--    from 1 to 1.
4079       DO  nb = subbox_start, subbox_end
4080          IF ( interpolation_trilinear )  THEN
4081             particle_start = start_index(nb)
4082             particle_end   = end_index(nb)
4083          ELSE
4084             particle_start = 1
4085             particle_end   = number_of_particles
4086          ENDIF
4087!
4088!--         Loop from particle start to particle end
4089            DO  n = particle_start, particle_end
4090
4091!
4092!--          Transport of particles with inertia
4093             particles(n)%x = xv(n) + particles(n)%speed_x * dt_particle(n)
4094             particles(n)%y = yv(n) + particles(n)%speed_y * dt_particle(n)
4095             particles(n)%z = zv(n) + particles(n)%speed_z * dt_particle(n)
4096!
4097!--          Update of the particle velocity
4098             IF ( cloud_droplets )  THEN
4099!
4100!--             Terminal velocity is computed for vertical direction (Rogers et al.,
4101!--             1993, J. Appl. Meteorol.)
4102                diameter = particles(n)%radius * 2000.0_wp !diameter in mm
4103                IF ( diameter <= d0_rog )  THEN
4104                   w_s = k_cap_rog * diameter * ( 1.0_wp - EXP( -k_low_rog * diameter ) )
4105                ELSE
4106                   w_s = a_rog - b_rog * EXP( -c_rog * diameter )
4107                ENDIF
4108
4109!
4110!--             If selected, add random velocities following Soelch and Kaercher
4111!--             (2010, Q. J. R. Meteorol. Soc.)
4112                IF ( use_sgs_for_particles )  THEN
4113                    lagr_timescale(n) = km(kp,jp,ip) / MAX( e(kp,jp,ip), 1.0E-20_wp )
4114                     RL             = EXP( -1.0_wp * dt_3d / MAX( lagr_timescale(n), &
4115                                             1.0E-20_wp ) )
4116                    sigma          = SQRT( e(kp,jp,ip) )
4117
4118                    rg1 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4119                    rg2 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4120                    rg3 = random_gauss( iran_part, 5.0_wp ) - 1.0_wp
4121
4122                    particles(n)%rvar1 = RL * particles(n)%rvar1 +                &
4123                                         SQRT( 1.0_wp - RL**2 ) * sigma * rg1
4124                    particles(n)%rvar2 = RL * particles(n)%rvar2 +                &
4125                                         SQRT( 1.0_wp - RL**2 ) * sigma * rg2
4126                    particles(n)%rvar3 = RL * particles(n)%rvar3 +                &
4127                                         SQRT( 1.0_wp - RL**2 ) * sigma * rg3
4128
4129                    particles(n)%speed_x = u_int(n) + particles(n)%rvar1
4130                    particles(n)%speed_y = v_int(n) + particles(n)%rvar2
4131                    particles(n)%speed_z = w_int(n) + particles(n)%rvar3 - w_s
4132                ELSE
4133                    particles(n)%speed_x = u_int(n)
4134                    particles(n)%speed_y = v_int(n)
4135                    particles(n)%speed_z = w_int(n) - w_s
4136                ENDIF
4137
4138             ELSE
4139
4140                IF ( use_sgs_for_particles )  THEN
4141                   exp_arg  = particle_groups(particles(n)%group)%exp_arg
4142                   exp_term = EXP( -exp_arg * dt_particle(n) )
4143                ELSE
4144                   exp_arg  = particle_groups(particles(n)%group)%exp_arg
4145                   exp_term = particle_groups(particles(n)%group)%exp_term
4146                ENDIF
4147                particles(n)%speed_x = particles(n)%speed_x * exp_term +             &
4148                                       u_int(n) * ( 1.0_wp - exp_term )
4149                particles(n)%speed_y = particles(n)%speed_y * exp_term +             &
4150                                       v_int(n) * ( 1.0_wp - exp_term )
4151                particles(n)%speed_z = particles(n)%speed_z * exp_term +             &
4152                                       ( w_int(n) - ( 1.0_wp - dens_ratio(n) ) * g / &
4153                                       exp_arg ) * ( 1.0_wp - exp_term )
4154             ENDIF
4155          ENDDO
4156       ENDDO
4157
4158    ENDIF
4159
4160!
4161!-- Store the old age of the particle ( needed to prevent that a
4162!-- particle crosses several PEs during one timestep, and for the
4163!-- evaluation of the subgrid particle velocity fluctuations )
4164    particles(1:number_of_particles)%age_m = particles(1:number_of_particles)%age
4165
4166!
4167!--    loop over subboxes. In case of simple interpolation scheme no subboxes
4168!--    are introduced, as they are not required. Accordingly, this loops goes
4169!--    from 1 to 1.
4170!
4171!-- Decide whether the particle loop runs over the subboxes or only over 1,
4172!-- number_of_particles. This depends on the selected interpolation method.
4173    IF ( interpolation_trilinear )  THEN
4174       subbox_start = 0
4175       subbox_end   = 7
4176    ELSE
4177       subbox_start = 1
4178       subbox_end   = 1
4179    ENDIF
4180    DO  nb = subbox_start, subbox_end
4181       IF ( interpolation_trilinear )  THEN
4182          particle_start = start_index(nb)
4183          particle_end   = end_index(nb)
4184       ELSE
4185          particle_start = 1
4186          particle_end   = number_of_particles
4187       ENDIF
4188!
4189!--    Loop from particle start to particle end
4190       DO  n = particle_start, particle_end
4191!
4192!--       Increment the particle age and the total time that the particle
4193!--       has advanced within the particle timestep procedure
4194          particles(n)%age    = particles(n)%age    + dt_particle(n)
4195          particles(n)%dt_sum = particles(n)%dt_sum + dt_particle(n)
4196
4197!
4198!--       Check whether there is still a particle that has not yet completed
4199!--       the total LES timestep
4200          IF ( ( dt_3d - particles(n)%dt_sum ) > 1E-8_wp )  THEN
4201             dt_3d_reached_l = .FALSE.
4202          ENDIF
4203
4204       ENDDO
4205    ENDDO
4206
4207    CALL cpu_log( log_point_s(44), 'lpm_advec', 'pause' )
4208
4209
4210 END SUBROUTINE lpm_advec
4211
4212 
4213!------------------------------------------------------------------------------! 
4214! Description:
4215! ------------
4216!> Calculation of subgrid-scale particle speed using the stochastic model
4217!> of Weil et al. (2004, JAS, 61, 2877-2887).
4218!------------------------------------------------------------------------------!
4219 SUBROUTINE weil_stochastic_eq( v_sgs, fs_n, e_n, dedxi_n, dedt_n, diss_n,     &
4220                                dt_n, rg_n, fac )
4221
4222    REAL(wp) ::  a1      !< dummy argument
4223    REAL(wp) ::  dedt_n  !< time derivative of TKE at particle position
4224    REAL(wp) ::  dedxi_n !< horizontal derivative of TKE at particle position
4225    REAL(wp) ::  diss_n  !< dissipation at particle position
4226    REAL(wp) ::  dt_n    !< particle timestep
4227    REAL(wp) ::  e_n     !< TKE at particle position
4228    REAL(wp) ::  fac     !< flag to identify adjacent topography
4229    REAL(wp) ::  fs_n    !< weighting factor to prevent that subgrid-scale particle speed becomes too large
4230    REAL(wp) ::  rg_n    !< random number
4231    REAL(wp) ::  term1   !< memory term
4232    REAL(wp) ::  term2   !< drift correction term
4233    REAL(wp) ::  term3   !< random term
4234    REAL(wp) ::  v_sgs   !< subgrid-scale velocity component
4235
4236!-- At first, limit TKE to a small non-zero number, in order to prevent
4237!-- the occurrence of extremely large SGS-velocities in case TKE is zero,
4238!-- (could occur at the simulation begin).
4239    e_n = MAX( e_n, 1E-20_wp )
4240!
4241!-- Please note, terms 1 and 2 (drift and memory term, respectively) are
4242!-- multiplied by a flag to switch of both terms near topography.
4243!-- This is necessary, as both terms may cause a subgrid-scale velocity build up
4244!-- if particles are trapped in regions with very small TKE, e.g. in narrow street
4245!-- canyons resolved by only a few grid points. Hence, term 1 and term 2 are
4246!-- disabled if one of the adjacent grid points belongs to topography.
4247!-- Moreover, in this case, the  previous subgrid-scale component is also set
4248!-- to zero.
4249
4250    a1 = fs_n * c_0 * diss_n
4251!
4252!-- Memory term
4253    term1 = - a1 * v_sgs * dt_n / ( 4.0_wp * sgs_wf_part * e_n + 1E-20_wp )    &
4254                 * fac
4255!
4256!-- Drift correction term
4257    term2 = ( ( dedt_n * v_sgs / e_n ) + dedxi_n ) * 0.5_wp * dt_n              &
4258                 * fac
4259!
4260!-- Random term
4261    term3 = SQRT( MAX( a1, 1E-20_wp ) ) * ( rg_n - 1.0_wp ) * SQRT( dt_n )
4262!
4263!-- In cese one of the adjacent grid-boxes belongs to topograhy, the previous
4264!-- subgrid-scale velocity component is set to zero, in order to prevent a
4265!-- velocity build-up.
4266!-- This case, set also previous subgrid-scale component to zero.
4267    v_sgs = v_sgs * fac + term1 + term2 + term3
4268
4269 END SUBROUTINE weil_stochastic_eq
4270 
4271 
4272!------------------------------------------------------------------------------! 
4273! Description:
4274! ------------
4275!> Boundary conditions for the Lagrangian particles.
4276!> The routine consists of two different parts. One handles the bottom (flat)
4277!> and top boundary. In this part, also particles which exceeded their lifetime
4278!> are deleted.
4279!> The other part handles the reflection of particles from vertical walls.
4280!> This part was developed by Jin Zhang during 2006-2007.
4281!>
4282!> To do: Code structure for finding the t_index values and for checking the
4283!> -----  reflection conditions is basically the same for all four cases, so it
4284!>        should be possible to further simplify/shorten it.
4285!>
4286!> THE WALLS PART OF THIS ROUTINE HAS NOT BEEN TESTED FOR OCEAN RUNS SO FAR!!!!
4287!> (see offset_ocean_*)
4288!------------------------------------------------------------------------------!
4289 SUBROUTINE lpm_boundary_conds( location_bc , i, j, k )
4290
4291    CHARACTER (LEN=*), INTENT(IN) ::  location_bc !< general mode: boundary conditions at bottom/top of the model domain
4292                                   !< or at vertical surfaces (buildings, terrain steps)   
4293    INTEGER(iwp), INTENT(IN) ::  i !< grid index of particle box along x
4294    INTEGER(iwp), INTENT(IN) ::  j !< grid index of particle box along y
4295    INTEGER(iwp), INTENT(IN) ::  k !< grid index of particle box along z
4296
4297    INTEGER(iwp) ::  inc            !< dummy for sorting algorithmus
4298    INTEGER(iwp) ::  ir             !< dummy for sorting algorithmus
4299    INTEGER(iwp) ::  i1             !< grid index (x) of old particle position
4300    INTEGER(iwp) ::  i2             !< grid index (x) of current particle position
4301    INTEGER(iwp) ::  i3             !< grid index (x) of intermediate particle position
4302    INTEGER(iwp) ::  index_reset    !< index reset height
4303    INTEGER(iwp) ::  jr             !< dummy for sorting algorithmus
4304    INTEGER(iwp) ::  j1             !< grid index (y) of old particle position
4305    INTEGER(iwp) ::  j2             !< grid index (y) of current particle position
4306    INTEGER(iwp) ::  j3             !< grid index (y) of intermediate particle position
4307    INTEGER(iwp) ::  k1             !< grid index (z) of old particle position
4308    INTEGER(iwp) ::  k2             !< grid index (z) of current particle position
4309    INTEGER(iwp) ::  k3             !< grid index (z) of intermediate particle position
4310    INTEGER(iwp) ::  n              !< particle number
4311    INTEGER(iwp) ::  particles_top  !< maximum reset height
4312    INTEGER(iwp) ::  t_index        !< running index for intermediate particle timesteps in reflection algorithmus
4313    INTEGER(iwp) ::  t_index_number !< number of intermediate particle timesteps in reflection algorithmus
4314    INTEGER(iwp) ::  tmp_x          !< dummy for sorting algorithm
4315    INTEGER(iwp) ::  tmp_y          !< dummy for sorting algorithm
4316    INTEGER(iwp) ::  tmp_z          !< dummy for sorting algorithm
4317
4318    INTEGER(iwp), DIMENSION(0:10) ::  x_ind(0:10) = 0 !< index array (x) of intermediate particle positions
4319    INTEGER(iwp), DIMENSION(0:10) ::  y_ind(0:10) = 0 !< index array (y) of intermediate particle positions
4320    INTEGER(iwp), DIMENSION(0:10) ::  z_ind(0:10) = 0 !< index array (z) of intermediate particle positions
4321
4322    LOGICAL  ::  cross_wall_x    !< flag to check if particle reflection along x is necessary
4323    LOGICAL  ::  cross_wall_y    !< flag to check if particle reflection along y is necessary
4324    LOGICAL  ::  cross_wall_z    !< flag to check if particle reflection along z is necessary
4325    LOGICAL  ::  reflect_x       !< flag to check if particle is already reflected along x
4326    LOGICAL  ::  reflect_y       !< flag to check if particle is already reflected along y
4327    LOGICAL  ::  reflect_z       !< flag to check if particle is already reflected along z
4328    LOGICAL  ::  tmp_reach_x     !< dummy for sorting algorithmus
4329    LOGICAL  ::  tmp_reach_y     !< dummy for sorting algorithmus
4330    LOGICAL  ::  tmp_reach_z     !< dummy for sorting algorithmus
4331    LOGICAL  ::  x_wall_reached  !< flag to check if particle has already reached wall
4332    LOGICAL  ::  y_wall_reached  !< flag to check if particle has already reached wall
4333    LOGICAL  ::  z_wall_reached  !< flag to check if particle has already reached wall
4334
4335    LOGICAL, DIMENSION(0:10) ::  reach_x  !< flag to check if particle is at a yz-wall
4336    LOGICAL, DIMENSION(0:10) ::  reach_y  !< flag to check if particle is at a xz-wall
4337    LOGICAL, DIMENSION(0:10) ::  reach_z  !< flag to check if particle is at a xy-wall
4338
4339    REAL(wp) ::  dt_particle    !< particle timestep
4340    REAL(wp) ::  eps = 1E-10_wp !< security number to check if particle has reached a wall
4341    REAL(wp) ::  pos_x          !< intermediate particle position (x)
4342    REAL(wp) ::  pos_x_old      !< particle position (x) at previous particle timestep
4343    REAL(wp) ::  pos_y          !< intermediate particle position (y)
4344    REAL(wp) ::  pos_y_old      !< particle position (y) at previous particle timestep
4345    REAL(wp) ::  pos_z          !< intermediate particle position (z)
4346    REAL(wp) ::  pos_z_old      !< particle position (z) at previous particle timestep
4347    REAL(wp) ::  prt_x          !< current particle position (x)
4348    REAL(wp) ::  prt_y          !< current particle position (y)
4349    REAL(wp) ::  prt_z          !< current particle position (z)
4350    REAL(wp) ::  ran_val        !< location of wall in z
4351    REAL(wp) ::  reset_top      !< location of wall in z
4352    REAL(wp) ::  t_old          !< previous reflection time
4353    REAL(wp) ::  tmp_t          !< dummy for sorting algorithmus
4354    REAL(wp) ::  xwall          !< location of wall in x
4355    REAL(wp) ::  ywall          !< location of wall in y
4356    REAL(wp) ::  zwall          !< location of wall in z
4357
4358    REAL(wp), DIMENSION(0:10) ::  t  !< reflection time
4359
4360    SELECT CASE ( location_bc )
4361
4362       CASE ( 'bottom/top' )
4363
4364!
4365!--    Apply boundary conditions to those particles that have crossed the top or
4366!--    bottom boundary and delete those particles, which are older than allowed
4367       DO  n = 1, number_of_particles
4368
4369!
4370!--       Stop if particles have moved further than the length of one
4371!--       PE subdomain (newly released particles have age = age_m!)
4372          IF ( particles(n)%age /= particles(n)%age_m )  THEN
4373             IF ( ABS(particles(n)%speed_x) >                                  &
4374                  ((nxr-nxl+2)*dx)/(particles(n)%age-particles(n)%age_m)  .OR. &
4375                  ABS(particles(n)%speed_y) >                                  &
4376                  ((nyn-nys+2)*dy)/(particles(n)%age-particles(n)%age_m) )  THEN
4377
4378                  WRITE( message_string, * )  'particle too fast.  n = ',  n
4379                  CALL message( 'lpm_boundary_conds', 'PA0148', 2, 2, -1, 6, 1 )
4380             ENDIF
4381          ENDIF
4382
4383          IF ( particles(n)%age > particle_maximum_age  .AND.  &
4384               particles(n)%particle_mask )                              &
4385          THEN
4386             particles(n)%particle_mask  = .FALSE.
4387             deleted_particles = deleted_particles + 1
4388          ENDIF
4389
4390          IF ( particles(n)%z >= zw(nz)  .AND.  particles(n)%particle_mask )  THEN
4391             IF ( ibc_par_t == 1 )  THEN
4392!
4393!--             Particle absorption
4394                particles(n)%particle_mask  = .FALSE.
4395                deleted_particles = deleted_particles + 1
4396             ELSEIF ( ibc_par_t == 2 )  THEN
4397!
4398!--             Particle reflection
4399                particles(n)%z       = 2.0_wp * zw(nz) - particles(n)%z
4400                particles(n)%speed_z = -particles(n)%speed_z
4401                IF ( use_sgs_for_particles  .AND. &
4402                     particles(n)%rvar3 > 0.0_wp )  THEN
4403                   particles(n)%rvar3 = -particles(n)%rvar3
4404                ENDIF
4405             ENDIF
4406          ENDIF
4407
4408          IF ( particles(n)%z < zw(0)  .AND.  particles(n)%particle_mask )  THEN
4409             IF ( ibc_par_b == 1 )  THEN
4410!
4411!--             Particle absorption
4412                particles(n)%particle_mask  = .FALSE.
4413                deleted_particles = deleted_particles + 1
4414             ELSEIF ( ibc_par_b == 2 )  THEN
4415!
4416!--             Particle reflection
4417                particles(n)%z       = 2.0_wp * zw(0) - particles(n)%z
4418                particles(n)%speed_z = -particles(n)%speed_z
4419                IF ( use_sgs_for_particles  .AND. &
4420                     particles(n)%rvar3 < 0.0_wp )  THEN
4421                   particles(n)%rvar3 = -particles(n)%rvar3
4422                ENDIF
4423             ELSEIF ( ibc_par_b == 3 )  THEN
4424!
4425!--             Find reset height. @note this works only in non-strechted cases
4426                particles_top = INT( pst(1) / dz(1) )
4427                index_reset = MINLOC( prt_count(nzb+1:particles_top,j,i), DIM = 1 )
4428                reset_top = zu(index_reset)
4429                iran_part = iran_part + myid
4430                ran_val = random_function( iran_part )
4431                particles(n)%z       = reset_top *  ( 1.0  + ( ran_val / 10.0_wp) )
4432                particles(n)%speed_z = 0.0_wp
4433                IF ( curvature_solution_effects )  THEN
4434                   particles(n)%radius = particles(n)%aux1
4435                ELSE
4436                   particles(n)%radius = 1.0E-8
4437                ENDIF
4438             ENDIF
4439          ENDIF
4440       ENDDO
4441
4442      CASE ( 'walls' )
4443
4444       CALL cpu_log( log_point_s(48), 'lpm_wall_reflect', 'start' )
4445
4446       DO  n = 1, number_of_particles
4447!
4448!--       Recalculate particle timestep
4449          dt_particle = particles(n)%age - particles(n)%age_m
4450!
4451!--       Obtain x/y indices for current particle position
4452          i2 = particles(n)%x * ddx
4453          j2 = particles(n)%y * ddy
4454          IF ( zw(k)   < particles(n)%z ) k2 = k + 1
4455          IF ( zw(k)   > particles(n)%.AND.  zw(k-1) < particles(n)%z ) k2 = k
4456          IF ( zw(k-1) > particles(n)%z ) k2 = k - 1
4457!
4458!--       Save current particle positions
4459          prt_x = particles(n)%x
4460          prt_y = particles(n)%y
4461          prt_z = particles(n)%z
4462!
4463!--       Recalculate old particle positions
4464          pos_x_old = particles(n)%x - particles(n)%speed_x * dt_particle
4465          pos_y_old = particles(n)%y - particles(n)%speed_y * dt_particle
4466          pos_z_old = particles(n)%z - particles(n)%speed_z * dt_particle
4467!
4468!--       Obtain x/y indices for old particle positions
4469          i1 = i
4470          j1 = j
4471          k1 = k
4472!
4473!--       Determine horizontal as well as vertical walls at which particle can
4474!--       be potentially reflected.
4475!--       Start with walls aligned in yz layer.
4476!--       Wall to the right
4477          IF ( prt_x > pos_x_old )  THEN
4478             xwall = ( i1 + 1 ) * dx
4479!
4480!--       Wall to the left
4481          ELSE
4482             xwall = i1 * dx
4483          ENDIF
4484!
4485!--       Walls aligned in xz layer
4486!--       Wall to the north
4487          IF ( prt_y > pos_y_old )  THEN
4488             ywall = ( j1 + 1 ) * dy
4489!--       Wall to the south
4490          ELSE
4491             ywall = j1 * dy
4492          ENDIF
4493
4494          IF ( prt_z > pos_z_old )  THEN
4495             zwall = zw(k)
4496          ELSE
4497             zwall = zw(k-1)
4498          ENDIF
4499!
4500!--       Initialize flags to check if particle reflection is necessary
4501          cross_wall_x = .FALSE.
4502          cross_wall_y = .FALSE.
4503          cross_wall_z = .FALSE.
4504!
4505!--       Initialize flags to check if a wall is reached
4506          reach_x      = .FALSE.
4507          reach_y      = .FALSE.
4508          reach_z      = .FALSE.
4509!
4510!--       Initialize flags to check if a particle was already reflected
4511          reflect_x    = .FALSE.
4512          reflect_y    = .FALSE.
4513          reflect_z    = .FALSE.
4514!
4515!--       Initialize flags to check if a wall is already crossed.
4516!--       ( Required to obtain correct indices. )
4517          x_wall_reached = .FALSE.
4518          y_wall_reached = .FALSE.
4519          z_wall_reached = .FALSE.
4520!
4521!--       Initialize time array
4522          t     = 0.0_wp
4523!
4524!--       Check if particle can reach any wall. This case, calculate the
4525!--       fractional time needed to reach this wall. Store this fractional
4526!--       timestep in array t. Moreover, store indices for these grid
4527!--       boxes where the respective wall belongs to. 
4528!--       Start with x-direction.
4529          t_index    = 1
4530          t(t_index) = ( xwall - pos_x_old )                                   &
4531                     / MERGE( MAX( prt_x - pos_x_old,  1E-30_wp ),             &
4532                              MIN( prt_x - pos_x_old, -1E-30_wp ),             &
4533                              prt_x > pos_x_old )
4534          x_ind(t_index)   = i2
4535          y_ind(t_index)   = j1
4536          z_ind(t_index)   = k1
4537          reach_x(t_index) = .TRUE.
4538          reach_y(t_index) = .FALSE.
4539          reach_z(t_index) = .FALSE.
4540!
4541!--       Store these values only if particle really reaches any wall. t must
4542!--       be in a interval between [0:1].
4543          IF ( t(t_index) <= 1.0_wp  .AND.  t(t_index) >= 0.0_wp )  THEN
4544             t_index      = t_index + 1
4545             cross_wall_x = .TRUE.
4546          ENDIF
4547!
4548!--       y-direction
4549          t(t_index) = ( ywall - pos_y_old )                                   &
4550                     / MERGE( MAX( prt_y - pos_y_old,  1E-30_wp ),             &
4551                              MIN( prt_y - pos_y_old, -1E-30_wp ),             &
4552                              prt_y > pos_y_old )
4553          x_ind(t_index)   = i1
4554          y_ind(t_index)   = j2
4555          z_ind(t_index)   = k1
4556          reach_x(t_index) = .FALSE.
4557          reach_y(t_index) = .TRUE.
4558          reach_z(t_index) = .FALSE.
4559          IF ( t(t_index) <= 1.0_wp  .AND.  t(t_index) >= 0.0_wp )  THEN
4560             t_index      = t_index + 1
4561             cross_wall_y = .TRUE.
4562          ENDIF
4563!
4564!--       z-direction
4565          t(t_index) = (zwall - pos_z_old )                                    &
4566                     / MERGE( MAX( prt_z - pos_z_old,  1E-30_wp ),             &
4567                              MIN( prt_z - pos_z_old, -1E-30_wp ),             &
4568                              prt_z > pos_z_old )
4569
4570          x_ind(t_index)   = i1
4571          y_ind(t_index)   = j1
4572          z_ind(t_index)   = k2
4573          reach_x(t_index) = .FALSE.
4574          reach_y(t_index) = .FALSE.
4575          reach_z(t_index) = .TRUE.
4576          IF( t(t_index) <= 1.0_wp  .AND.  t(t_index) >= 0.0_wp)  THEN
4577             t_index      = t_index + 1
4578             cross_wall_z = .TRUE.
4579          ENDIF
4580
4581          t_index_number = t_index - 1
4582!
4583!--       Carry out reflection only if particle reaches any wall
4584          IF ( cross_wall_x  .OR.  cross_wall_y  .OR.  cross_wall_z )  THEN
4585!
4586!--          Sort fractional timesteps in ascending order. Also sort the
4587!--          corresponding indices and flag according to the time interval a 
4588!--          particle reaches the respective wall.
4589             inc = 1
4590             jr  = 1
4591             DO WHILE ( inc <= t_index_number )
4592                inc = 3 * inc + 1
4593             ENDDO
4594
4595             DO WHILE ( inc > 1 )
4596                inc = inc / 3
4597                DO  ir = inc+1, t_index_number
4598                   tmp_t       = t(ir)
4599                   tmp_x       = x_ind(ir)
4600                   tmp_y       = y_ind(ir)
4601                   tmp_z       = z_ind(ir)
4602                   tmp_reach_x = reach_x(ir)
4603                   tmp_reach_y = reach_y(ir)
4604                   tmp_reach_z = reach_z(ir)
4605                   jr    = ir
4606                   DO WHILE ( t(jr-inc) > tmp_t )
4607                      t(jr)       = t(jr-inc)
4608                      x_ind(jr)   = x_ind(jr-inc)
4609                      y_ind(jr)   = y_ind(jr-inc)
4610                      z_ind(jr)   = z_ind(jr-inc)
4611                      reach_x(jr) = reach_x(jr-inc)
4612                      reach_y(jr) = reach_y(jr-inc)
4613                      reach_z(jr) = reach_z(jr-inc)
4614                      jr    = jr - inc
4615                      IF ( jr <= inc )  EXIT
4616                   ENDDO
4617                   t(jr)       = tmp_t
4618                   x_ind(jr)   = tmp_x
4619                   y_ind(jr)   = tmp_y
4620                   z_ind(jr)   = tmp_z
4621                   reach_x(jr) = tmp_reach_x
4622                   reach_y(jr) = tmp_reach_y
4623                   reach_z(jr) = tmp_reach_z
4624                ENDDO
4625             ENDDO
4626!
4627!--          Initialize temporary particle positions
4628             pos_x = pos_x_old
4629             pos_y = pos_y_old
4630             pos_z = pos_z_old
4631!
4632!--          Loop over all times a particle possibly moves into a new grid box
4633             t_old = 0.0_wp
4634             DO t_index = 1, t_index_number
4635!
4636!--             Calculate intermediate particle position according to the
4637!--             timesteps a particle reaches any wall.
4638                pos_x = pos_x + ( t(t_index) - t_old ) * dt_particle           &
4639                                                       * particles(n)%speed_x
4640                pos_y = pos_y + ( t(t_index) - t_old ) * dt_particle           &
4641                                                       * particles(n)%speed_y
4642                pos_z = pos_z + ( t(t_index) - t_old ) * dt_particle           &
4643                                                       * particles(n)%speed_z
4644!
4645!--             Obtain x/y grid indices for intermediate particle position from
4646!--             sorted index array
4647                i3 = x_ind(t_index)
4648                j3 = y_ind(t_index)
4649                k3 = z_ind(t_index)
4650!
4651!--             Check which wall is already reached
4652                IF ( .NOT. x_wall_reached )  x_wall_reached = reach_x(t_index) 
4653                IF ( .NOT. y_wall_reached )  y_wall_reached = reach_y(t_index)
4654                IF ( .NOT. z_wall_reached )  z_wall_reached = reach_z(t_index)
4655!
4656!--             Check if a particle needs to be reflected at any yz-wall. If
4657!--             necessary, carry out reflection. Please note, a security
4658!--             constant is required, as the particle position does not
4659!--             necessarily exactly match the wall location due to rounding
4660!--             errors.
4661                IF ( reach_x(t_index)                      .AND.               & 
4662                     ABS( pos_x - xwall ) < eps            .AND.               &
4663                     .NOT. BTEST(wall_flags_0(k3,j3,i3),0) .AND.               &
4664                     .NOT. reflect_x )  THEN
4665!
4666!
4667!--                Reflection in x-direction.
4668!--                Ensure correct reflection by MIN/MAX functions, depending on
4669!--                direction of particle transport.
4670!--                Due to rounding errors pos_x does not exactly match the wall
4671!--                location, leading to erroneous reflection.             
4672                   pos_x = MERGE( MIN( 2.0_wp * xwall - pos_x, xwall ),        &
4673                                  MAX( 2.0_wp * xwall - pos_x, xwall ),        &
4674                                  particles(n)%x > xwall )
4675!
4676!--                Change sign of particle speed                     
4677                   particles(n)%speed_x = - particles(n)%speed_x
4678!
4679!--                Also change sign of subgrid-scale particle speed
4680                   particles(n)%rvar1 = - particles(n)%rvar1
4681!
4682!--                Set flag that reflection along x is already done
4683                   reflect_x          = .TRUE.
4684!
4685!--                As the particle does not cross any further yz-wall during
4686!--                this timestep, set further x-indices to the current one.
4687                   x_ind(t_index:t_index_number) = i1
4688!
4689!--             If particle already reached the wall but was not reflected,
4690!--             set further x-indices to the new one.
4691                ELSEIF ( x_wall_reached .AND. .NOT. reflect_x )  THEN
4692                    x_ind(t_index:t_index_number) = i2
4693                ENDIF !particle reflection in x direction done
4694
4695!
4696!--             Check if a particle needs to be reflected at any xz-wall. If
4697!--             necessary, carry out reflection. Please note, a security
4698!--             constant is required, as the particle position does not
4699!--             necessarily exactly match the wall location due to rounding
4700!--             errors.
4701                IF ( reach_y(t_index)                      .AND.               & 
4702                     ABS( pos_y - ywall ) < eps            .AND.               &
4703                     .NOT. BTEST(wall_flags_0(k3,j3,i3),0) .AND.               &
4704                     .NOT. reflect_y )  THEN
4705!
4706!
4707!--                Reflection in y-direction.
4708!--                Ensure correct reflection by MIN/MAX functions, depending on
4709!--                direction of particle transport.
4710!--                Due to rounding errors pos_y does not exactly match the wall
4711!--                location, leading to erroneous reflection.             
4712                   pos_y = MERGE( MIN( 2.0_wp * ywall - pos_y, ywall ),        &
4713                                  MAX( 2.0_wp * ywall - pos_y, ywall ),        &
4714                                  particles(n)%y > ywall )
4715!
4716!--                Change sign of particle speed                     
4717                   particles(n)%speed_y = - particles(n)%speed_y
4718!
4719!--                Also change sign of subgrid-scale particle speed
4720                   particles(n)%rvar2 = - particles(n)%rvar2
4721!
4722!--                Set flag that reflection along y is already done
4723                   reflect_y          = .TRUE.
4724!
4725!--                As the particle does not cross any further xz-wall during
4726!--                this timestep, set further y-indices to the current one.
4727                   y_ind(t_index:t_index_number) = j1
4728!
4729!--             If particle already reached the wall but was not reflected,
4730!--             set further y-indices to the new one.
4731                ELSEIF ( y_wall_reached .AND. .NOT. reflect_y )  THEN
4732                    y_ind(t_index:t_index_number) = j2
4733                ENDIF !particle reflection in y direction done
4734
4735!
4736!--             Check if a particle needs to be reflected at any xy-wall. If
4737!--             necessary, carry out reflection. Please note, a security
4738!--             constant is required, as the particle position does not
4739!--             necessarily exactly match the wall location due to rounding
4740!--             errors.
4741                IF ( reach_z(t_index)                      .AND.               & 
4742                     ABS( pos_z - zwall ) < eps            .AND.               &
4743                     .NOT. BTEST(wall_flags_0(k3,j3,i3),0) .AND.               &
4744                     .NOT. reflect_z )  THEN
4745!
4746!
4747!--                Reflection in z-direction.
4748!--                Ensure correct reflection by MIN/MAX functions, depending on
4749!--                direction of particle transport.
4750!--                Due to rounding errors pos_z does not exactly match the wall
4751!--                location, leading to erroneous reflection.             
4752                   pos_z = MERGE( MIN( 2.0_wp * zwall - pos_z, zwall ),        &
4753                                  MAX( 2.0_wp * zwall - pos_z, zwall ),        &
4754                                  particles(n)%z > zwall )
4755!
4756!--                Change sign of particle speed                     
4757                   particles(n)%speed_z = - particles(n)%speed_z
4758!
4759!--                Also change sign of subgrid-scale particle speed
4760                   particles(n)%rvar3 = - particles(n)%rvar3
4761!
4762!--                Set flag that reflection along z is already done
4763                   reflect_z          = .TRUE.
4764!
4765!--                As the particle does not cross any further xy-wall during
4766!--                this timestep, set further z-indices to the current one.
4767                   z_ind(t_index:t_index_number) = k1
4768!
4769!--             If particle already reached the wall but was not reflected,
4770!--             set further z-indices to the new one.
4771                ELSEIF ( z_wall_reached .AND. .NOT. reflect_z )  THEN
4772                    z_ind(t_index:t_index_number) = k2
4773                ENDIF !particle reflection in z direction done               
4774
4775!
4776!--             Swap time
4777                t_old = t(t_index)
4778
4779             ENDDO
4780!
4781!--          If a particle was reflected, calculate final position from last
4782!--          intermediate position.
4783             IF ( reflect_x  .OR.  reflect_y  .OR.  reflect_z )  THEN
4784
4785                particles(n)%x = pos_x + ( 1.0_wp - t_old ) * dt_particle      &
4786                                                         * particles(n)%speed_x
4787                particles(n)%y = pos_y + ( 1.0_wp - t_old ) * dt_particle      &
4788                                                         * particles(n)%speed_y
4789                particles(n)%z = pos_z + ( 1.0_wp - t_old ) * dt_particle      &
4790                                                         * particles(n)%speed_z
4791
4792             ENDIF
4793
4794          ENDIF
4795
4796       ENDDO
4797
4798       CALL cpu_log( log_point_s(48), 'lpm_wall_reflect', 'stop' )
4799
4800       CASE DEFAULT
4801          CONTINUE
4802
4803    END SELECT
4804
4805 END SUBROUTINE lpm_boundary_conds
4806
4807
4808!------------------------------------------------------------------------------!
4809! Description:
4810! ------------
4811!> Calculates change in droplet radius by condensation/evaporation, using
4812!> either an analytic formula or by numerically integrating the radius growth
4813!> equation including curvature and solution effects using Rosenbrocks method
4814!> (see Numerical recipes in FORTRAN, 2nd edition, p. 731).
4815!> The analytical formula and growth equation follow those given in
4816!> Rogers and Yau (A short course in cloud physics, 3rd edition, p. 102/103).
4817!------------------------------------------------------------------------------!
4818 SUBROUTINE lpm_droplet_condensation (i,j,k)
4819
4820    INTEGER(iwp), INTENT(IN) ::  i              !<
4821    INTEGER(iwp), INTENT(IN) ::  j              !<
4822    INTEGER(iwp), INTENT(IN) ::  k              !<
4823    INTEGER(iwp) ::  n                          !<
4824
4825    REAL(wp) ::  afactor                       !< curvature effects
4826    REAL(wp) ::  arg                           !<
4827    REAL(wp) ::  bfactor                       !< solute effects
4828    REAL(wp) ::  ddenom                        !<
4829    REAL(wp) ::  delta_r                       !<
4830    REAL(wp) ::  diameter                      !< diameter of cloud droplets
4831    REAL(wp) ::  diff_coeff                    !< diffusivity for water vapor
4832    REAL(wp) ::  drdt                          !<
4833    REAL(wp) ::  dt_ros                        !<
4834    REAL(wp) ::  dt_ros_sum                    !<
4835    REAL(wp) ::  d2rdtdr                       !<
4836    REAL(wp) ::  e_a                           !< current vapor pressure
4837    REAL(wp) ::  e_s                           !< current saturation vapor pressure
4838    REAL(wp) ::  error                         !< local truncation error in Rosenbrock
4839    REAL(wp) ::  k1                            !<
4840    REAL(wp) ::  k2                            !<
4841    REAL(wp) ::  r_err                         !< First order estimate of Rosenbrock radius
4842    REAL(wp) ::  r_ros                         !< Rosenbrock radius
4843    REAL(wp) ::  r_ros_ini                     !< initial Rosenbrock radius
4844    REAL(wp) ::  r0                            !< gas-kinetic lengthscale
4845    REAL(wp) ::  sigma                         !< surface tension of water
4846    REAL(wp) ::  thermal_conductivity          !< thermal conductivity for water
4847    REAL(wp) ::  t_int                         !< temperature
4848    REAL(wp) ::  w_s                           !< terminal velocity of droplets
4849    REAL(wp) ::  re_p                          !< particle Reynolds number
4850!
4851!-- Parameters for Rosenbrock method (see Verwer et al., 1999)
4852    REAL(wp), PARAMETER ::  prec = 1.0E-3_wp     !< precision of Rosenbrock solution
4853    REAL(wp), PARAMETER ::  q_increase = 1.5_wp  !< increase factor in timestep
4854    REAL(wp), PARAMETER ::  q_decrease = 0.9_wp  !< decrease factor in timestep
4855    REAL(wp), PARAMETER ::  gamma = 0.292893218814_wp !< = 1.0 - 1.0 / SQRT(2.0)
4856!
4857!-- Parameters for terminal velocity
4858    REAL(wp), PARAMETER ::  a_rog = 9.65_wp      !< parameter for fall velocity
4859    REAL(wp), PARAMETER ::  b_rog = 10.43_wp     !< parameter for fall velocity
4860    REAL(wp), PARAMETER ::  c_rog = 0.6_wp       !< parameter for fall velocity
4861    REAL(wp), PARAMETER ::  k_cap_rog = 4.0_wp   !< parameter for fall velocity
4862    REAL(wp), PARAMETER ::  k_low_rog = 12.0_wp  !< parameter for fall velocity
4863    REAL(wp), PARAMETER ::  d0_rog = 0.745_wp    !< separation diameter
4864
4865    REAL(wp), DIMENSION(number_of_particles) ::  ventilation_effect     !<
4866    REAL(wp), DIMENSION(number_of_particles) ::  new_r                  !<
4867
4868    CALL cpu_log( log_point_s(42), 'lpm_droplet_condens', 'start' )
4869
4870!
4871!-- Absolute temperature
4872    t_int = pt(k,j,i) * exner(k)
4873!
4874!-- Saturation vapor pressure (Eq. 10 in Bolton, 1980)
4875    e_s = magnus( t_int )
4876!
4877!-- Current vapor pressure
4878    e_a = q(k,j,i) * hyp(k) / ( q(k,j,i) + rd_d_rv )
4879!
4880!-- Thermal conductivity for water (from Rogers and Yau, Table 7.1)
4881    thermal_conductivity = 7.94048E-05_wp * t_int + 0.00227011_wp
4882!
4883!-- Moldecular diffusivity of water vapor in air (Hall und Pruppacher, 1976)
4884    diff_coeff           = 0.211E-4_wp * ( t_int / 273.15_wp )**1.94_wp * &
4885                           ( 101325.0_wp / hyp(k) )
4886!
4887!-- Lengthscale for gas-kinetic effects (from Mordy, 1959, p. 23):
4888    r0 = diff_coeff / 0.036_wp * SQRT( 2.0_wp * pi / ( r_v * t_int ) )
4889!
4890!-- Calculate effects of heat conductivity and diffusion of water vapor on the
4891!-- diffusional growth process (usually known as 1.0 / (F_k + F_d) )
4892    ddenom  = 1.0_wp / ( rho_l * r_v * t_int / ( e_s * diff_coeff ) +          &
4893                         ( l_v / ( r_v * t_int ) - 1.0_wp ) * rho_l *          &
4894                         l_v / ( thermal_conductivity * t_int )                &
4895                       )
4896    new_r = 0.0_wp
4897!
4898!-- Determine ventilation effect on evaporation of large drops
4899    DO  n = 1, number_of_particles
4900
4901       IF ( particles(n)%radius