source: palm/trunk/SOURCE/interaction_droplets_ptq.f90 @ 1320

 MODULE interaction_droplets_ptq_mod

!--------------------------------------------------------------------------------!
! This file is part of PALM.
!
! PALM is free software: you can redistribute it and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation,
! either version 3 of the License, or (at your option) any later version.
!
! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License along with
! PALM. If not, see <http://www.gnu.org/licenses/>.
!
! Copyright 1997-2014 Leibniz Universitaet Hannover
!--------------------------------------------------------------------------------!
!
! Current revisions:
! -----------------
!
!
! Former revisions:
! -----------------
! $Id: interaction_droplets_ptq.f90 1320 2014-03-20 08:40:49Z raasch $
!
! 1036 2012-10-22 13:43:42Z raasch
! code put under GPL (PALM 3.9)
!
! 799 2011-12-21 17:48:03Z franke
! Bugfix: pt_d_t(k) was missing in calculation of pt_p
!
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.1  2005/06/26 19:57:47  raasch
! Initial revision
!
!
! Description:
! ------------
! Release of latent heat and change of specific humidity due to condensation /
! evaporation of droplets.
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC interaction_droplets_ptq

    INTERFACE interaction_droplets_ptq
       MODULE PROCEDURE interaction_droplets_ptq
       MODULE PROCEDURE interaction_droplets_ptq_ij
    END INTERFACE interaction_droplets_ptq
 
 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE interaction_droplets_ptq

       USE arrays_3d,                                                          &
           ONLY:  pt_p, ql_c, q_p
           
       USE cloud_parameters,                                                   &
           ONLY:  l_d_cp, pt_d_t
           
       USE indices,                                                            &
           ONLY:  nxl, nxr, nyn, nys, nzb_2d, nzt
           
       USE kinds

       USE pegrid

       IMPLICIT NONE

       INTEGER(iwp) ::  i !:
       INTEGER(iwp) ::  j !:
       INTEGER(iwp) ::  k !:

 
       DO  i = nxl, nxr
          DO  j = nys, nyn
             DO  k = nzb_2d(j,i)+1, nzt
                q_p(k,j,i)  = q_p(k,j,i)  - ql_c(k,j,i)
                pt_p(k,j,i) = pt_p(k,j,i) + l_d_cp * ql_c(k,j,i) * pt_d_t(k)
             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE interaction_droplets_ptq


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE interaction_droplets_ptq_ij( i, j )

       USE arrays_3d,                                                          &
           ONLY:  pt_p, ql_c, q_p

       USE cloud_parameters,                                                   &
           ONLY:  l_d_cp, pt_d_t

       USE indices,                                                            &
           ONLY:  nxl, nxr, nyn, nys, nzb_2d, nzt

       USE kinds,                                                              &
           ONLY:  iwp, wp

       USE pegrid

       IMPLICIT NONE

       INTEGER(iwp) ::  i !:
       INTEGER(iwp) ::  j !:
       INTEGER(iwp) ::  k !:


       DO  k = nzb_2d(j,i)+1, nzt
          q_p(k,j,i)  = q_p(k,j,i)  - ql_c(k,j,i)
          pt_p(k,j,i) = pt_p(k,j,i) + l_d_cp * ql_c(k,j,i) * pt_d_t(k)
       ENDDO

    END SUBROUTINE interaction_droplets_ptq_ij

 END MODULE interaction_droplets_ptq_mod