source: palm/trunk/SOURCE/init_pegrid.f90 @ 2508

Last change on this file since 2508 was 2414, checked in by Giersch, 7 years ago

Redundant preprocessor directives removed

  • Property svn:keywords set to Id
File size: 48.5 KB
Line 
1!> @file init_pegrid.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_pegrid.f90 2414 2017-09-06 12:54:47Z suehring $
27! Redundant preprocessor directives removed
28!
29! 2372 2017-08-25 12:37:32Z sward
30! Shifted cyclic boundary conditions implemented
31!
32! 2365 2017-08-21 14:59:59Z kanani
33! Vertical nesting implemented (SadiqHuq)
34!
35! 2300 2017-06-29 13:31:14Z raasch
36! host-specific settings removed
37!
38! 2298 2017-06-29 09:28:18Z raasch
39! MPI2 related parts removed
40!
41! 2271 2017-06-09 12:34:55Z sward
42! Error message changed
43!
44! 2259 2017-06-08 09:09:11Z gronemeier
45! Implemented synthetic turbulence generator
46!
47! 2238 2017-05-31 16:49:16Z suehring
48! Remove unnecessary module load of pmc_interface
49!
50! 2231 2017-05-30 16:44:33Z suehring
51!
52! 2200 2017-04-11 11:37:51Z suehring
53! monotonic_adjustment removed
54!
55! 2197 2017-03-24 02:25:00Z raasch
56! bugfix: do not allow odd values for nz at the coarsest grid level in case of
57! optimized multigrid solver
58!
59! 2180 2017-03-17 13:33:05Z hellstea
60! Checks to ensure (2178) that pdims match the grid dimensions in the
61! automatic determination of pdims are canceled as unnecessary
62!
63! 2178 2017-03-17 11:07:39Z hellstea
64! Checks to ensure that pdims match the grid dimensions are added in the
65! automatic determination of pdims
66!
67! 2050 2016-11-08 15:00:55Z gronemeier
68! Implement turbulent outflow condition
69!
70! 2000 2016-08-20 18:09:15Z knoop
71! Forced header and separation lines into 80 columns
72!
73! 1968 2016-07-18 12:01:49Z suehring
74! Extent MPI-datatypes for exchange of 2D-INTEGER arrays on coarser multigrid
75! level 
76!
77! 1964 2016-07-14 15:35:18Z hellstea
78! Bugfix: erroneous setting of nest_bound_l/r/s/n = .TRUE. for vertical nesting mode removed.
79!
80! 1923 2016-05-31 16:37:07Z boeske
81! Initial version of purely vertical nesting introduced.
82!
83! 1922 2016-05-31 16:36:08Z boeske
84! Bugfix: array transposition checks restricted to cases if a fourier
85! transform is used , removed unused variable nnx_z
86!
87! 1833 2016-04-07 14:23:03Z raasch
88! spectra related variables moved to spectra_mod
89!
90! 1815 2016-04-06 13:49:59Z raasch
91! cpp-directives for intel openmp bug removed
92!
93! 1804 2016-04-05 16:30:18Z maronga
94! Removed code for parameter file check (__check)
95!
96! 1779 2016-03-03 08:01:28Z raasch
97! changes regarding nested domain removed: virtual PE grid will be automatically
98! calculated for nested runs too
99!
100! 1764 2016-02-28 12:45:19Z raasch
101! cpp-statements for nesting removed
102!
103! 1762 2016-02-25 12:31:13Z hellstea
104! Introduction of nested domain feature
105!
106! 1682 2015-10-07 23:56:08Z knoop
107! Code annotations made doxygen readable
108!
109! 1677 2015-10-02 13:25:23Z boeske
110! New MPI-data types for exchange of 3D integer arrays.
111!
112! 1575 2015-03-27 09:56:27Z raasch
113! adjustments for psolver-queries, calculation of ngp_xz added
114!
115! 1565 2015-03-09 20:59:31Z suehring
116! Refine if-clause for setting nbgp.
117!
118! 1557 2015-03-05 16:43:04Z suehring
119! Adjustment for monotonic limiter
120!
121! 1468 2014-09-24 14:06:57Z maronga
122! Adapted for use on up to 6-digit processor cores
123!
124! 1435 2014-07-21 10:37:02Z keck
125! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
126!
127! 1402 2014-05-09 14:25:13Z raasch
128! location messages modified
129!
130! 1384 2014-05-02 14:31:06Z raasch
131! location messages added
132!
133! 1353 2014-04-08 15:21:23Z heinze
134! REAL constants provided with KIND-attribute
135!
136! 1322 2014-03-20 16:38:49Z raasch
137! REAL functions provided with KIND-attribute
138!
139! 1320 2014-03-20 08:40:49Z raasch
140! ONLY-attribute added to USE-statements,
141! kind-parameters added to all INTEGER and REAL declaration statements,
142! kinds are defined in new module kinds,
143! revision history before 2012 removed,
144! comment fields (!:) to be used for variable explanations added to
145! all variable declaration statements
146!
147! 1304 2014-03-12 10:29:42Z raasch
148! bugfix: single core MPI runs missed some settings of transpose indices
149!
150! 1212 2013-08-15 08:46:27Z raasch
151! error message for poisfft_hybrid removed
152!
153! 1159 2013-05-21 11:58:22Z fricke
154! dirichlet/neumann and neumann/dirichlet removed
155!
156! 1139 2013-04-18 07:25:03Z raasch
157! bugfix for calculating the id of the PE carrying the recycling plane
158!
159! 1111 2013-03-08 23:54:10Z raasch
160! initialization of poisfft moved to module poisfft
161!
162! 1092 2013-02-02 11:24:22Z raasch
163! unused variables removed
164!
165! 1056 2012-11-16 15:28:04Z raasch
166! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
167! p2 as automatic arrays in recursive subroutine next_mg_level
168!
169! 1041 2012-11-06 02:36:29Z raasch
170! a 2d virtual processor topology is used by default for all machines
171!
172! 1036 2012-10-22 13:43:42Z raasch
173! code put under GPL (PALM 3.9)
174!
175! 1003 2012-09-14 14:35:53Z raasch
176! subdomains must have identical size (grid matching = "match" removed)
177!
178! 1001 2012-09-13 14:08:46Z raasch
179! all actions concerning upstream-spline-method removed
180!
181! 978 2012-08-09 08:28:32Z fricke
182! dirichlet/neumann and neumann/dirichlet added
183! nxlu and nysv are also calculated for inflow boundary
184!
185! 809 2012-01-30 13:32:58Z maronga
186! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
187!
188! 807 2012-01-25 11:53:51Z maronga
189! New cpp directive "__check" implemented which is used by check_namelist_files
190!
191! Revision 1.1  1997/07/24 11:15:09  raasch
192! Initial revision
193!
194!
195! Description:
196! ------------
197!> Determination of the virtual processor topology (if not prescribed by the
198!> user)and computation of the grid point number and array bounds of the local
199!> domains.
200!------------------------------------------------------------------------------!
201 SUBROUTINE init_pegrid
202 
203
204    USE control_parameters,                                                    &
205        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
206               coupling_topology, gathered_size, grid_level,                   &
207               grid_level_count, inflow_l, inflow_n, inflow_r, inflow_s,       &
208               io_blocks, io_group, maximum_grid_level,                        &
209               maximum_parallel_io_streams, message_string,                    &
210               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
211               nest_bound_n, nest_bound_r, nest_bound_s, nest_domain, neutral, &
212               psolver, outflow_l, outflow_n, outflow_r, outflow_s,            &
213               outflow_source_plane, recycling_width, scalar_advec,            &
214               subdomain_size, turbulent_outflow, y_shift
215
216    USE grid_variables,                                                        &
217        ONLY:  dx
218       
219    USE indices,                                                               &
220        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
221               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
222               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
223               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
224               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
225
226    USE kinds
227     
228    USE pegrid
229     
230    USE spectra_mod,                                                           &
231        ONLY:  calculate_spectra, dt_dosp
232
233    USE synthetic_turbulence_generator_mod,                                    &
234        ONLY:  use_synthetic_turbulence_generator
235
236    USE transpose_indices,                                                     &
237        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
238               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
239
240    USE vertical_nesting_mod,                                                  &
241        ONLY:  vnested, vnest_init_pegrid_domain, vnest_init_pegrid_rank
242
243    IMPLICIT NONE
244
245    INTEGER(iwp) ::  i                        !<
246    INTEGER(iwp) ::  id_inflow_l              !<
247    INTEGER(iwp) ::  id_outflow_l             !< local value of id_outflow
248    INTEGER(iwp) ::  id_outflow_source_l      !< local value of id_outflow_source
249    INTEGER(iwp) ::  id_recycling_l           !<
250    INTEGER(iwp) ::  ind(5)                   !<
251    INTEGER(iwp) ::  j                        !<
252    INTEGER(iwp) ::  k                        !<
253    INTEGER(iwp) ::  maximum_grid_level_l     !<
254    INTEGER(iwp) ::  mg_levels_x              !<
255    INTEGER(iwp) ::  mg_levels_y              !<
256    INTEGER(iwp) ::  mg_levels_z              !<
257    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
258    INTEGER(iwp) ::  nnx_y                    !<
259    INTEGER(iwp) ::  nnx_z                    !<
260    INTEGER(iwp) ::  nny_x                    !<
261    INTEGER(iwp) ::  nny_z                    !<
262    INTEGER(iwp) ::  nnz_x                    !<
263    INTEGER(iwp) ::  nnz_y                    !<
264    INTEGER(iwp) ::  numproc_sqr              !<
265    INTEGER(iwp) ::  nxl_l                    !<
266    INTEGER(iwp) ::  nxr_l                    !<
267    INTEGER(iwp) ::  nyn_l                    !<
268    INTEGER(iwp) ::  nys_l                    !<
269    INTEGER(iwp) ::  nzb_l                    !<
270    INTEGER(iwp) ::  nzt_l                    !<
271    INTEGER(iwp) ::  omp_get_num_threads      !<
272
273    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
274    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
275    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
276    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
277    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
278
279    INTEGER(iwp), DIMENSION(2) ::  pdims_remote         !<
280    INTEGER(iwp)               ::  lcoord(2)            !< PE coordinates of left neighbor along x and y
281    INTEGER(iwp)               ::  rcoord(2)            !< PE coordinates of right neighbor along x and y
282
283!
284!-- Get the number of OpenMP threads
285    !$OMP PARALLEL
286!$  threads_per_task = omp_get_num_threads()
287    !$OMP END PARALLEL
288
289
290#if defined( __parallel )
291
292    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
293                           .FALSE. )
294
295!
296!-- Determine the processor topology or check it, if prescribed by the user
297    IF ( npex == -1  .AND.  npey == -1 )  THEN
298
299!
300!--    Automatic determination of the topology
301       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
302       pdims(1)    = MAX( numproc_sqr , 1 )
303       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
304          pdims(1) = pdims(1) - 1
305       ENDDO
306       pdims(2) = numprocs / pdims(1)
307
308    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
309
310!
311!--    Prescribed by user. Number of processors on the prescribed topology
312!--    must be equal to the number of PEs available to the job
313       IF ( ( npex * npey ) /= numprocs )  THEN
314          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
315              'topology (', npex*npey,') does not match & the number of ', &
316              'PEs available to the job (', numprocs, ')'
317          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
318       ENDIF
319       pdims(1) = npex
320       pdims(2) = npey
321
322    ELSE
323!
324!--    If the processor topology is prescribed by the user, the number of
325!--    PEs must be given in both directions
326       message_string = 'if the processor topology is prescribed by th' //  &
327                'e user& both values of "npex" and "npey" must be given' // &
328                ' in the &NAMELIST-parameter file'
329       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
330
331    ENDIF
332
333!
334!-- If necessary, set horizontal boundary conditions to non-cyclic
335    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
336    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
337
338
339!
340!-- Create the virtual processor grid
341    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
342                          comm2d, ierr )
343    CALL MPI_COMM_RANK( comm2d, myid, ierr )
344    WRITE (myid_char,'(''_'',I6.6)')  myid
345
346    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
347    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
348    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
349
350!
351!-- In case of cyclic boundary conditions, a y-shift at the boundaries in
352!-- x-direction can be introduced via parameter y_shift. The shift is done
353!-- by modifying the processor grid in such a way that processors located
354!-- at the x-boundary communicate across it to processors with y-coordinate
355!-- shifted by y_shift relative to their own. This feature can not be used
356!-- in combination with an fft pressure solver. It has been implemented to
357!-- counter the effect of streak structures in case of cyclic boundary
358!-- conditions. For a description of these see Munters
359!-- (2016; dx.doi.org/10.1063/1.4941912)
360!--
361!-- Get coordinates of left and right neighbor on PE grid
362    IF ( y_shift /= 0 ) THEN
363
364       IF ( bc_lr /= 'cyclic'  .OR.  bc_ns /= 'cyclic' )  THEN
365          message_string = 'y_shift /= 0 is only allowed for cyclic ' //       &
366                           'boundary conditions in both directions '
367          CALL message( 'check_parameters', 'PA0467', 1, 2, 0, 6, 0 )
368       ENDIF
369       IF ( TRIM( psolver ) /= 'multigrid' .AND.                               &
370            TRIM( psolver ) /= 'multigrid_noopt')                              &
371       THEN
372          message_string = 'y_shift /= 0 requires a multigrid pressure solver '
373          CALL message( 'check_parameters', 'PA0468', 1, 2, 0, 6, 0 )
374       ENDIF
375
376       CALL MPI_CART_COORDS( comm2d, pright, ndim, rcoord, ierr )
377       CALL MPI_CART_COORDS( comm2d, pleft, ndim, lcoord, ierr )
378
379!
380!--    If the x(y)-coordinate of the right (left) neighbor is smaller (greater)
381!--    than that of the calling process, then the calling process is located on
382!--    the right (left) boundary of the processor grid. In that case,
383!--    the y-coordinate of that neighbor is increased (decreased) by y_shift.
384!--    The rank of the process with that coordinate is then inquired and the
385!--    neighbor rank for MPI_SENDRECV, pright (pleft) is set to it.
386!--    In this way, the calling process receives a new right (left) neighbor
387!--    for all future MPI_SENDRECV calls. That neighbor has a y-coordinate
388!--    of y+(-)y_shift, where y is the original right (left) neighbor's
389!--    y-coordinate. The modulo-operation ensures that if the neighbor's
390!--    y-coordinate exceeds the grid-boundary, it will be relocated to
391!--    the opposite part of the grid cyclicly.
392       IF ( rcoord(1) < pcoord(1) ) THEN
393          rcoord(2) = MODULO( rcoord(2) + y_shift, pdims(2) )
394          CALL MPI_CART_RANK( comm2d, rcoord, pright, ierr )
395       ENDIF
396
397       IF ( lcoord(1) > pcoord(1) ) THEN
398          lcoord(2) = MODULO( lcoord(2) - y_shift, pdims(2) )
399          CALL MPI_CART_RANK( comm2d, lcoord, pleft, ierr )
400       ENDIF
401    ENDIF
402
403!
404!-- Vertical nesting: store four lists that identify partner ranks to exchange
405!-- data
406    IF ( vnested )  CALL vnest_init_pegrid_rank
407
408!
409!-- Determine sub-topologies for transpositions
410!-- Transposition from z to x:
411    remain_dims(1) = .TRUE.
412    remain_dims(2) = .FALSE.
413    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
414    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
415!
416!-- Transposition from x to y
417    remain_dims(1) = .FALSE.
418    remain_dims(2) = .TRUE.
419    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
420    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
421
422
423!
424!-- Calculate array bounds along x-direction for every PE.
425    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
426              nysf(0:pdims(2)-1) )
427
428    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
429       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
430                               'is not an& integral divisor of the number ',  &
431                               'processors (', pdims(1),')'
432       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
433    ELSE
434       nnx  = ( nx + 1 ) / pdims(1)
435       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
436          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
437                       'requirements given by the number of PEs &used',       &
438                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
439                                   - ( nx + 1 ) ) ), ' instead of nx =', nx
440          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
441       ENDIF
442    ENDIF   
443
444!
445!-- Left and right array bounds, number of gridpoints
446    DO  i = 0, pdims(1)-1
447       nxlf(i)   = i * nnx
448       nxrf(i)   = ( i + 1 ) * nnx - 1
449    ENDDO
450
451!
452!-- Calculate array bounds in y-direction for every PE.
453    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
454       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
455                           'is not an& integral divisor of the number of',     &
456                           'processors (', pdims(2),')'
457       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
458    ELSE
459       nny  = ( ny + 1 ) / pdims(2)
460       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
461          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
462                       'requirements given by the number of PEs &used ',      &
463                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
464                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
465          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
466       ENDIF
467    ENDIF   
468
469!
470!-- South and north array bounds
471    DO  j = 0, pdims(2)-1
472       nysf(j)   = j * nny
473       nynf(j)   = ( j + 1 ) * nny - 1
474    ENDDO
475
476!
477!-- Local array bounds of the respective PEs
478    nxl = nxlf(pcoord(1))
479    nxr = nxrf(pcoord(1))
480    nys = nysf(pcoord(2))
481    nyn = nynf(pcoord(2))
482    nzb = 0
483    nzt = nz
484    nnz = nz
485
486!
487!-- Set switches to define if the PE is situated at the border of the virtual
488!-- processor grid
489    IF ( nxl == 0 )   left_border_pe  = .TRUE.
490    IF ( nxr == nx )  right_border_pe = .TRUE.
491    IF ( nys == 0 )   south_border_pe = .TRUE.
492    IF ( nyn == ny )  north_border_pe = .TRUE.
493
494!
495!-- Calculate array bounds and gridpoint numbers for the transposed arrays
496!-- (needed in the pressure solver)
497!-- For the transposed arrays, cyclic boundaries as well as top and bottom
498!-- boundaries are omitted, because they are obstructive to the transposition
499
500!
501!-- 1. transposition  z --> x
502!-- This transposition is not neccessary in case of a 1d-decomposition along x
503    IF ( psolver == 'poisfft'  .OR.  calculate_spectra  .OR.                   &
504         use_synthetic_turbulence_generator )  THEN
505
506       IF ( pdims(2) /= 1 )  THEN
507          IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
508             WRITE( message_string, * ) 'transposition z --> x:',              &
509                       '&nz=',nz,' is not an integral divisior of pdims(1)=',  &
510                                                                   pdims(1)
511             CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
512          ENDIF
513       ENDIF
514
515       nys_x = nys
516       nyn_x = nyn
517       nny_x = nny
518       nnz_x = nz / pdims(1)
519       nzb_x = 1 + myidx * nnz_x
520       nzt_x = ( myidx + 1 ) * nnz_x
521       sendrecvcount_zx = nnx * nny * nnz_x
522
523    ENDIF
524
525
526    IF ( psolver == 'poisfft' )  THEN 
527!
528!--    2. transposition  x --> y
529       IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
530          WRITE( message_string, * ) 'transposition x --> y:',                 &
531                            '&nx+1=',nx+1,' is not an integral divisor of ',   &
532                            'pdims(2)=',pdims(2)
533          CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
534       ENDIF
535
536       nnz_y = nnz_x
537       nzb_y = nzb_x
538       nzt_y = nzt_x
539       nnx_y = (nx+1) / pdims(2)
540       nxl_y = myidy * nnx_y
541       nxr_y = ( myidy + 1 ) * nnx_y - 1
542       sendrecvcount_xy = nnx_y * nny_x * nnz_y
543!
544!--    3. transposition  y --> z 
545!--    (ELSE:  x --> y  in case of 1D-decomposition along x)
546       nxl_z = nxl_y
547       nxr_z = nxr_y
548       nny_z = (ny+1) / pdims(1)
549       nys_z = myidx * nny_z
550       nyn_z = ( myidx + 1 ) * nny_z - 1
551       sendrecvcount_yz = nnx_y * nny_z * nnz_y
552
553       IF ( pdims(2) /= 1 )  THEN
554!
555!--       y --> z
556!--       This transposition is not neccessary in case of a 1d-decomposition
557!--       along x, except that the uptream-spline method is switched on
558          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
559             WRITE( message_string, * ) 'transposition y --> z:',              &
560                               '& ny+1=',ny+1,' is not an integral divisor of',&
561                               ' pdims(1)=',pdims(1)
562             CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
563          ENDIF
564
565       ELSE
566!
567!--       x --> y
568!--       This condition must be fulfilled for a 1D-decomposition along x
569          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
570             WRITE( message_string, * ) 'transposition x --> y:',              &
571                               '& ny+1=',ny+1,' is not an integral divisor of',&
572                               ' pdims(1)=',pdims(1)
573             CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
574          ENDIF
575
576       ENDIF
577
578    ENDIF
579
580!
581!-- Indices for direct transpositions z --> y (used for calculating spectra)
582    IF ( calculate_spectra )  THEN
583       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
584          WRITE( message_string, * ) 'direct transposition z --> y (needed ',  &
585                    'for spectra):& nz=',nz,' is not an integral divisor of ', &
586                    'pdims(2)=',pdims(2)
587          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
588       ELSE
589          nxl_yd = nxl
590          nxr_yd = nxr
591          nzb_yd = 1 + myidy * ( nz / pdims(2) )
592          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
593          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
594       ENDIF
595    ENDIF
596
597    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
598!
599!--    Indices for direct transpositions y --> x
600!--    (they are only possible in case of a 1d-decomposition along x)
601       IF ( pdims(2) == 1 )  THEN
602          nny_x = nny / pdims(1)
603          nys_x = myid * nny_x
604          nyn_x = ( myid + 1 ) * nny_x - 1
605          nzb_x = 1
606          nzt_x = nz
607          sendrecvcount_xy = nnx * nny_x * nz
608       ENDIF
609
610    ENDIF
611
612    IF ( psolver == 'poisfft' )  THEN
613!
614!--    Indices for direct transpositions x --> y
615!--    (they are only possible in case of a 1d-decomposition along y)
616       IF ( pdims(1) == 1 )  THEN
617          nnx_y = nnx / pdims(2)
618          nxl_y = myid * nnx_y
619          nxr_y = ( myid + 1 ) * nnx_y - 1
620          nzb_y = 1
621          nzt_y = nz
622          sendrecvcount_xy = nnx_y * nny * nz
623       ENDIF
624
625    ENDIF
626
627!
628!-- Arrays for storing the array bounds are needed any more
629    DEALLOCATE( nxlf , nxrf , nynf , nysf )
630
631
632!
633!-- Collect index bounds from other PEs (to be written to restart file later)
634    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
635
636    IF ( myid == 0 )  THEN
637
638       hor_index_bounds(1,0) = nxl
639       hor_index_bounds(2,0) = nxr
640       hor_index_bounds(3,0) = nys
641       hor_index_bounds(4,0) = nyn
642
643!
644!--    Receive data from all other PEs
645       DO  i = 1, numprocs-1
646          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
647                         ierr )
648          hor_index_bounds(:,i) = ibuf(1:4)
649       ENDDO
650
651    ELSE
652!
653!--    Send index bounds to PE0
654       ibuf(1) = nxl
655       ibuf(2) = nxr
656       ibuf(3) = nys
657       ibuf(4) = nyn
658       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
659
660    ENDIF
661
662
663#if defined( __print )
664!
665!-- Control output
666    IF ( myid == 0 )  THEN
667       PRINT*, '*** processor topology ***'
668       PRINT*, ' '
669       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
670               &'   nys: nyn'
671       PRINT*, '------------------------------------------------------------',&
672               &'-----------'
673       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
674                       myidx, myidy, nxl, nxr, nys, nyn
6751000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
676               2(2X,I4,':',I4))
677
678!
679!--    Receive data from the other PEs
680       DO  i = 1,numprocs-1
681          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
682                         ierr )
683          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
684       ENDDO
685    ELSE
686
687!
688!--    Send data to PE0
689       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
690       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
691       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
692       ibuf(12) = nyn
693       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
694    ENDIF
695#endif
696
697
698!
699!-- Determine the number of ghost point layers
700    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
701         momentum_advec == 'ws-scheme' )  THEN
702       nbgp = 3
703    ELSE
704       nbgp = 1
705    ENDIF 
706
707!
708!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
709!-- which is needed for coupled atmosphere-ocean runs.
710!-- First, calculate number of grid points of an xy-plane.
711    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
712    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
713    CALL MPI_TYPE_COMMIT( type_xy, ierr )
714
715    IF ( TRIM( coupling_mode ) /= 'uncoupled' .AND. .NOT. vnested )  THEN
716   
717!
718!--    Pass the number of grid points of the atmosphere model to
719!--    the ocean model and vice versa
720       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
721
722          nx_a = nx
723          ny_a = ny
724
725          IF ( myid == 0 )  THEN
726
727             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
728                            ierr )
729             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
730                            ierr )
731             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
732                            ierr )
733             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
734                            status, ierr )
735             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
736                            status, ierr )
737             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
738                            comm_inter, status, ierr )
739          ENDIF
740
741          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
742          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
743          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
744       
745       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
746
747          nx_o = nx
748          ny_o = ny 
749
750          IF ( myid == 0 ) THEN
751
752             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
753                            ierr )
754             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
755                            ierr )
756             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
757                            status, ierr )
758             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
759             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
760             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
761          ENDIF
762
763          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
764          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
765          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
766
767       ENDIF
768 
769       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
770       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
771
772!
773!--    Determine if the horizontal grid and the number of PEs in ocean and
774!--    atmosphere is same or not
775       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
776            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
777       THEN
778          coupling_topology = 0
779       ELSE
780          coupling_topology = 1
781       ENDIF 
782
783!
784!--    Determine the target PEs for the exchange between ocean and
785!--    atmosphere (comm2d)
786       IF ( coupling_topology == 0 )  THEN
787!
788!--       In case of identical topologies, every atmosphere PE has exactly one
789!--       ocean PE counterpart and vice versa
790          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
791             target_id = myid + numprocs
792          ELSE
793             target_id = myid 
794          ENDIF
795
796       ELSE
797!
798!--       In case of nonequivalent topology in ocean and atmosphere only for
799!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
800!--       data echxchange between ocean and atmosphere will be done only
801!--       between these PEs.   
802          IF ( myid == 0 )  THEN
803
804             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
805                target_id = numprocs 
806             ELSE
807                target_id = 0
808             ENDIF
809
810          ENDIF
811
812       ENDIF
813
814    ENDIF
815
816!
817!-- Store partner grid point co-ordinates as lists.
818!-- Create custom MPI vector datatypes for contiguous data transfer
819    IF ( vnested )  CALL vnest_init_pegrid_domain
820
821
822#else
823
824!
825!-- Array bounds when running on a single PE (respectively a non-parallel
826!-- machine)
827    nxl = 0
828    nxr = nx
829    nnx = nxr - nxl + 1
830    nys = 0
831    nyn = ny
832    nny = nyn - nys + 1
833    nzb = 0
834    nzt = nz
835    nnz = nz
836
837    ALLOCATE( hor_index_bounds(4,0:0) )
838    hor_index_bounds(1,0) = nxl
839    hor_index_bounds(2,0) = nxr
840    hor_index_bounds(3,0) = nys
841    hor_index_bounds(4,0) = nyn
842
843!
844!-- Array bounds for the pressure solver (in the parallel code, these bounds
845!-- are the ones for the transposed arrays)
846    nys_x = nys
847    nyn_x = nyn
848    nzb_x = nzb + 1
849    nzt_x = nzt
850
851    nxl_y = nxl
852    nxr_y = nxr
853    nzb_y = nzb + 1
854    nzt_y = nzt
855
856    nxl_z = nxl
857    nxr_z = nxr
858    nys_z = nys
859    nyn_z = nyn
860
861#endif
862
863!
864!-- Calculate number of grid levels necessary for the multigrid poisson solver
865!-- as well as the gridpoint indices on each level
866    IF ( psolver(1:9) == 'multigrid' )  THEN
867
868!
869!--    First calculate number of possible grid levels for the subdomains
870       mg_levels_x = 1
871       mg_levels_y = 1
872       mg_levels_z = 1
873
874       i = nnx
875       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
876          i = i / 2
877          mg_levels_x = mg_levels_x + 1
878       ENDDO
879
880       j = nny
881       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
882          j = j / 2
883          mg_levels_y = mg_levels_y + 1
884       ENDDO
885
886       k = nz    ! do not use nnz because it might be > nz due to transposition
887                 ! requirements
888       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
889          k = k / 2
890          mg_levels_z = mg_levels_z + 1
891       ENDDO
892!
893!--    The optimized MG-solver does not allow odd values for nz at the coarsest
894!--    grid level
895       IF ( TRIM( psolver ) /= 'multigrid_noopt' )  THEN
896          IF ( MOD( k, 2 ) /= 0 )  mg_levels_z = mg_levels_z - 1
897       ENDIF
898
899       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
900
901!
902!--    Find out, if the total domain allows more levels. These additional
903!--    levels are identically processed on all PEs.
904       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
905
906          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
907
908             mg_switch_to_pe0_level_l = maximum_grid_level
909
910             mg_levels_x = 1
911             mg_levels_y = 1
912
913             i = nx+1
914             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
915                i = i / 2
916                mg_levels_x = mg_levels_x + 1
917             ENDDO
918
919             j = ny+1
920             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
921                j = j / 2
922                mg_levels_y = mg_levels_y + 1
923             ENDDO
924
925             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
926
927             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
928                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
929                                           mg_switch_to_pe0_level_l + 1
930             ELSE
931                mg_switch_to_pe0_level_l = 0
932             ENDIF
933
934          ELSE
935             mg_switch_to_pe0_level_l = 0
936             maximum_grid_level_l = maximum_grid_level
937
938          ENDIF
939
940!
941!--       Use switch level calculated above only if it is not pre-defined
942!--       by user
943          IF ( mg_switch_to_pe0_level == 0 )  THEN
944             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
945                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
946                maximum_grid_level     = maximum_grid_level_l
947             ENDIF
948
949          ELSE
950!
951!--          Check pre-defined value and reset to default, if neccessary
952             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
953                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
954                message_string = 'mg_switch_to_pe0_level ' // &
955                                 'out of range and reset to 0'
956                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
957                mg_switch_to_pe0_level = 0
958             ELSE
959!
960!--             Use the largest number of possible levels anyway and recalculate
961!--             the switch level to this largest number of possible values
962                maximum_grid_level = maximum_grid_level_l
963
964             ENDIF
965
966          ENDIF
967
968       ENDIF
969
970       ALLOCATE( grid_level_count(maximum_grid_level),                       &
971                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
972                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
973                 nzt_mg(0:maximum_grid_level) )
974
975       grid_level_count = 0
976!
977!--    Index zero required as dummy due to definition of arrays f2 and p2 in
978!--    recursive subroutine next_mg_level
979       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
980
981       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
982
983       DO  i = maximum_grid_level, 1 , -1
984
985          IF ( i == mg_switch_to_pe0_level )  THEN
986#if defined( __parallel )
987!
988!--          Save the grid size of the subdomain at the switch level, because
989!--          it is needed in poismg.
990             ind(1) = nxl_l; ind(2) = nxr_l
991             ind(3) = nys_l; ind(4) = nyn_l
992             ind(5) = nzt_l
993             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
994             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
995                                 MPI_INTEGER, comm2d, ierr )
996             DO  j = 0, numprocs-1
997                DO  k = 1, 5
998                   mg_loc_ind(k,j) = ind_all(k+j*5)
999                ENDDO
1000             ENDDO
1001             DEALLOCATE( ind_all )
1002!
1003!--          Calculate the grid size of the total domain
1004             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
1005             nxl_l = 0
1006             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
1007             nys_l = 0
1008!
1009!--          The size of this gathered array must not be larger than the
1010!--          array tend, which is used in the multigrid scheme as a temporary
1011!--          array. Therefore the subdomain size of an PE is calculated and
1012!--          the size of the gathered grid. These values are used in 
1013!--          routines pres and poismg
1014             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
1015                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
1016             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
1017                              ( nzt_l - nzb + 2 )
1018
1019#else
1020             message_string = 'multigrid gather/scatter impossible ' // &
1021                          'in non parallel mode'
1022             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
1023#endif
1024          ENDIF
1025
1026          nxl_mg(i) = nxl_l
1027          nxr_mg(i) = nxr_l
1028          nys_mg(i) = nys_l
1029          nyn_mg(i) = nyn_l
1030          nzt_mg(i) = nzt_l
1031
1032          nxl_l = nxl_l / 2 
1033          nxr_l = nxr_l / 2
1034          nys_l = nys_l / 2 
1035          nyn_l = nyn_l / 2 
1036          nzt_l = nzt_l / 2 
1037
1038       ENDDO
1039
1040!
1041!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
1042!--    if grid data are collected on PE0 already on the finest grid level.
1043!--    To be solved later.
1044       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
1045          message_string = 'grid coarsening on subdomain level cannot be performed'
1046          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
1047       ENDIF
1048
1049    ELSE
1050
1051       maximum_grid_level = 0
1052
1053    ENDIF
1054
1055!
1056!-- Default level 0 tells exchange_horiz that all ghost planes have to be
1057!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
1058!-- is required.
1059    grid_level = 0
1060
1061#if defined( __parallel )
1062!
1063!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
1064    ngp_y  = nyn - nys + 1 + 2 * nbgp
1065
1066!
1067!-- Define new MPI derived datatypes for the exchange of ghost points in
1068!-- x- and y-direction for 2D-arrays (line)
1069    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x,     &
1070                          ierr )
1071    CALL MPI_TYPE_COMMIT( type_x, ierr )
1072
1073    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1074    CALL MPI_TYPE_COMMIT( type_y, ierr )
1075!
1076!-- Define new MPI derived datatypes for the exchange of ghost points in
1077!-- x- and y-direction for 2D-INTEGER arrays (line) - on normal grid
1078    ALLOCATE( type_x_int(0:maximum_grid_level),                                &
1079              type_y_int(0:maximum_grid_level) )
1080
1081    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER,          &
1082                          type_x_int(0), ierr )
1083    CALL MPI_TYPE_COMMIT( type_x_int(0), ierr )
1084
1085    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int(0), ierr )
1086    CALL MPI_TYPE_COMMIT( type_y_int(0), ierr )
1087!
1088!-- Calculate gridpoint numbers for the exchange of ghost points along x
1089!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1090!-- exchange of ghost points in y-direction (xz-plane).
1091!-- Do these calculations for the model grid and (if necessary) also
1092!-- for the coarser grid levels used in the multigrid method
1093    ALLOCATE ( ngp_xz(0:maximum_grid_level), ngp_yz(0:maximum_grid_level),     &
1094               type_xz(0:maximum_grid_level), type_yz(0:maximum_grid_level) )
1095
1096    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1097
1098!
1099!-- Discern between the model grid, which needs nbgp ghost points and
1100!-- grid levels for the multigrid scheme. In the latter case only one
1101!-- ghost point is necessary.
1102!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1103!-- grid. The following loop is needed for data exchange in poismg.f90.
1104!
1105!-- Determine number of grid points of yz-layer for exchange
1106    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1107
1108!
1109!-- Define an MPI-datatype for the exchange of left/right boundaries.
1110!-- Although data are contiguous in physical memory (which does not
1111!-- necessarily require an MPI-derived datatype), the data exchange between
1112!-- left and right PE's using the MPI-derived type is 10% faster than without.
1113    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1114                          MPI_REAL, type_xz(0), ierr )
1115    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1116
1117    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1118                          ierr ) 
1119    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1120
1121!
1122!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1123    IF ( psolver(1:9) == 'multigrid' )  THEN
1124!   
1125!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1126       DO  i = maximum_grid_level, 1 , -1
1127!
1128!--       For 3D-exchange
1129          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1130          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1131
1132          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i), &
1133                                MPI_REAL, type_xz(i), ierr )
1134          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1135
1136          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1137                                ierr )
1138          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1139
1140
1141!--       For 2D-exchange of INTEGER arrays on coarser grid level, where 2 ghost
1142!--       points need to be exchanged.
1143          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+5, 2, nyn_l-nys_l+5, MPI_INTEGER,          &
1144                                type_x_int(i), ierr )
1145          CALL MPI_TYPE_COMMIT( type_x_int(i), ierr )
1146
1147
1148          CALL MPI_TYPE_VECTOR( 2, nyn_l-nys_l+5, nyn_l-nys_l+5, MPI_INTEGER,          &
1149                                type_y_int(i), ierr )
1150          CALL MPI_TYPE_COMMIT( type_y_int(i), ierr )
1151
1152
1153
1154          nxl_l = nxl_l / 2
1155          nxr_l = nxr_l / 2
1156          nys_l = nys_l / 2
1157          nyn_l = nyn_l / 2
1158          nzt_l = nzt_l / 2
1159
1160       ENDDO
1161
1162    ENDIF
1163!
1164!-- Define data types for exchange of 3D Integer arrays.
1165    ngp_yz_int = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1166
1167    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int, &
1168                          MPI_INTEGER, type_xz_int, ierr )
1169    CALL MPI_TYPE_COMMIT( type_xz_int, ierr )
1170
1171    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int, ngp_yz_int, MPI_INTEGER, type_yz_int, &
1172                          ierr )
1173    CALL MPI_TYPE_COMMIT( type_yz_int, ierr )
1174
1175#endif
1176
1177#if defined( __parallel )
1178!
1179!-- Setting of flags for inflow/outflow/nesting conditions.
1180    IF ( pleft == MPI_PROC_NULL )  THEN
1181       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1182          inflow_l  = .TRUE.
1183       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1184          outflow_l = .TRUE.
1185       ELSEIF ( bc_lr == 'nested' )  THEN
1186          nest_bound_l = .TRUE.
1187       ENDIF
1188    ENDIF
1189 
1190    IF ( pright == MPI_PROC_NULL )  THEN
1191       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1192          outflow_r = .TRUE.
1193       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1194          inflow_r  = .TRUE.
1195       ELSEIF ( bc_lr == 'nested' )  THEN
1196          nest_bound_r = .TRUE.
1197       ENDIF
1198    ENDIF
1199
1200    IF ( psouth == MPI_PROC_NULL )  THEN
1201       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1202          outflow_s = .TRUE.
1203       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1204          inflow_s  = .TRUE.
1205       ELSEIF ( bc_ns == 'nested' )  THEN
1206          nest_bound_s = .TRUE.
1207       ENDIF
1208    ENDIF
1209
1210    IF ( pnorth == MPI_PROC_NULL )  THEN
1211       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1212          inflow_n  = .TRUE.
1213       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1214          outflow_n = .TRUE.
1215       ELSEIF ( bc_ns == 'nested' )  THEN
1216          nest_bound_n = .TRUE.
1217       ENDIF
1218    ENDIF
1219
1220!
1221!-- Broadcast the id of the inflow PE
1222    IF ( inflow_l )  THEN
1223       id_inflow_l = myidx
1224    ELSE
1225       id_inflow_l = 0
1226    ENDIF
1227    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1228    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1229                        comm1dx, ierr )
1230
1231!
1232!-- Broadcast the id of the recycling plane
1233!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1234    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1235         NINT( recycling_width / dx ) <= nxr )  THEN
1236       id_recycling_l = myidx
1237    ELSE
1238       id_recycling_l = 0
1239    ENDIF
1240    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1241    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1242                        comm1dx, ierr )
1243
1244!
1245!-- Broadcast the id of the outflow PE and outflow-source plane
1246    IF ( turbulent_outflow )  THEN
1247
1248       IF ( outflow_r )  THEN
1249          id_outflow_l = myidx
1250       ELSE
1251          id_outflow_l = 0
1252       ENDIF
1253       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1254       CALL MPI_ALLREDUCE( id_outflow_l, id_outflow, 1, MPI_INTEGER, MPI_SUM, &
1255                           comm1dx, ierr )
1256
1257       IF ( NINT( outflow_source_plane / dx ) >= nxl  .AND. &
1258            NINT( outflow_source_plane / dx ) <= nxr )  THEN
1259          id_outflow_source_l = myidx
1260       ELSE
1261          id_outflow_source_l = 0
1262       ENDIF
1263       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1264       CALL MPI_ALLREDUCE( id_outflow_source_l, id_outflow_source, 1, &
1265                           MPI_INTEGER, MPI_SUM, comm1dx, ierr )
1266
1267    ENDIF
1268
1269    CALL location_message( 'finished', .TRUE. )
1270
1271#else
1272    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1273       inflow_l  = .TRUE.
1274       outflow_r = .TRUE.
1275    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1276       outflow_l = .TRUE.
1277       inflow_r  = .TRUE.
1278    ENDIF
1279
1280    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1281       inflow_n  = .TRUE.
1282       outflow_s = .TRUE.
1283    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1284       outflow_n = .TRUE.
1285       inflow_s  = .TRUE.
1286    ENDIF
1287#endif
1288
1289!
1290!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1291!-- one more grid point.
1292    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l )  THEN
1293       nxlu = nxl + 1
1294    ELSE
1295       nxlu = nxl
1296    ENDIF
1297    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s )  THEN
1298       nysv = nys + 1
1299    ELSE
1300       nysv = nys
1301    ENDIF
1302
1303!
1304!-- Allocate wall flag arrays used in the multigrid solver
1305    IF ( psolver(1:9) == 'multigrid' )  THEN
1306
1307       DO  i = maximum_grid_level, 1, -1
1308
1309           SELECT CASE ( i )
1310
1311              CASE ( 1 )
1312                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1313                                        nys_mg(i)-1:nyn_mg(i)+1, &
1314                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1315
1316              CASE ( 2 )
1317                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1318                                        nys_mg(i)-1:nyn_mg(i)+1, &
1319                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1320
1321              CASE ( 3 )
1322                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1323                                        nys_mg(i)-1:nyn_mg(i)+1, &
1324                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1325
1326              CASE ( 4 )
1327                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1328                                        nys_mg(i)-1:nyn_mg(i)+1, &
1329                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1330
1331              CASE ( 5 )
1332                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1333                                        nys_mg(i)-1:nyn_mg(i)+1, &
1334                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1335
1336              CASE ( 6 )
1337                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1338                                        nys_mg(i)-1:nyn_mg(i)+1, &
1339                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1340
1341              CASE ( 7 )
1342                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1343                                        nys_mg(i)-1:nyn_mg(i)+1, &
1344                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1345
1346              CASE ( 8 )
1347                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1348                                        nys_mg(i)-1:nyn_mg(i)+1, &
1349                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1350
1351              CASE ( 9 )
1352                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1353                                        nys_mg(i)-1:nyn_mg(i)+1, &
1354                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1355
1356              CASE ( 10 )
1357                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1358                                        nys_mg(i)-1:nyn_mg(i)+1, &
1359                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1360
1361              CASE DEFAULT
1362                 message_string = 'more than 10 multigrid levels'
1363                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1364
1365          END SELECT
1366
1367       ENDDO
1368
1369    ENDIF
1370
1371!
1372!-- Calculate the number of groups into which parallel I/O is split.
1373!-- The default for files which are opened by all PEs (or where each
1374!-- PE opens his own independent file) is, that all PEs are doing input/output
1375!-- in parallel at the same time. This might cause performance or even more
1376!-- severe problems depending on the configuration of the underlying file
1377!-- system.
1378!-- First, set the default:
1379    IF ( maximum_parallel_io_streams == -1  .OR. &
1380         maximum_parallel_io_streams > numprocs )  THEN
1381       maximum_parallel_io_streams = numprocs
1382    ENDIF
1383
1384!
1385!-- Now calculate the number of io_blocks and the io_group to which the
1386!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
1387!-- for all PEs belonging to the same group. A preliminary setting with myid
1388!-- based on MPI_COMM_WORLD has been done in parin.
1389    io_blocks = numprocs / maximum_parallel_io_streams
1390    io_group  = MOD( myid+1, io_blocks )
1391   
1392
1393 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.