source: palm/trunk/SOURCE/init_pegrid.f90 @ 2298

Last change on this file since 2298 was 2298, checked in by raasch, 7 years ago

write_binary is of type LOGICAL now, MPI2-related code removed, obsolete variables removed, sendrecv_in_background related parts removed, missing variable descriptions added

  • Property svn:keywords set to Id
File size: 45.0 KB
Line 
1!> @file init_pegrid.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_pegrid.f90 2298 2017-06-29 09:28:18Z raasch $
27! MPI2 related parts removed
28!
29! 2271 2017-06-09 12:34:55Z sward
30! Error message changed
31!
32! 2259 2017-06-08 09:09:11Z gronemeier
33! Implemented synthetic turbulence generator
34!
35! 2238 2017-05-31 16:49:16Z suehring
36! Remove unnecessary module load of pmc_interface
37!
38! 2231 2017-05-30 16:44:33Z suehring
39!
40! 2200 2017-04-11 11:37:51Z suehring
41! monotonic_adjustment removed
42!
43! 2197 2017-03-24 02:25:00Z raasch
44! bugfix: do not allow odd values for nz at the coarsest grid level in case of
45! optimized multigrid solver
46!
47! 2180 2017-03-17 13:33:05Z hellstea
48! Checks to ensure (2178) that pdims match the grid dimensions in the
49! automatic determination of pdims are canceled as unnecessary
50!
51! 2178 2017-03-17 11:07:39Z hellstea
52! Checks to ensure that pdims match the grid dimensions are added in the
53! automatic determination of pdims
54!
55! 2050 2016-11-08 15:00:55Z gronemeier
56! Implement turbulent outflow condition
57!
58! 2000 2016-08-20 18:09:15Z knoop
59! Forced header and separation lines into 80 columns
60!
61! 1968 2016-07-18 12:01:49Z suehring
62! Extent MPI-datatypes for exchange of 2D-INTEGER arrays on coarser multigrid
63! level 
64!
65! 1964 2016-07-14 15:35:18Z hellstea
66! Bugfix: erroneous setting of nest_bound_l/r/s/n = .TRUE. for vertical nesting mode removed.
67!
68! 1923 2016-05-31 16:37:07Z boeske
69! Initial version of purely vertical nesting introduced.
70!
71! 1922 2016-05-31 16:36:08Z boeske
72! Bugfix: array transposition checks restricted to cases if a fourier
73! transform is used , removed unused variable nnx_z
74!
75! 1833 2016-04-07 14:23:03Z raasch
76! spectra related variables moved to spectra_mod
77!
78! 1815 2016-04-06 13:49:59Z raasch
79! cpp-directives for intel openmp bug removed
80!
81! 1804 2016-04-05 16:30:18Z maronga
82! Removed code for parameter file check (__check)
83!
84! 1779 2016-03-03 08:01:28Z raasch
85! changes regarding nested domain removed: virtual PE grid will be automatically
86! calculated for nested runs too
87!
88! 1764 2016-02-28 12:45:19Z raasch
89! cpp-statements for nesting removed
90!
91! 1762 2016-02-25 12:31:13Z hellstea
92! Introduction of nested domain feature
93!
94! 1682 2015-10-07 23:56:08Z knoop
95! Code annotations made doxygen readable
96!
97! 1677 2015-10-02 13:25:23Z boeske
98! New MPI-data types for exchange of 3D integer arrays.
99!
100! 1575 2015-03-27 09:56:27Z raasch
101! adjustments for psolver-queries, calculation of ngp_xz added
102!
103! 1565 2015-03-09 20:59:31Z suehring
104! Refine if-clause for setting nbgp.
105!
106! 1557 2015-03-05 16:43:04Z suehring
107! Adjustment for monotonic limiter
108!
109! 1468 2014-09-24 14:06:57Z maronga
110! Adapted for use on up to 6-digit processor cores
111!
112! 1435 2014-07-21 10:37:02Z keck
113! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
114!
115! 1402 2014-05-09 14:25:13Z raasch
116! location messages modified
117!
118! 1384 2014-05-02 14:31:06Z raasch
119! location messages added
120!
121! 1353 2014-04-08 15:21:23Z heinze
122! REAL constants provided with KIND-attribute
123!
124! 1322 2014-03-20 16:38:49Z raasch
125! REAL functions provided with KIND-attribute
126!
127! 1320 2014-03-20 08:40:49Z raasch
128! ONLY-attribute added to USE-statements,
129! kind-parameters added to all INTEGER and REAL declaration statements,
130! kinds are defined in new module kinds,
131! revision history before 2012 removed,
132! comment fields (!:) to be used for variable explanations added to
133! all variable declaration statements
134!
135! 1304 2014-03-12 10:29:42Z raasch
136! bugfix: single core MPI runs missed some settings of transpose indices
137!
138! 1212 2013-08-15 08:46:27Z raasch
139! error message for poisfft_hybrid removed
140!
141! 1159 2013-05-21 11:58:22Z fricke
142! dirichlet/neumann and neumann/dirichlet removed
143!
144! 1139 2013-04-18 07:25:03Z raasch
145! bugfix for calculating the id of the PE carrying the recycling plane
146!
147! 1111 2013-03-08 23:54:10Z raasch
148! initialization of poisfft moved to module poisfft
149!
150! 1092 2013-02-02 11:24:22Z raasch
151! unused variables removed
152!
153! 1056 2012-11-16 15:28:04Z raasch
154! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
155! p2 as automatic arrays in recursive subroutine next_mg_level
156!
157! 1041 2012-11-06 02:36:29Z raasch
158! a 2d virtual processor topology is used by default for all machines
159!
160! 1036 2012-10-22 13:43:42Z raasch
161! code put under GPL (PALM 3.9)
162!
163! 1003 2012-09-14 14:35:53Z raasch
164! subdomains must have identical size (grid matching = "match" removed)
165!
166! 1001 2012-09-13 14:08:46Z raasch
167! all actions concerning upstream-spline-method removed
168!
169! 978 2012-08-09 08:28:32Z fricke
170! dirichlet/neumann and neumann/dirichlet added
171! nxlu and nysv are also calculated for inflow boundary
172!
173! 809 2012-01-30 13:32:58Z maronga
174! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
175!
176! 807 2012-01-25 11:53:51Z maronga
177! New cpp directive "__check" implemented which is used by check_namelist_files
178!
179! Revision 1.1  1997/07/24 11:15:09  raasch
180! Initial revision
181!
182!
183! Description:
184! ------------
185!> Determination of the virtual processor topology (if not prescribed by the
186!> user)and computation of the grid point number and array bounds of the local
187!> domains.
188!------------------------------------------------------------------------------!
189 SUBROUTINE init_pegrid
190 
191
192    USE control_parameters,                                                    &
193        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
194               coupling_topology, gathered_size, grid_level,                   &
195               grid_level_count, host, inflow_l, inflow_n, inflow_r, inflow_s, &
196               io_blocks, io_group, maximum_grid_level,                        &
197               maximum_parallel_io_streams, message_string,                    &
198               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
199               nest_bound_n, nest_bound_r, nest_bound_s, nest_domain, neutral, &
200               psolver, outflow_l, outflow_n, outflow_r, outflow_s,            &
201               outflow_source_plane, recycling_width, scalar_advec,            &
202               subdomain_size, turbulent_outflow
203
204    USE grid_variables,                                                        &
205        ONLY:  dx
206       
207    USE indices,                                                               &
208        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
209               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
210               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
211               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
212               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
213
214    USE kinds
215     
216    USE pegrid
217     
218    USE spectra_mod,                                                           &
219        ONLY:  calculate_spectra, dt_dosp
220
221    USE synthetic_turbulence_generator_mod,                                    &
222        ONLY:  use_synthetic_turbulence_generator
223
224    USE transpose_indices,                                                     &
225        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
226               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
227
228    IMPLICIT NONE
229
230    INTEGER(iwp) ::  i                        !<
231    INTEGER(iwp) ::  id_inflow_l              !<
232    INTEGER(iwp) ::  id_outflow_l             !< local value of id_outflow
233    INTEGER(iwp) ::  id_outflow_source_l      !< local value of id_outflow_source
234    INTEGER(iwp) ::  id_recycling_l           !<
235    INTEGER(iwp) ::  ind(5)                   !<
236    INTEGER(iwp) ::  j                        !<
237    INTEGER(iwp) ::  k                        !<
238    INTEGER(iwp) ::  maximum_grid_level_l     !<
239    INTEGER(iwp) ::  mg_levels_x              !<
240    INTEGER(iwp) ::  mg_levels_y              !<
241    INTEGER(iwp) ::  mg_levels_z              !<
242    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
243    INTEGER(iwp) ::  nnx_y                    !<
244    INTEGER(iwp) ::  nnx_z                    !<
245    INTEGER(iwp) ::  nny_x                    !<
246    INTEGER(iwp) ::  nny_z                    !<
247    INTEGER(iwp) ::  nnz_x                    !<
248    INTEGER(iwp) ::  nnz_y                    !<
249    INTEGER(iwp) ::  numproc_sqr              !<
250    INTEGER(iwp) ::  nxl_l                    !<
251    INTEGER(iwp) ::  nxr_l                    !<
252    INTEGER(iwp) ::  nyn_l                    !<
253    INTEGER(iwp) ::  nys_l                    !<
254    INTEGER(iwp) ::  nzb_l                    !<
255    INTEGER(iwp) ::  nzt_l                    !<
256    INTEGER(iwp) ::  omp_get_num_threads      !<
257
258    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
259    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
260    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
261    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
262    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
263
264    INTEGER(iwp), DIMENSION(2) :: pdims_remote          !<
265
266!
267!-- Get the number of OpenMP threads
268    !$OMP PARALLEL
269!$  threads_per_task = omp_get_num_threads()
270    !$OMP END PARALLEL
271
272
273#if defined( __parallel )
274
275    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
276                           .FALSE. )
277
278!
279!-- Determine the processor topology or check it, if prescribed by the user
280    IF ( npex == -1  .AND.  npey == -1 )  THEN
281
282!
283!--    Automatic determination of the topology
284       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
285       pdims(1)    = MAX( numproc_sqr , 1 )
286       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
287          pdims(1) = pdims(1) - 1
288       ENDDO
289       pdims(2) = numprocs / pdims(1)
290
291    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
292
293!
294!--    Prescribed by user. Number of processors on the prescribed topology
295!--    must be equal to the number of PEs available to the job
296       IF ( ( npex * npey ) /= numprocs )  THEN
297          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
298              'topology (', npex*npey,') does not match & the number of ', &
299              'PEs available to the job (', numprocs, ')'
300          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
301       ENDIF
302       pdims(1) = npex
303       pdims(2) = npey
304
305    ELSE
306!
307!--    If the processor topology is prescribed by the user, the number of
308!--    PEs must be given in both directions
309       message_string = 'if the processor topology is prescribed by th' //  &
310                'e user& both values of "npex" and "npey" must be given' // &
311                ' in the &NAMELIST-parameter file'
312       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
313
314    ENDIF
315
316!
317!-- For communication speedup, set barriers in front of collective
318!-- communications by default on SGI-type systems
319    IF ( host(3:5) == 'sgi' )  collective_wait = .TRUE.
320
321!
322!-- If necessary, set horizontal boundary conditions to non-cyclic
323    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
324    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
325
326
327!
328!-- Create the virtual processor grid
329    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
330                          comm2d, ierr )
331    CALL MPI_COMM_RANK( comm2d, myid, ierr )
332    WRITE (myid_char,'(''_'',I6.6)')  myid
333
334    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
335    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
336    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
337
338!
339!-- Determine sub-topologies for transpositions
340!-- Transposition from z to x:
341    remain_dims(1) = .TRUE.
342    remain_dims(2) = .FALSE.
343    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
344    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
345!
346!-- Transposition from x to y
347    remain_dims(1) = .FALSE.
348    remain_dims(2) = .TRUE.
349    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
350    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
351
352
353!
354!-- Calculate array bounds along x-direction for every PE.
355    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
356              nysf(0:pdims(2)-1) )
357
358    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
359       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
360                               'is not an& integral divisor of the number ',  &
361                               'processors (', pdims(1),')'
362       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
363    ELSE
364       nnx  = ( nx + 1 ) / pdims(1)
365       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
366          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
367                       'requirements given by the number of PEs &used',       &
368                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
369                                   - ( nx + 1 ) ) ), ' instead of nx =', nx
370          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
371       ENDIF
372    ENDIF   
373
374!
375!-- Left and right array bounds, number of gridpoints
376    DO  i = 0, pdims(1)-1
377       nxlf(i)   = i * nnx
378       nxrf(i)   = ( i + 1 ) * nnx - 1
379    ENDDO
380
381!
382!-- Calculate array bounds in y-direction for every PE.
383    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
384       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
385                           'is not an& integral divisor of the number of',     &
386                           'processors (', pdims(2),')'
387       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
388    ELSE
389       nny  = ( ny + 1 ) / pdims(2)
390       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
391          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
392                       'requirements given by the number of PEs &used ',      &
393                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
394                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
395          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
396       ENDIF
397    ENDIF   
398
399!
400!-- South and north array bounds
401    DO  j = 0, pdims(2)-1
402       nysf(j)   = j * nny
403       nynf(j)   = ( j + 1 ) * nny - 1
404    ENDDO
405
406!
407!-- Local array bounds of the respective PEs
408    nxl = nxlf(pcoord(1))
409    nxr = nxrf(pcoord(1))
410    nys = nysf(pcoord(2))
411    nyn = nynf(pcoord(2))
412    nzb = 0
413    nzt = nz
414    nnz = nz
415
416!
417!-- Set switches to define if the PE is situated at the border of the virtual
418!-- processor grid
419    IF ( nxl == 0 )   left_border_pe  = .TRUE.
420    IF ( nxr == nx )  right_border_pe = .TRUE.
421    IF ( nys == 0 )   south_border_pe = .TRUE.
422    IF ( nyn == ny )  north_border_pe = .TRUE.
423
424!
425!-- Calculate array bounds and gridpoint numbers for the transposed arrays
426!-- (needed in the pressure solver)
427!-- For the transposed arrays, cyclic boundaries as well as top and bottom
428!-- boundaries are omitted, because they are obstructive to the transposition
429
430!
431!-- 1. transposition  z --> x
432!-- This transposition is not neccessary in case of a 1d-decomposition along x
433    IF ( psolver == 'poisfft'  .OR.  calculate_spectra  .OR.                   &
434         use_synthetic_turbulence_generator )  THEN
435
436       IF ( pdims(2) /= 1 )  THEN
437          IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
438             WRITE( message_string, * ) 'transposition z --> x:',              &
439                       '&nz=',nz,' is not an integral divisior of pdims(1)=',  &
440                                                                   pdims(1)
441             CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
442          ENDIF
443       ENDIF
444
445       nys_x = nys
446       nyn_x = nyn
447       nny_x = nny
448       nnz_x = nz / pdims(1)
449       nzb_x = 1 + myidx * nnz_x
450       nzt_x = ( myidx + 1 ) * nnz_x
451       sendrecvcount_zx = nnx * nny * nnz_x
452
453    ENDIF
454
455
456    IF ( psolver == 'poisfft' )  THEN 
457!
458!--    2. transposition  x --> y
459       IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
460          WRITE( message_string, * ) 'transposition x --> y:',                 &
461                            '&nx+1=',nx+1,' is not an integral divisor of ',   &
462                            'pdims(2)=',pdims(2)
463          CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
464       ENDIF
465
466       nnz_y = nnz_x
467       nzb_y = nzb_x
468       nzt_y = nzt_x
469       nnx_y = (nx+1) / pdims(2)
470       nxl_y = myidy * nnx_y
471       nxr_y = ( myidy + 1 ) * nnx_y - 1
472       sendrecvcount_xy = nnx_y * nny_x * nnz_y
473!
474!--    3. transposition  y --> z 
475!--    (ELSE:  x --> y  in case of 1D-decomposition along x)
476       nxl_z = nxl_y
477       nxr_z = nxr_y
478       nny_z = (ny+1) / pdims(1)
479       nys_z = myidx * nny_z
480       nyn_z = ( myidx + 1 ) * nny_z - 1
481       sendrecvcount_yz = nnx_y * nny_z * nnz_y
482
483       IF ( pdims(2) /= 1 )  THEN
484!
485!--       y --> z
486!--       This transposition is not neccessary in case of a 1d-decomposition
487!--       along x, except that the uptream-spline method is switched on
488          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
489             WRITE( message_string, * ) 'transposition y --> z:',              &
490                               '& ny+1=',ny+1,' is not an integral divisor of',&
491                               ' pdims(1)=',pdims(1)
492             CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
493          ENDIF
494
495       ELSE
496!
497!--       x --> y
498!--       This condition must be fulfilled for a 1D-decomposition along x
499          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
500             WRITE( message_string, * ) 'transposition x --> y:',              &
501                               '& ny+1=',ny+1,' is not an integral divisor of',&
502                               ' pdims(1)=',pdims(1)
503             CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
504          ENDIF
505
506       ENDIF
507
508    ENDIF
509
510!
511!-- Indices for direct transpositions z --> y (used for calculating spectra)
512    IF ( calculate_spectra )  THEN
513       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
514          WRITE( message_string, * ) 'direct transposition z --> y (needed ',  &
515                    'for spectra):& nz=',nz,' is not an integral divisor of ', &
516                    'pdims(2)=',pdims(2)
517          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
518       ELSE
519          nxl_yd = nxl
520          nxr_yd = nxr
521          nzb_yd = 1 + myidy * ( nz / pdims(2) )
522          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
523          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
524       ENDIF
525    ENDIF
526
527    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
528!
529!--    Indices for direct transpositions y --> x
530!--    (they are only possible in case of a 1d-decomposition along x)
531       IF ( pdims(2) == 1 )  THEN
532          nny_x = nny / pdims(1)
533          nys_x = myid * nny_x
534          nyn_x = ( myid + 1 ) * nny_x - 1
535          nzb_x = 1
536          nzt_x = nz
537          sendrecvcount_xy = nnx * nny_x * nz
538       ENDIF
539
540    ENDIF
541
542    IF ( psolver == 'poisfft' )  THEN
543!
544!--    Indices for direct transpositions x --> y
545!--    (they are only possible in case of a 1d-decomposition along y)
546       IF ( pdims(1) == 1 )  THEN
547          nnx_y = nnx / pdims(2)
548          nxl_y = myid * nnx_y
549          nxr_y = ( myid + 1 ) * nnx_y - 1
550          nzb_y = 1
551          nzt_y = nz
552          sendrecvcount_xy = nnx_y * nny * nz
553       ENDIF
554
555    ENDIF
556
557!
558!-- Arrays for storing the array bounds are needed any more
559    DEALLOCATE( nxlf , nxrf , nynf , nysf )
560
561
562!
563!-- Collect index bounds from other PEs (to be written to restart file later)
564    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
565
566    IF ( myid == 0 )  THEN
567
568       hor_index_bounds(1,0) = nxl
569       hor_index_bounds(2,0) = nxr
570       hor_index_bounds(3,0) = nys
571       hor_index_bounds(4,0) = nyn
572
573!
574!--    Receive data from all other PEs
575       DO  i = 1, numprocs-1
576          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
577                         ierr )
578          hor_index_bounds(:,i) = ibuf(1:4)
579       ENDDO
580
581    ELSE
582!
583!--    Send index bounds to PE0
584       ibuf(1) = nxl
585       ibuf(2) = nxr
586       ibuf(3) = nys
587       ibuf(4) = nyn
588       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
589
590    ENDIF
591
592
593#if defined( __print )
594!
595!-- Control output
596    IF ( myid == 0 )  THEN
597       PRINT*, '*** processor topology ***'
598       PRINT*, ' '
599       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
600               &'   nys: nyn'
601       PRINT*, '------------------------------------------------------------',&
602               &'-----------'
603       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
604                       myidx, myidy, nxl, nxr, nys, nyn
6051000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
606               2(2X,I4,':',I4))
607
608!
609!--    Receive data from the other PEs
610       DO  i = 1,numprocs-1
611          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
612                         ierr )
613          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
614       ENDDO
615    ELSE
616
617!
618!--    Send data to PE0
619       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
620       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
621       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
622       ibuf(12) = nyn
623       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
624    ENDIF
625#endif
626
627#if defined( __parallel )
628
629!
630!-- Determine the number of ghost point layers
631    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
632         momentum_advec == 'ws-scheme' )  THEN
633       nbgp = 3
634    ELSE
635       nbgp = 1
636    ENDIF 
637
638!
639!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
640!-- which is needed for coupled atmosphere-ocean runs.
641!-- First, calculate number of grid points of an xy-plane.
642    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
643    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
644    CALL MPI_TYPE_COMMIT( type_xy, ierr )
645
646    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
647   
648!
649!--    Pass the number of grid points of the atmosphere model to
650!--    the ocean model and vice versa
651       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
652
653          nx_a = nx
654          ny_a = ny
655
656          IF ( myid == 0 )  THEN
657
658             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
659                            ierr )
660             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
661                            ierr )
662             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
663                            ierr )
664             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
665                            status, ierr )
666             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
667                            status, ierr )
668             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
669                            comm_inter, status, ierr )
670          ENDIF
671
672          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
673          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
674          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
675       
676       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
677
678          nx_o = nx
679          ny_o = ny 
680
681          IF ( myid == 0 ) THEN
682
683             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
684                            ierr )
685             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
686                            ierr )
687             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
688                            status, ierr )
689             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
690             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
691             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
692          ENDIF
693
694          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
695          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
696          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
697
698       ENDIF
699 
700       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
701       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
702
703!
704!--    Determine if the horizontal grid and the number of PEs in ocean and
705!--    atmosphere is same or not
706       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
707            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
708       THEN
709          coupling_topology = 0
710       ELSE
711          coupling_topology = 1
712       ENDIF 
713
714!
715!--    Determine the target PEs for the exchange between ocean and
716!--    atmosphere (comm2d)
717       IF ( coupling_topology == 0 )  THEN
718!
719!--       In case of identical topologies, every atmosphere PE has exactly one
720!--       ocean PE counterpart and vice versa
721          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
722             target_id = myid + numprocs
723          ELSE
724             target_id = myid 
725          ENDIF
726
727       ELSE
728!
729!--       In case of nonequivalent topology in ocean and atmosphere only for
730!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
731!--       data echxchange between ocean and atmosphere will be done only
732!--       between these PEs.   
733          IF ( myid == 0 )  THEN
734
735             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
736                target_id = numprocs 
737             ELSE
738                target_id = 0
739             ENDIF
740
741          ENDIF
742
743       ENDIF
744
745    ENDIF
746
747
748#endif
749
750#else
751
752!
753!-- Array bounds when running on a single PE (respectively a non-parallel
754!-- machine)
755    nxl = 0
756    nxr = nx
757    nnx = nxr - nxl + 1
758    nys = 0
759    nyn = ny
760    nny = nyn - nys + 1
761    nzb = 0
762    nzt = nz
763    nnz = nz
764
765    ALLOCATE( hor_index_bounds(4,0:0) )
766    hor_index_bounds(1,0) = nxl
767    hor_index_bounds(2,0) = nxr
768    hor_index_bounds(3,0) = nys
769    hor_index_bounds(4,0) = nyn
770
771!
772!-- Array bounds for the pressure solver (in the parallel code, these bounds
773!-- are the ones for the transposed arrays)
774    nys_x = nys
775    nyn_x = nyn
776    nzb_x = nzb + 1
777    nzt_x = nzt
778
779    nxl_y = nxl
780    nxr_y = nxr
781    nzb_y = nzb + 1
782    nzt_y = nzt
783
784    nxl_z = nxl
785    nxr_z = nxr
786    nys_z = nys
787    nyn_z = nyn
788
789#endif
790
791!
792!-- Calculate number of grid levels necessary for the multigrid poisson solver
793!-- as well as the gridpoint indices on each level
794    IF ( psolver(1:9) == 'multigrid' )  THEN
795
796!
797!--    First calculate number of possible grid levels for the subdomains
798       mg_levels_x = 1
799       mg_levels_y = 1
800       mg_levels_z = 1
801
802       i = nnx
803       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
804          i = i / 2
805          mg_levels_x = mg_levels_x + 1
806       ENDDO
807
808       j = nny
809       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
810          j = j / 2
811          mg_levels_y = mg_levels_y + 1
812       ENDDO
813
814       k = nz    ! do not use nnz because it might be > nz due to transposition
815                 ! requirements
816       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
817          k = k / 2
818          mg_levels_z = mg_levels_z + 1
819       ENDDO
820!
821!--    The optimized MG-solver does not allow odd values for nz at the coarsest
822!--    grid level
823       IF ( TRIM( psolver ) /= 'multigrid_noopt' )  THEN
824          IF ( MOD( k, 2 ) /= 0 )  mg_levels_z = mg_levels_z - 1
825       ENDIF
826
827       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
828
829!
830!--    Find out, if the total domain allows more levels. These additional
831!--    levels are identically processed on all PEs.
832       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
833
834          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
835
836             mg_switch_to_pe0_level_l = maximum_grid_level
837
838             mg_levels_x = 1
839             mg_levels_y = 1
840
841             i = nx+1
842             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
843                i = i / 2
844                mg_levels_x = mg_levels_x + 1
845             ENDDO
846
847             j = ny+1
848             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
849                j = j / 2
850                mg_levels_y = mg_levels_y + 1
851             ENDDO
852
853             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
854
855             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
856                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
857                                           mg_switch_to_pe0_level_l + 1
858             ELSE
859                mg_switch_to_pe0_level_l = 0
860             ENDIF
861
862          ELSE
863             mg_switch_to_pe0_level_l = 0
864             maximum_grid_level_l = maximum_grid_level
865
866          ENDIF
867
868!
869!--       Use switch level calculated above only if it is not pre-defined
870!--       by user
871          IF ( mg_switch_to_pe0_level == 0 )  THEN
872             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
873                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
874                maximum_grid_level     = maximum_grid_level_l
875             ENDIF
876
877          ELSE
878!
879!--          Check pre-defined value and reset to default, if neccessary
880             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
881                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
882                message_string = 'mg_switch_to_pe0_level ' // &
883                                 'out of range and reset to 0'
884                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
885                mg_switch_to_pe0_level = 0
886             ELSE
887!
888!--             Use the largest number of possible levels anyway and recalculate
889!--             the switch level to this largest number of possible values
890                maximum_grid_level = maximum_grid_level_l
891
892             ENDIF
893
894          ENDIF
895
896       ENDIF
897
898       ALLOCATE( grid_level_count(maximum_grid_level),                       &
899                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
900                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
901                 nzt_mg(0:maximum_grid_level) )
902
903       grid_level_count = 0
904!
905!--    Index zero required as dummy due to definition of arrays f2 and p2 in
906!--    recursive subroutine next_mg_level
907       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
908
909       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
910
911       DO  i = maximum_grid_level, 1 , -1
912
913          IF ( i == mg_switch_to_pe0_level )  THEN
914#if defined( __parallel )
915!
916!--          Save the grid size of the subdomain at the switch level, because
917!--          it is needed in poismg.
918             ind(1) = nxl_l; ind(2) = nxr_l
919             ind(3) = nys_l; ind(4) = nyn_l
920             ind(5) = nzt_l
921             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
922             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
923                                 MPI_INTEGER, comm2d, ierr )
924             DO  j = 0, numprocs-1
925                DO  k = 1, 5
926                   mg_loc_ind(k,j) = ind_all(k+j*5)
927                ENDDO
928             ENDDO
929             DEALLOCATE( ind_all )
930!
931!--          Calculate the grid size of the total domain
932             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
933             nxl_l = 0
934             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
935             nys_l = 0
936!
937!--          The size of this gathered array must not be larger than the
938!--          array tend, which is used in the multigrid scheme as a temporary
939!--          array. Therefore the subdomain size of an PE is calculated and
940!--          the size of the gathered grid. These values are used in 
941!--          routines pres and poismg
942             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
943                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
944             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
945                              ( nzt_l - nzb + 2 )
946
947#else
948             message_string = 'multigrid gather/scatter impossible ' // &
949                          'in non parallel mode'
950             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
951#endif
952          ENDIF
953
954          nxl_mg(i) = nxl_l
955          nxr_mg(i) = nxr_l
956          nys_mg(i) = nys_l
957          nyn_mg(i) = nyn_l
958          nzt_mg(i) = nzt_l
959
960          nxl_l = nxl_l / 2 
961          nxr_l = nxr_l / 2
962          nys_l = nys_l / 2 
963          nyn_l = nyn_l / 2 
964          nzt_l = nzt_l / 2 
965
966       ENDDO
967
968!
969!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
970!--    if grid data are collected on PE0 already on the finest grid level.
971!--    To be solved later.
972       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
973          message_string = 'grid coarsening on subdomain level cannot be performed'
974          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
975       ENDIF
976
977    ELSE
978
979       maximum_grid_level = 0
980
981    ENDIF
982
983!
984!-- Default level 0 tells exchange_horiz that all ghost planes have to be
985!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
986!-- is required.
987    grid_level = 0
988
989#if defined( __parallel )
990!
991!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
992    ngp_y  = nyn - nys + 1 + 2 * nbgp
993
994!
995!-- Define new MPI derived datatypes for the exchange of ghost points in
996!-- x- and y-direction for 2D-arrays (line)
997    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x,     &
998                          ierr )
999    CALL MPI_TYPE_COMMIT( type_x, ierr )
1000
1001    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1002    CALL MPI_TYPE_COMMIT( type_y, ierr )
1003!
1004!-- Define new MPI derived datatypes for the exchange of ghost points in
1005!-- x- and y-direction for 2D-INTEGER arrays (line) - on normal grid
1006    ALLOCATE( type_x_int(0:maximum_grid_level),                                &
1007              type_y_int(0:maximum_grid_level) )
1008
1009    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER,          &
1010                          type_x_int(0), ierr )
1011    CALL MPI_TYPE_COMMIT( type_x_int(0), ierr )
1012
1013    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int(0), ierr )
1014    CALL MPI_TYPE_COMMIT( type_y_int(0), ierr )
1015!
1016!-- Calculate gridpoint numbers for the exchange of ghost points along x
1017!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1018!-- exchange of ghost points in y-direction (xz-plane).
1019!-- Do these calculations for the model grid and (if necessary) also
1020!-- for the coarser grid levels used in the multigrid method
1021    ALLOCATE ( ngp_xz(0:maximum_grid_level), ngp_yz(0:maximum_grid_level),     &
1022               type_xz(0:maximum_grid_level), type_yz(0:maximum_grid_level) )
1023
1024    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1025
1026!
1027!-- Discern between the model grid, which needs nbgp ghost points and
1028!-- grid levels for the multigrid scheme. In the latter case only one
1029!-- ghost point is necessary.
1030!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1031!-- grid. The following loop is needed for data exchange in poismg.f90.
1032!
1033!-- Determine number of grid points of yz-layer for exchange
1034    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1035
1036!
1037!-- Define an MPI-datatype for the exchange of left/right boundaries.
1038!-- Although data are contiguous in physical memory (which does not
1039!-- necessarily require an MPI-derived datatype), the data exchange between
1040!-- left and right PE's using the MPI-derived type is 10% faster than without.
1041    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1042                          MPI_REAL, type_xz(0), ierr )
1043    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1044
1045    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1046                          ierr ) 
1047    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1048
1049!
1050!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1051    IF ( psolver(1:9) == 'multigrid' )  THEN
1052!   
1053!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1054       DO  i = maximum_grid_level, 1 , -1
1055!
1056!--       For 3D-exchange
1057          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1058          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1059
1060          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i), &
1061                                MPI_REAL, type_xz(i), ierr )
1062          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1063
1064          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1065                                ierr )
1066          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1067
1068
1069!--       For 2D-exchange of INTEGER arrays on coarser grid level, where 2 ghost
1070!--       points need to be exchanged.
1071          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+5, 2, nyn_l-nys_l+5, MPI_INTEGER,          &
1072                                type_x_int(i), ierr )
1073          CALL MPI_TYPE_COMMIT( type_x_int(i), ierr )
1074
1075
1076          CALL MPI_TYPE_VECTOR( 2, nyn_l-nys_l+5, nyn_l-nys_l+5, MPI_INTEGER,          &
1077                                type_y_int(i), ierr )
1078          CALL MPI_TYPE_COMMIT( type_y_int(i), ierr )
1079
1080
1081
1082          nxl_l = nxl_l / 2
1083          nxr_l = nxr_l / 2
1084          nys_l = nys_l / 2
1085          nyn_l = nyn_l / 2
1086          nzt_l = nzt_l / 2
1087
1088       ENDDO
1089
1090    ENDIF
1091!
1092!-- Define data types for exchange of 3D Integer arrays.
1093    ngp_yz_int = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1094
1095    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int, &
1096                          MPI_INTEGER, type_xz_int, ierr )
1097    CALL MPI_TYPE_COMMIT( type_xz_int, ierr )
1098
1099    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int, ngp_yz_int, MPI_INTEGER, type_yz_int, &
1100                          ierr )
1101    CALL MPI_TYPE_COMMIT( type_yz_int, ierr )
1102
1103#endif
1104
1105#if defined( __parallel )
1106!
1107!-- Setting of flags for inflow/outflow/nesting conditions.
1108    IF ( pleft == MPI_PROC_NULL )  THEN
1109       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1110          inflow_l  = .TRUE.
1111       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1112          outflow_l = .TRUE.
1113       ELSEIF ( bc_lr == 'nested' )  THEN
1114          nest_bound_l = .TRUE.
1115       ENDIF
1116    ENDIF
1117 
1118    IF ( pright == MPI_PROC_NULL )  THEN
1119       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1120          outflow_r = .TRUE.
1121       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1122          inflow_r  = .TRUE.
1123       ELSEIF ( bc_lr == 'nested' )  THEN
1124          nest_bound_r = .TRUE.
1125       ENDIF
1126    ENDIF
1127
1128    IF ( psouth == MPI_PROC_NULL )  THEN
1129       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1130          outflow_s = .TRUE.
1131       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1132          inflow_s  = .TRUE.
1133       ELSEIF ( bc_ns == 'nested' )  THEN
1134          nest_bound_s = .TRUE.
1135       ENDIF
1136    ENDIF
1137
1138    IF ( pnorth == MPI_PROC_NULL )  THEN
1139       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1140          inflow_n  = .TRUE.
1141       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1142          outflow_n = .TRUE.
1143       ELSEIF ( bc_ns == 'nested' )  THEN
1144          nest_bound_n = .TRUE.
1145       ENDIF
1146    ENDIF
1147
1148!
1149!-- Broadcast the id of the inflow PE
1150    IF ( inflow_l )  THEN
1151       id_inflow_l = myidx
1152    ELSE
1153       id_inflow_l = 0
1154    ENDIF
1155    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1156    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1157                        comm1dx, ierr )
1158
1159!
1160!-- Broadcast the id of the recycling plane
1161!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1162    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1163         NINT( recycling_width / dx ) <= nxr )  THEN
1164       id_recycling_l = myidx
1165    ELSE
1166       id_recycling_l = 0
1167    ENDIF
1168    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1169    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1170                        comm1dx, ierr )
1171
1172!
1173!-- Broadcast the id of the outflow PE and outflow-source plane
1174    IF ( turbulent_outflow )  THEN
1175
1176       IF ( outflow_r )  THEN
1177          id_outflow_l = myidx
1178       ELSE
1179          id_outflow_l = 0
1180       ENDIF
1181       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1182       CALL MPI_ALLREDUCE( id_outflow_l, id_outflow, 1, MPI_INTEGER, MPI_SUM, &
1183                           comm1dx, ierr )
1184
1185       IF ( NINT( outflow_source_plane / dx ) >= nxl  .AND. &
1186            NINT( outflow_source_plane / dx ) <= nxr )  THEN
1187          id_outflow_source_l = myidx
1188       ELSE
1189          id_outflow_source_l = 0
1190       ENDIF
1191       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1192       CALL MPI_ALLREDUCE( id_outflow_source_l, id_outflow_source, 1, &
1193                           MPI_INTEGER, MPI_SUM, comm1dx, ierr )
1194
1195    ENDIF
1196
1197    CALL location_message( 'finished', .TRUE. )
1198
1199#else
1200    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1201       inflow_l  = .TRUE.
1202       outflow_r = .TRUE.
1203    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1204       outflow_l = .TRUE.
1205       inflow_r  = .TRUE.
1206    ENDIF
1207
1208    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1209       inflow_n  = .TRUE.
1210       outflow_s = .TRUE.
1211    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1212       outflow_n = .TRUE.
1213       inflow_s  = .TRUE.
1214    ENDIF
1215#endif
1216
1217!
1218!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1219!-- one more grid point.
1220    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l )  THEN
1221       nxlu = nxl + 1
1222    ELSE
1223       nxlu = nxl
1224    ENDIF
1225    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s )  THEN
1226       nysv = nys + 1
1227    ELSE
1228       nysv = nys
1229    ENDIF
1230
1231!
1232!-- Allocate wall flag arrays used in the multigrid solver
1233    IF ( psolver(1:9) == 'multigrid' )  THEN
1234
1235       DO  i = maximum_grid_level, 1, -1
1236
1237           SELECT CASE ( i )
1238
1239              CASE ( 1 )
1240                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1241                                        nys_mg(i)-1:nyn_mg(i)+1, &
1242                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1243
1244              CASE ( 2 )
1245                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1246                                        nys_mg(i)-1:nyn_mg(i)+1, &
1247                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1248
1249              CASE ( 3 )
1250                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1251                                        nys_mg(i)-1:nyn_mg(i)+1, &
1252                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1253
1254              CASE ( 4 )
1255                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1256                                        nys_mg(i)-1:nyn_mg(i)+1, &
1257                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1258
1259              CASE ( 5 )
1260                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1261                                        nys_mg(i)-1:nyn_mg(i)+1, &
1262                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1263
1264              CASE ( 6 )
1265                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1266                                        nys_mg(i)-1:nyn_mg(i)+1, &
1267                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1268
1269              CASE ( 7 )
1270                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1271                                        nys_mg(i)-1:nyn_mg(i)+1, &
1272                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1273
1274              CASE ( 8 )
1275                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1276                                        nys_mg(i)-1:nyn_mg(i)+1, &
1277                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1278
1279              CASE ( 9 )
1280                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1281                                        nys_mg(i)-1:nyn_mg(i)+1, &
1282                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1283
1284              CASE ( 10 )
1285                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1286                                        nys_mg(i)-1:nyn_mg(i)+1, &
1287                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1288
1289              CASE DEFAULT
1290                 message_string = 'more than 10 multigrid levels'
1291                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1292
1293          END SELECT
1294
1295       ENDDO
1296
1297    ENDIF
1298
1299!
1300!-- Calculate the number of groups into which parallel I/O is split.
1301!-- The default for files which are opened by all PEs (or where each
1302!-- PE opens his own independent file) is, that all PEs are doing input/output
1303!-- in parallel at the same time. This might cause performance or even more
1304!-- severe problems depending on the configuration of the underlying file
1305!-- system.
1306!-- First, set the default:
1307    IF ( maximum_parallel_io_streams == -1  .OR. &
1308         maximum_parallel_io_streams > numprocs )  THEN
1309       maximum_parallel_io_streams = numprocs
1310    ENDIF
1311
1312!
1313!-- Now calculate the number of io_blocks and the io_group to which the
1314!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
1315!-- for all PEs belonging to the same group. A preliminary setting with myid
1316!-- based on MPI_COMM_WORLD has been done in parin.
1317    io_blocks = numprocs / maximum_parallel_io_streams
1318    io_group  = MOD( myid+1, io_blocks )
1319   
1320
1321 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.