source: palm/trunk/SOURCE/init_pegrid.f90 @ 2238

Last change on this file since 2238 was 2238, checked in by suehring, 4 years ago

Further bugfixes in Makefile; remove unnecessary module load in init_pegrid

  • Property svn:keywords set to Id
File size: 46.8 KB
Line 
1!> @file init_pegrid.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_pegrid.f90 2238 2017-05-31 16:49:16Z suehring $
27! Remove unnecessary module load of pmc_interface
28!
29! 2231 2017-05-30 16:44:33Z suehring
30!
31! 2200 2017-04-11 11:37:51Z suehring
32! monotonic_adjustment removed
33!
34! 2197 2017-03-24 02:25:00Z raasch
35! bugfix: do not allow odd values for nz at the coarsest grid level in case of
36! optimized multigrid solver
37!
38! 2180 2017-03-17 13:33:05Z hellstea
39! Checks to ensure (2178) that pdims match the grid dimensions in the
40! automatic determination of pdims are canceled as unnecessary
41!
42! 2178 2017-03-17 11:07:39Z hellstea
43! Checks to ensure that pdims match the grid dimensions are added in the
44! automatic determination of pdims
45!
46! 2050 2016-11-08 15:00:55Z gronemeier
47! Implement turbulent outflow condition
48!
49! 2000 2016-08-20 18:09:15Z knoop
50! Forced header and separation lines into 80 columns
51!
52! 1968 2016-07-18 12:01:49Z suehring
53! Extent MPI-datatypes for exchange of 2D-INTEGER arrays on coarser multigrid
54! level 
55!
56! 1964 2016-07-14 15:35:18Z hellstea
57! Bugfix: erroneous setting of nest_bound_l/r/s/n = .TRUE. for vertical nesting mode removed.
58!
59! 1923 2016-05-31 16:37:07Z boeske
60! Initial version of purely vertical nesting introduced.
61!
62! 1922 2016-05-31 16:36:08Z boeske
63! Bugfix: array transposition checks restricted to cases if a fourier
64! transform is used , removed unused variable nnx_z
65!
66! 1833 2016-04-07 14:23:03Z raasch
67! spectra related variables moved to spectra_mod
68!
69! 1815 2016-04-06 13:49:59Z raasch
70! cpp-directives for intel openmp bug removed
71!
72! 1804 2016-04-05 16:30:18Z maronga
73! Removed code for parameter file check (__check)
74!
75! 1779 2016-03-03 08:01:28Z raasch
76! changes regarding nested domain removed: virtual PE grid will be automatically
77! calculated for nested runs too
78!
79! 1764 2016-02-28 12:45:19Z raasch
80! cpp-statements for nesting removed
81!
82! 1762 2016-02-25 12:31:13Z hellstea
83! Introduction of nested domain feature
84!
85! 1682 2015-10-07 23:56:08Z knoop
86! Code annotations made doxygen readable
87!
88! 1677 2015-10-02 13:25:23Z boeske
89! New MPI-data types for exchange of 3D integer arrays.
90!
91! 1575 2015-03-27 09:56:27Z raasch
92! adjustments for psolver-queries, calculation of ngp_xz added
93!
94! 1565 2015-03-09 20:59:31Z suehring
95! Refine if-clause for setting nbgp.
96!
97! 1557 2015-03-05 16:43:04Z suehring
98! Adjustment for monotonic limiter
99!
100! 1468 2014-09-24 14:06:57Z maronga
101! Adapted for use on up to 6-digit processor cores
102!
103! 1435 2014-07-21 10:37:02Z keck
104! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
105!
106! 1402 2014-05-09 14:25:13Z raasch
107! location messages modified
108!
109! 1384 2014-05-02 14:31:06Z raasch
110! location messages added
111!
112! 1353 2014-04-08 15:21:23Z heinze
113! REAL constants provided with KIND-attribute
114!
115! 1322 2014-03-20 16:38:49Z raasch
116! REAL functions provided with KIND-attribute
117!
118! 1320 2014-03-20 08:40:49Z raasch
119! ONLY-attribute added to USE-statements,
120! kind-parameters added to all INTEGER and REAL declaration statements,
121! kinds are defined in new module kinds,
122! revision history before 2012 removed,
123! comment fields (!:) to be used for variable explanations added to
124! all variable declaration statements
125!
126! 1304 2014-03-12 10:29:42Z raasch
127! bugfix: single core MPI runs missed some settings of transpose indices
128!
129! 1212 2013-08-15 08:46:27Z raasch
130! error message for poisfft_hybrid removed
131!
132! 1159 2013-05-21 11:58:22Z fricke
133! dirichlet/neumann and neumann/dirichlet removed
134!
135! 1139 2013-04-18 07:25:03Z raasch
136! bugfix for calculating the id of the PE carrying the recycling plane
137!
138! 1111 2013-03-08 23:54:10Z raasch
139! initialization of poisfft moved to module poisfft
140!
141! 1092 2013-02-02 11:24:22Z raasch
142! unused variables removed
143!
144! 1056 2012-11-16 15:28:04Z raasch
145! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
146! p2 as automatic arrays in recursive subroutine next_mg_level
147!
148! 1041 2012-11-06 02:36:29Z raasch
149! a 2d virtual processor topology is used by default for all machines
150!
151! 1036 2012-10-22 13:43:42Z raasch
152! code put under GPL (PALM 3.9)
153!
154! 1003 2012-09-14 14:35:53Z raasch
155! subdomains must have identical size (grid matching = "match" removed)
156!
157! 1001 2012-09-13 14:08:46Z raasch
158! all actions concerning upstream-spline-method removed
159!
160! 978 2012-08-09 08:28:32Z fricke
161! dirichlet/neumann and neumann/dirichlet added
162! nxlu and nysv are also calculated for inflow boundary
163!
164! 809 2012-01-30 13:32:58Z maronga
165! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
166!
167! 807 2012-01-25 11:53:51Z maronga
168! New cpp directive "__check" implemented which is used by check_namelist_files
169!
170! Revision 1.1  1997/07/24 11:15:09  raasch
171! Initial revision
172!
173!
174! Description:
175! ------------
176!> Determination of the virtual processor topology (if not prescribed by the
177!> user)and computation of the grid point number and array bounds of the local
178!> domains.
179!------------------------------------------------------------------------------!
180 SUBROUTINE init_pegrid
181 
182
183    USE control_parameters,                                                    &
184        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
185               coupling_topology, gathered_size, grid_level,                   &
186               grid_level_count, host, inflow_l, inflow_n, inflow_r, inflow_s, &
187               io_blocks, io_group, maximum_grid_level,                        &
188               maximum_parallel_io_streams, message_string,                    &
189               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
190               nest_bound_n, nest_bound_r, nest_bound_s, nest_domain, neutral, &
191               psolver, outflow_l, outflow_n, outflow_r, outflow_s,            &
192               outflow_source_plane, recycling_width, scalar_advec,            &
193               subdomain_size, turbulent_outflow
194
195    USE grid_variables,                                                        &
196        ONLY:  dx
197       
198    USE indices,                                                               &
199        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
200               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
201               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
202               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
203               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
204
205    USE kinds
206     
207    USE pegrid
208     
209    USE spectra_mod,                                                           &
210        ONLY:  calculate_spectra, dt_dosp
211
212    USE transpose_indices,                                                     &
213        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
214               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
215
216    IMPLICIT NONE
217
218    INTEGER(iwp) ::  i                        !<
219    INTEGER(iwp) ::  id_inflow_l              !<
220    INTEGER(iwp) ::  id_outflow_l             !< local value of id_outflow
221    INTEGER(iwp) ::  id_outflow_source_l      !< local value of id_outflow_source
222    INTEGER(iwp) ::  id_recycling_l           !<
223    INTEGER(iwp) ::  ind(5)                   !<
224    INTEGER(iwp) ::  j                        !<
225    INTEGER(iwp) ::  k                        !<
226    INTEGER(iwp) ::  maximum_grid_level_l     !<
227    INTEGER(iwp) ::  mg_levels_x              !<
228    INTEGER(iwp) ::  mg_levels_y              !<
229    INTEGER(iwp) ::  mg_levels_z              !<
230    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
231    INTEGER(iwp) ::  nnx_y                    !<
232    INTEGER(iwp) ::  nnx_z                    !<
233    INTEGER(iwp) ::  nny_x                    !<
234    INTEGER(iwp) ::  nny_z                    !<
235    INTEGER(iwp) ::  nnz_x                    !<
236    INTEGER(iwp) ::  nnz_y                    !<
237    INTEGER(iwp) ::  numproc_sqr              !<
238    INTEGER(iwp) ::  nxl_l                    !<
239    INTEGER(iwp) ::  nxr_l                    !<
240    INTEGER(iwp) ::  nyn_l                    !<
241    INTEGER(iwp) ::  nys_l                    !<
242    INTEGER(iwp) ::  nzb_l                    !<
243    INTEGER(iwp) ::  nzt_l                    !<
244    INTEGER(iwp) ::  omp_get_num_threads      !<
245
246    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
247    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
248    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
249    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
250    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
251
252    INTEGER(iwp), DIMENSION(2) :: pdims_remote          !<
253
254#if defined( __mpi2 )
255    LOGICAL ::  found                                   !<
256#endif
257
258!
259!-- Get the number of OpenMP threads
260    !$OMP PARALLEL
261!$  threads_per_task = omp_get_num_threads()
262    !$OMP END PARALLEL
263
264
265#if defined( __parallel )
266
267    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
268                           .FALSE. )
269
270!
271!-- Determine the processor topology or check it, if prescribed by the user
272    IF ( npex == -1  .AND.  npey == -1 )  THEN
273
274!
275!--    Automatic determination of the topology
276       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
277       pdims(1)    = MAX( numproc_sqr , 1 )
278       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
279          pdims(1) = pdims(1) - 1
280       ENDDO
281       pdims(2) = numprocs / pdims(1)
282
283    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
284
285!
286!--    Prescribed by user. Number of processors on the prescribed topology
287!--    must be equal to the number of PEs available to the job
288       IF ( ( npex * npey ) /= numprocs )  THEN
289          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
290              'topology (', npex*npey,') does not match & the number of ', &
291              'PEs available to the job (', numprocs, ')'
292          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
293       ENDIF
294       pdims(1) = npex
295       pdims(2) = npey
296
297    ELSE
298!
299!--    If the processor topology is prescribed by the user, the number of
300!--    PEs must be given in both directions
301       message_string = 'if the processor topology is prescribed by th' //  &
302                'e user& both values of "npex" and "npey" must be given' // &
303                ' in the &NAMELIST-parameter file'
304       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
305
306    ENDIF
307
308!
309!-- For communication speedup, set barriers in front of collective
310!-- communications by default on SGI-type systems
311    IF ( host(3:5) == 'sgi' )  collective_wait = .TRUE.
312
313!
314!-- If necessary, set horizontal boundary conditions to non-cyclic
315    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
316    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
317
318
319!
320!-- Create the virtual processor grid
321    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
322                          comm2d, ierr )
323    CALL MPI_COMM_RANK( comm2d, myid, ierr )
324    WRITE (myid_char,'(''_'',I6.6)')  myid
325
326    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
327    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
328    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
329
330!
331!-- Determine sub-topologies for transpositions
332!-- Transposition from z to x:
333    remain_dims(1) = .TRUE.
334    remain_dims(2) = .FALSE.
335    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
336    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
337!
338!-- Transposition from x to y
339    remain_dims(1) = .FALSE.
340    remain_dims(2) = .TRUE.
341    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
342    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
343
344
345!
346!-- Calculate array bounds along x-direction for every PE.
347    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
348              nysf(0:pdims(2)-1) )
349
350    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
351       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
352                               'is not an& integral divisor of the number ',  &
353                               'processors (', pdims(1),')'
354       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
355    ELSE
356       nnx  = ( nx + 1 ) / pdims(1)
357       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
358          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
359                       'requirements given by the number of PEs &used',       &
360                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
361                                   - ( nx + 1 ) ) ), ' instead of nx =', nx
362          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
363       ENDIF
364    ENDIF   
365
366!
367!-- Left and right array bounds, number of gridpoints
368    DO  i = 0, pdims(1)-1
369       nxlf(i)   = i * nnx
370       nxrf(i)   = ( i + 1 ) * nnx - 1
371    ENDDO
372
373!
374!-- Calculate array bounds in y-direction for every PE.
375    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
376       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
377                           'is not an& integral divisor of the number of',     &
378                           'processors (', pdims(2),')'
379       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
380    ELSE
381       nny  = ( ny + 1 ) / pdims(2)
382       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
383          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
384                       'requirements given by the number of PEs &used ',      &
385                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
386                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
387          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
388       ENDIF
389    ENDIF   
390
391!
392!-- South and north array bounds
393    DO  j = 0, pdims(2)-1
394       nysf(j)   = j * nny
395       nynf(j)   = ( j + 1 ) * nny - 1
396    ENDDO
397
398!
399!-- Local array bounds of the respective PEs
400    nxl = nxlf(pcoord(1))
401    nxr = nxrf(pcoord(1))
402    nys = nysf(pcoord(2))
403    nyn = nynf(pcoord(2))
404    nzb = 0
405    nzt = nz
406    nnz = nz
407
408!
409!-- Set switches to define if the PE is situated at the border of the virtual
410!-- processor grid
411    IF ( nxl == 0 )   left_border_pe  = .TRUE.
412    IF ( nxr == nx )  right_border_pe = .TRUE.
413    IF ( nys == 0 )   south_border_pe = .TRUE.
414    IF ( nyn == ny )  north_border_pe = .TRUE.
415
416!
417!-- Calculate array bounds and gridpoint numbers for the transposed arrays
418!-- (needed in the pressure solver)
419!-- For the transposed arrays, cyclic boundaries as well as top and bottom
420!-- boundaries are omitted, because they are obstructive to the transposition
421
422!
423!-- 1. transposition  z --> x
424!-- This transposition is not neccessary in case of a 1d-decomposition along x
425    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
426
427       IF ( pdims(2) /= 1 )  THEN
428          IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
429             WRITE( message_string, * ) 'transposition z --> x:',              &
430                       '&nz=',nz,' is not an integral divisior of pdims(1)=',  &
431                                                                   pdims(1)
432             CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
433          ENDIF
434       ENDIF
435
436       nys_x = nys
437       nyn_x = nyn
438       nny_x = nny
439       nnz_x = nz / pdims(1)
440       nzb_x = 1 + myidx * nnz_x
441       nzt_x = ( myidx + 1 ) * nnz_x
442       sendrecvcount_zx = nnx * nny * nnz_x
443
444    ENDIF
445
446
447    IF ( psolver == 'poisfft' )  THEN 
448!
449!--    2. transposition  x --> y
450       IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
451          WRITE( message_string, * ) 'transposition x --> y:',                 &
452                            '&nx+1=',nx+1,' is not an integral divisor of ',   &
453                            'pdims(2)=',pdims(2)
454          CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
455       ENDIF
456
457       nnz_y = nnz_x
458       nzb_y = nzb_x
459       nzt_y = nzt_x
460       nnx_y = (nx+1) / pdims(2)
461       nxl_y = myidy * nnx_y
462       nxr_y = ( myidy + 1 ) * nnx_y - 1
463       sendrecvcount_xy = nnx_y * nny_x * nnz_y
464!
465!--    3. transposition  y --> z 
466!--    (ELSE:  x --> y  in case of 1D-decomposition along x)
467       nxl_z = nxl_y
468       nxr_z = nxr_y
469       nny_z = (ny+1) / pdims(1)
470       nys_z = myidx * nny_z
471       nyn_z = ( myidx + 1 ) * nny_z - 1
472       sendrecvcount_yz = nnx_y * nny_z * nnz_y
473
474       IF ( pdims(2) /= 1 )  THEN
475!
476!--       y --> z
477!--       This transposition is not neccessary in case of a 1d-decomposition
478!--       along x, except that the uptream-spline method is switched on
479          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
480             WRITE( message_string, * ) 'transposition y --> z:',              &
481                               '& ny+1=',ny+1,' is not an integral divisor of',&
482                               ' pdims(1)=',pdims(1)
483             CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
484          ENDIF
485
486       ELSE
487!
488!--       x --> y
489!--       This condition must be fulfilled for a 1D-decomposition along x
490          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
491             WRITE( message_string, * ) 'transposition x --> y:',              &
492                               '& ny+1=',ny+1,' is not an integral divisor of',&
493                               ' pdims(1)=',pdims(1)
494             CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
495          ENDIF
496
497       ENDIF
498
499    ENDIF
500
501!
502!-- Indices for direct transpositions z --> y (used for calculating spectra)
503    IF ( calculate_spectra )  THEN
504       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
505          WRITE( message_string, * ) 'direct transposition z --> y (needed ',  &
506                    'for spectra):& nz=',nz,' is not an integral divisor of ', &
507                    'pdims(2)=',pdims(2)
508          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
509       ELSE
510          nxl_yd = nxl
511          nxr_yd = nxr
512          nzb_yd = 1 + myidy * ( nz / pdims(2) )
513          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
514          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
515       ENDIF
516    ENDIF
517
518    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
519!
520!--    Indices for direct transpositions y --> x
521!--    (they are only possible in case of a 1d-decomposition along x)
522       IF ( pdims(2) == 1 )  THEN
523          nny_x = nny / pdims(1)
524          nys_x = myid * nny_x
525          nyn_x = ( myid + 1 ) * nny_x - 1
526          nzb_x = 1
527          nzt_x = nz
528          sendrecvcount_xy = nnx * nny_x * nz
529       ENDIF
530
531    ENDIF
532
533    IF ( psolver == 'poisfft' )  THEN
534!
535!--    Indices for direct transpositions x --> y
536!--    (they are only possible in case of a 1d-decomposition along y)
537       IF ( pdims(1) == 1 )  THEN
538          nnx_y = nnx / pdims(2)
539          nxl_y = myid * nnx_y
540          nxr_y = ( myid + 1 ) * nnx_y - 1
541          nzb_y = 1
542          nzt_y = nz
543          sendrecvcount_xy = nnx_y * nny * nz
544       ENDIF
545
546    ENDIF
547
548!
549!-- Arrays for storing the array bounds are needed any more
550    DEALLOCATE( nxlf , nxrf , nynf , nysf )
551
552
553!
554!-- Collect index bounds from other PEs (to be written to restart file later)
555    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
556
557    IF ( myid == 0 )  THEN
558
559       hor_index_bounds(1,0) = nxl
560       hor_index_bounds(2,0) = nxr
561       hor_index_bounds(3,0) = nys
562       hor_index_bounds(4,0) = nyn
563
564!
565!--    Receive data from all other PEs
566       DO  i = 1, numprocs-1
567          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
568                         ierr )
569          hor_index_bounds(:,i) = ibuf(1:4)
570       ENDDO
571
572    ELSE
573!
574!--    Send index bounds to PE0
575       ibuf(1) = nxl
576       ibuf(2) = nxr
577       ibuf(3) = nys
578       ibuf(4) = nyn
579       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
580
581    ENDIF
582
583
584#if defined( __print )
585!
586!-- Control output
587    IF ( myid == 0 )  THEN
588       PRINT*, '*** processor topology ***'
589       PRINT*, ' '
590       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
591               &'   nys: nyn'
592       PRINT*, '------------------------------------------------------------',&
593               &'-----------'
594       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
595                       myidx, myidy, nxl, nxr, nys, nyn
5961000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
597               2(2X,I4,':',I4))
598
599!
600!--    Receive data from the other PEs
601       DO  i = 1,numprocs-1
602          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
603                         ierr )
604          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
605       ENDDO
606    ELSE
607
608!
609!--    Send data to PE0
610       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
611       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
612       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
613       ibuf(12) = nyn
614       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
615    ENDIF
616#endif
617
618#if defined( __parallel )
619#if defined( __mpi2 )
620!
621!-- In case of coupled runs, get the port name on PE0 of the atmosphere model
622!-- and pass it to PE0 of the ocean model
623    IF ( myid == 0 )  THEN
624
625       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
626
627          CALL MPI_OPEN_PORT( MPI_INFO_NULL, port_name, ierr )
628
629          CALL MPI_PUBLISH_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, &
630                                 ierr )
631
632!
633!--       Write a flag file for the ocean model and the other atmosphere
634!--       processes.
635!--       There seems to be a bug in MPICH2 which causes hanging processes
636!--       in case that execution of LOOKUP_NAME is continued too early
637!--       (i.e. before the port has been created)
638          OPEN( 90, FILE='COUPLING_PORT_OPENED', FORM='FORMATTED' )
639          WRITE ( 90, '(''TRUE'')' )
640          CLOSE ( 90 )
641
642       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
643
644!
645!--       Continue only if the atmosphere model has created the port.
646!--       There seems to be a bug in MPICH2 which causes hanging processes
647!--       in case that execution of LOOKUP_NAME is continued too early
648!--       (i.e. before the port has been created)
649          INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
650          DO WHILE ( .NOT. found )
651             INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
652          ENDDO
653
654          CALL MPI_LOOKUP_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, ierr )
655
656       ENDIF
657
658    ENDIF
659
660!
661!-- In case of coupled runs, establish the connection between the atmosphere
662!-- and the ocean model and define the intercommunicator (comm_inter)
663    CALL MPI_BARRIER( comm2d, ierr )
664    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
665
666       CALL MPI_COMM_ACCEPT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
667                             comm_inter, ierr )
668       coupling_mode_remote = 'ocean_to_atmosphere'
669
670    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
671
672       CALL MPI_COMM_CONNECT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
673                              comm_inter, ierr )
674       coupling_mode_remote = 'atmosphere_to_ocean'
675
676    ENDIF
677#endif
678
679!
680!-- Determine the number of ghost point layers
681    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
682         momentum_advec == 'ws-scheme' )  THEN
683       nbgp = 3
684    ELSE
685       nbgp = 1
686    ENDIF
687
688!
689!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
690!-- which is needed for coupled atmosphere-ocean runs.
691!-- First, calculate number of grid points of an xy-plane.
692    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
693    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
694    CALL MPI_TYPE_COMMIT( type_xy, ierr )
695
696    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
697   
698!
699!--    Pass the number of grid points of the atmosphere model to
700!--    the ocean model and vice versa
701       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
702
703          nx_a = nx
704          ny_a = ny
705
706          IF ( myid == 0 )  THEN
707
708             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
709                            ierr )
710             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
711                            ierr )
712             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
713                            ierr )
714             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
715                            status, ierr )
716             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
717                            status, ierr )
718             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
719                            comm_inter, status, ierr )
720          ENDIF
721
722          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
723          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
724          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
725       
726       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
727
728          nx_o = nx
729          ny_o = ny
730
731          IF ( myid == 0 ) THEN
732
733             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
734                            ierr )
735             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
736                            ierr )
737             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
738                            status, ierr )
739             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
740             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
741             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
742          ENDIF
743
744          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
745          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
746          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
747
748       ENDIF
749 
750       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
751       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
752
753!
754!--    Determine if the horizontal grid and the number of PEs in ocean and
755!--    atmosphere is same or not
756       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
757            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
758       THEN
759          coupling_topology = 0
760       ELSE
761          coupling_topology = 1
762       ENDIF
763
764!
765!--    Determine the target PEs for the exchange between ocean and
766!--    atmosphere (comm2d)
767       IF ( coupling_topology == 0 )  THEN
768!
769!--       In case of identical topologies, every atmosphere PE has exactly one
770!--       ocean PE counterpart and vice versa
771          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
772             target_id = myid + numprocs
773          ELSE
774             target_id = myid
775          ENDIF
776
777       ELSE
778!
779!--       In case of nonequivalent topology in ocean and atmosphere only for
780!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
781!--       data echxchange between ocean and atmosphere will be done only
782!--       between these PEs.   
783          IF ( myid == 0 )  THEN
784
785             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
786                target_id = numprocs
787             ELSE
788                target_id = 0
789             ENDIF
790
791          ENDIF
792
793       ENDIF
794
795    ENDIF
796
797
798#endif
799
800#else
801
802!
803!-- Array bounds when running on a single PE (respectively a non-parallel
804!-- machine)
805    nxl = 0
806    nxr = nx
807    nnx = nxr - nxl + 1
808    nys = 0
809    nyn = ny
810    nny = nyn - nys + 1
811    nzb = 0
812    nzt = nz
813    nnz = nz
814
815    ALLOCATE( hor_index_bounds(4,0:0) )
816    hor_index_bounds(1,0) = nxl
817    hor_index_bounds(2,0) = nxr
818    hor_index_bounds(3,0) = nys
819    hor_index_bounds(4,0) = nyn
820
821!
822!-- Array bounds for the pressure solver (in the parallel code, these bounds
823!-- are the ones for the transposed arrays)
824    nys_x = nys
825    nyn_x = nyn
826    nzb_x = nzb + 1
827    nzt_x = nzt
828
829    nxl_y = nxl
830    nxr_y = nxr
831    nzb_y = nzb + 1
832    nzt_y = nzt
833
834    nxl_z = nxl
835    nxr_z = nxr
836    nys_z = nys
837    nyn_z = nyn
838
839#endif
840
841!
842!-- Calculate number of grid levels necessary for the multigrid poisson solver
843!-- as well as the gridpoint indices on each level
844    IF ( psolver(1:9) == 'multigrid' )  THEN
845
846!
847!--    First calculate number of possible grid levels for the subdomains
848       mg_levels_x = 1
849       mg_levels_y = 1
850       mg_levels_z = 1
851
852       i = nnx
853       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
854          i = i / 2
855          mg_levels_x = mg_levels_x + 1
856       ENDDO
857
858       j = nny
859       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
860          j = j / 2
861          mg_levels_y = mg_levels_y + 1
862       ENDDO
863
864       k = nz    ! do not use nnz because it might be > nz due to transposition
865                 ! requirements
866       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
867          k = k / 2
868          mg_levels_z = mg_levels_z + 1
869       ENDDO
870!
871!--    The optimized MG-solver does not allow odd values for nz at the coarsest
872!--    grid level
873       IF ( TRIM( psolver ) /= 'multigrid_noopt' )  THEN
874          IF ( MOD( k, 2 ) /= 0 )  mg_levels_z = mg_levels_z - 1
875       ENDIF
876
877       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
878
879!
880!--    Find out, if the total domain allows more levels. These additional
881!--    levels are identically processed on all PEs.
882       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
883
884          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
885
886             mg_switch_to_pe0_level_l = maximum_grid_level
887
888             mg_levels_x = 1
889             mg_levels_y = 1
890
891             i = nx+1
892             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
893                i = i / 2
894                mg_levels_x = mg_levels_x + 1
895             ENDDO
896
897             j = ny+1
898             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
899                j = j / 2
900                mg_levels_y = mg_levels_y + 1
901             ENDDO
902
903             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
904
905             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
906                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
907                                           mg_switch_to_pe0_level_l + 1
908             ELSE
909                mg_switch_to_pe0_level_l = 0
910             ENDIF
911
912          ELSE
913             mg_switch_to_pe0_level_l = 0
914             maximum_grid_level_l = maximum_grid_level
915
916          ENDIF
917
918!
919!--       Use switch level calculated above only if it is not pre-defined
920!--       by user
921          IF ( mg_switch_to_pe0_level == 0 )  THEN
922             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
923                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
924                maximum_grid_level     = maximum_grid_level_l
925             ENDIF
926
927          ELSE
928!
929!--          Check pre-defined value and reset to default, if neccessary
930             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
931                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
932                message_string = 'mg_switch_to_pe0_level ' // &
933                                 'out of range and reset to default (=0)'
934                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
935                mg_switch_to_pe0_level = 0
936             ELSE
937!
938!--             Use the largest number of possible levels anyway and recalculate
939!--             the switch level to this largest number of possible values
940                maximum_grid_level = maximum_grid_level_l
941
942             ENDIF
943
944          ENDIF
945
946       ENDIF
947
948       ALLOCATE( grid_level_count(maximum_grid_level),                       &
949                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
950                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
951                 nzt_mg(0:maximum_grid_level) )
952
953       grid_level_count = 0
954!
955!--    Index zero required as dummy due to definition of arrays f2 and p2 in
956!--    recursive subroutine next_mg_level
957       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
958
959       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
960
961       DO  i = maximum_grid_level, 1 , -1
962
963          IF ( i == mg_switch_to_pe0_level )  THEN
964#if defined( __parallel )
965!
966!--          Save the grid size of the subdomain at the switch level, because
967!--          it is needed in poismg.
968             ind(1) = nxl_l; ind(2) = nxr_l
969             ind(3) = nys_l; ind(4) = nyn_l
970             ind(5) = nzt_l
971             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
972             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
973                                 MPI_INTEGER, comm2d, ierr )
974             DO  j = 0, numprocs-1
975                DO  k = 1, 5
976                   mg_loc_ind(k,j) = ind_all(k+j*5)
977                ENDDO
978             ENDDO
979             DEALLOCATE( ind_all )
980!
981!--          Calculate the grid size of the total domain
982             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
983             nxl_l = 0
984             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
985             nys_l = 0
986!
987!--          The size of this gathered array must not be larger than the
988!--          array tend, which is used in the multigrid scheme as a temporary
989!--          array. Therefore the subdomain size of an PE is calculated and
990!--          the size of the gathered grid. These values are used in 
991!--          routines pres and poismg
992             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
993                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
994             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
995                              ( nzt_l - nzb + 2 )
996
997#else
998             message_string = 'multigrid gather/scatter impossible ' // &
999                          'in non parallel mode'
1000             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
1001#endif
1002          ENDIF
1003
1004          nxl_mg(i) = nxl_l
1005          nxr_mg(i) = nxr_l
1006          nys_mg(i) = nys_l
1007          nyn_mg(i) = nyn_l
1008          nzt_mg(i) = nzt_l
1009
1010          nxl_l = nxl_l / 2 
1011          nxr_l = nxr_l / 2
1012          nys_l = nys_l / 2 
1013          nyn_l = nyn_l / 2 
1014          nzt_l = nzt_l / 2 
1015
1016       ENDDO
1017
1018!
1019!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
1020!--    if grid data are collected on PE0 already on the finest grid level.
1021!--    To be solved later.
1022       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
1023          message_string = 'grid coarsening on subdomain level cannot be performed'
1024          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
1025       ENDIF
1026
1027    ELSE
1028
1029       maximum_grid_level = 0
1030
1031    ENDIF
1032
1033!
1034!-- Default level 0 tells exchange_horiz that all ghost planes have to be
1035!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
1036!-- is required.
1037    grid_level = 0
1038
1039#if defined( __parallel )
1040!
1041!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
1042    ngp_y  = nyn - nys + 1 + 2 * nbgp
1043
1044!
1045!-- Define new MPI derived datatypes for the exchange of ghost points in
1046!-- x- and y-direction for 2D-arrays (line)
1047    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x,     &
1048                          ierr )
1049    CALL MPI_TYPE_COMMIT( type_x, ierr )
1050
1051    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1052    CALL MPI_TYPE_COMMIT( type_y, ierr )
1053!
1054!-- Define new MPI derived datatypes for the exchange of ghost points in
1055!-- x- and y-direction for 2D-INTEGER arrays (line) - on normal grid
1056    ALLOCATE( type_x_int(0:maximum_grid_level),                                &
1057              type_y_int(0:maximum_grid_level) )
1058
1059    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER,          &
1060                          type_x_int(0), ierr )
1061    CALL MPI_TYPE_COMMIT( type_x_int(0), ierr )
1062
1063    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int(0), ierr )
1064    CALL MPI_TYPE_COMMIT( type_y_int(0), ierr )
1065!
1066!-- Calculate gridpoint numbers for the exchange of ghost points along x
1067!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1068!-- exchange of ghost points in y-direction (xz-plane).
1069!-- Do these calculations for the model grid and (if necessary) also
1070!-- for the coarser grid levels used in the multigrid method
1071    ALLOCATE ( ngp_xz(0:maximum_grid_level), ngp_yz(0:maximum_grid_level),     &
1072               type_xz(0:maximum_grid_level), type_yz(0:maximum_grid_level) )
1073
1074    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1075
1076!
1077!-- Discern between the model grid, which needs nbgp ghost points and
1078!-- grid levels for the multigrid scheme. In the latter case only one
1079!-- ghost point is necessary.
1080!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1081!-- grid. The following loop is needed for data exchange in poismg.f90.
1082!
1083!-- Determine number of grid points of yz-layer for exchange
1084    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1085
1086!
1087!-- Define an MPI-datatype for the exchange of left/right boundaries.
1088!-- Although data are contiguous in physical memory (which does not
1089!-- necessarily require an MPI-derived datatype), the data exchange between
1090!-- left and right PE's using the MPI-derived type is 10% faster than without.
1091    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1092                          MPI_REAL, type_xz(0), ierr )
1093    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1094
1095    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1096                          ierr ) 
1097    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1098
1099!
1100!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1101    IF ( psolver(1:9) == 'multigrid' )  THEN
1102!   
1103!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1104       DO  i = maximum_grid_level, 1 , -1
1105!
1106!--       For 3D-exchange
1107          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1108          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1109
1110          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i), &
1111                                MPI_REAL, type_xz(i), ierr )
1112          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1113
1114          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1115                                ierr )
1116          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1117
1118
1119!--       For 2D-exchange of INTEGER arrays on coarser grid level, where 2 ghost
1120!--       points need to be exchanged.
1121          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+5, 2, nyn_l-nys_l+5, MPI_INTEGER,          &
1122                                type_x_int(i), ierr )
1123          CALL MPI_TYPE_COMMIT( type_x_int(i), ierr )
1124
1125
1126          CALL MPI_TYPE_VECTOR( 2, nyn_l-nys_l+5, nyn_l-nys_l+5, MPI_INTEGER,          &
1127                                type_y_int(i), ierr )
1128          CALL MPI_TYPE_COMMIT( type_y_int(i), ierr )
1129
1130
1131
1132          nxl_l = nxl_l / 2
1133          nxr_l = nxr_l / 2
1134          nys_l = nys_l / 2
1135          nyn_l = nyn_l / 2
1136          nzt_l = nzt_l / 2
1137
1138       ENDDO
1139
1140    ENDIF
1141!
1142!-- Define data types for exchange of 3D Integer arrays.
1143    ngp_yz_int = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1144
1145    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int, &
1146                          MPI_INTEGER, type_xz_int, ierr )
1147    CALL MPI_TYPE_COMMIT( type_xz_int, ierr )
1148
1149    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int, ngp_yz_int, MPI_INTEGER, type_yz_int, &
1150                          ierr )
1151    CALL MPI_TYPE_COMMIT( type_yz_int, ierr )
1152
1153#endif
1154
1155#if defined( __parallel )
1156!
1157!-- Setting of flags for inflow/outflow/nesting conditions.
1158    IF ( pleft == MPI_PROC_NULL )  THEN
1159       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1160          inflow_l  = .TRUE.
1161       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1162          outflow_l = .TRUE.
1163       ELSEIF ( bc_lr == 'nested' )  THEN
1164          nest_bound_l = .TRUE.
1165       ENDIF
1166    ENDIF
1167 
1168    IF ( pright == MPI_PROC_NULL )  THEN
1169       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1170          outflow_r = .TRUE.
1171       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1172          inflow_r  = .TRUE.
1173       ELSEIF ( bc_lr == 'nested' )  THEN
1174          nest_bound_r = .TRUE.
1175       ENDIF
1176    ENDIF
1177
1178    IF ( psouth == MPI_PROC_NULL )  THEN
1179       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1180          outflow_s = .TRUE.
1181       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1182          inflow_s  = .TRUE.
1183       ELSEIF ( bc_ns == 'nested' )  THEN
1184          nest_bound_s = .TRUE.
1185       ENDIF
1186    ENDIF
1187
1188    IF ( pnorth == MPI_PROC_NULL )  THEN
1189       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1190          inflow_n  = .TRUE.
1191       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1192          outflow_n = .TRUE.
1193       ELSEIF ( bc_ns == 'nested' )  THEN
1194          nest_bound_n = .TRUE.
1195       ENDIF
1196    ENDIF
1197
1198!
1199!-- Broadcast the id of the inflow PE
1200    IF ( inflow_l )  THEN
1201       id_inflow_l = myidx
1202    ELSE
1203       id_inflow_l = 0
1204    ENDIF
1205    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1206    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1207                        comm1dx, ierr )
1208
1209!
1210!-- Broadcast the id of the recycling plane
1211!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1212    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1213         NINT( recycling_width / dx ) <= nxr )  THEN
1214       id_recycling_l = myidx
1215    ELSE
1216       id_recycling_l = 0
1217    ENDIF
1218    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1219    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1220                        comm1dx, ierr )
1221
1222!
1223!-- Broadcast the id of the outflow PE and outflow-source plane
1224    IF ( turbulent_outflow )  THEN
1225
1226       IF ( outflow_r )  THEN
1227          id_outflow_l = myidx
1228       ELSE
1229          id_outflow_l = 0
1230       ENDIF
1231       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1232       CALL MPI_ALLREDUCE( id_outflow_l, id_outflow, 1, MPI_INTEGER, MPI_SUM, &
1233                           comm1dx, ierr )
1234
1235       IF ( NINT( outflow_source_plane / dx ) >= nxl  .AND. &
1236            NINT( outflow_source_plane / dx ) <= nxr )  THEN
1237          id_outflow_source_l = myidx
1238       ELSE
1239          id_outflow_source_l = 0
1240       ENDIF
1241       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1242       CALL MPI_ALLREDUCE( id_outflow_source_l, id_outflow_source, 1, &
1243                           MPI_INTEGER, MPI_SUM, comm1dx, ierr )
1244
1245    ENDIF
1246
1247    CALL location_message( 'finished', .TRUE. )
1248
1249#else
1250    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1251       inflow_l  = .TRUE.
1252       outflow_r = .TRUE.
1253    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1254       outflow_l = .TRUE.
1255       inflow_r  = .TRUE.
1256    ENDIF
1257
1258    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1259       inflow_n  = .TRUE.
1260       outflow_s = .TRUE.
1261    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1262       outflow_n = .TRUE.
1263       inflow_s  = .TRUE.
1264    ENDIF
1265#endif
1266
1267!
1268!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1269!-- one more grid point.
1270    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l )  THEN
1271       nxlu = nxl + 1
1272    ELSE
1273       nxlu = nxl
1274    ENDIF
1275    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s )  THEN
1276       nysv = nys + 1
1277    ELSE
1278       nysv = nys
1279    ENDIF
1280
1281!
1282!-- Allocate wall flag arrays used in the multigrid solver
1283    IF ( psolver(1:9) == 'multigrid' )  THEN
1284
1285       DO  i = maximum_grid_level, 1, -1
1286
1287           SELECT CASE ( i )
1288
1289              CASE ( 1 )
1290                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1291                                        nys_mg(i)-1:nyn_mg(i)+1, &
1292                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1293
1294              CASE ( 2 )
1295                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1296                                        nys_mg(i)-1:nyn_mg(i)+1, &
1297                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1298
1299              CASE ( 3 )
1300                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1301                                        nys_mg(i)-1:nyn_mg(i)+1, &
1302                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1303
1304              CASE ( 4 )
1305                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1306                                        nys_mg(i)-1:nyn_mg(i)+1, &
1307                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1308
1309              CASE ( 5 )
1310                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1311                                        nys_mg(i)-1:nyn_mg(i)+1, &
1312                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1313
1314              CASE ( 6 )
1315                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1316                                        nys_mg(i)-1:nyn_mg(i)+1, &
1317                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1318
1319              CASE ( 7 )
1320                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1321                                        nys_mg(i)-1:nyn_mg(i)+1, &
1322                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1323
1324              CASE ( 8 )
1325                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1326                                        nys_mg(i)-1:nyn_mg(i)+1, &
1327                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1328
1329              CASE ( 9 )
1330                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1331                                        nys_mg(i)-1:nyn_mg(i)+1, &
1332                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1333
1334              CASE ( 10 )
1335                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1336                                        nys_mg(i)-1:nyn_mg(i)+1, &
1337                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1338
1339              CASE DEFAULT
1340                 message_string = 'more than 10 multigrid levels'
1341                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1342
1343          END SELECT
1344
1345       ENDDO
1346
1347    ENDIF
1348
1349!
1350!-- Calculate the number of groups into which parallel I/O is split.
1351!-- The default for files which are opened by all PEs (or where each
1352!-- PE opens his own independent file) is, that all PEs are doing input/output
1353!-- in parallel at the same time. This might cause performance or even more
1354!-- severe problems depending on the configuration of the underlying file
1355!-- system.
1356!-- First, set the default:
1357    IF ( maximum_parallel_io_streams == -1  .OR. &
1358         maximum_parallel_io_streams > numprocs )  THEN
1359       maximum_parallel_io_streams = numprocs
1360    ENDIF
1361
1362!
1363!-- Now calculate the number of io_blocks and the io_group to which the
1364!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
1365!-- for all PEs belonging to the same group. A preliminary setting with myid
1366!-- based on MPI_COMM_WORLD has been done in parin.
1367    io_blocks = numprocs / maximum_parallel_io_streams
1368    io_group  = MOD( myid+1, io_blocks )
1369   
1370
1371 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.