source: palm/trunk/SOURCE/init_pegrid.f90 @ 1816

Last change on this file since 1816 was 1816, checked in by raasch, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 42.9 KB
Line 
1!> @file init_pegrid.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2014 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! ------------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: init_pegrid.f90 1816 2016-04-06 14:11:06Z raasch $
26!
27! 1815 2016-04-06 13:49:59Z raasch
28! cpp-directives for intel openmp bug removed
29!
30! 1804 2016-04-05 16:30:18Z maronga
31! Removed code for parameter file check (__check)
32!
33! 1779 2016-03-03 08:01:28Z raasch
34! changes regarding nested domain removed: virtual PE grid will be automatically
35! calculated for nested runs too
36!
37! 1764 2016-02-28 12:45:19Z raasch
38! cpp-statements for nesting removed
39!
40! 1762 2016-02-25 12:31:13Z hellstea
41! Introduction of nested domain feature
42!
43! 1682 2015-10-07 23:56:08Z knoop
44! Code annotations made doxygen readable
45!
46! 1677 2015-10-02 13:25:23Z boeske
47! New MPI-data types for exchange of 3D integer arrays.
48!
49! 1575 2015-03-27 09:56:27Z raasch
50! adjustments for psolver-queries, calculation of ngp_xz added
51!
52! 1565 2015-03-09 20:59:31Z suehring
53! Refine if-clause for setting nbgp.
54!
55! 1557 2015-03-05 16:43:04Z suehring
56! Adjustment for monotonic limiter
57!
58! 1468 2014-09-24 14:06:57Z maronga
59! Adapted for use on up to 6-digit processor cores
60!
61! 1435 2014-07-21 10:37:02Z keck
62! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
63!
64! 1402 2014-05-09 14:25:13Z raasch
65! location messages modified
66!
67! 1384 2014-05-02 14:31:06Z raasch
68! location messages added
69!
70! 1353 2014-04-08 15:21:23Z heinze
71! REAL constants provided with KIND-attribute
72!
73! 1322 2014-03-20 16:38:49Z raasch
74! REAL functions provided with KIND-attribute
75!
76! 1320 2014-03-20 08:40:49Z raasch
77! ONLY-attribute added to USE-statements,
78! kind-parameters added to all INTEGER and REAL declaration statements,
79! kinds are defined in new module kinds,
80! revision history before 2012 removed,
81! comment fields (!:) to be used for variable explanations added to
82! all variable declaration statements
83!
84! 1304 2014-03-12 10:29:42Z raasch
85! bugfix: single core MPI runs missed some settings of transpose indices
86!
87! 1212 2013-08-15 08:46:27Z raasch
88! error message for poisfft_hybrid removed
89!
90! 1159 2013-05-21 11:58:22Z fricke
91! dirichlet/neumann and neumann/dirichlet removed
92!
93! 1139 2013-04-18 07:25:03Z raasch
94! bugfix for calculating the id of the PE carrying the recycling plane
95!
96! 1111 2013-03-08 23:54:10Z raasch
97! initialization of poisfft moved to module poisfft
98!
99! 1092 2013-02-02 11:24:22Z raasch
100! unused variables removed
101!
102! 1056 2012-11-16 15:28:04Z raasch
103! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
104! p2 as automatic arrays in recursive subroutine next_mg_level
105!
106! 1041 2012-11-06 02:36:29Z raasch
107! a 2d virtual processor topology is used by default for all machines
108!
109! 1036 2012-10-22 13:43:42Z raasch
110! code put under GPL (PALM 3.9)
111!
112! 1003 2012-09-14 14:35:53Z raasch
113! subdomains must have identical size (grid matching = "match" removed)
114!
115! 1001 2012-09-13 14:08:46Z raasch
116! all actions concerning upstream-spline-method removed
117!
118! 978 2012-08-09 08:28:32Z fricke
119! dirichlet/neumann and neumann/dirichlet added
120! nxlu and nysv are also calculated for inflow boundary
121!
122! 809 2012-01-30 13:32:58Z maronga
123! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
124!
125! 807 2012-01-25 11:53:51Z maronga
126! New cpp directive "__check" implemented which is used by check_namelist_files
127!
128! Revision 1.1  1997/07/24 11:15:09  raasch
129! Initial revision
130!
131!
132! Description:
133! ------------
134!> Determination of the virtual processor topology (if not prescribed by the
135!> user)and computation of the grid point number and array bounds of the local
136!> domains.
137!------------------------------------------------------------------------------!
138 SUBROUTINE init_pegrid
139 
140
141    USE control_parameters,                                                    &
142        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
143               coupling_topology, dt_dosp, gathered_size, grid_level,          &
144               grid_level_count, host, inflow_l, inflow_n, inflow_r, inflow_s, &
145               io_blocks, io_group, maximum_grid_level,                        &
146               maximum_parallel_io_streams, message_string,                    &
147               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
148               nest_bound_n, nest_bound_r, nest_bound_s, neutral, psolver,     &
149               outflow_l, outflow_n, outflow_r, outflow_s, recycling_width,    &
150               scalar_advec, subdomain_size
151
152    USE grid_variables,                                                        &
153        ONLY:  dx
154       
155    USE indices,                                                               &
156        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
157               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
158               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
159               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
160               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
161
162    USE kinds
163     
164    USE pegrid
165 
166    USE transpose_indices,                                                     &
167        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
168               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
169
170    IMPLICIT NONE
171
172    INTEGER(iwp) ::  i                        !<
173    INTEGER(iwp) ::  id_inflow_l              !<
174    INTEGER(iwp) ::  id_recycling_l           !<
175    INTEGER(iwp) ::  ind(5)                   !<
176    INTEGER(iwp) ::  j                        !<
177    INTEGER(iwp) ::  k                        !<
178    INTEGER(iwp) ::  maximum_grid_level_l     !<
179    INTEGER(iwp) ::  mg_levels_x              !<
180    INTEGER(iwp) ::  mg_levels_y              !<
181    INTEGER(iwp) ::  mg_levels_z              !<
182    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
183    INTEGER(iwp) ::  nnx_y                    !<
184    INTEGER(iwp) ::  nnx_z                    !<
185    INTEGER(iwp) ::  nny_x                    !<
186    INTEGER(iwp) ::  nny_z                    !<
187    INTEGER(iwp) ::  nnz_x                    !<
188    INTEGER(iwp) ::  nnz_y                    !<
189    INTEGER(iwp) ::  numproc_sqr              !<
190    INTEGER(iwp) ::  nxl_l                    !<
191    INTEGER(iwp) ::  nxr_l                    !<
192    INTEGER(iwp) ::  nyn_l                    !<
193    INTEGER(iwp) ::  nys_l                    !<
194    INTEGER(iwp) ::  nzb_l                    !<
195    INTEGER(iwp) ::  nzt_l                    !<
196    INTEGER(iwp) ::  omp_get_num_threads      !<
197
198    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
199    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
200    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
201    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
202    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
203
204    INTEGER(iwp), DIMENSION(2) :: pdims_remote          !<
205
206#if defined( __mpi2 )
207    LOGICAL ::  found                                   !<
208#endif
209
210!
211!-- Get the number of OpenMP threads
212    !$OMP PARALLEL
213!$  threads_per_task = omp_get_num_threads()
214    !$OMP END PARALLEL
215
216
217#if defined( __parallel )
218
219    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
220                           .FALSE. )
221
222!
223!--    Determine the processor topology or check it, if prescribed by the user
224    IF ( npex == -1  .AND.  npey == -1 )  THEN
225
226!
227!--       Automatic determination of the topology
228       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
229       pdims(1)    = MAX( numproc_sqr , 1 )
230       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
231          pdims(1) = pdims(1) - 1
232       ENDDO
233       pdims(2) = numprocs / pdims(1)
234
235    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
236
237!
238!--    Prescribed by user. Number of processors on the prescribed topology
239!--    must be equal to the number of PEs available to the job
240       IF ( ( npex * npey ) /= numprocs )  THEN
241          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
242              'topology (', npex*npey,') does not match & the number of ', &
243              'PEs available to the job (', numprocs, ')'
244          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
245       ENDIF
246       pdims(1) = npex
247       pdims(2) = npey
248
249    ELSE
250!
251!--    If the processor topology is prescribed by the user, the number of
252!--    PEs must be given in both directions
253       message_string = 'if the processor topology is prescribed by th' //  &
254                'e user& both values of "npex" and "npey" must be given' // &
255                ' in the &NAMELIST-parameter file'
256       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
257
258    ENDIF
259
260!
261!-- For communication speedup, set barriers in front of collective
262!-- communications by default on SGI-type systems
263    IF ( host(3:5) == 'sgi' )  collective_wait = .TRUE.
264
265!
266!-- If necessary, set horizontal boundary conditions to non-cyclic
267    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
268    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
269
270
271!
272!-- Create the virtual processor grid
273    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
274                          comm2d, ierr )
275    CALL MPI_COMM_RANK( comm2d, myid, ierr )
276    WRITE (myid_char,'(''_'',I6.6)')  myid
277
278    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
279    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
280    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
281
282!
283!-- Determine sub-topologies for transpositions
284!-- Transposition from z to x:
285    remain_dims(1) = .TRUE.
286    remain_dims(2) = .FALSE.
287    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
288    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
289!
290!-- Transposition from x to y
291    remain_dims(1) = .FALSE.
292    remain_dims(2) = .TRUE.
293    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
294    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
295
296
297!
298!-- Calculate array bounds along x-direction for every PE.
299    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
300              nysf(0:pdims(2)-1) )
301
302    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
303       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
304                               'is not an& integral divisor of the number ',  &
305                               'processors (', pdims(1),')'
306       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
307    ELSE
308       nnx  = ( nx + 1 ) / pdims(1)
309       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
310          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
311                       'requirements given by the number of PEs &used',       &
312                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
313                                   - ( nx + 1 ) ) ), ' instead of nx =', nx
314          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
315       ENDIF
316    ENDIF   
317
318!
319!-- Left and right array bounds, number of gridpoints
320    DO  i = 0, pdims(1)-1
321       nxlf(i)   = i * nnx
322       nxrf(i)   = ( i + 1 ) * nnx - 1
323    ENDDO
324
325!
326!-- Calculate array bounds in y-direction for every PE.
327    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
328       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
329                           'is not an& integral divisor of the number of',     &
330                           'processors (', pdims(2),')'
331       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
332    ELSE
333       nny  = ( ny + 1 ) / pdims(2)
334       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
335          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
336                       'requirements given by the number of PEs &used ',      &
337                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
338                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
339          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
340       ENDIF
341    ENDIF   
342
343!
344!-- South and north array bounds
345    DO  j = 0, pdims(2)-1
346       nysf(j)   = j * nny
347       nynf(j)   = ( j + 1 ) * nny - 1
348    ENDDO
349
350!
351!-- Local array bounds of the respective PEs
352    nxl = nxlf(pcoord(1))
353    nxr = nxrf(pcoord(1))
354    nys = nysf(pcoord(2))
355    nyn = nynf(pcoord(2))
356    nzb = 0
357    nzt = nz
358    nnz = nz
359
360!
361!-- Set switches to define if the PE is situated at the border of the virtual
362!-- processor grid
363    IF ( nxl == 0 )   left_border_pe  = .TRUE.
364    IF ( nxr == nx )  right_border_pe = .TRUE.
365    IF ( nys == 0 )   south_border_pe = .TRUE.
366    IF ( nyn == ny )  north_border_pe = .TRUE.
367
368!
369!-- Calculate array bounds and gridpoint numbers for the transposed arrays
370!-- (needed in the pressure solver)
371!-- For the transposed arrays, cyclic boundaries as well as top and bottom
372!-- boundaries are omitted, because they are obstructive to the transposition
373
374!
375!-- 1. transposition  z --> x
376!-- This transposition is not neccessary in case of a 1d-decomposition along x
377    nys_x = nys
378    nyn_x = nyn
379    nny_x = nny
380    nnz_x = nz / pdims(1)
381    nzb_x = 1 + myidx * nnz_x
382    nzt_x = ( myidx + 1 ) * nnz_x
383    sendrecvcount_zx = nnx * nny * nnz_x
384
385    IF ( pdims(2) /= 1 )  THEN
386       IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
387          WRITE( message_string, * ) 'transposition z --> x:',                &
388                       '&nz=',nz,' is not an integral divisior of pdims(1)=', &
389                                                                   pdims(1)
390          CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
391       ENDIF
392    ENDIF
393
394!
395!-- 2. transposition  x --> y
396    nnz_y = nnz_x
397    nzb_y = nzb_x
398    nzt_y = nzt_x
399    IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
400       WRITE( message_string, * ) 'transposition x --> y:',                &
401                         '&nx+1=',nx+1,' is not an integral divisor of ',&
402                         'pdims(2)=',pdims(2)
403       CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
404    ENDIF
405    nnx_y = (nx+1) / pdims(2)
406    nxl_y = myidy * nnx_y
407    nxr_y = ( myidy + 1 ) * nnx_y - 1
408    sendrecvcount_xy = nnx_y * nny_x * nnz_y
409
410!
411!-- 3. transposition  y --> z  (ELSE:  x --> y  in case of 1D-decomposition
412!-- along x)
413    nnx_z = nnx_y
414    nxl_z = nxl_y
415    nxr_z = nxr_y
416    nny_z = (ny+1) / pdims(1)
417    nys_z = myidx * nny_z
418    nyn_z = ( myidx + 1 ) * nny_z - 1
419    sendrecvcount_yz = nnx_y * nny_z * nnz_y
420
421    IF ( pdims(2) /= 1 )  THEN
422!
423!--    y --> z
424!--    This transposition is not neccessary in case of a 1d-decomposition
425!--    along x, except that the uptream-spline method is switched on
426       IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
427          WRITE( message_string, * ) 'transposition y --> z:',            &
428                            '& ny+1=',ny+1,' is not an integral divisor of ',&
429                            'pdims(1)=',pdims(1)
430          CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
431       ENDIF
432
433    ELSE
434!
435!--    x --> y. This condition must be fulfilled for a 1D-decomposition along x
436       IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
437          WRITE( message_string, * ) 'transposition x --> y:',               &
438                            '& ny+1=',ny+1,' is not an integral divisor of ',&
439                            'pdims(1)=',pdims(1)
440          CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
441       ENDIF
442
443    ENDIF
444
445!
446!-- Indices for direct transpositions z --> y (used for calculating spectra)
447    IF ( dt_dosp /= 9999999.9_wp )  THEN
448       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
449          WRITE( message_string, * ) 'direct transposition z --> y (needed ', &
450                    'for spectra):& nz=',nz,' is not an integral divisor of ',&
451                    'pdims(2)=',pdims(2)
452          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
453       ELSE
454          nxl_yd = nxl
455          nxr_yd = nxr
456          nzb_yd = 1 + myidy * ( nz / pdims(2) )
457          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
458          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
459       ENDIF
460    ENDIF
461
462!
463!-- Indices for direct transpositions y --> x (they are only possible in case
464!-- of a 1d-decomposition along x)
465    IF ( pdims(2) == 1 )  THEN
466       nny_x = nny / pdims(1)
467       nys_x = myid * nny_x
468       nyn_x = ( myid + 1 ) * nny_x - 1
469       nzb_x = 1
470       nzt_x = nz
471       sendrecvcount_xy = nnx * nny_x * nz
472    ENDIF
473
474!
475!-- Indices for direct transpositions x --> y (they are only possible in case
476!-- of a 1d-decomposition along y)
477    IF ( pdims(1) == 1 )  THEN
478       nnx_y = nnx / pdims(2)
479       nxl_y = myid * nnx_y
480       nxr_y = ( myid + 1 ) * nnx_y - 1
481       nzb_y = 1
482       nzt_y = nz
483       sendrecvcount_xy = nnx_y * nny * nz
484    ENDIF
485
486!
487!-- Arrays for storing the array bounds are needed any more
488    DEALLOCATE( nxlf , nxrf , nynf , nysf )
489
490
491!
492!-- Collect index bounds from other PEs (to be written to restart file later)
493    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
494
495    IF ( myid == 0 )  THEN
496
497       hor_index_bounds(1,0) = nxl
498       hor_index_bounds(2,0) = nxr
499       hor_index_bounds(3,0) = nys
500       hor_index_bounds(4,0) = nyn
501
502!
503!--    Receive data from all other PEs
504       DO  i = 1, numprocs-1
505          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
506                         ierr )
507          hor_index_bounds(:,i) = ibuf(1:4)
508       ENDDO
509
510    ELSE
511!
512!--    Send index bounds to PE0
513       ibuf(1) = nxl
514       ibuf(2) = nxr
515       ibuf(3) = nys
516       ibuf(4) = nyn
517       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
518
519    ENDIF
520
521
522#if defined( __print )
523!
524!-- Control output
525    IF ( myid == 0 )  THEN
526       PRINT*, '*** processor topology ***'
527       PRINT*, ' '
528       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
529               &'   nys: nyn'
530       PRINT*, '------------------------------------------------------------',&
531               &'-----------'
532       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
533                       myidx, myidy, nxl, nxr, nys, nyn
5341000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
535               2(2X,I4,':',I4))
536
537!
538!--    Receive data from the other PEs
539       DO  i = 1,numprocs-1
540          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
541                         ierr )
542          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
543       ENDDO
544    ELSE
545
546!
547!--    Send data to PE0
548       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
549       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
550       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
551       ibuf(12) = nyn
552       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
553    ENDIF
554#endif
555
556#if defined( __parallel )
557#if defined( __mpi2 )
558!
559!-- In case of coupled runs, get the port name on PE0 of the atmosphere model
560!-- and pass it to PE0 of the ocean model
561    IF ( myid == 0 )  THEN
562
563       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
564
565          CALL MPI_OPEN_PORT( MPI_INFO_NULL, port_name, ierr )
566
567          CALL MPI_PUBLISH_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, &
568                                 ierr )
569
570!
571!--       Write a flag file for the ocean model and the other atmosphere
572!--       processes.
573!--       There seems to be a bug in MPICH2 which causes hanging processes
574!--       in case that execution of LOOKUP_NAME is continued too early
575!--       (i.e. before the port has been created)
576          OPEN( 90, FILE='COUPLING_PORT_OPENED', FORM='FORMATTED' )
577          WRITE ( 90, '(''TRUE'')' )
578          CLOSE ( 90 )
579
580       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
581
582!
583!--       Continue only if the atmosphere model has created the port.
584!--       There seems to be a bug in MPICH2 which causes hanging processes
585!--       in case that execution of LOOKUP_NAME is continued too early
586!--       (i.e. before the port has been created)
587          INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
588          DO WHILE ( .NOT. found )
589             INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
590          ENDDO
591
592          CALL MPI_LOOKUP_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, ierr )
593
594       ENDIF
595
596    ENDIF
597
598!
599!-- In case of coupled runs, establish the connection between the atmosphere
600!-- and the ocean model and define the intercommunicator (comm_inter)
601    CALL MPI_BARRIER( comm2d, ierr )
602    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
603
604       CALL MPI_COMM_ACCEPT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
605                             comm_inter, ierr )
606       coupling_mode_remote = 'ocean_to_atmosphere'
607
608    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
609
610       CALL MPI_COMM_CONNECT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
611                              comm_inter, ierr )
612       coupling_mode_remote = 'atmosphere_to_ocean'
613
614    ENDIF
615#endif
616
617!
618!-- Determine the number of ghost point layers
619    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
620         scalar_advec == 'ws-scheme-mono' .OR.                                &
621         momentum_advec == 'ws-scheme' )  THEN
622       nbgp = 3
623    ELSE
624       nbgp = 1
625    ENDIF
626
627!
628!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
629!-- which is needed for coupled atmosphere-ocean runs.
630!-- First, calculate number of grid points of an xy-plane.
631    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
632    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
633    CALL MPI_TYPE_COMMIT( type_xy, ierr )
634
635    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
636   
637!
638!--    Pass the number of grid points of the atmosphere model to
639!--    the ocean model and vice versa
640       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
641
642          nx_a = nx
643          ny_a = ny
644
645          IF ( myid == 0 )  THEN
646
647             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
648                            ierr )
649             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
650                            ierr )
651             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
652                            ierr )
653             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
654                            status, ierr )
655             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
656                            status, ierr )
657             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
658                            comm_inter, status, ierr )
659          ENDIF
660
661          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
662          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
663          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
664       
665       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
666
667          nx_o = nx
668          ny_o = ny
669
670          IF ( myid == 0 ) THEN
671
672             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
673                            ierr )
674             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
675                            ierr )
676             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
677                            status, ierr )
678             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
679             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
680             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
681          ENDIF
682
683          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
684          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
685          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
686
687       ENDIF
688 
689       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
690       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
691
692!
693!--    Determine if the horizontal grid and the number of PEs in ocean and
694!--    atmosphere is same or not
695       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
696            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
697       THEN
698          coupling_topology = 0
699       ELSE
700          coupling_topology = 1
701       ENDIF
702
703!
704!--    Determine the target PEs for the exchange between ocean and
705!--    atmosphere (comm2d)
706       IF ( coupling_topology == 0 )  THEN
707!
708!--       In case of identical topologies, every atmosphere PE has exactly one
709!--       ocean PE counterpart and vice versa
710          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
711             target_id = myid + numprocs
712          ELSE
713             target_id = myid
714          ENDIF
715
716       ELSE
717!
718!--       In case of nonequivalent topology in ocean and atmosphere only for
719!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
720!--       data echxchange between ocean and atmosphere will be done only
721!--       between these PEs.   
722          IF ( myid == 0 )  THEN
723
724             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
725                target_id = numprocs
726             ELSE
727                target_id = 0
728             ENDIF
729
730          ENDIF
731
732       ENDIF
733
734    ENDIF
735
736
737#endif
738
739#else
740
741!
742!-- Array bounds when running on a single PE (respectively a non-parallel
743!-- machine)
744    nxl = 0
745    nxr = nx
746    nnx = nxr - nxl + 1
747    nys = 0
748    nyn = ny
749    nny = nyn - nys + 1
750    nzb = 0
751    nzt = nz
752    nnz = nz
753
754    ALLOCATE( hor_index_bounds(4,0:0) )
755    hor_index_bounds(1,0) = nxl
756    hor_index_bounds(2,0) = nxr
757    hor_index_bounds(3,0) = nys
758    hor_index_bounds(4,0) = nyn
759
760!
761!-- Array bounds for the pressure solver (in the parallel code, these bounds
762!-- are the ones for the transposed arrays)
763    nys_x = nys
764    nyn_x = nyn
765    nzb_x = nzb + 1
766    nzt_x = nzt
767
768    nxl_y = nxl
769    nxr_y = nxr
770    nzb_y = nzb + 1
771    nzt_y = nzt
772
773    nxl_z = nxl
774    nxr_z = nxr
775    nys_z = nys
776    nyn_z = nyn
777
778#endif
779
780!
781!-- Calculate number of grid levels necessary for the multigrid poisson solver
782!-- as well as the gridpoint indices on each level
783    IF ( psolver(1:9) == 'multigrid' )  THEN
784
785!
786!--    First calculate number of possible grid levels for the subdomains
787       mg_levels_x = 1
788       mg_levels_y = 1
789       mg_levels_z = 1
790
791       i = nnx
792       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
793          i = i / 2
794          mg_levels_x = mg_levels_x + 1
795       ENDDO
796
797       j = nny
798       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
799          j = j / 2
800          mg_levels_y = mg_levels_y + 1
801       ENDDO
802
803       k = nz    ! do not use nnz because it might be > nz due to transposition
804                 ! requirements
805       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
806          k = k / 2
807          mg_levels_z = mg_levels_z + 1
808       ENDDO
809
810       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
811
812!
813!--    Find out, if the total domain allows more levels. These additional
814!--    levels are identically processed on all PEs.
815       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
816
817          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
818
819             mg_switch_to_pe0_level_l = maximum_grid_level
820
821             mg_levels_x = 1
822             mg_levels_y = 1
823
824             i = nx+1
825             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
826                i = i / 2
827                mg_levels_x = mg_levels_x + 1
828             ENDDO
829
830             j = ny+1
831             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
832                j = j / 2
833                mg_levels_y = mg_levels_y + 1
834             ENDDO
835
836             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
837
838             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
839                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
840                                           mg_switch_to_pe0_level_l + 1
841             ELSE
842                mg_switch_to_pe0_level_l = 0
843             ENDIF
844
845          ELSE
846             mg_switch_to_pe0_level_l = 0
847             maximum_grid_level_l = maximum_grid_level
848
849          ENDIF
850
851!
852!--       Use switch level calculated above only if it is not pre-defined
853!--       by user
854          IF ( mg_switch_to_pe0_level == 0 )  THEN
855             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
856                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
857                maximum_grid_level     = maximum_grid_level_l
858             ENDIF
859
860          ELSE
861!
862!--          Check pre-defined value and reset to default, if neccessary
863             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
864                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
865                message_string = 'mg_switch_to_pe0_level ' // &
866                                 'out of range and reset to default (=0)'
867                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
868                mg_switch_to_pe0_level = 0
869             ELSE
870!
871!--             Use the largest number of possible levels anyway and recalculate
872!--             the switch level to this largest number of possible values
873                maximum_grid_level = maximum_grid_level_l
874
875             ENDIF
876
877          ENDIF
878
879       ENDIF
880
881       ALLOCATE( grid_level_count(maximum_grid_level),                       &
882                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
883                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
884                 nzt_mg(0:maximum_grid_level) )
885
886       grid_level_count = 0
887!
888!--    Index zero required as dummy due to definition of arrays f2 and p2 in
889!--    recursive subroutine next_mg_level
890       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
891
892       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
893
894       DO  i = maximum_grid_level, 1 , -1
895
896          IF ( i == mg_switch_to_pe0_level )  THEN
897#if defined( __parallel )
898!
899!--          Save the grid size of the subdomain at the switch level, because
900!--          it is needed in poismg.
901             ind(1) = nxl_l; ind(2) = nxr_l
902             ind(3) = nys_l; ind(4) = nyn_l
903             ind(5) = nzt_l
904             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
905             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
906                                 MPI_INTEGER, comm2d, ierr )
907             DO  j = 0, numprocs-1
908                DO  k = 1, 5
909                   mg_loc_ind(k,j) = ind_all(k+j*5)
910                ENDDO
911             ENDDO
912             DEALLOCATE( ind_all )
913!
914!--          Calculate the grid size of the total domain
915             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
916             nxl_l = 0
917             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
918             nys_l = 0
919!
920!--          The size of this gathered array must not be larger than the
921!--          array tend, which is used in the multigrid scheme as a temporary
922!--          array. Therefore the subdomain size of an PE is calculated and
923!--          the size of the gathered grid. These values are used in 
924!--          routines pres and poismg
925             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
926                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
927             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
928                              ( nzt_l - nzb + 2 )
929
930#else
931             message_string = 'multigrid gather/scatter impossible ' // &
932                          'in non parallel mode'
933             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
934#endif
935          ENDIF
936
937          nxl_mg(i) = nxl_l
938          nxr_mg(i) = nxr_l
939          nys_mg(i) = nys_l
940          nyn_mg(i) = nyn_l
941          nzt_mg(i) = nzt_l
942
943          nxl_l = nxl_l / 2 
944          nxr_l = nxr_l / 2
945          nys_l = nys_l / 2 
946          nyn_l = nyn_l / 2 
947          nzt_l = nzt_l / 2 
948
949       ENDDO
950
951!
952!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
953!--    if grid data are collected on PE0 already on the finest grid level.
954!--    To be solved later.
955       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
956          message_string = 'grid coarsening on subdomain level cannot be performed'
957          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
958       ENDIF
959
960    ELSE
961
962       maximum_grid_level = 0
963
964    ENDIF
965
966!
967!-- Default level 0 tells exchange_horiz that all ghost planes have to be
968!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
969!-- is required.
970    grid_level = 0
971
972#if defined( __parallel )
973!
974!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
975    ngp_y  = nyn - nys + 1 + 2 * nbgp
976
977!
978!-- Define new MPI derived datatypes for the exchange of ghost points in
979!-- x- and y-direction for 2D-arrays (line)
980    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x, &
981                          ierr )
982    CALL MPI_TYPE_COMMIT( type_x, ierr )
983    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER, &
984                          type_x_int, ierr )
985    CALL MPI_TYPE_COMMIT( type_x_int, ierr )
986
987    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
988    CALL MPI_TYPE_COMMIT( type_y, ierr )
989    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int, ierr )
990    CALL MPI_TYPE_COMMIT( type_y_int, ierr )
991
992
993!
994!-- Calculate gridpoint numbers for the exchange of ghost points along x
995!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
996!-- exchange of ghost points in y-direction (xz-plane).
997!-- Do these calculations for the model grid and (if necessary) also
998!-- for the coarser grid levels used in the multigrid method
999    ALLOCATE ( ngp_xz(0:maximum_grid_level), ngp_yz(0:maximum_grid_level),     &
1000               type_xz(0:maximum_grid_level), type_yz(0:maximum_grid_level) )
1001
1002    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1003
1004!
1005!-- Discern between the model grid, which needs nbgp ghost points and
1006!-- grid levels for the multigrid scheme. In the latter case only one
1007!-- ghost point is necessary.
1008!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1009!-- grid. The following loop is needed for data exchange in poismg.f90.
1010!
1011!-- Determine number of grid points of yz-layer for exchange
1012    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1013
1014!
1015!-- Define an MPI-datatype for the exchange of left/right boundaries.
1016!-- Although data are contiguous in physical memory (which does not
1017!-- necessarily require an MPI-derived datatype), the data exchange between
1018!-- left and right PE's using the MPI-derived type is 10% faster than without.
1019    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1020                          MPI_REAL, type_xz(0), ierr )
1021    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1022
1023    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1024                          ierr ) 
1025    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1026
1027!
1028!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1029    IF ( psolver(1:9) == 'multigrid' )  THEN
1030!   
1031!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1032       DO  i = maximum_grid_level, 1 , -1
1033
1034          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1035          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1036
1037          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i), &
1038                                MPI_REAL, type_xz(i), ierr )
1039          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1040
1041          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1042                                ierr )
1043          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1044
1045          nxl_l = nxl_l / 2
1046          nxr_l = nxr_l / 2
1047          nys_l = nys_l / 2
1048          nyn_l = nyn_l / 2
1049          nzt_l = nzt_l / 2
1050
1051       ENDDO
1052
1053    ENDIF
1054!
1055!-- Define data types for exchange of 3D Integer arrays.
1056    ngp_yz_int = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1057
1058    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int, &
1059                          MPI_INTEGER, type_xz_int, ierr )
1060    CALL MPI_TYPE_COMMIT( type_xz_int, ierr )
1061
1062    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int, ngp_yz_int, MPI_INTEGER, type_yz_int, &
1063                          ierr )
1064    CALL MPI_TYPE_COMMIT( type_yz_int, ierr )
1065
1066#endif
1067
1068#if defined( __parallel )
1069!
1070!-- Setting of flags for inflow/outflow/nesting conditions in case of non-cyclic
1071!-- horizontal boundary conditions.
1072    IF ( pleft == MPI_PROC_NULL )  THEN
1073       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1074          inflow_l  = .TRUE.
1075       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1076          outflow_l = .TRUE.
1077       ELSEIF ( bc_lr == 'nested' )  THEN
1078          nest_bound_l = .TRUE.
1079       ENDIF
1080    ENDIF
1081
1082    IF ( pright == MPI_PROC_NULL )  THEN
1083       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1084          outflow_r = .TRUE.
1085       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1086          inflow_r  = .TRUE.
1087       ELSEIF ( bc_lr == 'nested' )  THEN
1088          nest_bound_r = .TRUE.
1089       ENDIF
1090    ENDIF
1091
1092    IF ( psouth == MPI_PROC_NULL )  THEN
1093       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1094          outflow_s = .TRUE.
1095       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1096          inflow_s  = .TRUE.
1097       ELSEIF ( bc_ns == 'nested' )  THEN
1098          nest_bound_s = .TRUE.
1099       ENDIF
1100    ENDIF
1101
1102    IF ( pnorth == MPI_PROC_NULL )  THEN
1103       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1104          inflow_n  = .TRUE.
1105       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1106          outflow_n = .TRUE.
1107       ELSEIF ( bc_ns == 'nested' )  THEN
1108          nest_bound_n = .TRUE.
1109       ENDIF
1110    ENDIF
1111
1112!
1113!-- Broadcast the id of the inflow PE
1114    IF ( inflow_l )  THEN
1115       id_inflow_l = myidx
1116    ELSE
1117       id_inflow_l = 0
1118    ENDIF
1119    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1120    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1121                        comm1dx, ierr )
1122
1123!
1124!-- Broadcast the id of the recycling plane
1125!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1126    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1127         NINT( recycling_width / dx ) <= nxr )  THEN
1128       id_recycling_l = myidx
1129    ELSE
1130       id_recycling_l = 0
1131    ENDIF
1132    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1133    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1134                        comm1dx, ierr )
1135
1136    CALL location_message( 'finished', .TRUE. )
1137
1138#else
1139    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1140       inflow_l  = .TRUE.
1141       outflow_r = .TRUE.
1142    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1143       outflow_l = .TRUE.
1144       inflow_r  = .TRUE.
1145    ENDIF
1146
1147    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1148       inflow_n  = .TRUE.
1149       outflow_s = .TRUE.
1150    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1151       outflow_n = .TRUE.
1152       inflow_s  = .TRUE.
1153    ENDIF
1154#endif
1155
1156!
1157!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1158!-- one more grid point.
1159    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l )  THEN
1160       nxlu = nxl + 1
1161    ELSE
1162       nxlu = nxl
1163    ENDIF
1164    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s )  THEN
1165       nysv = nys + 1
1166    ELSE
1167       nysv = nys
1168    ENDIF
1169
1170!
1171!-- Allocate wall flag arrays used in the multigrid solver
1172    IF ( psolver(1:9) == 'multigrid' )  THEN
1173
1174       DO  i = maximum_grid_level, 1, -1
1175
1176           SELECT CASE ( i )
1177
1178              CASE ( 1 )
1179                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1180                                        nys_mg(i)-1:nyn_mg(i)+1, &
1181                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1182
1183              CASE ( 2 )
1184                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1185                                        nys_mg(i)-1:nyn_mg(i)+1, &
1186                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1187
1188              CASE ( 3 )
1189                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1190                                        nys_mg(i)-1:nyn_mg(i)+1, &
1191                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1192
1193              CASE ( 4 )
1194                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1195                                        nys_mg(i)-1:nyn_mg(i)+1, &
1196                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1197
1198              CASE ( 5 )
1199                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1200                                        nys_mg(i)-1:nyn_mg(i)+1, &
1201                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1202
1203              CASE ( 6 )
1204                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1205                                        nys_mg(i)-1:nyn_mg(i)+1, &
1206                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1207
1208              CASE ( 7 )
1209                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1210                                        nys_mg(i)-1:nyn_mg(i)+1, &
1211                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1212
1213              CASE ( 8 )
1214                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1215                                        nys_mg(i)-1:nyn_mg(i)+1, &
1216                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1217
1218              CASE ( 9 )
1219                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1220                                        nys_mg(i)-1:nyn_mg(i)+1, &
1221                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1222
1223              CASE ( 10 )
1224                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1225                                        nys_mg(i)-1:nyn_mg(i)+1, &
1226                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1227
1228              CASE DEFAULT
1229                 message_string = 'more than 10 multigrid levels'
1230                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1231
1232          END SELECT
1233
1234       ENDDO
1235
1236    ENDIF
1237
1238!
1239!-- Calculate the number of groups into which parallel I/O is split.
1240!-- The default for files which are opened by all PEs (or where each
1241!-- PE opens his own independent file) is, that all PEs are doing input/output
1242!-- in parallel at the same time. This might cause performance or even more
1243!-- severe problems depending on the configuration of the underlying file
1244!-- system.
1245!-- First, set the default:
1246    IF ( maximum_parallel_io_streams == -1  .OR. &
1247         maximum_parallel_io_streams > numprocs )  THEN
1248       maximum_parallel_io_streams = numprocs
1249    ENDIF
1250
1251!
1252!-- Now calculate the number of io_blocks and the io_group to which the
1253!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
1254!-- for all PEs belonging to the same group. A preliminary setting with myid
1255!-- based on MPI_COMM_WORLD has been done in parin.
1256    io_blocks = numprocs / maximum_parallel_io_streams
1257    io_group  = MOD( myid+1, io_blocks )
1258   
1259
1260 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.