source: palm/trunk/SOURCE/init_ocean.f90 @ 2032

Last change on this file since 2032 was 2032, checked in by knoop, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 5.2 KB
Line 
1!> @file init_ocean.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2016 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! ------------------
26! $Id: init_ocean.f90 2032 2016-10-21 15:13:51Z knoop $
27!
28! 2031 2016-10-21 15:11:58Z knoop
29! renamed variable rho_init to rho_ocean_init
30!
31! 2000 2016-08-20 18:09:15Z knoop
32! Forced header and separation lines into 80 columns
33!
34! 1682 2015-10-07 23:56:08Z knoop
35! Code annotations made doxygen readable
36!
37! 1353 2014-04-08 15:21:23Z heinze
38! REAL constants provided with KIND-attribute
39!
40! 1322 2014-03-20 16:38:49Z raasch
41! REAL constants defined as wp_kind
42!
43! 1320 2014-03-20 08:40:49Z raasch
44! ONLY-attribute added to USE-statements,
45! kind-parameters added to all INTEGER and REAL declaration statements,
46! kinds are defined in new module kinds,
47! revision history before 2012 removed,
48! comment fields (!:) to be used for variable explanations added to
49! all variable declaration statements
50!
51! 1179 2013-06-14 05:57:58Z raasch
52! Initial density profile is stored in array hom
53!
54! 1036 2012-10-22 13:43:42Z raasch
55! code put under GPL (PALM 3.9)
56!
57! 97 2007-06-21 08:23:15Z raasch
58! Initial revision
59!
60! Description:
61! ------------
62!> Initialization of quantities needed for the ocean version
63!------------------------------------------------------------------------------!
64 SUBROUTINE init_ocean
65 
66
67    USE arrays_3d,                                                             &
68        ONLY:  dzu, hyp, pt_init, ref_state, sa_init, zu, zw
69
70    USE control_parameters,                                                    &
71        ONLY:  g, prho_reference, rho_surface, rho_reference,                  &
72               surface_pressure, use_single_reference_value
73
74    USE eqn_state_seawater_mod,                                                &
75        ONLY:  eqn_state_seawater, eqn_state_seawater_func
76
77    USE indices,                                                               &
78        ONLY:  nzb, nzt
79
80    USE kinds
81
82    USE pegrid
83
84    USE statistics,                                                            &
85        ONLY:  hom, statistic_regions
86
87    IMPLICIT NONE
88
89    INTEGER(iwp) ::  k !<
90    INTEGER(iwp) ::  n !<
91
92    REAL(wp)     ::  pt_l !<
93    REAL(wp)     ::  sa_l !<
94
95    REAL(wp), DIMENSION(nzb:nzt+1) ::  rho_ocean_init !<
96
97    ALLOCATE( hyp(nzb:nzt+1) )
98
99!
100!-- Set water density near the ocean surface
101    rho_surface = 1027.62_wp
102
103!
104!-- Calculate initial vertical profile of hydrostatic pressure (in Pa)
105!-- and the reference density (used later in buoyancy term)
106!-- First step: Calculate pressure using reference density
107    hyp(nzt+1) = surface_pressure * 100.0_wp
108
109    hyp(nzt)      = hyp(nzt+1) + rho_surface * g * 0.5_wp * dzu(nzt+1)
110    rho_ocean_init(nzt) = rho_surface
111
112    DO  k = nzt-1, 1, -1
113       hyp(k) = hyp(k+1) + rho_surface * g * dzu(k)
114    ENDDO
115    hyp(0) = hyp(1) + rho_surface * g * dzu(1)
116
117!
118!-- Second step: Iteratively calculate in situ density (based on presssure)
119!-- and pressure (based on in situ density)
120    DO  n = 1, 5
121
122       rho_reference = rho_surface * 0.5_wp * dzu(nzt+1)
123
124       DO  k = nzt-1, 0, -1
125
126          sa_l = 0.5_wp * ( sa_init(k) + sa_init(k+1) )
127          pt_l = 0.5_wp * ( pt_init(k) + pt_init(k+1) )
128
129          rho_ocean_init(k) = eqn_state_seawater_func( hyp(k), pt_l, sa_l )
130
131          rho_reference = rho_reference + rho_ocean_init(k) * dzu(k+1)
132
133       ENDDO
134
135       rho_reference = rho_reference / ( zw(nzt) - zu(nzb) )
136
137       DO  k = nzt-1, 0, -1
138          hyp(k) = hyp(k+1) + g * 0.5_wp * ( rho_ocean_init(k) + rho_ocean_init(k+1 ) ) * &
139                              dzu(k+1)
140       ENDDO
141
142    ENDDO
143
144!
145!-- Calculate the reference potential density
146    prho_reference = 0.0_wp
147    DO  k = 0, nzt
148
149       sa_l = 0.5_wp * ( sa_init(k) + sa_init(k+1) )
150       pt_l = 0.5_wp * ( pt_init(k) + pt_init(k+1) )
151
152       prho_reference = prho_reference + dzu(k+1) * &
153                        eqn_state_seawater_func( 0.0_wp, pt_l, sa_l )
154
155    ENDDO
156
157    prho_reference = prho_reference / ( zu(nzt) - zu(nzb) )
158
159!
160!-- Calculate the 3d array of initial in situ and potential density,
161!-- based on the initial temperature and salinity profile
162    CALL eqn_state_seawater
163
164!
165!-- Store initial density profile
166    hom(:,1,77,:)  = SPREAD( rho_ocean_init(:), 2, statistic_regions+1 )
167
168!
169!-- Set the reference state to be used in the buoyancy terms
170    IF ( use_single_reference_value )  THEN
171       ref_state(:) = prho_reference
172    ELSE
173       ref_state(:) = rho_ocean_init(:)
174    ENDIF
175
176
177 END SUBROUTINE init_ocean
Note: See TracBrowser for help on using the repository browser.