source: palm/trunk/SOURCE/init_ocean.f90 @ 1322

Last change on this file since 1322 was 1322, checked in by raasch, 8 years ago

REAL functions and a lot of REAL constants provided with KIND-attribute,
some small bugfixes

  • Property svn:keywords set to Id
File size: 4.7 KB
Line 
1 SUBROUTINE init_ocean
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2014 Leibniz Universitaet Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! REAL constants defined as wp_kind
23!
24! Former revisions:
25! ------------------
26! $Id: init_ocean.f90 1322 2014-03-20 16:38:49Z raasch $
27!
28! 1320 2014-03-20 08:40:49Z raasch
29! ONLY-attribute added to USE-statements,
30! kind-parameters added to all INTEGER and REAL declaration statements,
31! kinds are defined in new module kinds,
32! revision history before 2012 removed,
33! comment fields (!:) to be used for variable explanations added to
34! all variable declaration statements
35!
36! 1179 2013-06-14 05:57:58Z raasch
37! Initial density profile is stored in array hom
38!
39! 1036 2012-10-22 13:43:42Z raasch
40! code put under GPL (PALM 3.9)
41!
42! 97 2007-06-21 08:23:15Z raasch
43! Initial revision
44!
45! Description:
46! ------------
47! Initialization of quantities needed for the ocean version
48!------------------------------------------------------------------------------!
49
50    USE arrays_3d,                                                             &
51        ONLY:  dzu, hyp, pt_init, ref_state, sa_init, zu, zw
52
53    USE control_parameters,                                                    &
54        ONLY:  g, prho_reference, rho_surface, rho_reference,                  &
55               surface_pressure, use_single_reference_value
56
57    USE eqn_state_seawater_mod,                                                &
58        ONLY:  eqn_state_seawater, eqn_state_seawater_func
59
60    USE indices,                                                               &
61        ONLY:  nzb, nzt
62
63    USE kinds
64
65    USE pegrid
66
67    USE statistics,                                                            &
68        ONLY:  hom, statistic_regions
69
70    IMPLICIT NONE
71
72    INTEGER(iwp) ::  k !:
73    INTEGER(iwp) ::  n !:
74
75    REAL(wp)     ::  pt_l !:
76    REAL(wp)     ::  sa_l !:
77
78    REAL(wp), DIMENSION(nzb:nzt+1) ::  rho_init !:
79
80    ALLOCATE( hyp(nzb:nzt+1) )
81
82!
83!-- Set water density near the ocean surface
84    rho_surface = 1027.62
85
86!
87!-- Calculate initial vertical profile of hydrostatic pressure (in Pa)
88!-- and the reference density (used later in buoyancy term)
89!-- First step: Calculate pressure using reference density
90    hyp(nzt+1) = surface_pressure * 100.0_wp
91
92    hyp(nzt)      = hyp(nzt+1) + rho_surface * g * 0.5 * dzu(nzt+1)
93    rho_init(nzt) = rho_surface
94
95    DO  k = nzt-1, 1, -1
96       hyp(k) = hyp(k+1) + rho_surface * g * dzu(k)
97    ENDDO
98    hyp(0) = hyp(1) + rho_surface * g * dzu(1)
99
100!
101!-- Second step: Iteratively calculate in situ density (based on presssure)
102!-- and pressure (based on in situ density)
103    DO  n = 1, 5
104
105       rho_reference = rho_surface * 0.5 * dzu(nzt+1)
106
107       DO  k = nzt-1, 0, -1
108
109          sa_l = 0.5 * ( sa_init(k) + sa_init(k+1) )
110          pt_l = 0.5 * ( pt_init(k) + pt_init(k+1) )
111
112          rho_init(k) = eqn_state_seawater_func( hyp(k), pt_l, sa_l )
113
114          rho_reference = rho_reference + rho_init(k) * dzu(k+1)
115
116       ENDDO
117
118       rho_reference = rho_reference / ( zw(nzt) - zu(nzb) )
119
120       DO  k = nzt-1, 0, -1
121          hyp(k) = hyp(k+1) + g * 0.5 * ( rho_init(k) + rho_init(k+1 ) ) * &
122                              dzu(k+1)
123       ENDDO
124
125    ENDDO
126
127!
128!-- Calculate the reference potential density
129    prho_reference = 0.0
130    DO  k = 0, nzt
131
132       sa_l = 0.5 * ( sa_init(k) + sa_init(k+1) )
133       pt_l = 0.5 * ( pt_init(k) + pt_init(k+1) )
134
135       prho_reference = prho_reference + dzu(k+1) * &
136                        eqn_state_seawater_func( 0.0_wp, pt_l, sa_l )
137
138    ENDDO
139
140    prho_reference = prho_reference / ( zu(nzt) - zu(nzb) )
141
142!
143!-- Calculate the 3d array of initial in situ and potential density,
144!-- based on the initial temperature and salinity profile
145    CALL eqn_state_seawater
146
147!
148!-- Store initial density profile
149    hom(:,1,77,:)  = SPREAD( rho_init(:), 2, statistic_regions+1 )
150
151!
152!-- Set the reference state to be used in the buoyancy terms
153    IF ( use_single_reference_value )  THEN
154       ref_state(:) = prho_reference
155    ELSE
156       ref_state(:) = rho_init(:)
157    ENDIF
158
159
160 END SUBROUTINE init_ocean
Note: See TracBrowser for help on using the repository browser.