| 1 | SUBROUTINE init_masks |
|---|
| 2 | |
|---|
| 3 | !------------------------------------------------------------------------------! |
|---|
| 4 | ! Current revisions: |
|---|
| 5 | ! ----------------- |
|---|
| 6 | ! New cpp directive "__check" implemented which is used by check_namelist_files |
|---|
| 7 | ! |
|---|
| 8 | ! Former revisions: |
|---|
| 9 | ! ----------------- |
|---|
| 10 | ! $Id: init_masks.f90 807 2012-01-25 11:53:51Z maronga $ |
|---|
| 11 | ! |
|---|
| 12 | ! 771 2011-10-27 10:56:21Z heinze |
|---|
| 13 | ! +lpt |
|---|
| 14 | ! |
|---|
| 15 | ! 595 2010-11-12 09:52:10Z helmke |
|---|
| 16 | ! Calculation of z locations for masked output changed |
|---|
| 17 | ! |
|---|
| 18 | ! 564 2010-09-30 13:18:59Z helmke |
|---|
| 19 | ! assignment of mask_xyz_loop added, palm message identifiers of masked output |
|---|
| 20 | ! changed |
|---|
| 21 | ! |
|---|
| 22 | ! 557 2010-09-07 14:50:07Z weinreis |
|---|
| 23 | ! bugfix message string in set_mask_locations |
|---|
| 24 | ! |
|---|
| 25 | ! 553 2010-09-01 14:09:06Z weinreis |
|---|
| 26 | ! parameters for masked output are replaced by arrays |
|---|
| 27 | ! |
|---|
| 28 | ! 493 2010-03-01 08:30:24Z raasch |
|---|
| 29 | ! netcdf_format_mask* and format_parallel_io replaced by netcdf_data_format |
|---|
| 30 | ! |
|---|
| 31 | ! 410 2009-12-04 17:05:40Z letzel |
|---|
| 32 | ! Initial revision |
|---|
| 33 | ! |
|---|
| 34 | ! |
|---|
| 35 | ! Description: |
|---|
| 36 | ! ------------ |
|---|
| 37 | ! Initialize masked data output |
|---|
| 38 | !------------------------------------------------------------------------------! |
|---|
| 39 | |
|---|
| 40 | USE arrays_3d |
|---|
| 41 | USE control_parameters |
|---|
| 42 | USE grid_variables |
|---|
| 43 | USE indices |
|---|
| 44 | USE netcdf_control |
|---|
| 45 | USE particle_attributes |
|---|
| 46 | USE pegrid |
|---|
| 47 | |
|---|
| 48 | IMPLICIT NONE |
|---|
| 49 | |
|---|
| 50 | CHARACTER (LEN=6) :: var |
|---|
| 51 | CHARACTER (LEN=7) :: unit |
|---|
| 52 | CHARACTER (LEN=10), DIMENSION(max_masks,100) :: do_mask, do_mask_user |
|---|
| 53 | |
|---|
| 54 | INTEGER :: i, ilen, ind(6), ind_array(1), j, k, n, sender |
|---|
| 55 | INTEGER, DIMENSION(:), ALLOCATABLE :: tmp_array |
|---|
| 56 | |
|---|
| 57 | LOGICAL :: found |
|---|
| 58 | ! |
|---|
| 59 | !-- Allocation and initialization |
|---|
| 60 | ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) ) |
|---|
| 61 | |
|---|
| 62 | ALLOCATE( mask_i(max_masks,nxr-nxl+1), & |
|---|
| 63 | mask_j(max_masks,nyn-nys+1), & |
|---|
| 64 | mask_k(max_masks,nzt-nzb+1) ) |
|---|
| 65 | ! |
|---|
| 66 | !-- internal mask arrays ("mask,dimension,selection") |
|---|
| 67 | ALLOCATE( mask(max_masks,3,mask_xyz_dimension), & |
|---|
| 68 | mask_loop(max_masks,3,3) ) |
|---|
| 69 | |
|---|
| 70 | ! |
|---|
| 71 | !-- Parallel mask output not yet tested |
|---|
| 72 | IF ( netcdf_data_format > 2 ) THEN |
|---|
| 73 | message_string = 'NetCDF file formats '// & |
|---|
| 74 | '3 (NetCDF 4) and 4 (NetCDF 4 Classic model)'// & |
|---|
| 75 | '&are currently not supported (not yet tested).' |
|---|
| 76 | CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 ) |
|---|
| 77 | ENDIF |
|---|
| 78 | |
|---|
| 79 | ! |
|---|
| 80 | !-- Store data output parameters for masked data output in few shared arrays |
|---|
| 81 | DO mid = 1, masks |
|---|
| 82 | |
|---|
| 83 | do_mask (mid,:) = data_output_masks(mid,:) |
|---|
| 84 | do_mask_user(mid,:) = data_output_masks_user(mid,:) |
|---|
| 85 | mask (mid,1,:) = mask_x(mid,:) |
|---|
| 86 | mask (mid,2,:) = mask_y(mid,:) |
|---|
| 87 | mask (mid,3,:) = mask_z(mid,:) |
|---|
| 88 | |
|---|
| 89 | IF ( mask_x_loop(mid,1) == -1.0 .AND. mask_x_loop(mid,2) == -1.0 & |
|---|
| 90 | .AND. mask_x_loop(mid,3) == -1.0 ) THEN |
|---|
| 91 | mask_loop(mid,1,1:2) = -1.0 |
|---|
| 92 | mask_loop(mid,1,3) = 0.0 |
|---|
| 93 | ELSE |
|---|
| 94 | mask_loop(mid,1,:) = mask_x_loop(mid,:) |
|---|
| 95 | ENDIF |
|---|
| 96 | IF ( mask_y_loop(mid,1) == -1.0 .AND. mask_y_loop(mid,2) == -1.0 & |
|---|
| 97 | .AND. mask_y_loop(mid,3) == -1.0 ) THEN |
|---|
| 98 | mask_loop(mid,2,1:2) = -1.0 |
|---|
| 99 | mask_loop(mid,2,3) = 0.0 |
|---|
| 100 | ELSE |
|---|
| 101 | mask_loop(mid,2,:) = mask_y_loop(mid,:) |
|---|
| 102 | ENDIF |
|---|
| 103 | IF ( mask_z_loop(mid,1) == -1.0 .AND. mask_z_loop(mid,2) == -1.0 & |
|---|
| 104 | .AND. mask_z_loop(mid,3) == -1.0 ) THEN |
|---|
| 105 | mask_loop(mid,3,1:2) = -1.0 |
|---|
| 106 | mask_loop(mid,3,3) = 0.0 |
|---|
| 107 | ELSE |
|---|
| 108 | mask_loop(mid,3,:) = mask_z_loop(mid,:) |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | ENDDO |
|---|
| 112 | |
|---|
| 113 | mask_i = -1; mask_j = -1; mask_k = -1 |
|---|
| 114 | |
|---|
| 115 | ! |
|---|
| 116 | !-- Global arrays are required by define_netcdf_header. |
|---|
| 117 | IF ( myid == 0 .OR. netcdf_data_format > 2 ) THEN |
|---|
| 118 | ALLOCATE( mask_i_global(max_masks,nx+1), & |
|---|
| 119 | mask_j_global(max_masks,ny+1), & |
|---|
| 120 | mask_k_global(max_masks,nz+1) ) |
|---|
| 121 | mask_i_global = -1; mask_j_global = -1; mask_k_global = -1 |
|---|
| 122 | ENDIF |
|---|
| 123 | |
|---|
| 124 | ! |
|---|
| 125 | !-- Determine variable names for each mask |
|---|
| 126 | DO mid = 1, masks |
|---|
| 127 | ! |
|---|
| 128 | !-- Append user-defined data output variables to the standard data output |
|---|
| 129 | IF ( do_mask_user(mid,1) /= ' ' ) THEN |
|---|
| 130 | i = 1 |
|---|
| 131 | DO WHILE ( do_mask(mid,i) /= ' ' .AND. i <= 100 ) |
|---|
| 132 | i = i + 1 |
|---|
| 133 | ENDDO |
|---|
| 134 | j = 1 |
|---|
| 135 | DO WHILE ( do_mask_user(mid,j) /= ' ' .AND. j <= 100 ) |
|---|
| 136 | IF ( i > 100 ) THEN |
|---|
| 137 | WRITE ( message_string, * ) 'number of output quantitities ', & |
|---|
| 138 | 'given by data_output_mask and data_output_mask_user ', & |
|---|
| 139 | 'exceeds the limit of 100' |
|---|
| 140 | CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 ) |
|---|
| 141 | ENDIF |
|---|
| 142 | do_mask(mid,i) = do_mask_user(mid,j) |
|---|
| 143 | i = i + 1 |
|---|
| 144 | j = j + 1 |
|---|
| 145 | ENDDO |
|---|
| 146 | ENDIF |
|---|
| 147 | |
|---|
| 148 | ! |
|---|
| 149 | !-- Check and set steering parameters for mask data output and averaging |
|---|
| 150 | i = 1 |
|---|
| 151 | DO WHILE ( do_mask(mid,i) /= ' ' .AND. i <= 100 ) |
|---|
| 152 | ! |
|---|
| 153 | !-- Check for data averaging |
|---|
| 154 | ilen = LEN_TRIM( do_mask(mid,i) ) |
|---|
| 155 | j = 0 ! no data averaging |
|---|
| 156 | IF ( ilen > 3 ) THEN |
|---|
| 157 | IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' ) THEN |
|---|
| 158 | j = 1 ! data averaging |
|---|
| 159 | do_mask(mid,i) = do_mask(mid,i)(1:ilen-3) |
|---|
| 160 | ENDIF |
|---|
| 161 | ENDIF |
|---|
| 162 | var = TRIM( do_mask(mid,i) ) |
|---|
| 163 | ! |
|---|
| 164 | !-- Check for allowed value and set units |
|---|
| 165 | SELECT CASE ( TRIM( var ) ) |
|---|
| 166 | |
|---|
| 167 | CASE ( 'e' ) |
|---|
| 168 | IF ( constant_diffusion ) THEN |
|---|
| 169 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 170 | '" requires constant_diffusion = .FALSE.' |
|---|
| 171 | CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 ) |
|---|
| 172 | ENDIF |
|---|
| 173 | unit = 'm2/s2' |
|---|
| 174 | |
|---|
| 175 | CASE ( 'lpt' ) |
|---|
| 176 | IF ( .NOT. cloud_physics ) THEN |
|---|
| 177 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 178 | '" requires cloud_physics = .TRUE.' |
|---|
| 179 | CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 180 | ENDIF |
|---|
| 181 | unit = 'K' |
|---|
| 182 | |
|---|
| 183 | CASE ( 'pc', 'pr' ) |
|---|
| 184 | IF ( .NOT. particle_advection ) THEN |
|---|
| 185 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 186 | '" requires a "particles_par"-NAMELIST in the ', & |
|---|
| 187 | 'parameter file (PARIN)' |
|---|
| 188 | CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 ) |
|---|
| 189 | ENDIF |
|---|
| 190 | IF ( TRIM( var ) == 'pc' ) unit = 'number' |
|---|
| 191 | IF ( TRIM( var ) == 'pr' ) unit = 'm' |
|---|
| 192 | |
|---|
| 193 | CASE ( 'q', 'vpt' ) |
|---|
| 194 | IF ( .NOT. humidity ) THEN |
|---|
| 195 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 196 | '" requires humidity = .TRUE.' |
|---|
| 197 | CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 ) |
|---|
| 198 | ENDIF |
|---|
| 199 | IF ( TRIM( var ) == 'q' ) unit = 'kg/kg' |
|---|
| 200 | IF ( TRIM( var ) == 'vpt' ) unit = 'K' |
|---|
| 201 | |
|---|
| 202 | CASE ( 'ql' ) |
|---|
| 203 | IF ( .NOT. ( cloud_physics .OR. cloud_droplets ) ) THEN |
|---|
| 204 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 205 | '" requires cloud_physics = .TRUE. or cloud_droplets', & |
|---|
| 206 | ' = .TRUE.' |
|---|
| 207 | CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 208 | ENDIF |
|---|
| 209 | unit = 'kg/kg' |
|---|
| 210 | |
|---|
| 211 | CASE ( 'ql_c', 'ql_v', 'ql_vp' ) |
|---|
| 212 | IF ( .NOT. cloud_droplets ) THEN |
|---|
| 213 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 214 | '" requires cloud_droplets = .TRUE.' |
|---|
| 215 | CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 ) |
|---|
| 216 | ENDIF |
|---|
| 217 | IF ( TRIM( var ) == 'ql_c' ) unit = 'kg/kg' |
|---|
| 218 | IF ( TRIM( var ) == 'ql_v' ) unit = 'm3' |
|---|
| 219 | IF ( TRIM( var ) == 'ql_vp' ) unit = 'none' |
|---|
| 220 | |
|---|
| 221 | CASE ( 'qv' ) |
|---|
| 222 | IF ( .NOT. cloud_physics ) THEN |
|---|
| 223 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 224 | '" requires cloud_physics = .TRUE.' |
|---|
| 225 | CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 226 | ENDIF |
|---|
| 227 | unit = 'kg/kg' |
|---|
| 228 | |
|---|
| 229 | CASE ( 'rho' ) |
|---|
| 230 | IF ( .NOT. ocean ) THEN |
|---|
| 231 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 232 | '" requires ocean = .TRUE.' |
|---|
| 233 | CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 ) |
|---|
| 234 | ENDIF |
|---|
| 235 | unit = 'kg/m3' |
|---|
| 236 | |
|---|
| 237 | CASE ( 's' ) |
|---|
| 238 | IF ( .NOT. passive_scalar ) THEN |
|---|
| 239 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 240 | '" requires passive_scalar = .TRUE.' |
|---|
| 241 | CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 ) |
|---|
| 242 | ENDIF |
|---|
| 243 | unit = 'conc' |
|---|
| 244 | |
|---|
| 245 | CASE ( 'sa' ) |
|---|
| 246 | IF ( .NOT. ocean ) THEN |
|---|
| 247 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 248 | '" requires ocean = .TRUE.' |
|---|
| 249 | CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 ) |
|---|
| 250 | ENDIF |
|---|
| 251 | unit = 'psu' |
|---|
| 252 | |
|---|
| 253 | CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*' ) |
|---|
| 254 | WRITE ( message_string, * ) 'illegal value for data_',& |
|---|
| 255 | 'output: "', TRIM( var ), '" is only allowed', & |
|---|
| 256 | 'for horizontal cross section' |
|---|
| 257 | CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 ) |
|---|
| 258 | ! IF ( TRIM( var ) == 'lwp*' .AND. .NOT. cloud_physics ) THEN |
|---|
| 259 | ! WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 260 | ! '" requires cloud_physics = .TRUE.' |
|---|
| 261 | ! CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 262 | ! ENDIF |
|---|
| 263 | ! IF ( TRIM( var ) == 'pra*' .AND. .NOT. precipitation ) THEN |
|---|
| 264 | ! WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 265 | ! '" requires precipitation = .TRUE.' |
|---|
| 266 | ! CALL message( 'init_masks', 'PA0112', 1, 2, 0, 6, 0 ) |
|---|
| 267 | ! ENDIF |
|---|
| 268 | ! IF ( TRIM( var ) == 'pra*' .AND. j == 1 ) THEN |
|---|
| 269 | ! WRITE ( message_string, * ) 'temporal averaging of ', & |
|---|
| 270 | ! ' precipitation amount "', TRIM( var ), & |
|---|
| 271 | ! '" not possible' |
|---|
| 272 | ! CALL message( 'init_masks', 'PA0113', 1, 2, 0, 6, 0 ) |
|---|
| 273 | ! ENDIF |
|---|
| 274 | ! IF ( TRIM( var ) == 'prr*' .AND. .NOT. precipitation ) THEN |
|---|
| 275 | ! WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 276 | ! '" requires precipitation = .TRUE.' |
|---|
| 277 | ! CALL message( 'init_masks', 'PA0112', 1, 2, 0, 6, 0 ) |
|---|
| 278 | ! ENDIF |
|---|
| 279 | ! |
|---|
| 280 | ! IF ( TRIM( var ) == 'u*' ) unit = 'm/s' |
|---|
| 281 | ! IF ( TRIM( var ) == 't*' ) unit = 'K' |
|---|
| 282 | ! IF ( TRIM( var ) == 'lwp*' ) unit = 'kg/kg*m' |
|---|
| 283 | ! IF ( TRIM( var ) == 'pra*' ) unit = 'mm' |
|---|
| 284 | ! IF ( TRIM( var ) == 'prr*' ) unit = 'mm/s' |
|---|
| 285 | ! IF ( TRIM( var ) == 'z0*' ) unit = 'm' |
|---|
| 286 | |
|---|
| 287 | CASE ( 'p', 'pt', 'u', 'v', 'w' ) |
|---|
| 288 | IF ( TRIM( var ) == 'p' ) unit = 'Pa' |
|---|
| 289 | IF ( TRIM( var ) == 'pt' ) unit = 'K' |
|---|
| 290 | IF ( TRIM( var ) == 'u' ) unit = 'm/s' |
|---|
| 291 | IF ( TRIM( var ) == 'v' ) unit = 'm/s' |
|---|
| 292 | IF ( TRIM( var ) == 'w' ) unit = 'm/s' |
|---|
| 293 | CONTINUE |
|---|
| 294 | |
|---|
| 295 | CASE DEFAULT |
|---|
| 296 | CALL user_check_data_output( var, unit ) |
|---|
| 297 | |
|---|
| 298 | IF ( unit == 'illegal' ) THEN |
|---|
| 299 | IF ( do_mask_user(mid,1) /= ' ' ) THEN |
|---|
| 300 | WRITE ( message_string, * ) 'illegal value for data_',& |
|---|
| 301 | 'output or data_output_user: "', & |
|---|
| 302 | TRIM( do_mask(mid,i) ), '"' |
|---|
| 303 | CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 ) |
|---|
| 304 | ELSE |
|---|
| 305 | WRITE ( message_string, * ) 'illegal value for data_',& |
|---|
| 306 | 'output: "', TRIM( do_mask(mid,i) ), '"' |
|---|
| 307 | CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 ) |
|---|
| 308 | ENDIF |
|---|
| 309 | ENDIF |
|---|
| 310 | |
|---|
| 311 | END SELECT |
|---|
| 312 | ! |
|---|
| 313 | !-- Set the internal steering parameters appropriately |
|---|
| 314 | domask_no(mid,j) = domask_no(mid,j) + 1 |
|---|
| 315 | domask(mid,j,domask_no(mid,j)) = do_mask(mid,i) |
|---|
| 316 | domask_unit(mid,j,domask_no(mid,j)) = unit |
|---|
| 317 | |
|---|
| 318 | IF ( j == 1 ) THEN |
|---|
| 319 | ! |
|---|
| 320 | !-- Check, if variable is already subject to averaging |
|---|
| 321 | found = .FALSE. |
|---|
| 322 | DO k = 1, doav_n |
|---|
| 323 | IF ( TRIM( doav(k) ) == TRIM( var ) ) found = .TRUE. |
|---|
| 324 | ENDDO |
|---|
| 325 | |
|---|
| 326 | IF ( .NOT. found ) THEN |
|---|
| 327 | doav_n = doav_n + 1 |
|---|
| 328 | doav(doav_n) = var |
|---|
| 329 | ENDIF |
|---|
| 330 | ENDIF |
|---|
| 331 | |
|---|
| 332 | i = i + 1 |
|---|
| 333 | |
|---|
| 334 | ENDDO ! do_mask(mid,i) |
|---|
| 335 | ENDDO ! mid |
|---|
| 336 | |
|---|
| 337 | |
|---|
| 338 | ! |
|---|
| 339 | !-- Determine mask locations for each mask |
|---|
| 340 | DO mid = 1, masks |
|---|
| 341 | ! |
|---|
| 342 | !-- Set local masks for each subdomain along all three dimensions |
|---|
| 343 | CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr ) |
|---|
| 344 | CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn ) |
|---|
| 345 | CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt ) |
|---|
| 346 | ! |
|---|
| 347 | !-- Set global masks along all three dimensions (required by |
|---|
| 348 | !-- define_netcdf_header). |
|---|
| 349 | #if defined( __parallel ) .AND. .NOT. defined ( __check ) |
|---|
| 350 | ! |
|---|
| 351 | !-- PE0 receives partial arrays from all processors of the respective mask |
|---|
| 352 | !-- and outputs them. Here a barrier has to be set, because otherwise |
|---|
| 353 | !-- "-MPI- FATAL: Remote protocol queue full" may occur. |
|---|
| 354 | |
|---|
| 355 | CALL MPI_BARRIER( comm2d, ierr ) |
|---|
| 356 | |
|---|
| 357 | IF ( myid == 0 ) THEN |
|---|
| 358 | ! |
|---|
| 359 | !-- Local arrays can be relocated directly. |
|---|
| 360 | mask_i_global(mid,mask_start_l(mid,1): & |
|---|
| 361 | mask_start_l(mid,1)+mask_size_l(mid,1)-1) = & |
|---|
| 362 | mask_i(mid,:mask_size_l(mid,1)) |
|---|
| 363 | mask_j_global(mid,mask_start_l(mid,2): & |
|---|
| 364 | mask_start_l(mid,2)+mask_size_l(mid,2)-1) = & |
|---|
| 365 | mask_j(mid,:mask_size_l(mid,2)) |
|---|
| 366 | mask_k_global(mid,mask_start_l(mid,3): & |
|---|
| 367 | mask_start_l(mid,3)+mask_size_l(mid,3)-1) = & |
|---|
| 368 | mask_k(mid,:mask_size_l(mid,3)) |
|---|
| 369 | ! |
|---|
| 370 | !-- Receive data from all other PEs. |
|---|
| 371 | DO n = 1, numprocs-1 |
|---|
| 372 | ! |
|---|
| 373 | !-- Receive index limits first, then arrays. |
|---|
| 374 | !-- Index limits are received in arbitrary order from the PEs. |
|---|
| 375 | CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0, & |
|---|
| 376 | comm2d, status, ierr ) |
|---|
| 377 | ! |
|---|
| 378 | !-- Not all PEs have data for the mask. |
|---|
| 379 | IF ( ind(1) /= -9999 ) THEN |
|---|
| 380 | sender = status(MPI_SOURCE) |
|---|
| 381 | CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1, & |
|---|
| 382 | MPI_INTEGER, sender, 1, comm2d, status, ierr ) |
|---|
| 383 | mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2)) |
|---|
| 384 | CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1, & |
|---|
| 385 | MPI_INTEGER, sender, 2, comm2d, status, ierr ) |
|---|
| 386 | mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4)) |
|---|
| 387 | CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1, & |
|---|
| 388 | MPI_INTEGER, sender, 3, comm2d, status, ierr ) |
|---|
| 389 | mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6)) |
|---|
| 390 | ENDIF |
|---|
| 391 | ENDDO |
|---|
| 392 | |
|---|
| 393 | ELSE |
|---|
| 394 | ! |
|---|
| 395 | !-- If at least part of the mask resides on the PE, send the index limits |
|---|
| 396 | !-- for the target array, otherwise send -9999 to PE0. |
|---|
| 397 | IF ( mask_size_l(mid,1) > 0 .AND. mask_size_l(mid,2) > 0 .AND. & |
|---|
| 398 | mask_size_l(mid,3) > 0 ) & |
|---|
| 399 | THEN |
|---|
| 400 | ind(1) = mask_start_l(mid,1) |
|---|
| 401 | ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1 |
|---|
| 402 | ind(3) = mask_start_l(mid,2) |
|---|
| 403 | ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1 |
|---|
| 404 | ind(5) = mask_start_l(mid,3) |
|---|
| 405 | ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1 |
|---|
| 406 | ELSE |
|---|
| 407 | ind(1) = -9999; ind(2) = -9999 |
|---|
| 408 | ind(3) = -9999; ind(4) = -9999 |
|---|
| 409 | ind(5) = -9999; ind(6) = -9999 |
|---|
| 410 | ENDIF |
|---|
| 411 | CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr ) |
|---|
| 412 | ! |
|---|
| 413 | !-- If applicable, send data to PE0. |
|---|
| 414 | IF ( ind(1) /= -9999 ) THEN |
|---|
| 415 | tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1)) |
|---|
| 416 | CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1), & |
|---|
| 417 | MPI_INTEGER, 0, 1, comm2d, ierr ) |
|---|
| 418 | tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2)) |
|---|
| 419 | CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2), & |
|---|
| 420 | MPI_INTEGER, 0, 2, comm2d, ierr ) |
|---|
| 421 | tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3)) |
|---|
| 422 | CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3), & |
|---|
| 423 | MPI_INTEGER, 0, 3, comm2d, ierr ) |
|---|
| 424 | ENDIF |
|---|
| 425 | ENDIF |
|---|
| 426 | ! |
|---|
| 427 | !-- A barrier has to be set, because otherwise some PEs may proceed too fast |
|---|
| 428 | !-- so that PE0 may receive wrong data on tag 0. |
|---|
| 429 | CALL MPI_BARRIER( comm2d, ierr ) |
|---|
| 430 | |
|---|
| 431 | IF ( netcdf_data_format > 2 ) THEN |
|---|
| 432 | |
|---|
| 433 | CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, & |
|---|
| 434 | ierr ) |
|---|
| 435 | CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, & |
|---|
| 436 | ierr ) |
|---|
| 437 | CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, & |
|---|
| 438 | ierr ) |
|---|
| 439 | |
|---|
| 440 | ENDIF |
|---|
| 441 | |
|---|
| 442 | #elif .NOT. defined ( __parallel ) |
|---|
| 443 | ! |
|---|
| 444 | !-- Local arrays can be relocated directly. |
|---|
| 445 | mask_i_global(mid,:) = mask_i(mid,:) |
|---|
| 446 | mask_j_global(mid,:) = mask_j(mid,:) |
|---|
| 447 | mask_k_global(mid,:) = mask_k(mid,:) |
|---|
| 448 | #endif |
|---|
| 449 | ENDDO ! mid |
|---|
| 450 | |
|---|
| 451 | DEALLOCATE( tmp_array ) |
|---|
| 452 | ! |
|---|
| 453 | !-- Internal mask arrays cannot be deallocated on PE 0 because they are |
|---|
| 454 | !-- required for header output on PE 0. |
|---|
| 455 | IF ( myid /= 0 ) DEALLOCATE( mask, mask_loop ) |
|---|
| 456 | |
|---|
| 457 | CONTAINS |
|---|
| 458 | |
|---|
| 459 | SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, & |
|---|
| 460 | lb, ub ) |
|---|
| 461 | !------------------------------------------------------------------------------! |
|---|
| 462 | ! |
|---|
| 463 | ! Description: |
|---|
| 464 | ! ------------ |
|---|
| 465 | ! Set local mask for each subdomain along 'dim' direction. |
|---|
| 466 | !------------------------------------------------------------------------------! |
|---|
| 467 | |
|---|
| 468 | IMPLICIT NONE |
|---|
| 469 | |
|---|
| 470 | CHARACTER (LEN=2) :: dxyz_string, nxyz_string |
|---|
| 471 | INTEGER :: count, count_l, dim, m, loop_begin, loop_end, loop_stride, & |
|---|
| 472 | lb, nxyz, ub |
|---|
| 473 | REAL :: dxyz, ddxyz, tmp1, tmp2 |
|---|
| 474 | |
|---|
| 475 | count = 0; count_l = 0; ddxyz = 1.0 / dxyz; tmp1 = 0.0; tmp2 = 0.0 |
|---|
| 476 | |
|---|
| 477 | IF ( mask(mid,dim,1) >= 0.0 ) THEN |
|---|
| 478 | ! |
|---|
| 479 | !-- use predefined mask_* array |
|---|
| 480 | DO WHILE ( mask(mid,dim,count+1) >= 0.0 ) |
|---|
| 481 | count = count + 1 |
|---|
| 482 | IF ( dim == 1 .OR. dim == 2 ) THEN |
|---|
| 483 | m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz ) |
|---|
| 484 | ELSEIF ( dim == 3 ) THEN |
|---|
| 485 | ind_array = & |
|---|
| 486 | MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) ) |
|---|
| 487 | m = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1 |
|---|
| 488 | ENDIF |
|---|
| 489 | IF ( m > nxyz ) THEN |
|---|
| 490 | WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' ) & |
|---|
| 491 | m,' in mask ',mid,' along dimension ',dim, & |
|---|
| 492 | ' exceeds ',nxyz_string,' = ',nxyz |
|---|
| 493 | CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 ) |
|---|
| 494 | ENDIF |
|---|
| 495 | IF ( m >= lb .AND. m <= ub ) THEN |
|---|
| 496 | IF ( count_l == 0 ) mask_start_l(mid,dim) = count |
|---|
| 497 | count_l = count_l + 1 |
|---|
| 498 | IF ( dim == 1 ) THEN |
|---|
| 499 | mask_i(mid,count_l) = m |
|---|
| 500 | ELSEIF ( dim == 2 ) THEN |
|---|
| 501 | mask_j(mid,count_l) = m |
|---|
| 502 | ELSEIF ( dim == 3 ) THEN |
|---|
| 503 | mask_k(mid,count_l) = m |
|---|
| 504 | ENDIF |
|---|
| 505 | ENDIF |
|---|
| 506 | IF ( count == mask_xyz_dimension ) EXIT |
|---|
| 507 | ENDDO |
|---|
| 508 | mask_size(mid,dim) = count |
|---|
| 509 | mask_size_l(mid,dim) = count_l |
|---|
| 510 | |
|---|
| 511 | ELSE |
|---|
| 512 | ! |
|---|
| 513 | !-- use predefined mask_loop_* array, or use the default (all grid points |
|---|
| 514 | !-- along this direction) |
|---|
| 515 | IF ( mask_loop(mid,dim,1) < 0.0 ) THEN |
|---|
| 516 | tmp1 = mask_loop(mid,dim,1) |
|---|
| 517 | mask_loop(mid,dim,1) = 0.0 ! (default) |
|---|
| 518 | ENDIF |
|---|
| 519 | IF ( dim == 1 .OR. dim == 2 ) THEN |
|---|
| 520 | IF ( mask_loop(mid,dim,2) < 0.0 ) THEN |
|---|
| 521 | tmp2 = mask_loop(mid,dim,2) |
|---|
| 522 | mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim) ! (default) |
|---|
| 523 | ENDIF |
|---|
| 524 | IF ( MAXVAL( mask_loop(mid,dim,1:2) ) & |
|---|
| 525 | > nxyz * dxyz / mask_scale(dim) ) THEN |
|---|
| 526 | WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) & |
|---|
| 527 | 'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), & |
|---|
| 528 | ' and/or mask_loop(',mid,',',dim,',2)=', & |
|---|
| 529 | mask_loop(mid,dim,2),'&exceed ', & |
|---|
| 530 | nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', & |
|---|
| 531 | nxyz*dxyz/mask_scale(dim) |
|---|
| 532 | CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 ) |
|---|
| 533 | ENDIF |
|---|
| 534 | loop_begin = NINT( mask_loop(mid,dim,1) * mask_scale(dim) * ddxyz ) |
|---|
| 535 | loop_end = NINT( mask_loop(mid,dim,2) * mask_scale(dim) * ddxyz ) |
|---|
| 536 | loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz ) |
|---|
| 537 | ELSEIF ( dim == 3 ) THEN |
|---|
| 538 | IF ( mask_loop(mid,dim,2) < 0.0 ) THEN |
|---|
| 539 | tmp2 = mask_loop(mid,dim,2) |
|---|
| 540 | mask_loop(mid,dim,2) = zu(nz) / mask_scale(dim) ! (default) |
|---|
| 541 | ENDIF |
|---|
| 542 | IF ( MAXVAL( mask_loop(mid,dim,1:2) ) & |
|---|
| 543 | > zu(nz) / mask_scale(dim) ) THEN |
|---|
| 544 | WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) & |
|---|
| 545 | 'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), & |
|---|
| 546 | ' and/or mask_loop(',mid,',',dim,',2)=', & |
|---|
| 547 | mask_loop(mid,dim,2),'&exceed zu(nz)/mask_scale(',dim, & |
|---|
| 548 | ')=',zu(nz)/mask_scale(dim) |
|---|
| 549 | CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 ) |
|---|
| 550 | ENDIF |
|---|
| 551 | ind_array = & |
|---|
| 552 | MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) ) |
|---|
| 553 | loop_begin = & |
|---|
| 554 | ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1 |
|---|
| 555 | ind_array = & |
|---|
| 556 | MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) ) |
|---|
| 557 | loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1 |
|---|
| 558 | ! |
|---|
| 559 | !-- The following line assumes a constant vertical grid spacing within |
|---|
| 560 | !-- the vertical mask range; it fails for vertical grid stretching. |
|---|
| 561 | !-- Maybe revise later. Issue warning but continue execution. |
|---|
| 562 | loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz ) |
|---|
| 563 | |
|---|
| 564 | IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level ) & |
|---|
| 565 | THEN |
|---|
| 566 | WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) & |
|---|
| 567 | 'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),& |
|---|
| 568 | ' exceeds dz_stretch_level=',dz_stretch_level, & |
|---|
| 569 | '.&Vertical mask locations will not ', & |
|---|
| 570 | 'match the desired heights&within the stretching ', & |
|---|
| 571 | 'region. Recommendation: use mask instead of mask_loop.' |
|---|
| 572 | CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 ) |
|---|
| 573 | ENDIF |
|---|
| 574 | |
|---|
| 575 | ENDIF |
|---|
| 576 | ! |
|---|
| 577 | !-- If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2). |
|---|
| 578 | IF ( tmp1 < 0.0 ) mask_loop(mid,dim,1) = tmp1 |
|---|
| 579 | IF ( tmp2 < 0.0 ) mask_loop(mid,dim,2) = tmp2 |
|---|
| 580 | ! |
|---|
| 581 | !-- The default stride +/-1 (every grid point) applies if |
|---|
| 582 | !-- mask_loop(mid,dim,3) is not specified (its default is zero). |
|---|
| 583 | IF ( loop_stride == 0 ) THEN |
|---|
| 584 | IF ( loop_end >= loop_begin ) THEN |
|---|
| 585 | loop_stride = 1 |
|---|
| 586 | ELSE |
|---|
| 587 | loop_stride = -1 |
|---|
| 588 | ENDIF |
|---|
| 589 | ENDIF |
|---|
| 590 | DO m = loop_begin, loop_end, loop_stride |
|---|
| 591 | count = count + 1 |
|---|
| 592 | IF ( m >= lb .AND. m <= ub ) THEN |
|---|
| 593 | IF ( count_l == 0 ) mask_start_l(mid,dim) = count |
|---|
| 594 | count_l = count_l + 1 |
|---|
| 595 | IF ( dim == 1 ) THEN |
|---|
| 596 | mask_i(mid,count_l) = m |
|---|
| 597 | ELSEIF ( dim == 2 ) THEN |
|---|
| 598 | mask_j(mid,count_l) = m |
|---|
| 599 | ELSEIF ( dim == 3 ) THEN |
|---|
| 600 | mask_k(mid,count_l) = m |
|---|
| 601 | ENDIF |
|---|
| 602 | ENDIF |
|---|
| 603 | ENDDO |
|---|
| 604 | mask_size(mid,dim) = count |
|---|
| 605 | mask_size_l(mid,dim) = count_l |
|---|
| 606 | ENDIF |
|---|
| 607 | |
|---|
| 608 | END SUBROUTINE set_mask_locations |
|---|
| 609 | |
|---|
| 610 | END SUBROUTINE init_masks |
|---|
