| 1 | SUBROUTINE init_masks |
|---|
| 2 | |
|---|
| 3 | !------------------------------------------------------------------------------! |
|---|
| 4 | ! Current revisions: |
|---|
| 5 | ! ----------------- |
|---|
| 6 | ! |
|---|
| 7 | ! |
|---|
| 8 | ! Former revisions: |
|---|
| 9 | ! ----------------- |
|---|
| 10 | ! $Id: init_masks.f90 565 2010-09-30 13:34:53Z heinze $ |
|---|
| 11 | ! |
|---|
| 12 | ! 564 2010-09-30 13:18:59Z helmke |
|---|
| 13 | ! assignment of mask_xyz_loop added, palm message identifiers of masked output |
|---|
| 14 | ! changed |
|---|
| 15 | ! |
|---|
| 16 | ! 557 2010-09-07 14:50:07Z weinreis |
|---|
| 17 | ! bugfix message string in set_mask_locations |
|---|
| 18 | ! |
|---|
| 19 | ! 553 2010-09-01 14:09:06Z weinreis |
|---|
| 20 | ! parameters for masked output are replaced by arrays |
|---|
| 21 | ! |
|---|
| 22 | ! 493 2010-03-01 08:30:24Z raasch |
|---|
| 23 | ! netcdf_format_mask* and format_parallel_io replaced by netcdf_data_format |
|---|
| 24 | ! |
|---|
| 25 | ! 410 2009-12-04 17:05:40Z letzel |
|---|
| 26 | ! Initial revision |
|---|
| 27 | ! |
|---|
| 28 | ! |
|---|
| 29 | ! Description: |
|---|
| 30 | ! ------------ |
|---|
| 31 | ! Initialize masked data output |
|---|
| 32 | !------------------------------------------------------------------------------! |
|---|
| 33 | |
|---|
| 34 | USE arrays_3d |
|---|
| 35 | USE control_parameters |
|---|
| 36 | USE grid_variables |
|---|
| 37 | USE indices |
|---|
| 38 | USE netcdf_control |
|---|
| 39 | USE particle_attributes |
|---|
| 40 | USE pegrid |
|---|
| 41 | |
|---|
| 42 | IMPLICIT NONE |
|---|
| 43 | |
|---|
| 44 | CHARACTER (LEN=6) :: var |
|---|
| 45 | CHARACTER (LEN=7) :: unit |
|---|
| 46 | CHARACTER (LEN=10), DIMENSION(max_masks,100) :: do_mask, do_mask_user |
|---|
| 47 | |
|---|
| 48 | INTEGER :: i, ilen, ind(6), ind_array(1), j, k, n, sender |
|---|
| 49 | INTEGER, DIMENSION(:), ALLOCATABLE :: tmp_array |
|---|
| 50 | |
|---|
| 51 | LOGICAL :: found |
|---|
| 52 | ! |
|---|
| 53 | !-- Allocation and initialization |
|---|
| 54 | ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) ) |
|---|
| 55 | |
|---|
| 56 | ALLOCATE( mask_i(max_masks,nxr-nxl+1), & |
|---|
| 57 | mask_j(max_masks,nyn-nys+1), & |
|---|
| 58 | mask_k(max_masks,nzt-nzb+1) ) |
|---|
| 59 | ! |
|---|
| 60 | !-- internal mask arrays ("mask,dimension,selection") |
|---|
| 61 | ALLOCATE( mask(max_masks,3,mask_xyz_dimension), & |
|---|
| 62 | mask_loop(max_masks,3,3) ) |
|---|
| 63 | |
|---|
| 64 | ! |
|---|
| 65 | !-- Parallel mask output not yet tested |
|---|
| 66 | IF ( netcdf_data_format > 2 ) THEN |
|---|
| 67 | message_string = 'NetCDF file formats '// & |
|---|
| 68 | '3 (NetCDF 4) and 4 (NetCDF 4 Classic model)'// & |
|---|
| 69 | '&are currently not supported (not yet tested).' |
|---|
| 70 | CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 ) |
|---|
| 71 | ENDIF |
|---|
| 72 | |
|---|
| 73 | ! |
|---|
| 74 | !-- Store data output parameters for masked data output in few shared arrays |
|---|
| 75 | DO mid = 1, masks |
|---|
| 76 | |
|---|
| 77 | do_mask (mid,:) = data_output_masks(mid,:) |
|---|
| 78 | do_mask_user(mid,:) = data_output_masks_user(mid,:) |
|---|
| 79 | mask (mid,1,:) = mask_x(mid,:) |
|---|
| 80 | mask (mid,2,:) = mask_y(mid,:) |
|---|
| 81 | mask (mid,3,:) = mask_z(mid,:) |
|---|
| 82 | |
|---|
| 83 | IF ( mask_x_loop(mid,1) == -1.0 .AND. mask_x_loop(mid,2) == -1.0 & |
|---|
| 84 | .AND. mask_x_loop(mid,3) == -1.0 ) THEN |
|---|
| 85 | mask_loop(mid,1,1:2) = -1.0 |
|---|
| 86 | mask_loop(mid,1,3) = 0.0 |
|---|
| 87 | ELSE |
|---|
| 88 | mask_loop(mid,1,:) = mask_x_loop(mid,:) |
|---|
| 89 | ENDIF |
|---|
| 90 | IF ( mask_y_loop(mid,1) == -1.0 .AND. mask_y_loop(mid,2) == -1.0 & |
|---|
| 91 | .AND. mask_y_loop(mid,3) == -1.0 ) THEN |
|---|
| 92 | mask_loop(mid,2,1:2) = -1.0 |
|---|
| 93 | mask_loop(mid,2,3) = 0.0 |
|---|
| 94 | ELSE |
|---|
| 95 | mask_loop(mid,2,:) = mask_y_loop(mid,:) |
|---|
| 96 | ENDIF |
|---|
| 97 | IF ( mask_z_loop(mid,1) == -1.0 .AND. mask_z_loop(mid,2) == -1.0 & |
|---|
| 98 | .AND. mask_z_loop(mid,3) == -1.0 ) THEN |
|---|
| 99 | mask_loop(mid,3,1:2) = -1.0 |
|---|
| 100 | mask_loop(mid,3,3) = 0.0 |
|---|
| 101 | ELSE |
|---|
| 102 | mask_loop(mid,3,:) = mask_z_loop(mid,:) |
|---|
| 103 | ENDIF |
|---|
| 104 | |
|---|
| 105 | ENDDO |
|---|
| 106 | |
|---|
| 107 | mask_i = -1; mask_j = -1; mask_k = -1 |
|---|
| 108 | |
|---|
| 109 | ! |
|---|
| 110 | !-- Global arrays are required by define_netcdf_header. |
|---|
| 111 | IF ( myid == 0 .OR. netcdf_data_format > 2 ) THEN |
|---|
| 112 | ALLOCATE( mask_i_global(max_masks,nx+1), & |
|---|
| 113 | mask_j_global(max_masks,ny+1), & |
|---|
| 114 | mask_k_global(max_masks,nz+1) ) |
|---|
| 115 | mask_i_global = -1; mask_j_global = -1; mask_k_global = -1 |
|---|
| 116 | ENDIF |
|---|
| 117 | |
|---|
| 118 | ! |
|---|
| 119 | !-- Determine variable names for each mask |
|---|
| 120 | DO mid = 1, masks |
|---|
| 121 | ! |
|---|
| 122 | !-- Append user-defined data output variables to the standard data output |
|---|
| 123 | IF ( do_mask_user(mid,1) /= ' ' ) THEN |
|---|
| 124 | i = 1 |
|---|
| 125 | DO WHILE ( do_mask(mid,i) /= ' ' .AND. i <= 100 ) |
|---|
| 126 | i = i + 1 |
|---|
| 127 | ENDDO |
|---|
| 128 | j = 1 |
|---|
| 129 | DO WHILE ( do_mask_user(mid,j) /= ' ' .AND. j <= 100 ) |
|---|
| 130 | IF ( i > 100 ) THEN |
|---|
| 131 | WRITE ( message_string, * ) 'number of output quantitities ', & |
|---|
| 132 | 'given by data_output_mask and data_output_mask_user ', & |
|---|
| 133 | 'exceeds the limit of 100' |
|---|
| 134 | CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 ) |
|---|
| 135 | ENDIF |
|---|
| 136 | do_mask(mid,i) = do_mask_user(mid,j) |
|---|
| 137 | i = i + 1 |
|---|
| 138 | j = j + 1 |
|---|
| 139 | ENDDO |
|---|
| 140 | ENDIF |
|---|
| 141 | |
|---|
| 142 | ! |
|---|
| 143 | !-- Check and set steering parameters for mask data output and averaging |
|---|
| 144 | i = 1 |
|---|
| 145 | DO WHILE ( do_mask(mid,i) /= ' ' .AND. i <= 100 ) |
|---|
| 146 | ! |
|---|
| 147 | !-- Check for data averaging |
|---|
| 148 | ilen = LEN_TRIM( do_mask(mid,i) ) |
|---|
| 149 | j = 0 ! no data averaging |
|---|
| 150 | IF ( ilen > 3 ) THEN |
|---|
| 151 | IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' ) THEN |
|---|
| 152 | j = 1 ! data averaging |
|---|
| 153 | do_mask(mid,i) = do_mask(mid,i)(1:ilen-3) |
|---|
| 154 | ENDIF |
|---|
| 155 | ENDIF |
|---|
| 156 | var = TRIM( do_mask(mid,i) ) |
|---|
| 157 | ! |
|---|
| 158 | !-- Check for allowed value and set units |
|---|
| 159 | SELECT CASE ( TRIM( var ) ) |
|---|
| 160 | |
|---|
| 161 | CASE ( 'e' ) |
|---|
| 162 | IF ( constant_diffusion ) THEN |
|---|
| 163 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 164 | '" requires constant_diffusion = .FALSE.' |
|---|
| 165 | CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 ) |
|---|
| 166 | ENDIF |
|---|
| 167 | unit = 'm2/s2' |
|---|
| 168 | |
|---|
| 169 | CASE ( 'pc', 'pr' ) |
|---|
| 170 | IF ( .NOT. particle_advection ) THEN |
|---|
| 171 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 172 | '" requires a "particles_par"-NAMELIST in the ', & |
|---|
| 173 | 'parameter file (PARIN)' |
|---|
| 174 | CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 ) |
|---|
| 175 | ENDIF |
|---|
| 176 | IF ( TRIM( var ) == 'pc' ) unit = 'number' |
|---|
| 177 | IF ( TRIM( var ) == 'pr' ) unit = 'm' |
|---|
| 178 | |
|---|
| 179 | CASE ( 'q', 'vpt' ) |
|---|
| 180 | IF ( .NOT. humidity ) THEN |
|---|
| 181 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 182 | '" requires humidity = .TRUE.' |
|---|
| 183 | CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 ) |
|---|
| 184 | ENDIF |
|---|
| 185 | IF ( TRIM( var ) == 'q' ) unit = 'kg/kg' |
|---|
| 186 | IF ( TRIM( var ) == 'vpt' ) unit = 'K' |
|---|
| 187 | |
|---|
| 188 | CASE ( 'ql' ) |
|---|
| 189 | IF ( .NOT. ( cloud_physics .OR. cloud_droplets ) ) THEN |
|---|
| 190 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 191 | '" requires cloud_physics = .TRUE. or cloud_droplets', & |
|---|
| 192 | ' = .TRUE.' |
|---|
| 193 | CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 194 | ENDIF |
|---|
| 195 | unit = 'kg/kg' |
|---|
| 196 | |
|---|
| 197 | CASE ( 'ql_c', 'ql_v', 'ql_vp' ) |
|---|
| 198 | IF ( .NOT. cloud_droplets ) THEN |
|---|
| 199 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 200 | '" requires cloud_droplets = .TRUE.' |
|---|
| 201 | CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 ) |
|---|
| 202 | ENDIF |
|---|
| 203 | IF ( TRIM( var ) == 'ql_c' ) unit = 'kg/kg' |
|---|
| 204 | IF ( TRIM( var ) == 'ql_v' ) unit = 'm3' |
|---|
| 205 | IF ( TRIM( var ) == 'ql_vp' ) unit = 'none' |
|---|
| 206 | |
|---|
| 207 | CASE ( 'qv' ) |
|---|
| 208 | IF ( .NOT. cloud_physics ) THEN |
|---|
| 209 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 210 | '" requires cloud_physics = .TRUE.' |
|---|
| 211 | CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 212 | ENDIF |
|---|
| 213 | unit = 'kg/kg' |
|---|
| 214 | |
|---|
| 215 | CASE ( 'rho' ) |
|---|
| 216 | IF ( .NOT. ocean ) THEN |
|---|
| 217 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 218 | '" requires ocean = .TRUE.' |
|---|
| 219 | CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 ) |
|---|
| 220 | ENDIF |
|---|
| 221 | unit = 'kg/m3' |
|---|
| 222 | |
|---|
| 223 | CASE ( 's' ) |
|---|
| 224 | IF ( .NOT. passive_scalar ) THEN |
|---|
| 225 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 226 | '" requires passive_scalar = .TRUE.' |
|---|
| 227 | CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 ) |
|---|
| 228 | ENDIF |
|---|
| 229 | unit = 'conc' |
|---|
| 230 | |
|---|
| 231 | CASE ( 'sa' ) |
|---|
| 232 | IF ( .NOT. ocean ) THEN |
|---|
| 233 | WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 234 | '" requires ocean = .TRUE.' |
|---|
| 235 | CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 ) |
|---|
| 236 | ENDIF |
|---|
| 237 | unit = 'psu' |
|---|
| 238 | |
|---|
| 239 | CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*' ) |
|---|
| 240 | WRITE ( message_string, * ) 'illegal value for data_',& |
|---|
| 241 | 'output: "', TRIM( var ), '" is only allowed', & |
|---|
| 242 | 'for horizontal cross section' |
|---|
| 243 | CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 ) |
|---|
| 244 | ! IF ( TRIM( var ) == 'lwp*' .AND. .NOT. cloud_physics ) THEN |
|---|
| 245 | ! WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 246 | ! '" requires cloud_physics = .TRUE.' |
|---|
| 247 | ! CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 ) |
|---|
| 248 | ! ENDIF |
|---|
| 249 | ! IF ( TRIM( var ) == 'pra*' .AND. .NOT. precipitation ) THEN |
|---|
| 250 | ! WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 251 | ! '" requires precipitation = .TRUE.' |
|---|
| 252 | ! CALL message( 'init_masks', 'PA0112', 1, 2, 0, 6, 0 ) |
|---|
| 253 | ! ENDIF |
|---|
| 254 | ! IF ( TRIM( var ) == 'pra*' .AND. j == 1 ) THEN |
|---|
| 255 | ! WRITE ( message_string, * ) 'temporal averaging of ', & |
|---|
| 256 | ! ' precipitation amount "', TRIM( var ), & |
|---|
| 257 | ! '" not possible' |
|---|
| 258 | ! CALL message( 'init_masks', 'PA0113', 1, 2, 0, 6, 0 ) |
|---|
| 259 | ! ENDIF |
|---|
| 260 | ! IF ( TRIM( var ) == 'prr*' .AND. .NOT. precipitation ) THEN |
|---|
| 261 | ! WRITE ( message_string, * ) 'output of "', TRIM( var ), & |
|---|
| 262 | ! '" requires precipitation = .TRUE.' |
|---|
| 263 | ! CALL message( 'init_masks', 'PA0112', 1, 2, 0, 6, 0 ) |
|---|
| 264 | ! ENDIF |
|---|
| 265 | ! |
|---|
| 266 | ! IF ( TRIM( var ) == 'u*' ) unit = 'm/s' |
|---|
| 267 | ! IF ( TRIM( var ) == 't*' ) unit = 'K' |
|---|
| 268 | ! IF ( TRIM( var ) == 'lwp*' ) unit = 'kg/kg*m' |
|---|
| 269 | ! IF ( TRIM( var ) == 'pra*' ) unit = 'mm' |
|---|
| 270 | ! IF ( TRIM( var ) == 'prr*' ) unit = 'mm/s' |
|---|
| 271 | ! IF ( TRIM( var ) == 'z0*' ) unit = 'm' |
|---|
| 272 | |
|---|
| 273 | CASE ( 'p', 'pt', 'u', 'v', 'w' ) |
|---|
| 274 | IF ( TRIM( var ) == 'p' ) unit = 'Pa' |
|---|
| 275 | IF ( TRIM( var ) == 'pt' ) unit = 'K' |
|---|
| 276 | IF ( TRIM( var ) == 'u' ) unit = 'm/s' |
|---|
| 277 | IF ( TRIM( var ) == 'v' ) unit = 'm/s' |
|---|
| 278 | IF ( TRIM( var ) == 'w' ) unit = 'm/s' |
|---|
| 279 | CONTINUE |
|---|
| 280 | |
|---|
| 281 | CASE DEFAULT |
|---|
| 282 | CALL user_check_data_output( var, unit ) |
|---|
| 283 | |
|---|
| 284 | IF ( unit == 'illegal' ) THEN |
|---|
| 285 | IF ( do_mask_user(mid,1) /= ' ' ) THEN |
|---|
| 286 | WRITE ( message_string, * ) 'illegal value for data_',& |
|---|
| 287 | 'output or data_output_user: "', & |
|---|
| 288 | TRIM( do_mask(mid,i) ), '"' |
|---|
| 289 | CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 ) |
|---|
| 290 | ELSE |
|---|
| 291 | WRITE ( message_string, * ) 'illegal value for data_',& |
|---|
| 292 | 'output: "', TRIM( do_mask(mid,i) ), '"' |
|---|
| 293 | CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 ) |
|---|
| 294 | ENDIF |
|---|
| 295 | ENDIF |
|---|
| 296 | |
|---|
| 297 | END SELECT |
|---|
| 298 | ! |
|---|
| 299 | !-- Set the internal steering parameters appropriately |
|---|
| 300 | domask_no(mid,j) = domask_no(mid,j) + 1 |
|---|
| 301 | domask(mid,j,domask_no(mid,j)) = do_mask(mid,i) |
|---|
| 302 | domask_unit(mid,j,domask_no(mid,j)) = unit |
|---|
| 303 | |
|---|
| 304 | IF ( j == 1 ) THEN |
|---|
| 305 | ! |
|---|
| 306 | !-- Check, if variable is already subject to averaging |
|---|
| 307 | found = .FALSE. |
|---|
| 308 | DO k = 1, doav_n |
|---|
| 309 | IF ( TRIM( doav(k) ) == TRIM( var ) ) found = .TRUE. |
|---|
| 310 | ENDDO |
|---|
| 311 | |
|---|
| 312 | IF ( .NOT. found ) THEN |
|---|
| 313 | doav_n = doav_n + 1 |
|---|
| 314 | doav(doav_n) = var |
|---|
| 315 | ENDIF |
|---|
| 316 | ENDIF |
|---|
| 317 | |
|---|
| 318 | i = i + 1 |
|---|
| 319 | |
|---|
| 320 | ENDDO ! do_mask(mid,i) |
|---|
| 321 | ENDDO ! mid |
|---|
| 322 | |
|---|
| 323 | |
|---|
| 324 | ! |
|---|
| 325 | !-- Determine mask locations for each mask |
|---|
| 326 | DO mid = 1, masks |
|---|
| 327 | ! |
|---|
| 328 | !-- Set local masks for each subdomain along all three dimensions |
|---|
| 329 | CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr ) |
|---|
| 330 | CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn ) |
|---|
| 331 | CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt ) |
|---|
| 332 | ! |
|---|
| 333 | !-- Set global masks along all three dimensions (required by |
|---|
| 334 | !-- define_netcdf_header). |
|---|
| 335 | #if defined( __parallel ) |
|---|
| 336 | ! |
|---|
| 337 | !-- PE0 receives partial arrays from all processors of the respective mask |
|---|
| 338 | !-- and outputs them. Here a barrier has to be set, because otherwise |
|---|
| 339 | !-- "-MPI- FATAL: Remote protocol queue full" may occur. |
|---|
| 340 | CALL MPI_BARRIER( comm2d, ierr ) |
|---|
| 341 | |
|---|
| 342 | IF ( myid == 0 ) THEN |
|---|
| 343 | ! |
|---|
| 344 | !-- Local arrays can be relocated directly. |
|---|
| 345 | mask_i_global(mid,mask_start_l(mid,1): & |
|---|
| 346 | mask_start_l(mid,1)+mask_size_l(mid,1)-1) = & |
|---|
| 347 | mask_i(mid,:mask_size_l(mid,1)) |
|---|
| 348 | mask_j_global(mid,mask_start_l(mid,2): & |
|---|
| 349 | mask_start_l(mid,2)+mask_size_l(mid,2)-1) = & |
|---|
| 350 | mask_j(mid,:mask_size_l(mid,2)) |
|---|
| 351 | mask_k_global(mid,mask_start_l(mid,3): & |
|---|
| 352 | mask_start_l(mid,3)+mask_size_l(mid,3)-1) = & |
|---|
| 353 | mask_k(mid,:mask_size_l(mid,3)) |
|---|
| 354 | ! |
|---|
| 355 | !-- Receive data from all other PEs. |
|---|
| 356 | DO n = 1, numprocs-1 |
|---|
| 357 | ! |
|---|
| 358 | !-- Receive index limits first, then arrays. |
|---|
| 359 | !-- Index limits are received in arbitrary order from the PEs. |
|---|
| 360 | CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0, & |
|---|
| 361 | comm2d, status, ierr ) |
|---|
| 362 | ! |
|---|
| 363 | !-- Not all PEs have data for the mask. |
|---|
| 364 | IF ( ind(1) /= -9999 ) THEN |
|---|
| 365 | sender = status(MPI_SOURCE) |
|---|
| 366 | CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1, & |
|---|
| 367 | MPI_INTEGER, sender, 1, comm2d, status, ierr ) |
|---|
| 368 | mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2)) |
|---|
| 369 | CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1, & |
|---|
| 370 | MPI_INTEGER, sender, 2, comm2d, status, ierr ) |
|---|
| 371 | mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4)) |
|---|
| 372 | CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1, & |
|---|
| 373 | MPI_INTEGER, sender, 3, comm2d, status, ierr ) |
|---|
| 374 | mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6)) |
|---|
| 375 | ENDIF |
|---|
| 376 | ENDDO |
|---|
| 377 | |
|---|
| 378 | ELSE |
|---|
| 379 | ! |
|---|
| 380 | !-- If at least part of the mask resides on the PE, send the index limits |
|---|
| 381 | !-- for the target array, otherwise send -9999 to PE0. |
|---|
| 382 | IF ( mask_size_l(mid,1) > 0 .AND. mask_size_l(mid,2) > 0 .AND. & |
|---|
| 383 | mask_size_l(mid,3) > 0 ) & |
|---|
| 384 | THEN |
|---|
| 385 | ind(1) = mask_start_l(mid,1) |
|---|
| 386 | ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1 |
|---|
| 387 | ind(3) = mask_start_l(mid,2) |
|---|
| 388 | ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1 |
|---|
| 389 | ind(5) = mask_start_l(mid,3) |
|---|
| 390 | ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1 |
|---|
| 391 | ELSE |
|---|
| 392 | ind(1) = -9999; ind(2) = -9999 |
|---|
| 393 | ind(3) = -9999; ind(4) = -9999 |
|---|
| 394 | ind(5) = -9999; ind(6) = -9999 |
|---|
| 395 | ENDIF |
|---|
| 396 | CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr ) |
|---|
| 397 | ! |
|---|
| 398 | !-- If applicable, send data to PE0. |
|---|
| 399 | IF ( ind(1) /= -9999 ) THEN |
|---|
| 400 | tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1)) |
|---|
| 401 | CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1), & |
|---|
| 402 | MPI_INTEGER, 0, 1, comm2d, ierr ) |
|---|
| 403 | tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2)) |
|---|
| 404 | CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2), & |
|---|
| 405 | MPI_INTEGER, 0, 2, comm2d, ierr ) |
|---|
| 406 | tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3)) |
|---|
| 407 | CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3), & |
|---|
| 408 | MPI_INTEGER, 0, 3, comm2d, ierr ) |
|---|
| 409 | ENDIF |
|---|
| 410 | ENDIF |
|---|
| 411 | ! |
|---|
| 412 | !-- A barrier has to be set, because otherwise some PEs may proceed too fast |
|---|
| 413 | !-- so that PE0 may receive wrong data on tag 0. |
|---|
| 414 | CALL MPI_BARRIER( comm2d, ierr ) |
|---|
| 415 | |
|---|
| 416 | IF ( netcdf_data_format > 2 ) THEN |
|---|
| 417 | |
|---|
| 418 | CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, & |
|---|
| 419 | ierr ) |
|---|
| 420 | CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, & |
|---|
| 421 | ierr ) |
|---|
| 422 | CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, & |
|---|
| 423 | ierr ) |
|---|
| 424 | |
|---|
| 425 | ENDIF |
|---|
| 426 | |
|---|
| 427 | #else |
|---|
| 428 | ! |
|---|
| 429 | !-- Local arrays can be relocated directly. |
|---|
| 430 | mask_i_global(mid,:) = mask_i(mid,:) |
|---|
| 431 | mask_j_global(mid,:) = mask_j(mid,:) |
|---|
| 432 | mask_k_global(mid,:) = mask_k(mid,:) |
|---|
| 433 | #endif |
|---|
| 434 | ENDDO ! mid |
|---|
| 435 | |
|---|
| 436 | DEALLOCATE( tmp_array ) |
|---|
| 437 | ! |
|---|
| 438 | !-- Internal mask arrays cannot be deallocated on PE 0 because they are |
|---|
| 439 | !-- required for header output on PE 0. |
|---|
| 440 | IF ( myid /= 0 ) DEALLOCATE( mask, mask_loop ) |
|---|
| 441 | |
|---|
| 442 | CONTAINS |
|---|
| 443 | |
|---|
| 444 | SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, & |
|---|
| 445 | lb, ub ) |
|---|
| 446 | !------------------------------------------------------------------------------! |
|---|
| 447 | ! |
|---|
| 448 | ! Description: |
|---|
| 449 | ! ------------ |
|---|
| 450 | ! Set local mask for each subdomain along 'dim' direction. |
|---|
| 451 | !------------------------------------------------------------------------------! |
|---|
| 452 | |
|---|
| 453 | IMPLICIT NONE |
|---|
| 454 | |
|---|
| 455 | CHARACTER (LEN=2) :: dxyz_string, nxyz_string |
|---|
| 456 | INTEGER :: count, count_l, dim, m, loop_begin, loop_end, loop_stride, & |
|---|
| 457 | lb, nxyz, ub |
|---|
| 458 | REAL :: dxyz, ddxyz, tmp1, tmp2 |
|---|
| 459 | |
|---|
| 460 | count = 0; count_l = 0; ddxyz = 1.0 / dxyz; tmp1 = 0.0; tmp2 = 0.0 |
|---|
| 461 | |
|---|
| 462 | IF ( mask(mid,dim,1) >= 0.0 ) THEN |
|---|
| 463 | ! |
|---|
| 464 | !-- use predefined mask_* array |
|---|
| 465 | DO WHILE ( mask(mid,dim,count+1) >= 0.0 ) |
|---|
| 466 | count = count + 1 |
|---|
| 467 | IF ( dim == 1 .OR. dim == 2 ) THEN |
|---|
| 468 | m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz ) |
|---|
| 469 | ELSEIF ( dim == 3 ) THEN |
|---|
| 470 | ind_array = & |
|---|
| 471 | MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zw ) ) |
|---|
| 472 | m = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1 |
|---|
| 473 | ENDIF |
|---|
| 474 | IF ( m > nxyz ) THEN |
|---|
| 475 | WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' ) & |
|---|
| 476 | m,' in mask ',mid,' along dimension ',dim, & |
|---|
| 477 | ' exceeds ',nxyz_string,' = ',nxyz |
|---|
| 478 | CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 ) |
|---|
| 479 | ENDIF |
|---|
| 480 | IF ( m >= lb .AND. m <= ub ) THEN |
|---|
| 481 | IF ( count_l == 0 ) mask_start_l(mid,dim) = count |
|---|
| 482 | count_l = count_l + 1 |
|---|
| 483 | IF ( dim == 1 ) THEN |
|---|
| 484 | mask_i(mid,count_l) = m |
|---|
| 485 | ELSEIF ( dim == 2 ) THEN |
|---|
| 486 | mask_j(mid,count_l) = m |
|---|
| 487 | ELSEIF ( dim == 3 ) THEN |
|---|
| 488 | mask_k(mid,count_l) = m |
|---|
| 489 | ENDIF |
|---|
| 490 | ENDIF |
|---|
| 491 | IF ( count == mask_xyz_dimension ) EXIT |
|---|
| 492 | ENDDO |
|---|
| 493 | mask_size(mid,dim) = count |
|---|
| 494 | mask_size_l(mid,dim) = count_l |
|---|
| 495 | |
|---|
| 496 | ELSE |
|---|
| 497 | ! |
|---|
| 498 | !-- use predefined mask_loop_* array, or use the default (all grid points |
|---|
| 499 | !-- along this direction) |
|---|
| 500 | IF ( mask_loop(mid,dim,1) < 0.0 ) THEN |
|---|
| 501 | tmp1 = mask_loop(mid,dim,1) |
|---|
| 502 | mask_loop(mid,dim,1) = 0.0 ! (default) |
|---|
| 503 | ENDIF |
|---|
| 504 | IF ( dim == 1 .OR. dim == 2 ) THEN |
|---|
| 505 | IF ( mask_loop(mid,dim,2) < 0.0 ) THEN |
|---|
| 506 | tmp2 = mask_loop(mid,dim,2) |
|---|
| 507 | mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim) ! (default) |
|---|
| 508 | ENDIF |
|---|
| 509 | IF ( MAXVAL( mask_loop(mid,dim,1:2) ) & |
|---|
| 510 | > nxyz * dxyz / mask_scale(dim) ) THEN |
|---|
| 511 | WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) & |
|---|
| 512 | 'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), & |
|---|
| 513 | ' and/or mask_loop(',mid,',',dim,',2)=', & |
|---|
| 514 | mask_loop(mid,dim,2),'&exceed ', & |
|---|
| 515 | nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', & |
|---|
| 516 | nxyz*dxyz/mask_scale(dim) |
|---|
| 517 | CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 ) |
|---|
| 518 | ENDIF |
|---|
| 519 | loop_begin = NINT( mask_loop(mid,dim,1) * mask_scale(dim) * ddxyz ) |
|---|
| 520 | loop_end = NINT( mask_loop(mid,dim,2) * mask_scale(dim) * ddxyz ) |
|---|
| 521 | loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz ) |
|---|
| 522 | ELSEIF ( dim == 3 ) THEN |
|---|
| 523 | IF ( mask_loop(mid,dim,2) < 0.0 ) THEN |
|---|
| 524 | tmp2 = mask_loop(mid,dim,2) |
|---|
| 525 | mask_loop(mid,dim,2) = zw(nz) / mask_scale(dim) ! (default) |
|---|
| 526 | ENDIF |
|---|
| 527 | IF ( MAXVAL( mask_loop(mid,dim,1:2) ) & |
|---|
| 528 | > zw(nz) / mask_scale(dim) ) THEN |
|---|
| 529 | WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) & |
|---|
| 530 | 'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), & |
|---|
| 531 | ' and/or mask_loop(',mid,',',dim,',2)=', & |
|---|
| 532 | mask_loop(mid,dim,2),'&exceed zw(nz)/mask_scale(',dim, & |
|---|
| 533 | ')=',zw(nz)/mask_scale(dim) |
|---|
| 534 | CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 ) |
|---|
| 535 | ENDIF |
|---|
| 536 | ind_array = & |
|---|
| 537 | MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zw ) ) |
|---|
| 538 | loop_begin = & |
|---|
| 539 | ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1 |
|---|
| 540 | ind_array = & |
|---|
| 541 | MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zw ) ) |
|---|
| 542 | loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1 |
|---|
| 543 | ! |
|---|
| 544 | !-- The following line assumes a constant vertical grid spacing within |
|---|
| 545 | !-- the vertical mask range; it fails for vertical grid stretching. |
|---|
| 546 | !-- Maybe revise later. Issue warning but continue execution. |
|---|
| 547 | loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz ) |
|---|
| 548 | |
|---|
| 549 | IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level ) & |
|---|
| 550 | THEN |
|---|
| 551 | WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) & |
|---|
| 552 | 'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),& |
|---|
| 553 | ' exceeds dz_stretch_level=',dz_stretch_level, & |
|---|
| 554 | '.&Vertical mask locations will not ', & |
|---|
| 555 | 'match the desired heights&within the stretching ', & |
|---|
| 556 | 'region. Recommendation: use mask instead of mask_loop.' |
|---|
| 557 | CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 ) |
|---|
| 558 | ENDIF |
|---|
| 559 | |
|---|
| 560 | ENDIF |
|---|
| 561 | ! |
|---|
| 562 | !-- If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2). |
|---|
| 563 | IF ( tmp1 < 0.0 ) mask_loop(mid,dim,1) = tmp1 |
|---|
| 564 | IF ( tmp2 < 0.0 ) mask_loop(mid,dim,2) = tmp2 |
|---|
| 565 | ! |
|---|
| 566 | !-- The default stride +/-1 (every grid point) applies if |
|---|
| 567 | !-- mask_loop(mid,dim,3) is not specified (its default is zero). |
|---|
| 568 | IF ( loop_stride == 0 ) THEN |
|---|
| 569 | IF ( loop_end >= loop_begin ) THEN |
|---|
| 570 | loop_stride = 1 |
|---|
| 571 | ELSE |
|---|
| 572 | loop_stride = -1 |
|---|
| 573 | ENDIF |
|---|
| 574 | ENDIF |
|---|
| 575 | DO m = loop_begin, loop_end, loop_stride |
|---|
| 576 | count = count + 1 |
|---|
| 577 | IF ( m >= lb .AND. m <= ub ) THEN |
|---|
| 578 | IF ( count_l == 0 ) mask_start_l(mid,dim) = count |
|---|
| 579 | count_l = count_l + 1 |
|---|
| 580 | IF ( dim == 1 ) THEN |
|---|
| 581 | mask_i(mid,count_l) = m |
|---|
| 582 | ELSEIF ( dim == 2 ) THEN |
|---|
| 583 | mask_j(mid,count_l) = m |
|---|
| 584 | ELSEIF ( dim == 3 ) THEN |
|---|
| 585 | mask_k(mid,count_l) = m |
|---|
| 586 | ENDIF |
|---|
| 587 | ENDIF |
|---|
| 588 | ENDDO |
|---|
| 589 | mask_size(mid,dim) = count |
|---|
| 590 | mask_size_l(mid,dim) = count_l |
|---|
| 591 | ENDIF |
|---|
| 592 | |
|---|
| 593 | END SUBROUTINE set_mask_locations |
|---|
| 594 | |
|---|
| 595 | END SUBROUTINE init_masks |
|---|
