source: palm/trunk/SOURCE/init_masks.f90 @ 556

Last change on this file since 556 was 554, checked in by weinreis, 14 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 23.1 KB
Line 
1 SUBROUTINE init_masks
2
3!------------------------------------------------------------------------------!
4! Current revisions:
5! -----------------
6!
7!
8! Former revisions:
9! -----------------
10! $Id: init_masks.f90 554 2010-09-01 14:14:36Z raasch $
11!
12! 553 2010-09-01 14:09:06Z weinreis
13! parameters for masked output are replaced by arrays
14!
15! 493 2010-03-01 08:30:24Z raasch
16! netcdf_format_mask* and format_parallel_io replaced by netcdf_data_format
17!
18! 410 2009-12-04 17:05:40Z letzel
19! Initial revision
20!
21!
22! Description:
23! ------------
24! Initialize masked data output
25!------------------------------------------------------------------------------!
26
27    USE arrays_3d
28    USE control_parameters
29    USE grid_variables
30    USE indices
31    USE netcdf_control
32    USE particle_attributes
33    USE pegrid
34
35    IMPLICIT NONE
36
37    CHARACTER (LEN=6)   ::  var
38    CHARACTER (LEN=7)   ::  unit
39    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask, do_mask_user
40
41    INTEGER :: i, ilen, ind(6), ind_array(1), j, k, n, sender
42    INTEGER, DIMENSION(:), ALLOCATABLE ::  tmp_array
43
44    LOGICAL ::  found
45!
46!-- Allocation and initialization
47    ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) )
48
49    ALLOCATE( mask_i(max_masks,nxr-nxl+1), &
50              mask_j(max_masks,nyn-nys+1), &
51              mask_k(max_masks,nzt-nzb+1) )
52!
53!-- internal mask arrays ("mask,dimension,selection")
54    ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
55              mask_loop(max_masks,3,3) )
56   
57!
58!-- Parallel mask output not yet tested
59    IF ( netcdf_data_format > 2 )  THEN
60       message_string = 'NetCDF file formats '//                         &
61                        '3 (NetCDF 4) and 4 (NetCDF 4 Classic model)'//  &
62                        '&are currently not supported (not yet tested).'
63       CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
64    ENDIF
65
66!
67!-- Store data output parameters for masked data output in few shared arrays
68    DO mid = 1, masks
69       do_mask     (mid,:) = data_output_masks(mid,:)
70       do_mask_user(mid,:) = data_output_masks_user(mid,:)
71       mask      (mid,1,:) = mask_x(mid,:) 
72       mask      (mid,2,:) = mask_y(mid,:)
73       mask      (mid,3,:) = mask_z(mid,:) 
74       mask_loop (mid,1,:) = mask_x_loop(mid,:) 
75       mask_loop (mid,2,:) = mask_y_loop(mid,:) 
76       mask_loop (mid,3,:) = mask_z_loop(mid,:) 
77    ENDDO
78   
79    mask_i = -1; mask_j = -1; mask_k = -1
80   
81!
82!-- Global arrays are required by define_netcdf_header.
83    IF ( myid == 0  .OR.  netcdf_data_format > 2 )  THEN
84       ALLOCATE( mask_i_global(max_masks,nx+1), &
85                 mask_j_global(max_masks,ny+1), &
86                 mask_k_global(max_masks,nz+1) )
87       mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
88    ENDIF
89
90!
91!-- Determine variable names for each mask
92    DO  mid = 1, masks
93!
94!--    Append user-defined data output variables to the standard data output
95       IF ( do_mask_user(mid,1) /= ' ' )  THEN
96          i = 1
97          DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
98             i = i + 1
99          ENDDO
100          j = 1
101          DO  WHILE ( do_mask_user(mid,j) /= ' '  .AND.  j <= 100 )
102             IF ( i > 100 )  THEN
103                WRITE ( message_string, * ) 'number of output quantitities ', &
104                     'given by data_output_mask and data_output_mask_user ', &
105                     'exceeds the limit of 100'
106                CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
107             ENDIF
108             do_mask(mid,i) = do_mask_user(mid,j)
109             i = i + 1
110             j = j + 1
111          ENDDO
112       ENDIF
113
114!
115!--    Check and set steering parameters for mask data output and averaging
116       i   = 1
117       DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
118!
119!--       Check for data averaging
120          ilen = LEN_TRIM( do_mask(mid,i) )
121          j = 0                                              ! no data averaging
122          IF ( ilen > 3 )  THEN
123             IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' )  THEN
124                j = 1                                           ! data averaging
125                do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
126             ENDIF
127          ENDIF
128          var = TRIM( do_mask(mid,i) )
129!
130!--       Check for allowed value and set units
131          SELECT CASE ( TRIM( var ) )
132
133             CASE ( 'e' )
134                IF ( constant_diffusion )  THEN
135                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
136                        '" requires constant_diffusion = .FALSE.'
137                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
138                ENDIF
139                unit = 'm2/s2'
140
141             CASE ( 'pc', 'pr' )
142                IF ( .NOT. particle_advection )  THEN
143                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
144                        '" requires a "particles_par"-NAMELIST in the ', &
145                        'parameter file (PARIN)'
146                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
147                ENDIF
148                IF ( TRIM( var ) == 'pc' )  unit = 'number'
149                IF ( TRIM( var ) == 'pr' )  unit = 'm'
150
151             CASE ( 'q', 'vpt' )
152                IF ( .NOT. humidity )  THEN
153                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
154                        '" requires humidity = .TRUE.'
155                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
156                ENDIF
157                IF ( TRIM( var ) == 'q'   )  unit = 'kg/kg'
158                IF ( TRIM( var ) == 'vpt' )  unit = 'K'
159
160             CASE ( 'ql' )
161                IF ( .NOT. ( cloud_physics  .OR.  cloud_droplets ) )  THEN
162                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
163                        '" requires cloud_physics = .TRUE. or cloud_droplets', &
164                        ' = .TRUE.'
165                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
166                ENDIF
167                unit = 'kg/kg'
168
169             CASE ( 'ql_c', 'ql_v', 'ql_vp' )
170                IF ( .NOT. cloud_droplets )  THEN
171                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
172                        '" requires cloud_droplets = .TRUE.'
173                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
174                ENDIF
175                IF ( TRIM( var ) == 'ql_c'  )  unit = 'kg/kg'
176                IF ( TRIM( var ) == 'ql_v'  )  unit = 'm3'
177                IF ( TRIM( var ) == 'ql_vp' )  unit = 'none'
178
179             CASE ( 'qv' )
180                IF ( .NOT. cloud_physics )  THEN
181                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
182                        '" requires cloud_physics = .TRUE.'
183                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
184                ENDIF
185                unit = 'kg/kg'
186
187             CASE ( 'rho' )
188                IF ( .NOT. ocean )  THEN
189                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
190                        '" requires ocean = .TRUE.'
191                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
192                ENDIF
193                unit = 'kg/m3'
194
195             CASE ( 's' )
196                IF ( .NOT. passive_scalar )  THEN
197                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
198                        '" requires passive_scalar = .TRUE.'
199                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
200                ENDIF
201                unit = 'conc'
202
203             CASE ( 'sa' )
204                IF ( .NOT. ocean )  THEN
205                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
206                        '" requires ocean = .TRUE.'
207                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
208                ENDIF
209                unit = 'psu'
210
211             CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*' )
212                WRITE ( message_string, * ) 'illegal value for data_',&
213                     'output: "', TRIM( var ), '" is only allowed', &
214                     'for horizontal cross section'
215                CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
216!                IF ( TRIM( var ) == 'lwp*'  .AND.  .NOT. cloud_physics )  THEN
217!                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
218!                         '" requires cloud_physics = .TRUE.'
219!                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
220!                ENDIF
221!                IF ( TRIM( var ) == 'pra*'  .AND.  .NOT. precipitation )  THEN
222!                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
223!                         '" requires precipitation = .TRUE.'
224!                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
225!                ENDIF
226!                IF ( TRIM( var ) == 'pra*'  .AND.  j == 1 )  THEN
227!                   WRITE ( message_string, * ) 'temporal averaging of ', &
228!                         ' precipitation amount "', TRIM( var ),         &
229!                         '" not possible'
230!                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
231!                ENDIF
232!                IF ( TRIM( var ) == 'prr*'  .AND.  .NOT. precipitation )  THEN
233!                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
234!                         '" requires precipitation = .TRUE.'
235!                   CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
236!                ENDIF
237!
238!                IF ( TRIM( var ) == 'u*'   )  unit = 'm/s'
239!                IF ( TRIM( var ) == 't*'   )  unit = 'K'
240!                IF ( TRIM( var ) == 'lwp*' )  unit = 'kg/kg*m'
241!                IF ( TRIM( var ) == 'pra*' )  unit = 'mm'
242!                IF ( TRIM( var ) == 'prr*' )  unit = 'mm/s'
243!                IF ( TRIM( var ) == 'z0*'  )  unit = 'm'
244
245             CASE ( 'p', 'pt', 'u', 'v', 'w' )
246                IF ( TRIM( var ) == 'p'  )  unit = 'Pa'
247                IF ( TRIM( var ) == 'pt' )  unit = 'K'
248                IF ( TRIM( var ) == 'u'  )  unit = 'm/s'
249                IF ( TRIM( var ) == 'v'  )  unit = 'm/s'
250                IF ( TRIM( var ) == 'w'  )  unit = 'm/s'
251                CONTINUE
252
253             CASE DEFAULT
254                CALL user_check_data_output( var, unit )
255
256                IF ( unit == 'illegal' )  THEN
257                   IF ( do_mask_user(mid,1) /= ' ' )  THEN
258                      WRITE ( message_string, * ) 'illegal value for data_',&
259                           'output or data_output_user: "', &
260                           TRIM( do_mask(mid,i) ), '"'
261                      CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
262                   ELSE
263                      WRITE ( message_string, * ) 'illegal value for data_',&
264                           'output: "', TRIM( do_mask(mid,i) ), '"'
265                      CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
266                   ENDIF
267                ENDIF
268
269          END SELECT
270!
271!--       Set the internal steering parameters appropriately
272          domask_no(mid,j)                    = domask_no(mid,j) + 1
273          domask(mid,j,domask_no(mid,j))      = do_mask(mid,i)
274          domask_unit(mid,j,domask_no(mid,j)) = unit
275
276          IF ( j == 1 )  THEN
277!
278!--          Check, if variable is already subject to averaging
279             found = .FALSE.
280             DO  k = 1, doav_n
281                IF ( TRIM( doav(k) ) == TRIM( var ) )  found = .TRUE.
282             ENDDO
283
284             IF ( .NOT. found )  THEN
285                doav_n = doav_n + 1
286                doav(doav_n) = var
287             ENDIF
288          ENDIF
289
290          i = i + 1
291
292       ENDDO   ! do_mask(mid,i)
293    ENDDO   ! mid
294
295
296!
297!-- Determine mask locations for each mask
298    DO  mid = 1, masks
299!
300!--    Set local masks for each subdomain along all three dimensions
301       CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
302       CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
303       CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
304!
305!--    Set global masks along all three dimensions (required by
306!--    define_netcdf_header).
307#if defined( __parallel )
308!
309!--    PE0 receives partial arrays from all processors of the respective mask
310!--    and outputs them. Here a barrier has to be set, because otherwise
311!--    "-MPI- FATAL: Remote protocol queue full" may occur.
312       CALL MPI_BARRIER( comm2d, ierr )
313
314       IF ( myid == 0 )  THEN
315!
316!--       Local arrays can be relocated directly.
317          mask_i_global(mid,mask_start_l(mid,1): &
318                       mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
319                       mask_i(mid,:mask_size_l(mid,1))
320          mask_j_global(mid,mask_start_l(mid,2): &
321                       mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
322                       mask_j(mid,:mask_size_l(mid,2))
323          mask_k_global(mid,mask_start_l(mid,3): &
324                       mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
325                       mask_k(mid,:mask_size_l(mid,3))
326!
327!--       Receive data from all other PEs.
328          DO  n = 1, numprocs-1
329!
330!--          Receive index limits first, then arrays.
331!--          Index limits are received in arbitrary order from the PEs.
332             CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0,  &
333                  comm2d, status, ierr )
334!
335!--          Not all PEs have data for the mask.
336             IF ( ind(1) /= -9999 )  THEN
337                sender = status(MPI_SOURCE)
338                CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1,  &
339                               MPI_INTEGER, sender, 1, comm2d, status, ierr )
340                mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
341                CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1,  &
342                               MPI_INTEGER, sender, 2, comm2d, status, ierr )
343                mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
344                CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1,  &
345                               MPI_INTEGER, sender, 3, comm2d, status, ierr )
346                mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
347             ENDIF
348          ENDDO
349
350       ELSE
351!
352!--       If at least part of the mask resides on the PE, send the index limits
353!--       for the target array, otherwise send -9999 to PE0.
354          IF ( mask_size_l(mid,1) > 0 .AND.  mask_size_l(mid,2) > 0 .AND. &
355               mask_size_l(mid,3) > 0  ) &
356               THEN
357             ind(1) = mask_start_l(mid,1)
358             ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
359             ind(3) = mask_start_l(mid,2)
360             ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
361             ind(5) = mask_start_l(mid,3)
362             ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
363          ELSE
364             ind(1) = -9999; ind(2) = -9999
365             ind(3) = -9999; ind(4) = -9999
366             ind(5) = -9999; ind(6) = -9999
367          ENDIF
368          CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
369!
370!--       If applicable, send data to PE0.
371          IF ( ind(1) /= -9999 )  THEN
372             tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
373             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1),  &
374                            MPI_INTEGER, 0, 1, comm2d, ierr )
375             tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
376             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2),  &
377                            MPI_INTEGER, 0, 2, comm2d, ierr )
378             tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
379             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3),  &
380                            MPI_INTEGER, 0, 3, comm2d, ierr )
381          ENDIF
382       ENDIF
383!
384!--    A barrier has to be set, because otherwise some PEs may proceed too fast
385!--    so that PE0 may receive wrong data on tag 0.
386       CALL MPI_BARRIER( comm2d, ierr )
387       
388       IF ( netcdf_data_format > 2 )  THEN 
389         
390          CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, &
391                          ierr )
392          CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, &
393                          ierr )
394          CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, &
395                          ierr ) 
396         
397       ENDIF
398
399#else
400!
401!--    Local arrays can be relocated directly.
402       mask_i_global(mid,:) = mask_i(mid,:)
403       mask_j_global(mid,:) = mask_j(mid,:)
404       mask_k_global(mid,:) = mask_k(mid,:)
405#endif
406    ENDDO   ! mid
407
408    DEALLOCATE( tmp_array )
409!
410!-- Internal mask arrays cannot be deallocated on PE 0 because they are
411!-- required for header output on PE 0.
412    IF ( myid /= 0 )  DEALLOCATE( mask, mask_loop )
413
414 CONTAINS
415
416    SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
417                                   lb, ub )
418!------------------------------------------------------------------------------!
419!
420! Description:
421! ------------
422! Set local mask for each subdomain along 'dim' direction.
423!------------------------------------------------------------------------------!
424
425       IMPLICIT NONE
426
427       CHARACTER (LEN=2) :: dxyz_string, nxyz_string
428       INTEGER  ::  count, count_l, dim, m, loop_begin, loop_end, loop_stride, &
429                    lb, nxyz, ub
430       REAL     ::  dxyz, ddxyz, tmp1, tmp2
431
432       count = 0;  count_l = 0;  ddxyz = 1.0 / dxyz;  tmp1 = 0.0;  tmp2 = 0.0
433
434       IF ( mask(mid,dim,1) >= 0.0 )  THEN
435!
436!--       use predefined mask_* array
437          DO  WHILE ( mask(mid,dim,count+1) >= 0.0 )
438             count = count + 1
439             IF ( dim == 1 .OR. dim == 2 )  THEN
440                m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz )
441             ELSEIF ( dim == 3 )  THEN
442                ind_array =  &
443                     MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zw ) )
444                m = ind_array(1) - 1 + nzb  ! MINLOC uses lower array bound 1
445             ENDIF
446             IF ( m > nxyz )  THEN
447                WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' )  &
448                     m,' in mask ',mid,' along dimension ',dim,  &
449                     ' exceeds ',nxyz_string,' = ',nxyz
450                CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
451             ENDIF
452             IF ( m >= lb .AND. m <= ub )  THEN
453                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
454                count_l = count_l + 1
455                IF ( dim == 1 )  THEN
456                   mask_i(mid,count_l) = m
457                ELSEIF ( dim == 2 )  THEN
458                   mask_j(mid,count_l) = m
459                ELSEIF ( dim == 3 )  THEN
460                   mask_k(mid,count_l) = m
461                ENDIF
462             ENDIF
463             IF ( count == mask_xyz_dimension )  EXIT
464          ENDDO
465          mask_size(mid,dim)   = count
466          mask_size_l(mid,dim) = count_l
467
468       ELSE
469!
470!--       use predefined mask_loop_* array, or use the default (all grid points
471!--       along this direction)
472          IF ( mask_loop(mid,dim,1) < 0.0 )  THEN
473             tmp1 = mask_loop(mid,dim,1)
474             mask_loop(mid,dim,1) = 0.0   ! (default)
475          ENDIF
476          IF ( dim == 1 .OR. dim == 2 )  THEN
477             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
478                tmp2 = mask_loop(mid,dim,2)
479                mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim)   ! (default)
480             ENDIF
481             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
482                  > nxyz * dxyz / mask_scale(dim) )  THEN
483                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
484                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
485                     ' and/or mask_loop(',mid,',',dim,',2)=', &
486                     mask_loop(mid,dim,2),'&exceed ', &
487                     nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', &
488                     nxyz*dxyz/mask_scale(dim)
489                CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
490             ENDIF
491             loop_begin  = NINT( mask_loop(mid,dim,1) * mask_scale(dim) * ddxyz )
492             loop_end    = NINT( mask_loop(mid,dim,2) * mask_scale(dim) * ddxyz )
493             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
494          ELSEIF ( dim == 3 )  THEN
495             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
496                tmp2 = mask_loop(mid,dim,2)
497                mask_loop(mid,dim,2) = zw(nz) / mask_scale(dim)   ! (default)
498             ENDIF
499             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
500                  > zw(nz) / mask_scale(dim) )  THEN
501                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
502                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
503                     ' and/or mask_loop(',mid,',',dim,',2)=', &
504                     mask_loop(mid,dim,2),'&exceed zw(nz)/mask_scale(',dim, &
505                     ')=',zw(nz)/mask_scale(dim)
506                CALL message( 'init_masks', 'PA9998', 1, 2, 0, 6, 0 )
507             ENDIF
508             ind_array =  &
509                  MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zw ) )
510             loop_begin =  &
511                  ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
512             ind_array =  &
513                  MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zw ) )
514             loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
515!
516!--          The following line assumes a constant vertical grid spacing within
517!--          the vertical mask range; it fails for vertical grid stretching.
518!--          Maybe revise later. Issue warning but continue execution.
519             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
520
521             IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level )  &
522                  THEN
523                WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' )  &
524                     'mask_loop(',mid,dim,',2)=', mask_loop(mid,dim,2),&
525                     ' exceeds dz_stretch_level=',dz_stretch_level, &
526                     '.&Vertical mask locations will not ', &
527                     'match the desired heights&within the stretching ', &
528                     'region. Recommendation: use mask instead of mask_loop.'
529                CALL message( 'init_masks', 'PA9998', 0, 1, 0, 6, 0 )
530             ENDIF
531
532          ENDIF
533!
534!--       If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
535          IF ( tmp1 < 0.0 )  mask_loop(mid,dim,1) = tmp1
536          IF ( tmp2 < 0.0 )  mask_loop(mid,dim,2) = tmp2
537!
538!--       The default stride +/-1 (every grid point) applies if
539!--       mask_loop(mid,dim,3) is not specified (its default is zero).
540          IF ( loop_stride == 0 )  THEN
541             IF ( loop_end >= loop_begin )  THEN
542                loop_stride =  1
543             ELSE
544                loop_stride = -1
545             ENDIF
546          ENDIF
547          DO  m = loop_begin, loop_end, loop_stride
548             count = count + 1
549             IF ( m >= lb .AND. m <= ub )  THEN
550                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
551                count_l = count_l + 1
552                IF ( dim == 1 )  THEN
553                   mask_i(mid,count_l) = m
554                ELSEIF ( dim == 2 )  THEN
555                   mask_j(mid,count_l) = m
556                ELSEIF ( dim == 3 )  THEN
557                   mask_k(mid,count_l) = m
558                ENDIF
559             ENDIF
560          ENDDO
561          mask_size(mid,dim)   = count
562          mask_size_l(mid,dim) = count_l
563       ENDIF
564
565    END SUBROUTINE set_mask_locations
566
567 END SUBROUTINE init_masks
Note: See TracBrowser for help on using the repository browser.