source: palm/trunk/SOURCE/init_masks.f90 @ 1353

Last change on this file since 1353 was 1353, checked in by heinze, 10 years ago

REAL constants provided with KIND-attribute

  • Property svn:keywords set to Id
File size: 26.3 KB
Line 
1 SUBROUTINE init_masks
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2014 Leibniz Universitaet Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! REAL constants provided with KIND-attribute
23!
24! Former revisions:
25! -----------------
26! $Id: init_masks.f90 1353 2014-04-08 15:21:23Z heinze $
27!
28! 1324 2014-03-21 09:13:16Z suehring
29! Bugfix: ONLY statement for module netcdf_control removed
30!
31! 1320 2014-03-20 08:40:49Z raasch
32! ONLY-attribute added to USE-statements,
33! kind-parameters added to all INTEGER and REAL declaration statements,
34! kinds are defined in new module kinds,
35! revision history before 2012 removed,
36! comment fields (!:) to be used for variable explanations added to
37! all variable declaration statements
38!
39! 1186 2013-06-18 06:22:52Z raasch
40! bugfix: 0.0 replaced by zu(nzb) as the lowest default height level for masks,
41! because a zero value does not work in case of ocean runs
42!
43! 1036 2012-10-22 13:43:42Z raasch
44! code put under GPL (PALM 3.9)
45!
46! 1032 2012-10-21 13:03:21Z letzel
47! mask locations determined based on scalar positions
48!
49! 1031 2012-10-19 14:35:30Z raasch
50! netCDF4 without parallel file support implemented
51!
52! 996 2012-09-07 10:41:47Z raasch
53! little reformatting
54!
55! 978 2012-08-09 08:28:32Z fricke
56! +z0h*
57!
58! 809 2012-01-30 13:32:58Z maronga
59! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
60!
61! 807 2012-01-25 11:53:51Z maronga
62! New cpp directive "__check" implemented which is used by check_namelist_files
63!
64! 410 2009-12-04 17:05:40Z letzel
65! Initial revision
66!
67!
68! Description:
69! ------------
70! Initialize masked data output
71!------------------------------------------------------------------------------!
72
73    USE arrays_3d,                                                             &
74        ONLY:  zu, zw
75
76    USE control_parameters,                                                    &
77        ONLY:  constant_diffusion, cloud_droplets, cloud_physics,              &
78               data_output_masks, data_output_masks_user,                      &
79               doav, doav_n, domask, domask_no, dz, dz_stretch_level, humidity,&
80               mask, masks, mask_scale, mask_i,                                &
81               mask_i_global, mask_j, mask_j_global, mask_k, mask_k_global,    &
82               mask_loop, mask_size, mask_size_l, mask_start_l, mask_x,        &
83               mask_x_loop, mask_xyz_dimension, mask_y, mask_y_loop, mask_z,   &
84               mask_z_loop, max_masks,  message_string, mid,                   &
85               netcdf_data_format, passive_scalar, ocean
86
87    USE grid_variables,                                                        &
88        ONLY:  dx, dy
89
90    USE indices,                                                               &
91        ONLY:  nx, nxl, nxr, ny, nyn, nys, nz, nzb, nzt
92
93    USE kinds
94
95    USE netcdf_control
96
97    USE particle_attributes,                                                   &
98        ONLY:  particle_advection
99
100    USE pegrid
101
102    IMPLICIT NONE
103
104    CHARACTER (LEN=6) ::  var  !:
105    CHARACTER (LEN=7) ::  unit !:
106   
107    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask      !:
108    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask_user !:
109
110    INTEGER(iwp) ::  i            !:
111    INTEGER(iwp) ::  ilen         !:
112    INTEGER(iwp) ::  ind(6)       !:
113    INTEGER(iwp) ::  ind_array(1) !:
114    INTEGER(iwp) ::  j            !:
115    INTEGER(iwp) ::  k            !:
116    INTEGER(iwp) ::  n            !:
117    INTEGER(iwp) ::  sender       !:
118   
119    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  tmp_array !:
120
121    LOGICAL ::  found !:
122!
123!-- Allocation and initialization
124    ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) )
125
126    ALLOCATE( mask_i(max_masks,nxr-nxl+1), &
127              mask_j(max_masks,nyn-nys+1), &
128              mask_k(max_masks,nzt-nzb+1) )
129!
130!-- internal mask arrays ("mask,dimension,selection")
131    ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
132              mask_loop(max_masks,3,3) )
133   
134!
135!-- Parallel mask output not yet tested
136    IF ( netcdf_data_format > 4 )  THEN
137       message_string = 'netCDF file formats '//                         &
138                        '3 (netCDF 4) and 4 (netCDF 4 Classic model)'//  &
139                        '&are currently not supported (not yet tested).'
140       CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 )
141    ENDIF
142
143!
144!-- Store data output parameters for masked data output in few shared arrays
145    DO  mid = 1, masks
146   
147       do_mask     (mid,:) = data_output_masks(mid,:)
148       do_mask_user(mid,:) = data_output_masks_user(mid,:)
149       mask      (mid,1,:) = mask_x(mid,:) 
150       mask      (mid,2,:) = mask_y(mid,:)
151       mask      (mid,3,:) = mask_z(mid,:) 
152       
153       IF ( mask_x_loop(mid,1) == -1.0_wp  .AND.  mask_x_loop(mid,2) == -1.0_wp&
154            .AND.  mask_x_loop(mid,3) == -1.0_wp )  THEN
155          mask_loop(mid,1,1:2) = -1.0_wp
156          mask_loop(mid,1,3)   =  0.0_wp
157       ELSE
158          mask_loop(mid,1,:) = mask_x_loop(mid,:)
159       ENDIF
160       IF ( mask_y_loop(mid,1) == -1.0_wp  .AND.  mask_y_loop(mid,2) == -1.0_wp&
161            .AND.  mask_y_loop(mid,3) == -1.0_wp )  THEN
162          mask_loop(mid,2,1:2) = -1.0_wp
163          mask_loop(mid,2,3)   =  0.0_wp
164       ELSE
165          mask_loop(mid,2,:) = mask_y_loop(mid,:)
166       ENDIF
167       IF ( mask_z_loop(mid,1) == -1.0_wp  .AND.  mask_z_loop(mid,2) == -1.0_wp&
168            .AND.  mask_z_loop(mid,3) == -1.0_wp )  THEN
169          mask_loop(mid,3,1:2) = -1.0_wp
170          mask_loop(mid,3,3)   =  0.0_wp
171       ELSE
172          mask_loop(mid,3,:) = mask_z_loop(mid,:)
173       ENDIF
174       
175    ENDDO
176   
177    mask_i = -1; mask_j = -1; mask_k = -1
178   
179!
180!-- Global arrays are required by define_netcdf_header.
181    IF ( myid == 0  .OR.  netcdf_data_format > 4 )  THEN
182       ALLOCATE( mask_i_global(max_masks,nx+1), &
183                 mask_j_global(max_masks,ny+1), &
184                 mask_k_global(max_masks,nz+1) )
185       mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
186    ENDIF
187
188!
189!-- Determine variable names for each mask
190    DO  mid = 1, masks
191!
192!--    Append user-defined data output variables to the standard data output
193       IF ( do_mask_user(mid,1) /= ' ' )  THEN
194          i = 1
195          DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
196             i = i + 1
197          ENDDO
198          j = 1
199          DO  WHILE ( do_mask_user(mid,j) /= ' '  .AND.  j <= 100 )
200             IF ( i > 100 )  THEN
201                WRITE ( message_string, * ) 'number of output quantitities ', &
202                     'given by data_output_mask and data_output_mask_user ', &
203                     'exceeds the limit of 100'
204                CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 )
205             ENDIF
206             do_mask(mid,i) = do_mask_user(mid,j)
207             i = i + 1
208             j = j + 1
209          ENDDO
210       ENDIF
211
212!
213!--    Check and set steering parameters for mask data output and averaging
214       i   = 1
215       DO WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
216!
217!--       Check for data averaging
218          ilen = LEN_TRIM( do_mask(mid,i) )
219          j = 0                                              ! no data averaging
220          IF ( ilen > 3 )  THEN
221             IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' )  THEN
222                j = 1                                           ! data averaging
223                do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
224             ENDIF
225          ENDIF
226          var = TRIM( do_mask(mid,i) )
227!
228!--       Check for allowed value and set units
229          SELECT CASE ( TRIM( var ) )
230
231             CASE ( 'e' )
232                IF ( constant_diffusion )  THEN
233                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
234                        '" requires constant_diffusion = .FALSE.'
235                   CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 )
236                ENDIF
237                unit = 'm2/s2'
238
239             CASE ( 'lpt' )
240                IF ( .NOT. cloud_physics )  THEN
241                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
242                        '" requires cloud_physics = .TRUE.'
243                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
244                ENDIF
245                unit = 'K'
246
247             CASE ( 'pc', 'pr' )
248                IF ( .NOT. particle_advection )  THEN
249                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
250                        '" requires a "particles_par"-NAMELIST in the ', &
251                        'parameter file (PARIN)'
252                   CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 )
253                ENDIF
254                IF ( TRIM( var ) == 'pc' )  unit = 'number'
255                IF ( TRIM( var ) == 'pr' )  unit = 'm'
256
257             CASE ( 'q', 'vpt' )
258                IF ( .NOT. humidity )  THEN
259                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
260                        '" requires humidity = .TRUE.'
261                   CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 )
262                ENDIF
263                IF ( TRIM( var ) == 'q'   )  unit = 'kg/kg'
264                IF ( TRIM( var ) == 'vpt' )  unit = 'K'
265
266             CASE ( 'ql' )
267                IF ( .NOT. ( cloud_physics  .OR.  cloud_droplets ) )  THEN
268                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
269                        '" requires cloud_physics = .TRUE. or cloud_droplets', &
270                        ' = .TRUE.'
271                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
272                ENDIF
273                unit = 'kg/kg'
274
275             CASE ( 'ql_c', 'ql_v', 'ql_vp' )
276                IF ( .NOT. cloud_droplets )  THEN
277                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
278                        '" requires cloud_droplets = .TRUE.'
279                   CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 )
280                ENDIF
281                IF ( TRIM( var ) == 'ql_c'  )  unit = 'kg/kg'
282                IF ( TRIM( var ) == 'ql_v'  )  unit = 'm3'
283                IF ( TRIM( var ) == 'ql_vp' )  unit = 'none'
284
285             CASE ( 'qv' )
286                IF ( .NOT. cloud_physics )  THEN
287                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
288                        '" requires cloud_physics = .TRUE.'
289                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
290                ENDIF
291                unit = 'kg/kg'
292
293             CASE ( 'rho' )
294                IF ( .NOT. ocean )  THEN
295                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
296                        '" requires ocean = .TRUE.'
297                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
298                ENDIF
299                unit = 'kg/m3'
300
301             CASE ( 's' )
302                IF ( .NOT. passive_scalar )  THEN
303                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
304                        '" requires passive_scalar = .TRUE.'
305                   CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 )
306                ENDIF
307                unit = 'conc'
308
309             CASE ( 'sa' )
310                IF ( .NOT. ocean )  THEN
311                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
312                        '" requires ocean = .TRUE.'
313                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
314                ENDIF
315                unit = 'psu'
316
317             CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*', 'z0h*' )
318                WRITE ( message_string, * ) 'illegal value for data_',&
319                     'output: "', TRIM( var ), '" is only allowed', &
320                     'for horizontal cross section'
321                CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 )
322
323             CASE ( 'p', 'pt', 'u', 'v', 'w' )
324                IF ( TRIM( var ) == 'p'  )  unit = 'Pa'
325                IF ( TRIM( var ) == 'pt' )  unit = 'K'
326                IF ( TRIM( var ) == 'u'  )  unit = 'm/s'
327                IF ( TRIM( var ) == 'v'  )  unit = 'm/s'
328                IF ( TRIM( var ) == 'w'  )  unit = 'm/s'
329                CONTINUE
330
331             CASE DEFAULT
332                CALL user_check_data_output( var, unit )
333
334                IF ( unit == 'illegal' )  THEN
335                   IF ( do_mask_user(mid,1) /= ' ' )  THEN
336                      WRITE ( message_string, * ) 'illegal value for data_',&
337                           'output or data_output_user: "', &
338                           TRIM( do_mask(mid,i) ), '"'
339                      CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 )
340                   ELSE
341                      WRITE ( message_string, * ) 'illegal value for data_',&
342                           'output: "', TRIM( do_mask(mid,i) ), '"'
343                      CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 )
344                   ENDIF
345                ENDIF
346
347          END SELECT
348!
349!--       Set the internal steering parameters appropriately
350          domask_no(mid,j)                    = domask_no(mid,j) + 1
351          domask(mid,j,domask_no(mid,j))      = do_mask(mid,i)
352          domask_unit(mid,j,domask_no(mid,j)) = unit
353
354          IF ( j == 1 )  THEN
355!
356!--          Check, if variable is already subject to averaging
357             found = .FALSE.
358             DO  k = 1, doav_n
359                IF ( TRIM( doav(k) ) == TRIM( var ) )  found = .TRUE.
360             ENDDO
361
362             IF ( .NOT. found )  THEN
363                doav_n = doav_n + 1
364                doav(doav_n) = var
365             ENDIF
366          ENDIF
367
368          i = i + 1
369
370       ENDDO   ! do_mask(mid,i)
371    ENDDO   ! mid
372
373
374!
375!-- Determine mask locations for each mask
376    DO  mid = 1, masks
377!
378!--    Set local masks for each subdomain along all three dimensions
379       CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
380       CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
381       CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
382!
383!--    Set global masks along all three dimensions (required by
384!--    define_netcdf_header).
385#if defined( __parallel ) && ! defined ( __check )
386!
387!--    PE0 receives partial arrays from all processors of the respective mask
388!--    and outputs them. Here a barrier has to be set, because otherwise
389!--    "-MPI- FATAL: Remote protocol queue full" may occur.
390
391       CALL MPI_BARRIER( comm2d, ierr )
392
393       IF ( myid == 0 )  THEN
394!
395!--       Local arrays can be relocated directly.
396          mask_i_global(mid,mask_start_l(mid,1): &
397                       mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
398                       mask_i(mid,:mask_size_l(mid,1))
399          mask_j_global(mid,mask_start_l(mid,2): &
400                       mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
401                       mask_j(mid,:mask_size_l(mid,2))
402          mask_k_global(mid,mask_start_l(mid,3): &
403                       mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
404                       mask_k(mid,:mask_size_l(mid,3))
405!
406!--       Receive data from all other PEs.
407          DO  n = 1, numprocs-1
408!
409!--          Receive index limits first, then arrays.
410!--          Index limits are received in arbitrary order from the PEs.
411             CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0,  &
412                  comm2d, status, ierr )
413!
414!--          Not all PEs have data for the mask.
415             IF ( ind(1) /= -9999 )  THEN
416                sender = status(MPI_SOURCE)
417                CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1,  &
418                               MPI_INTEGER, sender, 1, comm2d, status, ierr )
419                mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
420                CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1,  &
421                               MPI_INTEGER, sender, 2, comm2d, status, ierr )
422                mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
423                CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1,  &
424                               MPI_INTEGER, sender, 3, comm2d, status, ierr )
425                mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
426             ENDIF
427          ENDDO
428
429       ELSE
430!
431!--       If at least part of the mask resides on the PE, send the index limits
432!--       for the target array, otherwise send -9999 to PE0.
433          IF ( mask_size_l(mid,1) > 0  .AND.  mask_size_l(mid,2) > 0  .AND.  &
434               mask_size_l(mid,3) > 0  )  THEN
435             ind(1) = mask_start_l(mid,1)
436             ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
437             ind(3) = mask_start_l(mid,2)
438             ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
439             ind(5) = mask_start_l(mid,3)
440             ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
441          ELSE
442             ind(1) = -9999; ind(2) = -9999
443             ind(3) = -9999; ind(4) = -9999
444             ind(5) = -9999; ind(6) = -9999
445          ENDIF
446          CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
447!
448!--       If applicable, send data to PE0.
449          IF ( ind(1) /= -9999 )  THEN
450             tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
451             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1),  &
452                            MPI_INTEGER, 0, 1, comm2d, ierr )
453             tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
454             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2),  &
455                            MPI_INTEGER, 0, 2, comm2d, ierr )
456             tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
457             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3),  &
458                            MPI_INTEGER, 0, 3, comm2d, ierr )
459          ENDIF
460       ENDIF
461!
462!--    A barrier has to be set, because otherwise some PEs may proceed too fast
463!--    so that PE0 may receive wrong data on tag 0.
464       CALL MPI_BARRIER( comm2d, ierr )
465       
466       IF ( netcdf_data_format > 4 )  THEN
467         
468          CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, &
469                          ierr )
470          CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, &
471                          ierr )
472          CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, &
473                          ierr ) 
474         
475       ENDIF
476
477#elif ! defined ( __parallel )
478!
479!--    Local arrays can be relocated directly.
480       mask_i_global(mid,:) = mask_i(mid,:)
481       mask_j_global(mid,:) = mask_j(mid,:)
482       mask_k_global(mid,:) = mask_k(mid,:)
483#endif
484    ENDDO   ! mid
485
486    DEALLOCATE( tmp_array )
487!
488!-- Internal mask arrays cannot be deallocated on PE 0 because they are
489!-- required for header output on PE 0.
490    IF ( myid /= 0 )  DEALLOCATE( mask, mask_loop )
491
492 CONTAINS
493
494    SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
495                                   lb, ub )
496!------------------------------------------------------------------------------!
497!
498! Description:
499! ------------
500! Set local mask for each subdomain along 'dim' direction.
501!------------------------------------------------------------------------------!
502
503       IMPLICIT NONE
504
505       CHARACTER (LEN=2) ::  dxyz_string !:
506       CHARACTER (LEN=2) ::  nxyz_string !:
507       
508       INTEGER(iwp)  ::  count       !:
509       INTEGER(iwp)  ::  count_l     !:
510       INTEGER(iwp)  ::  dim         !:
511       INTEGER(iwp)  ::  m           !:
512       INTEGER(iwp)  ::  loop_begin  !:
513       INTEGER(iwp)  ::  loop_end    !:
514       INTEGER(iwp)  ::  loop_stride !:
515       INTEGER(iwp)  ::  lb          !:
516       INTEGER(iwp)  ::  nxyz        !:
517       INTEGER(iwp)  ::  ub          !:
518       
519       REAL(wp)      ::  dxyz  !:
520       REAL(wp)      ::  ddxyz !:
521       REAL(wp)      ::  tmp1  !:
522       REAL(wp)      ::  tmp2  !:
523
524       count = 0;  count_l = 0 
525       ddxyz = 1.0_wp / dxyz 
526       tmp1  = 0.0_wp
527       tmp2  = 0.0_wp
528
529       IF ( mask(mid,dim,1) >= 0.0_wp )  THEN
530!
531!--       use predefined mask_* array
532          DO  WHILE ( mask(mid,dim,count+1) >= 0.0_wp )
533             count = count + 1
534             IF ( dim == 1 .OR. dim == 2 )  THEN
535                m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz - 0.5_wp )
536             ELSEIF ( dim == 3 )  THEN
537                ind_array =  &
538                     MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) )
539                m = ind_array(1) - 1 + nzb  ! MINLOC uses lower array bound 1
540             ENDIF
541             IF ( m > nxyz )  THEN
542                WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' )  &
543                     m,' in mask ',mid,' along dimension ',dim,  &
544                     ' exceeds ',nxyz_string,' = ',nxyz
545                CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 )
546             ENDIF
547             IF ( m >= lb .AND. m <= ub )  THEN
548                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
549                count_l = count_l + 1
550                IF ( dim == 1 )  THEN
551                   mask_i(mid,count_l) = m
552                ELSEIF ( dim == 2 )  THEN
553                   mask_j(mid,count_l) = m
554                ELSEIF ( dim == 3 )  THEN
555                   mask_k(mid,count_l) = m
556                ENDIF
557             ENDIF
558             IF ( count == mask_xyz_dimension )  EXIT
559          ENDDO
560          mask_size(mid,dim)   = count
561          mask_size_l(mid,dim) = count_l
562
563       ELSE
564!
565!--       use predefined mask_loop_* array, or use the default (all grid points
566!--       along this direction)
567          IF ( mask_loop(mid,dim,1) < 0.0_wp )  THEN
568             tmp1 = mask_loop(mid,dim,1)
569             mask_loop(mid,dim,1) = zw(nzb)  !   lowest level  (default)
570          ENDIF
571          IF ( dim == 1 .OR. dim == 2 )  THEN
572             IF ( mask_loop(mid,dim,2) < 0.0_wp )  THEN
573                tmp2 = mask_loop(mid,dim,2)
574                mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim)   ! (default)
575             ENDIF
576             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
577                  > nxyz * dxyz / mask_scale(dim) )  THEN
578                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
579                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
580                     ' and/or mask_loop(',mid,',',dim,',2)=', &
581                     mask_loop(mid,dim,2),'&exceed ', &
582                     nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', &
583                     nxyz*dxyz/mask_scale(dim)
584                CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 )
585             ENDIF
586             loop_begin  = NINT( mask_loop(mid,dim,1) * mask_scale(dim) &
587                  * ddxyz - 0.5_wp )
588             loop_end    = NINT( mask_loop(mid,dim,2) * mask_scale(dim) &
589                  * ddxyz - 0.5_wp )
590             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) &
591                  * ddxyz )
592          ELSEIF ( dim == 3 )  THEN
593             IF ( mask_loop(mid,dim,2) < 0.0_wp )  THEN
594                tmp2 = mask_loop(mid,dim,2)
595                mask_loop(mid,dim,2) = zu(nz) / mask_scale(dim)   ! (default)
596             ENDIF
597             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
598                  > zu(nz) / mask_scale(dim) )  THEN
599                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
600                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
601                     ' and/or mask_loop(',mid,',',dim,',2)=', &
602                     mask_loop(mid,dim,2),'&exceed zu(nz)/mask_scale(',dim, &
603                     ')=',zu(nz)/mask_scale(dim)
604                CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 )
605             ENDIF
606             ind_array =  &
607                  MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) )
608             loop_begin =  &
609                  ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
610             ind_array =  &
611                  MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) )
612             loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
613!
614!--          The following line assumes a constant vertical grid spacing within
615!--          the vertical mask range; it fails for vertical grid stretching.
616!--          Maybe revise later. Issue warning but continue execution.
617             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
618
619             IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level )  &
620                  THEN
621                WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) &
622                     'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),&
623                     ' exceeds dz_stretch_level=',dz_stretch_level, &
624                     '.&Vertical mask locations will not ', &
625                     'match the desired heights&within the stretching ', &
626                     'region. Recommendation: use mask instead of mask_loop.'
627                CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 )
628             ENDIF
629
630          ENDIF
631!
632!--       If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
633          IF ( tmp1 < 0.0_wp )  mask_loop(mid,dim,1) = tmp1
634          IF ( tmp2 < 0.0_wp )  mask_loop(mid,dim,2) = tmp2
635!
636!--       The default stride +/-1 (every grid point) applies if
637!--       mask_loop(mid,dim,3) is not specified (its default is zero).
638          IF ( loop_stride == 0 )  THEN
639             IF ( loop_end >= loop_begin )  THEN
640                loop_stride =  1
641             ELSE
642                loop_stride = -1
643             ENDIF
644          ENDIF
645          DO  m = loop_begin, loop_end, loop_stride
646             count = count + 1
647             IF ( m >= lb  .AND.  m <= ub )  THEN
648                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
649                count_l = count_l + 1
650                IF ( dim == 1 )  THEN
651                   mask_i(mid,count_l) = m
652                ELSEIF ( dim == 2 )  THEN
653                   mask_j(mid,count_l) = m
654                ELSEIF ( dim == 3 )  THEN
655                   mask_k(mid,count_l) = m
656                ENDIF
657             ENDIF
658          ENDDO
659          mask_size(mid,dim)   = count
660          mask_size_l(mid,dim) = count_l
661       ENDIF
662
663    END SUBROUTINE set_mask_locations
664
665 END SUBROUTINE init_masks
Note: See TracBrowser for help on using the repository browser.