source: palm/trunk/SOURCE/init_masks.f90 @ 1320

Last change on this file since 1320 was 1320, checked in by raasch, 10 years ago

ONLY-attribute added to USE-statements,
kind-parameters added to all INTEGER and REAL declaration statements,
kinds are defined in new module kinds,
old module precision_kind is removed,
revision history before 2012 removed,
comment fields (!:) to be used for variable explanations added to all variable declaration statements

  • Property svn:keywords set to Id
File size: 26.1 KB
Line 
1 SUBROUTINE init_masks
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2014 Leibniz Universitaet Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! ONLY-attribute added to USE-statements,
23! kind-parameters added to all INTEGER and REAL declaration statements,
24! kinds are defined in new module kinds,
25! revision history before 2012 removed,
26! comment fields (!:) to be used for variable explanations added to
27! all variable declaration statements
28!
29! Former revisions:
30! -----------------
31! $Id: init_masks.f90 1320 2014-03-20 08:40:49Z raasch $
32!
33! 1186 2013-06-18 06:22:52Z raasch
34! bugfix: 0.0 replaced by zu(nzb) as the lowest default height level for masks,
35! because a zero value does not work in case of ocean runs
36!
37! 1036 2012-10-22 13:43:42Z raasch
38! code put under GPL (PALM 3.9)
39!
40! 1032 2012-10-21 13:03:21Z letzel
41! mask locations determined based on scalar positions
42!
43! 1031 2012-10-19 14:35:30Z raasch
44! netCDF4 without parallel file support implemented
45!
46! 996 2012-09-07 10:41:47Z raasch
47! little reformatting
48!
49! 978 2012-08-09 08:28:32Z fricke
50! +z0h*
51!
52! 809 2012-01-30 13:32:58Z maronga
53! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
54!
55! 807 2012-01-25 11:53:51Z maronga
56! New cpp directive "__check" implemented which is used by check_namelist_files
57!
58! 410 2009-12-04 17:05:40Z letzel
59! Initial revision
60!
61!
62! Description:
63! ------------
64! Initialize masked data output
65!------------------------------------------------------------------------------!
66
67    USE arrays_3d,                                                             &
68        ONLY:  zu, zw
69
70    USE control_parameters,                                                    &
71        ONLY:  constant_diffusion, cloud_droplets, cloud_physics,              &
72               data_output_masks, data_output_masks_user,                      &
73               doav, doav_n, domask, domask_no, dz, dz_stretch_level, humidity,&
74               mask, masks, mask_scale, mask_i,                                &
75               mask_i_global, mask_j, mask_j_global, mask_k, mask_k_global,    &
76               mask_loop, mask_size, mask_size_l, mask_start_l, mask_x,        &
77               mask_x_loop, mask_xyz_dimension, mask_y, mask_y_loop, mask_z,   &
78               mask_z_loop, max_masks,  message_string, mid,                   &
79               netcdf_data_format, passive_scalar, ocean
80
81    USE grid_variables,                                                        &
82        ONLY:  dx, dy
83
84    USE indices,                                                               &
85        ONLY:  nx, nxl, nxr, ny, nyn, nys, nz, nzb, nzt
86
87    USE kinds
88
89    USE netcdf_control,                                                        &
90        ONLY:  domask_unit
91
92    USE particle_attributes,                                                   &
93        ONLY:  particle_advection
94
95    USE pegrid
96
97    IMPLICIT NONE
98
99    CHARACTER (LEN=6) ::  var  !:
100    CHARACTER (LEN=7) ::  unit !:
101   
102    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask      !:
103    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask_user !:
104
105    INTEGER(iwp) ::  i            !:
106    INTEGER(iwp) ::  ilen         !:
107    INTEGER(iwp) ::  ind(6)       !:
108    INTEGER(iwp) ::  ind_array(1) !:
109    INTEGER(iwp) ::  j            !:
110    INTEGER(iwp) ::  k            !:
111    INTEGER(iwp) ::  n            !:
112    INTEGER(iwp) ::  sender       !:
113   
114    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  tmp_array !:
115
116    LOGICAL ::  found !:
117!
118!-- Allocation and initialization
119    ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) )
120
121    ALLOCATE( mask_i(max_masks,nxr-nxl+1), &
122              mask_j(max_masks,nyn-nys+1), &
123              mask_k(max_masks,nzt-nzb+1) )
124!
125!-- internal mask arrays ("mask,dimension,selection")
126    ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
127              mask_loop(max_masks,3,3) )
128   
129!
130!-- Parallel mask output not yet tested
131    IF ( netcdf_data_format > 4 )  THEN
132       message_string = 'netCDF file formats '//                         &
133                        '3 (netCDF 4) and 4 (netCDF 4 Classic model)'//  &
134                        '&are currently not supported (not yet tested).'
135       CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 )
136    ENDIF
137
138!
139!-- Store data output parameters for masked data output in few shared arrays
140    DO  mid = 1, masks
141   
142       do_mask     (mid,:) = data_output_masks(mid,:)
143       do_mask_user(mid,:) = data_output_masks_user(mid,:)
144       mask      (mid,1,:) = mask_x(mid,:) 
145       mask      (mid,2,:) = mask_y(mid,:)
146       mask      (mid,3,:) = mask_z(mid,:) 
147       
148       IF ( mask_x_loop(mid,1) == -1.0  .AND.  mask_x_loop(mid,2) == -1.0  &
149            .AND.  mask_x_loop(mid,3) == -1.0 )  THEN
150          mask_loop(mid,1,1:2) = -1.0
151          mask_loop(mid,1,3) = 0.0
152       ELSE
153          mask_loop(mid,1,:) = mask_x_loop(mid,:)
154       ENDIF
155       IF ( mask_y_loop(mid,1) == -1.0  .AND.  mask_y_loop(mid,2) == -1.0  &
156            .AND.  mask_y_loop(mid,3) == -1.0 )  THEN
157          mask_loop(mid,2,1:2) = -1.0
158          mask_loop(mid,2,3) = 0.0
159       ELSE
160          mask_loop(mid,2,:) = mask_y_loop(mid,:)
161       ENDIF
162       IF ( mask_z_loop(mid,1) == -1.0  .AND.  mask_z_loop(mid,2) == -1.0  &
163            .AND.  mask_z_loop(mid,3) == -1.0 )  THEN
164          mask_loop(mid,3,1:2) = -1.0
165          mask_loop(mid,3,3) = 0.0
166       ELSE
167          mask_loop(mid,3,:) = mask_z_loop(mid,:)
168       ENDIF
169       
170    ENDDO
171   
172    mask_i = -1; mask_j = -1; mask_k = -1
173   
174!
175!-- Global arrays are required by define_netcdf_header.
176    IF ( myid == 0  .OR.  netcdf_data_format > 4 )  THEN
177       ALLOCATE( mask_i_global(max_masks,nx+1), &
178                 mask_j_global(max_masks,ny+1), &
179                 mask_k_global(max_masks,nz+1) )
180       mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
181    ENDIF
182
183!
184!-- Determine variable names for each mask
185    DO  mid = 1, masks
186!
187!--    Append user-defined data output variables to the standard data output
188       IF ( do_mask_user(mid,1) /= ' ' )  THEN
189          i = 1
190          DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
191             i = i + 1
192          ENDDO
193          j = 1
194          DO  WHILE ( do_mask_user(mid,j) /= ' '  .AND.  j <= 100 )
195             IF ( i > 100 )  THEN
196                WRITE ( message_string, * ) 'number of output quantitities ', &
197                     'given by data_output_mask and data_output_mask_user ', &
198                     'exceeds the limit of 100'
199                CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 )
200             ENDIF
201             do_mask(mid,i) = do_mask_user(mid,j)
202             i = i + 1
203             j = j + 1
204          ENDDO
205       ENDIF
206
207!
208!--    Check and set steering parameters for mask data output and averaging
209       i   = 1
210       DO WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
211!
212!--       Check for data averaging
213          ilen = LEN_TRIM( do_mask(mid,i) )
214          j = 0                                              ! no data averaging
215          IF ( ilen > 3 )  THEN
216             IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' )  THEN
217                j = 1                                           ! data averaging
218                do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
219             ENDIF
220          ENDIF
221          var = TRIM( do_mask(mid,i) )
222!
223!--       Check for allowed value and set units
224          SELECT CASE ( TRIM( var ) )
225
226             CASE ( 'e' )
227                IF ( constant_diffusion )  THEN
228                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
229                        '" requires constant_diffusion = .FALSE.'
230                   CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 )
231                ENDIF
232                unit = 'm2/s2'
233
234             CASE ( 'lpt' )
235                IF ( .NOT. cloud_physics )  THEN
236                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
237                        '" requires cloud_physics = .TRUE.'
238                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
239                ENDIF
240                unit = 'K'
241
242             CASE ( 'pc', 'pr' )
243                IF ( .NOT. particle_advection )  THEN
244                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
245                        '" requires a "particles_par"-NAMELIST in the ', &
246                        'parameter file (PARIN)'
247                   CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 )
248                ENDIF
249                IF ( TRIM( var ) == 'pc' )  unit = 'number'
250                IF ( TRIM( var ) == 'pr' )  unit = 'm'
251
252             CASE ( 'q', 'vpt' )
253                IF ( .NOT. humidity )  THEN
254                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
255                        '" requires humidity = .TRUE.'
256                   CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 )
257                ENDIF
258                IF ( TRIM( var ) == 'q'   )  unit = 'kg/kg'
259                IF ( TRIM( var ) == 'vpt' )  unit = 'K'
260
261             CASE ( 'ql' )
262                IF ( .NOT. ( cloud_physics  .OR.  cloud_droplets ) )  THEN
263                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
264                        '" requires cloud_physics = .TRUE. or cloud_droplets', &
265                        ' = .TRUE.'
266                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
267                ENDIF
268                unit = 'kg/kg'
269
270             CASE ( 'ql_c', 'ql_v', 'ql_vp' )
271                IF ( .NOT. cloud_droplets )  THEN
272                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
273                        '" requires cloud_droplets = .TRUE.'
274                   CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 )
275                ENDIF
276                IF ( TRIM( var ) == 'ql_c'  )  unit = 'kg/kg'
277                IF ( TRIM( var ) == 'ql_v'  )  unit = 'm3'
278                IF ( TRIM( var ) == 'ql_vp' )  unit = 'none'
279
280             CASE ( 'qv' )
281                IF ( .NOT. cloud_physics )  THEN
282                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
283                        '" requires cloud_physics = .TRUE.'
284                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
285                ENDIF
286                unit = 'kg/kg'
287
288             CASE ( 'rho' )
289                IF ( .NOT. ocean )  THEN
290                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
291                        '" requires ocean = .TRUE.'
292                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
293                ENDIF
294                unit = 'kg/m3'
295
296             CASE ( 's' )
297                IF ( .NOT. passive_scalar )  THEN
298                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
299                        '" requires passive_scalar = .TRUE.'
300                   CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 )
301                ENDIF
302                unit = 'conc'
303
304             CASE ( 'sa' )
305                IF ( .NOT. ocean )  THEN
306                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
307                        '" requires ocean = .TRUE.'
308                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
309                ENDIF
310                unit = 'psu'
311
312             CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*', 'z0h*' )
313                WRITE ( message_string, * ) 'illegal value for data_',&
314                     'output: "', TRIM( var ), '" is only allowed', &
315                     'for horizontal cross section'
316                CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 )
317
318             CASE ( 'p', 'pt', 'u', 'v', 'w' )
319                IF ( TRIM( var ) == 'p'  )  unit = 'Pa'
320                IF ( TRIM( var ) == 'pt' )  unit = 'K'
321                IF ( TRIM( var ) == 'u'  )  unit = 'm/s'
322                IF ( TRIM( var ) == 'v'  )  unit = 'm/s'
323                IF ( TRIM( var ) == 'w'  )  unit = 'm/s'
324                CONTINUE
325
326             CASE DEFAULT
327                CALL user_check_data_output( var, unit )
328
329                IF ( unit == 'illegal' )  THEN
330                   IF ( do_mask_user(mid,1) /= ' ' )  THEN
331                      WRITE ( message_string, * ) 'illegal value for data_',&
332                           'output or data_output_user: "', &
333                           TRIM( do_mask(mid,i) ), '"'
334                      CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 )
335                   ELSE
336                      WRITE ( message_string, * ) 'illegal value for data_',&
337                           'output: "', TRIM( do_mask(mid,i) ), '"'
338                      CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 )
339                   ENDIF
340                ENDIF
341
342          END SELECT
343!
344!--       Set the internal steering parameters appropriately
345          domask_no(mid,j)                    = domask_no(mid,j) + 1
346          domask(mid,j,domask_no(mid,j))      = do_mask(mid,i)
347          domask_unit(mid,j,domask_no(mid,j)) = unit
348
349          IF ( j == 1 )  THEN
350!
351!--          Check, if variable is already subject to averaging
352             found = .FALSE.
353             DO  k = 1, doav_n
354                IF ( TRIM( doav(k) ) == TRIM( var ) )  found = .TRUE.
355             ENDDO
356
357             IF ( .NOT. found )  THEN
358                doav_n = doav_n + 1
359                doav(doav_n) = var
360             ENDIF
361          ENDIF
362
363          i = i + 1
364
365       ENDDO   ! do_mask(mid,i)
366    ENDDO   ! mid
367
368
369!
370!-- Determine mask locations for each mask
371    DO  mid = 1, masks
372!
373!--    Set local masks for each subdomain along all three dimensions
374       CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
375       CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
376       CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
377!
378!--    Set global masks along all three dimensions (required by
379!--    define_netcdf_header).
380#if defined( __parallel ) && ! defined ( __check )
381!
382!--    PE0 receives partial arrays from all processors of the respective mask
383!--    and outputs them. Here a barrier has to be set, because otherwise
384!--    "-MPI- FATAL: Remote protocol queue full" may occur.
385
386       CALL MPI_BARRIER( comm2d, ierr )
387
388       IF ( myid == 0 )  THEN
389!
390!--       Local arrays can be relocated directly.
391          mask_i_global(mid,mask_start_l(mid,1): &
392                       mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
393                       mask_i(mid,:mask_size_l(mid,1))
394          mask_j_global(mid,mask_start_l(mid,2): &
395                       mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
396                       mask_j(mid,:mask_size_l(mid,2))
397          mask_k_global(mid,mask_start_l(mid,3): &
398                       mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
399                       mask_k(mid,:mask_size_l(mid,3))
400!
401!--       Receive data from all other PEs.
402          DO  n = 1, numprocs-1
403!
404!--          Receive index limits first, then arrays.
405!--          Index limits are received in arbitrary order from the PEs.
406             CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0,  &
407                  comm2d, status, ierr )
408!
409!--          Not all PEs have data for the mask.
410             IF ( ind(1) /= -9999 )  THEN
411                sender = status(MPI_SOURCE)
412                CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1,  &
413                               MPI_INTEGER, sender, 1, comm2d, status, ierr )
414                mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
415                CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1,  &
416                               MPI_INTEGER, sender, 2, comm2d, status, ierr )
417                mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
418                CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1,  &
419                               MPI_INTEGER, sender, 3, comm2d, status, ierr )
420                mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
421             ENDIF
422          ENDDO
423
424       ELSE
425!
426!--       If at least part of the mask resides on the PE, send the index limits
427!--       for the target array, otherwise send -9999 to PE0.
428          IF ( mask_size_l(mid,1) > 0  .AND.  mask_size_l(mid,2) > 0  .AND.  &
429               mask_size_l(mid,3) > 0  )  THEN
430             ind(1) = mask_start_l(mid,1)
431             ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
432             ind(3) = mask_start_l(mid,2)
433             ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
434             ind(5) = mask_start_l(mid,3)
435             ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
436          ELSE
437             ind(1) = -9999; ind(2) = -9999
438             ind(3) = -9999; ind(4) = -9999
439             ind(5) = -9999; ind(6) = -9999
440          ENDIF
441          CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
442!
443!--       If applicable, send data to PE0.
444          IF ( ind(1) /= -9999 )  THEN
445             tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
446             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1),  &
447                            MPI_INTEGER, 0, 1, comm2d, ierr )
448             tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
449             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2),  &
450                            MPI_INTEGER, 0, 2, comm2d, ierr )
451             tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
452             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3),  &
453                            MPI_INTEGER, 0, 3, comm2d, ierr )
454          ENDIF
455       ENDIF
456!
457!--    A barrier has to be set, because otherwise some PEs may proceed too fast
458!--    so that PE0 may receive wrong data on tag 0.
459       CALL MPI_BARRIER( comm2d, ierr )
460       
461       IF ( netcdf_data_format > 4 )  THEN
462         
463          CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, &
464                          ierr )
465          CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, &
466                          ierr )
467          CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, &
468                          ierr ) 
469         
470       ENDIF
471
472#elif ! defined ( __parallel )
473!
474!--    Local arrays can be relocated directly.
475       mask_i_global(mid,:) = mask_i(mid,:)
476       mask_j_global(mid,:) = mask_j(mid,:)
477       mask_k_global(mid,:) = mask_k(mid,:)
478#endif
479    ENDDO   ! mid
480
481    DEALLOCATE( tmp_array )
482!
483!-- Internal mask arrays cannot be deallocated on PE 0 because they are
484!-- required for header output on PE 0.
485    IF ( myid /= 0 )  DEALLOCATE( mask, mask_loop )
486
487 CONTAINS
488
489    SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
490                                   lb, ub )
491!------------------------------------------------------------------------------!
492!
493! Description:
494! ------------
495! Set local mask for each subdomain along 'dim' direction.
496!------------------------------------------------------------------------------!
497
498       IMPLICIT NONE
499
500       CHARACTER (LEN=2) ::  dxyz_string !:
501       CHARACTER (LEN=2) ::  nxyz_string !:
502       
503       INTEGER(iwp)  ::  count       !:
504       INTEGER(iwp)  ::  count_l     !:
505       INTEGER(iwp)  ::  dim         !:
506       INTEGER(iwp)  ::  m           !:
507       INTEGER(iwp)  ::  loop_begin  !:
508       INTEGER(iwp)  ::  loop_end    !:
509       INTEGER(iwp)  ::  loop_stride !:
510       INTEGER(iwp)  ::  lb          !:
511       INTEGER(iwp)  ::  nxyz        !:
512       INTEGER(iwp)  ::  ub          !:
513       
514       REAL(wp)      ::  dxyz  !:
515       REAL(wp)      ::  ddxyz !:
516       REAL(wp)      ::  tmp1  !:
517       REAL(wp)      ::  tmp2  !:
518
519       count = 0;  count_l = 0;  ddxyz = 1.0 / dxyz;  tmp1 = 0.0;  tmp2 = 0.0
520
521       IF ( mask(mid,dim,1) >= 0.0 )  THEN
522!
523!--       use predefined mask_* array
524          DO  WHILE ( mask(mid,dim,count+1) >= 0.0 )
525             count = count + 1
526             IF ( dim == 1 .OR. dim == 2 )  THEN
527                m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz - 0.5 )
528             ELSEIF ( dim == 3 )  THEN
529                ind_array =  &
530                     MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) )
531                m = ind_array(1) - 1 + nzb  ! MINLOC uses lower array bound 1
532             ENDIF
533             IF ( m > nxyz )  THEN
534                WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' )  &
535                     m,' in mask ',mid,' along dimension ',dim,  &
536                     ' exceeds ',nxyz_string,' = ',nxyz
537                CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 )
538             ENDIF
539             IF ( m >= lb .AND. m <= ub )  THEN
540                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
541                count_l = count_l + 1
542                IF ( dim == 1 )  THEN
543                   mask_i(mid,count_l) = m
544                ELSEIF ( dim == 2 )  THEN
545                   mask_j(mid,count_l) = m
546                ELSEIF ( dim == 3 )  THEN
547                   mask_k(mid,count_l) = m
548                ENDIF
549             ENDIF
550             IF ( count == mask_xyz_dimension )  EXIT
551          ENDDO
552          mask_size(mid,dim)   = count
553          mask_size_l(mid,dim) = count_l
554
555       ELSE
556!
557!--       use predefined mask_loop_* array, or use the default (all grid points
558!--       along this direction)
559          IF ( mask_loop(mid,dim,1) < 0.0 )  THEN
560             tmp1 = mask_loop(mid,dim,1)
561             mask_loop(mid,dim,1) = zw(nzb)  !   lowest level  (default)
562          ENDIF
563          IF ( dim == 1 .OR. dim == 2 )  THEN
564             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
565                tmp2 = mask_loop(mid,dim,2)
566                mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim)   ! (default)
567             ENDIF
568             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
569                  > nxyz * dxyz / mask_scale(dim) )  THEN
570                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
571                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
572                     ' and/or mask_loop(',mid,',',dim,',2)=', &
573                     mask_loop(mid,dim,2),'&exceed ', &
574                     nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', &
575                     nxyz*dxyz/mask_scale(dim)
576                CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 )
577             ENDIF
578             loop_begin  = NINT( mask_loop(mid,dim,1) * mask_scale(dim) &
579                  * ddxyz - 0.5 )
580             loop_end    = NINT( mask_loop(mid,dim,2) * mask_scale(dim) &
581                  * ddxyz - 0.5 )
582             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) &
583                  * ddxyz )
584          ELSEIF ( dim == 3 )  THEN
585             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
586                tmp2 = mask_loop(mid,dim,2)
587                mask_loop(mid,dim,2) = zu(nz) / mask_scale(dim)   ! (default)
588             ENDIF
589             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
590                  > zu(nz) / mask_scale(dim) )  THEN
591                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
592                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
593                     ' and/or mask_loop(',mid,',',dim,',2)=', &
594                     mask_loop(mid,dim,2),'&exceed zu(nz)/mask_scale(',dim, &
595                     ')=',zu(nz)/mask_scale(dim)
596                CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 )
597             ENDIF
598             ind_array =  &
599                  MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) )
600             loop_begin =  &
601                  ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
602             ind_array =  &
603                  MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) )
604             loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
605!
606!--          The following line assumes a constant vertical grid spacing within
607!--          the vertical mask range; it fails for vertical grid stretching.
608!--          Maybe revise later. Issue warning but continue execution.
609             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
610
611             IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level )  &
612                  THEN
613                WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) &
614                     'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),&
615                     ' exceeds dz_stretch_level=',dz_stretch_level, &
616                     '.&Vertical mask locations will not ', &
617                     'match the desired heights&within the stretching ', &
618                     'region. Recommendation: use mask instead of mask_loop.'
619                CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 )
620             ENDIF
621
622          ENDIF
623!
624!--       If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
625          IF ( tmp1 < 0.0 )  mask_loop(mid,dim,1) = tmp1
626          IF ( tmp2 < 0.0 )  mask_loop(mid,dim,2) = tmp2
627!
628!--       The default stride +/-1 (every grid point) applies if
629!--       mask_loop(mid,dim,3) is not specified (its default is zero).
630          IF ( loop_stride == 0 )  THEN
631             IF ( loop_end >= loop_begin )  THEN
632                loop_stride =  1
633             ELSE
634                loop_stride = -1
635             ENDIF
636          ENDIF
637          DO  m = loop_begin, loop_end, loop_stride
638             count = count + 1
639             IF ( m >= lb  .AND.  m <= ub )  THEN
640                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
641                count_l = count_l + 1
642                IF ( dim == 1 )  THEN
643                   mask_i(mid,count_l) = m
644                ELSEIF ( dim == 2 )  THEN
645                   mask_j(mid,count_l) = m
646                ELSEIF ( dim == 3 )  THEN
647                   mask_k(mid,count_l) = m
648                ENDIF
649             ENDIF
650          ENDDO
651          mask_size(mid,dim)   = count
652          mask_size_l(mid,dim) = count_l
653       ENDIF
654
655    END SUBROUTINE set_mask_locations
656
657 END SUBROUTINE init_masks
Note: See TracBrowser for help on using the repository browser.