source: palm/trunk/SOURCE/init_masks.f90 @ 1032

Last change on this file since 1032 was 1032, checked in by letzel, 9 years ago
  • mask locations determined based on scalar positions (init_masks)
  • save memory by not allocating pt_2 in case of neutral = .T. (init_3d_model, swap_timelevel)
  • minor reformatting (check_for_restart)
  • Property svn:keywords set to Id
File size: 23.3 KB
Line 
1 SUBROUTINE init_masks
2
3!------------------------------------------------------------------------------!
4! Current revisions:
5! -----------------
6! hotfix: mask locations determined based on scalar positions
7! netCDF4 without parallel file support implemented
8!
9! Former revisions:
10! -----------------
11! $Id: init_masks.f90 1032 2012-10-21 13:03:21Z letzel $
12!
13! 996 2012-09-07 10:41:47Z raasch
14! little reformatting
15!
16! 978 2012-08-09 08:28:32Z fricke
17! +z0h*
18!
19! 809 2012-01-30 13:32:58Z maronga
20! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
21!
22! 807 2012-01-25 11:53:51Z maronga
23! New cpp directive "__check" implemented which is used by check_namelist_files
24!
25! 771 2011-10-27 10:56:21Z heinze
26! +lpt
27!
28! 595 2010-11-12 09:52:10Z helmke
29! Calculation of z locations for masked output changed
30!
31! 564 2010-09-30 13:18:59Z helmke
32! assignment of mask_xyz_loop added, palm message identifiers of masked output
33! changed
34!
35! 557 2010-09-07 14:50:07Z weinreis
36! bugfix message string in set_mask_locations
37!
38! 553 2010-09-01 14:09:06Z weinreis
39! parameters for masked output are replaced by arrays
40!
41! 493 2010-03-01 08:30:24Z raasch
42! netcdf_format_mask* and format_parallel_io replaced by netcdf_data_format
43!
44! 410 2009-12-04 17:05:40Z letzel
45! Initial revision
46!
47!
48! Description:
49! ------------
50! Initialize masked data output
51!------------------------------------------------------------------------------!
52
53    USE arrays_3d
54    USE control_parameters
55    USE grid_variables
56    USE indices
57    USE netcdf_control
58    USE particle_attributes
59    USE pegrid
60
61    IMPLICIT NONE
62
63    CHARACTER (LEN=6)   ::  var
64    CHARACTER (LEN=7)   ::  unit
65    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask, do_mask_user
66
67    INTEGER :: i, ilen, ind(6), ind_array(1), j, k, n, sender
68    INTEGER, DIMENSION(:), ALLOCATABLE ::  tmp_array
69
70    LOGICAL ::  found
71!
72!-- Allocation and initialization
73    ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) )
74
75    ALLOCATE( mask_i(max_masks,nxr-nxl+1), &
76              mask_j(max_masks,nyn-nys+1), &
77              mask_k(max_masks,nzt-nzb+1) )
78!
79!-- internal mask arrays ("mask,dimension,selection")
80    ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
81              mask_loop(max_masks,3,3) )
82   
83!
84!-- Parallel mask output not yet tested
85    IF ( netcdf_data_format > 4 )  THEN
86       message_string = 'netCDF file formats '//                         &
87                        '3 (netCDF 4) and 4 (netCDF 4 Classic model)'//  &
88                        '&are currently not supported (not yet tested).'
89       CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 )
90    ENDIF
91
92!
93!-- Store data output parameters for masked data output in few shared arrays
94    DO  mid = 1, masks
95   
96       do_mask     (mid,:) = data_output_masks(mid,:)
97       do_mask_user(mid,:) = data_output_masks_user(mid,:)
98       mask      (mid,1,:) = mask_x(mid,:) 
99       mask      (mid,2,:) = mask_y(mid,:)
100       mask      (mid,3,:) = mask_z(mid,:) 
101       
102       IF ( mask_x_loop(mid,1) == -1.0  .AND.  mask_x_loop(mid,2) == -1.0  &
103            .AND.  mask_x_loop(mid,3) == -1.0 )  THEN
104          mask_loop(mid,1,1:2) = -1.0
105          mask_loop(mid,1,3) = 0.0
106       ELSE
107          mask_loop(mid,1,:) = mask_x_loop(mid,:)
108       ENDIF
109       IF ( mask_y_loop(mid,1) == -1.0  .AND.  mask_y_loop(mid,2) == -1.0  &
110            .AND.  mask_y_loop(mid,3) == -1.0 )  THEN
111          mask_loop(mid,2,1:2) = -1.0
112          mask_loop(mid,2,3) = 0.0
113       ELSE
114          mask_loop(mid,2,:) = mask_y_loop(mid,:)
115       ENDIF
116       IF ( mask_z_loop(mid,1) == -1.0  .AND.  mask_z_loop(mid,2) == -1.0  &
117            .AND.  mask_z_loop(mid,3) == -1.0 )  THEN
118          mask_loop(mid,3,1:2) = -1.0
119          mask_loop(mid,3,3) = 0.0
120       ELSE
121          mask_loop(mid,3,:) = mask_z_loop(mid,:)
122       ENDIF
123       
124    ENDDO
125   
126    mask_i = -1; mask_j = -1; mask_k = -1
127   
128!
129!-- Global arrays are required by define_netcdf_header.
130    IF ( myid == 0  .OR.  netcdf_data_format > 4 )  THEN
131       ALLOCATE( mask_i_global(max_masks,nx+1), &
132                 mask_j_global(max_masks,ny+1), &
133                 mask_k_global(max_masks,nz+1) )
134       mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
135    ENDIF
136
137!
138!-- Determine variable names for each mask
139    DO  mid = 1, masks
140!
141!--    Append user-defined data output variables to the standard data output
142       IF ( do_mask_user(mid,1) /= ' ' )  THEN
143          i = 1
144          DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
145             i = i + 1
146          ENDDO
147          j = 1
148          DO  WHILE ( do_mask_user(mid,j) /= ' '  .AND.  j <= 100 )
149             IF ( i > 100 )  THEN
150                WRITE ( message_string, * ) 'number of output quantitities ', &
151                     'given by data_output_mask and data_output_mask_user ', &
152                     'exceeds the limit of 100'
153                CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 )
154             ENDIF
155             do_mask(mid,i) = do_mask_user(mid,j)
156             i = i + 1
157             j = j + 1
158          ENDDO
159       ENDIF
160
161!
162!--    Check and set steering parameters for mask data output and averaging
163       i   = 1
164       DO WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
165!
166!--       Check for data averaging
167          ilen = LEN_TRIM( do_mask(mid,i) )
168          j = 0                                              ! no data averaging
169          IF ( ilen > 3 )  THEN
170             IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' )  THEN
171                j = 1                                           ! data averaging
172                do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
173             ENDIF
174          ENDIF
175          var = TRIM( do_mask(mid,i) )
176!
177!--       Check for allowed value and set units
178          SELECT CASE ( TRIM( var ) )
179
180             CASE ( 'e' )
181                IF ( constant_diffusion )  THEN
182                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
183                        '" requires constant_diffusion = .FALSE.'
184                   CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 )
185                ENDIF
186                unit = 'm2/s2'
187
188             CASE ( 'lpt' )
189                IF ( .NOT. cloud_physics )  THEN
190                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
191                        '" requires cloud_physics = .TRUE.'
192                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
193                ENDIF
194                unit = 'K'
195
196             CASE ( 'pc', 'pr' )
197                IF ( .NOT. particle_advection )  THEN
198                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
199                        '" requires a "particles_par"-NAMELIST in the ', &
200                        'parameter file (PARIN)'
201                   CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 )
202                ENDIF
203                IF ( TRIM( var ) == 'pc' )  unit = 'number'
204                IF ( TRIM( var ) == 'pr' )  unit = 'm'
205
206             CASE ( 'q', 'vpt' )
207                IF ( .NOT. humidity )  THEN
208                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
209                        '" requires humidity = .TRUE.'
210                   CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 )
211                ENDIF
212                IF ( TRIM( var ) == 'q'   )  unit = 'kg/kg'
213                IF ( TRIM( var ) == 'vpt' )  unit = 'K'
214
215             CASE ( 'ql' )
216                IF ( .NOT. ( cloud_physics  .OR.  cloud_droplets ) )  THEN
217                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
218                        '" requires cloud_physics = .TRUE. or cloud_droplets', &
219                        ' = .TRUE.'
220                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
221                ENDIF
222                unit = 'kg/kg'
223
224             CASE ( 'ql_c', 'ql_v', 'ql_vp' )
225                IF ( .NOT. cloud_droplets )  THEN
226                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
227                        '" requires cloud_droplets = .TRUE.'
228                   CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 )
229                ENDIF
230                IF ( TRIM( var ) == 'ql_c'  )  unit = 'kg/kg'
231                IF ( TRIM( var ) == 'ql_v'  )  unit = 'm3'
232                IF ( TRIM( var ) == 'ql_vp' )  unit = 'none'
233
234             CASE ( 'qv' )
235                IF ( .NOT. cloud_physics )  THEN
236                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
237                        '" requires cloud_physics = .TRUE.'
238                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
239                ENDIF
240                unit = 'kg/kg'
241
242             CASE ( 'rho' )
243                IF ( .NOT. ocean )  THEN
244                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
245                        '" requires ocean = .TRUE.'
246                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
247                ENDIF
248                unit = 'kg/m3'
249
250             CASE ( 's' )
251                IF ( .NOT. passive_scalar )  THEN
252                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
253                        '" requires passive_scalar = .TRUE.'
254                   CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 )
255                ENDIF
256                unit = 'conc'
257
258             CASE ( 'sa' )
259                IF ( .NOT. ocean )  THEN
260                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
261                        '" requires ocean = .TRUE.'
262                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
263                ENDIF
264                unit = 'psu'
265
266             CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*', 'z0h*' )
267                WRITE ( message_string, * ) 'illegal value for data_',&
268                     'output: "', TRIM( var ), '" is only allowed', &
269                     'for horizontal cross section'
270                CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 )
271
272             CASE ( 'p', 'pt', 'u', 'v', 'w' )
273                IF ( TRIM( var ) == 'p'  )  unit = 'Pa'
274                IF ( TRIM( var ) == 'pt' )  unit = 'K'
275                IF ( TRIM( var ) == 'u'  )  unit = 'm/s'
276                IF ( TRIM( var ) == 'v'  )  unit = 'm/s'
277                IF ( TRIM( var ) == 'w'  )  unit = 'm/s'
278                CONTINUE
279
280             CASE DEFAULT
281                CALL user_check_data_output( var, unit )
282
283                IF ( unit == 'illegal' )  THEN
284                   IF ( do_mask_user(mid,1) /= ' ' )  THEN
285                      WRITE ( message_string, * ) 'illegal value for data_',&
286                           'output or data_output_user: "', &
287                           TRIM( do_mask(mid,i) ), '"'
288                      CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 )
289                   ELSE
290                      WRITE ( message_string, * ) 'illegal value for data_',&
291                           'output: "', TRIM( do_mask(mid,i) ), '"'
292                      CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 )
293                   ENDIF
294                ENDIF
295
296          END SELECT
297!
298!--       Set the internal steering parameters appropriately
299          domask_no(mid,j)                    = domask_no(mid,j) + 1
300          domask(mid,j,domask_no(mid,j))      = do_mask(mid,i)
301          domask_unit(mid,j,domask_no(mid,j)) = unit
302
303          IF ( j == 1 )  THEN
304!
305!--          Check, if variable is already subject to averaging
306             found = .FALSE.
307             DO  k = 1, doav_n
308                IF ( TRIM( doav(k) ) == TRIM( var ) )  found = .TRUE.
309             ENDDO
310
311             IF ( .NOT. found )  THEN
312                doav_n = doav_n + 1
313                doav(doav_n) = var
314             ENDIF
315          ENDIF
316
317          i = i + 1
318
319       ENDDO   ! do_mask(mid,i)
320    ENDDO   ! mid
321
322
323!
324!-- Determine mask locations for each mask
325    DO  mid = 1, masks
326!
327!--    Set local masks for each subdomain along all three dimensions
328       CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
329       CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
330       CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
331!
332!--    Set global masks along all three dimensions (required by
333!--    define_netcdf_header).
334#if defined( __parallel ) && ! defined ( __check )
335!
336!--    PE0 receives partial arrays from all processors of the respective mask
337!--    and outputs them. Here a barrier has to be set, because otherwise
338!--    "-MPI- FATAL: Remote protocol queue full" may occur.
339
340       CALL MPI_BARRIER( comm2d, ierr )
341
342       IF ( myid == 0 )  THEN
343!
344!--       Local arrays can be relocated directly.
345          mask_i_global(mid,mask_start_l(mid,1): &
346                       mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
347                       mask_i(mid,:mask_size_l(mid,1))
348          mask_j_global(mid,mask_start_l(mid,2): &
349                       mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
350                       mask_j(mid,:mask_size_l(mid,2))
351          mask_k_global(mid,mask_start_l(mid,3): &
352                       mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
353                       mask_k(mid,:mask_size_l(mid,3))
354!
355!--       Receive data from all other PEs.
356          DO  n = 1, numprocs-1
357!
358!--          Receive index limits first, then arrays.
359!--          Index limits are received in arbitrary order from the PEs.
360             CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0,  &
361                  comm2d, status, ierr )
362!
363!--          Not all PEs have data for the mask.
364             IF ( ind(1) /= -9999 )  THEN
365                sender = status(MPI_SOURCE)
366                CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1,  &
367                               MPI_INTEGER, sender, 1, comm2d, status, ierr )
368                mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
369                CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1,  &
370                               MPI_INTEGER, sender, 2, comm2d, status, ierr )
371                mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
372                CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1,  &
373                               MPI_INTEGER, sender, 3, comm2d, status, ierr )
374                mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
375             ENDIF
376          ENDDO
377
378       ELSE
379!
380!--       If at least part of the mask resides on the PE, send the index limits
381!--       for the target array, otherwise send -9999 to PE0.
382          IF ( mask_size_l(mid,1) > 0  .AND.  mask_size_l(mid,2) > 0  .AND.  &
383               mask_size_l(mid,3) > 0  )  THEN
384             ind(1) = mask_start_l(mid,1)
385             ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
386             ind(3) = mask_start_l(mid,2)
387             ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
388             ind(5) = mask_start_l(mid,3)
389             ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
390          ELSE
391             ind(1) = -9999; ind(2) = -9999
392             ind(3) = -9999; ind(4) = -9999
393             ind(5) = -9999; ind(6) = -9999
394          ENDIF
395          CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
396!
397!--       If applicable, send data to PE0.
398          IF ( ind(1) /= -9999 )  THEN
399             tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
400             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1),  &
401                            MPI_INTEGER, 0, 1, comm2d, ierr )
402             tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
403             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2),  &
404                            MPI_INTEGER, 0, 2, comm2d, ierr )
405             tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
406             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3),  &
407                            MPI_INTEGER, 0, 3, comm2d, ierr )
408          ENDIF
409       ENDIF
410!
411!--    A barrier has to be set, because otherwise some PEs may proceed too fast
412!--    so that PE0 may receive wrong data on tag 0.
413       CALL MPI_BARRIER( comm2d, ierr )
414       
415       IF ( netcdf_data_format > 4 )  THEN
416         
417          CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, &
418                          ierr )
419          CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, &
420                          ierr )
421          CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, &
422                          ierr ) 
423         
424       ENDIF
425
426#elif ! defined ( __parallel )
427!
428!--    Local arrays can be relocated directly.
429       mask_i_global(mid,:) = mask_i(mid,:)
430       mask_j_global(mid,:) = mask_j(mid,:)
431       mask_k_global(mid,:) = mask_k(mid,:)
432#endif
433    ENDDO   ! mid
434
435    DEALLOCATE( tmp_array )
436!
437!-- Internal mask arrays cannot be deallocated on PE 0 because they are
438!-- required for header output on PE 0.
439    IF ( myid /= 0 )  DEALLOCATE( mask, mask_loop )
440
441 CONTAINS
442
443    SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
444                                   lb, ub )
445!------------------------------------------------------------------------------!
446!
447! Description:
448! ------------
449! Set local mask for each subdomain along 'dim' direction.
450!------------------------------------------------------------------------------!
451
452       IMPLICIT NONE
453
454       CHARACTER (LEN=2) :: dxyz_string, nxyz_string
455       INTEGER  ::  count, count_l, dim, m, loop_begin, loop_end, loop_stride, &
456                    lb, nxyz, ub
457       REAL     ::  dxyz, ddxyz, tmp1, tmp2
458
459       count = 0;  count_l = 0;  ddxyz = 1.0 / dxyz;  tmp1 = 0.0;  tmp2 = 0.0
460
461       IF ( mask(mid,dim,1) >= 0.0 )  THEN
462!
463!--       use predefined mask_* array
464          DO  WHILE ( mask(mid,dim,count+1) >= 0.0 )
465             count = count + 1
466             IF ( dim == 1 .OR. dim == 2 )  THEN
467                m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz - 0.5 )
468             ELSEIF ( dim == 3 )  THEN
469                ind_array =  &
470                     MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) )
471                m = ind_array(1) - 1 + nzb  ! MINLOC uses lower array bound 1
472             ENDIF
473             IF ( m > nxyz )  THEN
474                WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' )  &
475                     m,' in mask ',mid,' along dimension ',dim,  &
476                     ' exceeds ',nxyz_string,' = ',nxyz
477                CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 )
478             ENDIF
479             IF ( m >= lb .AND. m <= ub )  THEN
480                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
481                count_l = count_l + 1
482                IF ( dim == 1 )  THEN
483                   mask_i(mid,count_l) = m
484                ELSEIF ( dim == 2 )  THEN
485                   mask_j(mid,count_l) = m
486                ELSEIF ( dim == 3 )  THEN
487                   mask_k(mid,count_l) = m
488                ENDIF
489             ENDIF
490             IF ( count == mask_xyz_dimension )  EXIT
491          ENDDO
492          mask_size(mid,dim)   = count
493          mask_size_l(mid,dim) = count_l
494
495       ELSE
496!
497!--       use predefined mask_loop_* array, or use the default (all grid points
498!--       along this direction)
499          IF ( mask_loop(mid,dim,1) < 0.0 )  THEN
500             tmp1 = mask_loop(mid,dim,1)
501             mask_loop(mid,dim,1) = 0.0   ! (default)
502          ENDIF
503          IF ( dim == 1 .OR. dim == 2 )  THEN
504             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
505                tmp2 = mask_loop(mid,dim,2)
506                mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim)   ! (default)
507             ENDIF
508             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
509                  > nxyz * dxyz / mask_scale(dim) )  THEN
510                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
511                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
512                     ' and/or mask_loop(',mid,',',dim,',2)=', &
513                     mask_loop(mid,dim,2),'&exceed ', &
514                     nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', &
515                     nxyz*dxyz/mask_scale(dim)
516                CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 )
517             ENDIF
518             loop_begin  = NINT( mask_loop(mid,dim,1) * mask_scale(dim) &
519                  * ddxyz - 0.5 )
520             loop_end    = NINT( mask_loop(mid,dim,2) * mask_scale(dim) &
521                  * ddxyz - 0.5 )
522             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) &
523                  * ddxyz )
524          ELSEIF ( dim == 3 )  THEN
525             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
526                tmp2 = mask_loop(mid,dim,2)
527                mask_loop(mid,dim,2) = zu(nz) / mask_scale(dim)   ! (default)
528             ENDIF
529             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
530                  > zu(nz) / mask_scale(dim) )  THEN
531                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
532                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
533                     ' and/or mask_loop(',mid,',',dim,',2)=', &
534                     mask_loop(mid,dim,2),'&exceed zu(nz)/mask_scale(',dim, &
535                     ')=',zu(nz)/mask_scale(dim)
536                CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 )
537             ENDIF
538             ind_array =  &
539                  MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) )
540             loop_begin =  &
541                  ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
542             ind_array =  &
543                  MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) )
544             loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
545!
546!--          The following line assumes a constant vertical grid spacing within
547!--          the vertical mask range; it fails for vertical grid stretching.
548!--          Maybe revise later. Issue warning but continue execution.
549             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
550
551             IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level )  &
552                  THEN
553                WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) &
554                     'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),&
555                     ' exceeds dz_stretch_level=',dz_stretch_level, &
556                     '.&Vertical mask locations will not ', &
557                     'match the desired heights&within the stretching ', &
558                     'region. Recommendation: use mask instead of mask_loop.'
559                CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 )
560             ENDIF
561
562          ENDIF
563!
564!--       If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
565          IF ( tmp1 < 0.0 )  mask_loop(mid,dim,1) = tmp1
566          IF ( tmp2 < 0.0 )  mask_loop(mid,dim,2) = tmp2
567!
568!--       The default stride +/-1 (every grid point) applies if
569!--       mask_loop(mid,dim,3) is not specified (its default is zero).
570          IF ( loop_stride == 0 )  THEN
571             IF ( loop_end >= loop_begin )  THEN
572                loop_stride =  1
573             ELSE
574                loop_stride = -1
575             ENDIF
576          ENDIF
577          DO  m = loop_begin, loop_end, loop_stride
578             count = count + 1
579             IF ( m >= lb  .AND.  m <= ub )  THEN
580                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
581                count_l = count_l + 1
582                IF ( dim == 1 )  THEN
583                   mask_i(mid,count_l) = m
584                ELSEIF ( dim == 2 )  THEN
585                   mask_j(mid,count_l) = m
586                ELSEIF ( dim == 3 )  THEN
587                   mask_k(mid,count_l) = m
588                ENDIF
589             ENDIF
590          ENDDO
591          mask_size(mid,dim)   = count
592          mask_size_l(mid,dim) = count_l
593       ENDIF
594
595    END SUBROUTINE set_mask_locations
596
597 END SUBROUTINE init_masks
Note: See TracBrowser for help on using the repository browser.