source: palm/trunk/SOURCE/init_cloud_physics.f90 @ 1321

Last change on this file since 1321 was 1321, checked in by raasch, 7 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 4.9 KB
Line 
1 SUBROUTINE init_cloud_physics
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2014 Leibniz Universitaet Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! ------------------
26! $Id: init_cloud_physics.f90 1321 2014-03-20 09:40:40Z raasch $
27!
28! 1320 2014-03-20 08:40:49Z raasch
29! ONLY-attribute added to USE-statements,
30! kind-parameters added to all INTEGER and REAL declaration statements,
31! kinds are defined in new module mod_kinds,
32! revision history before 2012 removed,
33! comment fields (!:) to be used for variable explanations added to
34! all variable declaration statements
35!
36! 1065 2012-11-22 17:42:36Z hoffmann
37! The Courant number of sedimentation can be controlled with c_sedimentation.
38!
39! 1053 2012-11-13 17:11:03Z hoffmann
40! calculation of the maximum timestep according to the terminal velocity of rain
41! drops in the two moment cloud scheme
42!
43! calculation of frequently used constants (pirho_l, dpirho_l, schmidt_p_1d3,
44! hyrho)
45!
46! 1036 2012-10-22 13:43:42Z raasch
47! code put under GPL (PALM 3.9)
48!
49! 824 2012-02-17 09:09:57Z raasch
50! calculation of b_cond replaced by calculation of bfactor
51!
52! Revision 1.1  2000/04/13 14:37:22  schroeter
53! Initial revision
54!
55!
56! Description:
57! ------------
58! Initialization of parameters for handling cloud-physics
59!------------------------------------------------------------------------------!
60
61    USE arrays_3d,                                                             &
62        ONLY:  dzu, hyp, pt_init, zu
63       
64    USE cloud_parameters,                                                      &
65        ONLY:  bfactor, cp, c_sedimentation, dpirho_l, dt_precipitation,       &
66               hyrho, l_d_cp, l_d_r, l_d_rv, l_v, mass_of_solute,              &
67               molecular_weight_of_solute, molecular_weight_of_water, pirho_l, &
68               pt_d_t, rho_l, r_d, r_v, schmidt, schmidt_p_1d3, t_d_pt,        &
69               vanthoff, w_precipitation
70       
71    USE constants,                                                             &
72        ONLY:  pi
73       
74    USE control_parameters,                                                    &
75        ONLY:  g, icloud_scheme, message_string, precipitation, pt_surface,    &
76               rho_surface, surface_pressure
77   
78    USE indices,                                                               &
79        ONLY:  nzb, nzt
80   
81    USE kinds
82
83    IMPLICIT NONE
84
85    INTEGER(iwp) ::  k      !:
86   
87    REAL(wp) ::  t_surface  !:
88
89    ALLOCATE( hyp(nzb:nzt+1), pt_d_t(nzb:nzt+1), t_d_pt(nzb:nzt+1),  &
90              hyrho(nzb:nzt+1) )
91
92!
93!-- Calculate frequently used parameters
94    l_d_cp = l_v / cp
95    l_d_r  = l_v / r_d
96    l_d_rv = l_v / r_v
97
98    schmidt_p_1d3 = schmidt**( 1.0 / 3.0 )
99
100    pirho_l  = pi * rho_l / 6.0
101    dpirho_l = 1.0 / pirho_l
102!
103!-- Calculate timestep according to precipitation
104    IF ( icloud_scheme == 0  .AND.  precipitation )  THEN
105       dt_precipitation = c_sedimentation * MINVAL( dzu(nzb+2:nzt) ) /        &
106                          w_precipitation
107    ENDIF
108!
109!-- Calculate factor used in equation for droplet growth by condensation
110    bfactor = 3.0 * vanthoff * mass_of_solute * molecular_weight_of_water &
111              / ( 4.0 * pi * rho_l * molecular_weight_of_solute )
112!
113!-- Calculate:
114!-- pt / t : ratio of potential and actual temperature (pt_d_t)
115!-- t / pt : ratio of actual and potential temperature (t_d_pt)
116!-- p_0(z) : vertical profile of the hydrostatic pressure (hyp)
117    t_surface = pt_surface * ( surface_pressure / 1000.0 )**0.286
118    DO  k = nzb, nzt+1
119!
120!--    Check temperature in case of too large domain height
121       IF ( ( t_surface - g/cp * zu(k) ) < 0.0 )  THEN
122          WRITE( message_string, * )  'absolute temperature < 0.0 at zu(', k, &
123                                      ') = ', zu(k)
124          CALL message( 'init_cloud_physics', 'PA0142', 1, 2, 0, 6, 0 )
125       ENDIF
126       hyp(k)    = surface_pressure * 100.0 * &
127                   ( (t_surface - g/cp * zu(k)) / t_surface )**(1.0/0.286)
128       pt_d_t(k) = ( 100000.0 / hyp(k) )**0.286
129       t_d_pt(k) = 1.0 / pt_d_t(k)
130       hyrho(k)  = hyp(k) / ( r_d * t_d_pt(k) * pt_init(k) )       
131    ENDDO
132
133!
134!-- Compute reference density
135    rho_surface = surface_pressure * 100.0 / ( r_d * t_surface )
136
137
138 END SUBROUTINE init_cloud_physics
Note: See TracBrowser for help on using the repository browser.