SUBROUTINE init_cloud_physics

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! ------------------
! $Log: init_cloud_physics.f90,v $
! Revision 1.5  2005/06/26 19:55:58  raasch
! Initialization of cloud droplet constants, gas_constant renamed r_d,
! latent_heat renamed l_v
!
! Revision 1.4  2001/03/30 07:26:30  raasch
! Translation of remaining German identifiers (variables, subroutines, etc.),
! surface_pressure keeps unit hPa and is not converted to Pa
!
! Revision 1.3  2001/01/25 07:03:10  raasch
! Module test_variables removed
!
! Revision 1.2  2001/01/22 09:16:57  schroeter
! To calculate verticle pressure profile use actual surface-temperature in
! place of potential temperature as reference value.
!
! Revision 1.1  2000/04/13 14:37:22  schroeter
! Initial revision
!
!
! Description:
! ------------
! Initialization of parameters for handling cloud-physics
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE cloud_parameters
    USE control_parameters
    USE grid_variables
    USE indices

    IMPLICIT NONE

    INTEGER ::  k
    REAL    ::  t_surface

    ALLOCATE( hydro_press(nzb:nzt+1), pt_d_t(nzb:nzt+1), t_d_pt(nzb:nzt+1) )

!
!-- Compute frequently used parameters
    l_d_cp = l_v / cp
    l_d_r  = l_v / r_d
    l_d_rv = l_v / r_v

!
!-- Constant b in equation for droplet growth by condensation / evaporation.
!-- Factor 1E-3 is needed because formula is in cgs units
    mass_of_solute = 1.0E-17            ! in kg
    molecular_weight_of_solute = 58.5   ! NaCl
    b_cond = 4.3 * 2.0 * mass_of_solute / molecular_weight_of_solute * 1.0E-6

!
!-- Calculate:
!-- pt / t : ratio of potential and actual temperature (pt_d_t)
!-- t / pt : ratio of actual and potential temperature (t_d_pt)
!-- p_0(z) : vertical profile of the hydrostatic pressure (hydro_press)
    t_surface = pt_surface * ( surface_pressure / 1000.0 )**0.286
    DO  k = nzb, nzt+1
       hydro_press(k) = surface_pressure * 100.0 * &
                        ( (t_surface - g/cp * zu(k)) / t_surface )**(1.0/0.286)
       pt_d_t(k)      = ( 100000.0 / hydro_press(k) )**0.286
       t_d_pt(k)      = 1.0 / pt_d_t(k)       
    ENDDO

!
!-- Compute reference density
    rho_surface = surface_pressure * 100.0 / ( r_d * t_surface )


 END SUBROUTINE init_cloud_physics