source: palm/trunk/SOURCE/inflow_turbulence.f90 @ 1960

Last change on this file since 1960 was 1960, checked in by suehring, 5 years ago

Separate balance equations for humidity and passive_scalar

  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1!> @file inflow_turbulence.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! Separate humidity and passive scalar
22!
23! Former revisions:
24! -----------------
25! $Id: inflow_turbulence.f90 1960 2016-07-12 16:34:24Z suehring $
26!
27! 1806 2016-04-05 18:55:35Z gronemeier
28! Added comments to variables and code segments. Removed code redundancies.
29!
30! 1682 2015-10-07 23:56:08Z knoop
31! Code annotations made doxygen readable
32!
33! 1615 2015-07-08 18:49:19Z suehring
34! Enable turbulent inflow for passive_scalar and humidity
35!
36! 1560 2015-03-06 10:48:54Z keck
37! Option recycling_yshift added. If this option is switched on, the turbulence
38! data, which is mapped from the recycling plane to the inflow, is shifted in
39! y direction (by ny * dy / 2 )
40!
41! 1353 2014-04-08 15:21:23Z heinze
42! REAL constants provided with KIND-attribute
43!
44! 1346 2014-03-27 13:18:20Z heinze
45! Bugfix: REAL constants provided with KIND-attribute especially in call of
46! intrinsic function like MAX, MIN, SIGN
47!
48! 1320 2014-03-20 08:40:49Z raasch
49! ONLY-attribute added to USE-statements,
50! kind-parameters added to all INTEGER and REAL declaration statements,
51! kinds are defined in new module kinds,
52! revision history before 2012 removed,
53! comment fields (!:) to be used for variable explanations added to
54! all variable declaration statements
55!
56! 1092 2013-02-02 11:24:22Z raasch
57! unused variables removed
58!
59! 1036 2012-10-22 13:43:42Z raasch
60! code put under GPL (PALM 3.9)
61!
62! Initial version (2008/03/07)
63!
64! Description:
65! ------------
66!> Imposing turbulence at the respective inflow using the turbulence
67!> recycling method of Kataoka and Mizuno (2002).
68!------------------------------------------------------------------------------!
69 SUBROUTINE inflow_turbulence
70 
71
72    USE arrays_3d,                                                             &
73        ONLY:  e, inflow_damping_factor, mean_inflow_profiles, pt, q, s, u, v, w
74       
75    USE control_parameters,                                                    &
76        ONLY:  humidity, passive_scalar, recycling_plane, recycling_yshift
77       
78    USE cpulog,                                                                &
79        ONLY:  cpu_log, log_point
80       
81    USE indices,                                                               &
82        ONLY:  nbgp, nxl, ny, nyn, nys, nyng, nysg, nzb, nzt
83       
84    USE kinds
85   
86    USE pegrid
87
88
89    IMPLICIT NONE
90
91    INTEGER(iwp) ::  i        !< loop index
92    INTEGER(iwp) ::  j        !< loop index
93    INTEGER(iwp) ::  k        !< loop index
94    INTEGER(iwp) ::  l        !< loop index
95    INTEGER(iwp) ::  next     !< ID of receiving PE for y-shift
96    INTEGER(iwp) ::  ngp_ifd  !< number of grid points stored in avpr
97    INTEGER(iwp) ::  ngp_pr   !< number of grid points stored in inflow_dist
98    INTEGER(iwp) ::  prev     !< ID of sending PE for y-shift
99
100    REAL(wp), DIMENSION(nzb:nzt+1,7,nbgp)           ::                         &
101       avpr               !< stores averaged profiles at recycling plane
102    REAL(wp), DIMENSION(nzb:nzt+1,7,nbgp)           ::                         &
103       avpr_l             !< auxiliary variable to calculate avpr
104    REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,7,nbgp) ::                         &
105       inflow_dist        !< turbulence signal of vars, added at inflow boundary
106    REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,7,nbgp) ::                         &
107       local_inflow_dist  !< auxiliary variable for inflow_dist, used for yshift
108
109    CALL cpu_log( log_point(40), 'inflow_turbulence', 'start' )
110
111!
112!-- Carry out spanwise averaging in the recycling plane
113    avpr_l = 0.0_wp
114    ngp_pr = ( nzt - nzb + 2 ) * 7 * nbgp
115    ngp_ifd = ngp_pr * ( nyn - nys + 1 + 2 * nbgp )
116
117!
118!-- First, local averaging within the recycling domain
119    i = recycling_plane
120
121#if defined( __parallel )
122    IF ( myidx == id_recycling )  THEN
123       
124       DO  l = 1, nbgp
125          DO  j = nys, nyn
126             DO  k = nzb, nzt + 1
127
128                avpr_l(k,1,l) = avpr_l(k,1,l) + u(k,j,i)
129                avpr_l(k,2,l) = avpr_l(k,2,l) + v(k,j,i)
130                avpr_l(k,3,l) = avpr_l(k,3,l) + w(k,j,i)
131                avpr_l(k,4,l) = avpr_l(k,4,l) + pt(k,j,i)
132                avpr_l(k,5,l) = avpr_l(k,5,l) + e(k,j,i)
133                IF ( humidity )                                                &
134                   avpr_l(k,6,l) = avpr_l(k,6,l) + q(k,j,i)
135                IF ( passive_scalar )                                          &
136                   avpr_l(k,7,l) = avpr_l(k,7,l) + s(k,j,i)
137
138             ENDDO
139          ENDDO
140          i = i + 1
141       ENDDO
142
143    ENDIF
144!
145!-- Now, averaging over all PEs
146    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
147    CALL MPI_ALLREDUCE( avpr_l(nzb,1,1), avpr(nzb,1,1), ngp_pr, MPI_REAL,      &
148                        MPI_SUM, comm2d, ierr )
149
150#else
151    DO  l = 1, nbgp
152       DO  j = nys, nyn
153          DO  k = nzb, nzt + 1
154
155             avpr_l(k,1,l) = avpr_l(k,1,l) + u(k,j,i)
156             avpr_l(k,2,l) = avpr_l(k,2,l) + v(k,j,i)
157             avpr_l(k,3,l) = avpr_l(k,3,l) + w(k,j,i)
158             avpr_l(k,4,l) = avpr_l(k,4,l) + pt(k,j,i)
159             avpr_l(k,5,l) = avpr_l(k,5,l) + e(k,j,i)
160             IF ( humidity )                                                   &
161                avpr_l(k,6,l) = avpr_l(k,6,l) + q(k,j,i)
162             IF ( passive_scalar )                                             &
163                avpr_l(k,7,l) = avpr_l(k,7,l) + s(k,j,i)
164
165          ENDDO
166       ENDDO
167       i = i + 1 
168    ENDDO
169   
170    avpr = avpr_l
171#endif
172
173    avpr = avpr / ( ny + 1 )
174!
175!-- Calculate the disturbances at the recycling plane
176    i = recycling_plane
177
178#if defined( __parallel )
179    IF ( myidx == id_recycling )  THEN
180       DO  l = 1, nbgp
181          DO  j = nysg, nyng
182             DO  k = nzb, nzt + 1
183
184                inflow_dist(k,j,1,l) = u(k,j,i+1) - avpr(k,1,l)
185                inflow_dist(k,j,2,l) = v(k,j,i)   - avpr(k,2,l)
186                inflow_dist(k,j,3,l) = w(k,j,i)   - avpr(k,3,l)
187                inflow_dist(k,j,4,l) = pt(k,j,i)  - avpr(k,4,l)
188                inflow_dist(k,j,5,l) = e(k,j,i)   - avpr(k,5,l)
189                IF ( humidity )                                                &
190                   inflow_dist(k,j,6,l) = q(k,j,i) - avpr(k,6,l)
191                IF ( passive_scalar )                                          &
192                   inflow_dist(k,j,7,l) = s(k,j,i) - avpr(k,7,l)
193            ENDDO
194          ENDDO
195          i = i + 1
196       ENDDO
197
198    ENDIF
199#else
200    DO  l = 1, nbgp
201       DO  j = nysg, nyng
202          DO  k = nzb, nzt+1
203
204             inflow_dist(k,j,1,l) = u(k,j,i+1) - avpr(k,1,l)
205             inflow_dist(k,j,2,l) = v(k,j,i)   - avpr(k,2,l)
206             inflow_dist(k,j,3,l) = w(k,j,i)   - avpr(k,3,l)
207             inflow_dist(k,j,4,l) = pt(k,j,i)  - avpr(k,4,l)
208             inflow_dist(k,j,5,l) = e(k,j,i)   - avpr(k,5,l)
209             IF ( humidity )                                                   &
210                inflow_dist(k,j,6,l) = q(k,j,i) - avpr(k,6,l)
211             IF ( passive_scalar )                                             &
212                inflow_dist(k,j,7,l) = s(k,j,i) - avpr(k,7,l)
213             
214          ENDDO
215       ENDDO
216       i = i + 1
217    ENDDO
218#endif
219
220!
221!-- For parallel runs, send the disturbances to the respective inflow PE
222#if defined( __parallel )
223    IF ( myidx == id_recycling  .AND.  myidx /= id_inflow )  THEN
224
225       CALL MPI_SEND( inflow_dist(nzb,nysg,1,1), ngp_ifd, MPI_REAL,            &
226                      id_inflow, 1, comm1dx, ierr )
227
228    ELSEIF ( myidx /= id_recycling  .AND.  myidx == id_inflow )  THEN
229
230       inflow_dist = 0.0_wp
231       CALL MPI_RECV( inflow_dist(nzb,nysg,1,1), ngp_ifd, MPI_REAL,            &
232                      id_recycling, 1, comm1dx, status, ierr )
233
234    ENDIF
235
236!
237!-- y-shift for inflow_dist
238!-- Shift inflow_dist in positive y direction by a distance of INT( npey / 2 )
239    IF ( recycling_yshift .AND. myidx == id_inflow ) THEN
240!
241!--    Calculate the ID of the PE which sends data to this PE (prev) and of the
242!--    PE which receives data from this PE (next).
243       IF ( myidy >= INT( pdims(2) / 2 ) ) THEN
244          prev = myidy - INT( pdims(2) / 2 )
245       ELSE
246          prev = pdims(2) - ( INT( pdims(2) / 2 ) - myidy )
247       ENDIF
248     
249       IF ( myidy < pdims(2) - INT( pdims(2) / 2 ) ) THEN
250          next = myidy + INT( pdims(2) / 2 )
251       ELSE
252          next = INT( pdims(2) / 2 ) - ( pdims(2) - myidy )
253       ENDIF
254
255       local_inflow_dist = 0.0_wp
256
257       CALL MPI_SENDRECV( inflow_dist(nzb,nysg,1,1), ngp_ifd, MPI_REAL,        &
258                          next, 1, local_inflow_dist(nzb,nysg,1,1), ngp_ifd,   &
259                          MPI_REAL, prev, 1, comm1dy, status, ierr )
260
261       inflow_dist = local_inflow_dist
262
263    ENDIF
264
265#endif
266
267!
268!-- Add the disturbance at the inflow
269    IF ( nxl == 0 )  THEN
270
271       DO  j = nysg, nyng
272          DO  k = nzb, nzt + 1
273
274             u(k,j,-nbgp+1:0) = mean_inflow_profiles(k,1) +                 &
275                        inflow_dist(k,j,1,1:nbgp) * inflow_damping_factor(k)
276             v(k,j,-nbgp:-1)  = mean_inflow_profiles(k,2) +                 &
277                        inflow_dist(k,j,2,1:nbgp) * inflow_damping_factor(k)
278             w(k,j,-nbgp:-1)  =                                             &
279                        inflow_dist(k,j,3,1:nbgp) * inflow_damping_factor(k)
280             pt(k,j,-nbgp:-1) = mean_inflow_profiles(k,4) +                 &
281                        inflow_dist(k,j,4,1:nbgp) * inflow_damping_factor(k)
282             e(k,j,-nbgp:-1)  = mean_inflow_profiles(k,5) +                 &
283                        inflow_dist(k,j,5,1:nbgp) * inflow_damping_factor(k)
284             e(k,j,-nbgp:-1)  = MAX( e(k,j,-nbgp:-1), 0.0_wp )
285
286             IF ( humidity )                                                &
287                q(k,j,-nbgp:-1)  = mean_inflow_profiles(k,6) +              &
288                        inflow_dist(k,j,6,1:nbgp) * inflow_damping_factor(k)
289             IF ( passive_scalar )                                          &
290                s(k,j,-nbgp:-1)  = mean_inflow_profiles(k,7) +              &
291                        inflow_dist(k,j,7,1:nbgp) * inflow_damping_factor(k)
292
293          ENDDO
294       ENDDO
295
296    ENDIF
297
298
299    CALL cpu_log( log_point(40), 'inflow_turbulence', 'stop' )
300
301
302 END SUBROUTINE inflow_turbulence
Note: See TracBrowser for help on using the repository browser.