source: palm/trunk/SOURCE/eqn_state_seawater.f90 @ 97

Last change on this file since 97 was 97, checked in by raasch, 17 years ago

New:
---
ocean version including prognostic equation for salinity and equation of state for seawater. Routine buoyancy can be used with both temperature and density.
+ inipar-parameters bc_sa_t, bottom_salinityflux, ocean, sa_surface, sa_vertical_gradient, sa_vertical_gradient_level, top_salinityflux

advec_s_bc, average_3d_data, boundary_conds, buoyancy, check_parameters, data_output_2d, data_output_3d, diffusion_e, flow_statistics, header, init_grid, init_3d_model, modules, netcdf, parin, production_e, prognostic_equations, read_var_list, sum_up_3d_data, swap_timelevel, time_integration, user_interface, write_var_list, write_3d_binary

New:
eqn_state_seawater, init_ocean

Changed:


inipar-parameter use_pt_reference renamed use_reference

hydro_press renamed hyp, routine calc_mean_pt_profile renamed calc_mean_profile

format adjustments for the ocean version (run_control)

advec_particles, buoyancy, calc_liquid_water_content, check_parameters, diffusion_e, diffusivities, header, init_cloud_physics, modules, production_e, prognostic_equations, run_control

Errors:


Bugfix: height above topography instead of height above level k=0 is used for calculating the mixing length (diffusion_e and diffusivities).

Bugfix: error in boundary condition for TKE removed (advec_s_bc)

advec_s_bc, diffusion_e, prognostic_equations

  • Property svn:keywords set to Id
File size: 7.4 KB
Line 
1 MODULE eqn_state_seawater_mod
2
3!------------------------------------------------------------------------------!
4! Actual revisions:
5! -----------------
6!
7!
8! Former revisions:
9! -----------------
10! $Id: eqn_state_seawater.f90 97 2007-06-21 08:23:15Z raasch $
11!
12! Initial revision
13!
14!
15! Description:
16! ------------
17! Equation of state for seawater as a function of potential temperature,
18! salinity, and pressure.
19! For coefficients see Jackett et al., 2006: J. Atm. Ocean Tech.
20! eqn_state_seawater calculates the potential density referred at hyp(0).
21! eqn_state_seawater_func calculates density.
22!------------------------------------------------------------------------------!
23
24    IMPLICIT NONE
25
26    PRIVATE
27    PUBLIC eqn_state_seawater, eqn_state_seawater_func
28
29    REAL, DIMENSION(12), PARAMETER ::  nom =                             &
30                      (/ 9.9984085444849347D2,   7.3471625860981584D0,   &
31                        -5.3211231792841769D-2,  3.6492439109814549D-4,  &
32                         2.5880571023991390D0,  -6.7168282786692354D-3,  &
33                         1.9203202055760151D-3,  1.1798263740430364D-2,  &
34                         9.8920219266399117D-8,  4.6996642771754730D-6,  &
35                        -2.5862187075154352D-8, -3.2921414007960662D-12 /)
36
37    REAL, DIMENSION(13), PARAMETER ::  den =                             &
38                      (/ 1.0,                    7.2815210113327091D-3,  &
39                        -4.4787265461983921D-5,  3.3851002965802430D-7,  &
40                         1.3651202389758572D-10, 1.7632126669040377D-3,  &
41                        -8.8066583251206474D-6, -1.8832689434804897D-10, &
42                         5.7463776745432097D-6,  1.4716275472242334D-9,  &
43                         6.7103246285651894D-6, -2.4461698007024582D-17, &
44                        -9.1534417604289062D-18 /)
45
46    INTERFACE eqn_state_seawater
47       MODULE PROCEDURE eqn_state_seawater
48       MODULE PROCEDURE eqn_state_seawater_ij
49    END INTERFACE eqn_state_seawater
50 
51    INTERFACE eqn_state_seawater_func
52       MODULE PROCEDURE eqn_state_seawater_func
53    END INTERFACE eqn_state_seawater_func
54 
55 CONTAINS
56
57
58!------------------------------------------------------------------------------!
59! Call for all grid points
60!------------------------------------------------------------------------------!
61    SUBROUTINE eqn_state_seawater
62
63       USE arrays_3d
64       USE indices
65
66       IMPLICIT NONE
67
68       INTEGER ::  i, j, k
69
70       REAL ::  p1, p2, p3, pt1, pt2, pt3, pt4, sa1, sa15, sa2
71
72       DO  i = nxl, nxr
73          DO  j = nys, nyn
74             DO  k = nzb_s_inner(j,i)+1, nzt
75!
76!--             Pressure is needed in dbar
77                p1 = hyp(0) * 1E-4
78                p2 = p1 * p1
79                p3 = p2 * p1
80
81!
82!--             Temperature needed in degree Celsius
83                pt1 = pt_p(k,j,i) - 273.15
84                pt2 = pt1 * pt1
85                pt3 = pt1 * pt2
86                pt4 = pt2 * pt2
87
88                sa1  = sa_p(k,j,i)
89                sa15 = sa1 * SQRT( sa1 )
90                sa2  = sa1 * sa1
91
92                rho(k,j,i) =                                                   &
93                        ( nom(1)           + nom(2)*pt1     + nom(3)*pt2     + &
94                          nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 + &
95                          nom(7)*sa2       + nom(8)*p1      + nom(9)*p1*pt2  + &
96                          nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2   &
97                        ) /                                                    &
98                        ( den(1)           + den(2)*pt1     + den(3)*pt2     + &
99                          den(4)*pt3       + den(5)*pt4     + den(6)*sa1     + &
100                          den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    + &
101                          den(10)*sa15*pt2 + den(11)*p1     + den(12)*p2*pt3 + &
102                          den(13)*p3*pt1                                       &
103                        )
104
105             ENDDO
106!
107!--          Neumann conditions are assumed at bottom and top boundary
108             rho(nzt+1,j,i)            = rho(nzt,j,i)
109             rho(nzb_s_inner(j,i),j,i) = rho(nzb_s_inner(j,i)+1,j,i)
110          ENDDO
111       ENDDO
112
113    END SUBROUTINE eqn_state_seawater
114
115
116!------------------------------------------------------------------------------!
117! Call for grid point i,j
118!------------------------------------------------------------------------------!
119    SUBROUTINE eqn_state_seawater_ij( i, j )
120
121       USE arrays_3d
122       USE indices
123
124       IMPLICIT NONE
125
126       INTEGER ::  i, j, k
127
128       REAL ::  p1, p2, p3, pt1, pt2, pt3, pt4, sa1, sa15, sa2
129
130       DO  k = nzb_s_inner(j,i)+1, nzt
131!
132!--       Pressure is needed in dbar
133          p1 = hyp(0) * 1E-4
134          p2 = p1 * p1
135          p3 = p2 * p1
136
137!
138!--       Temperature needed in degree Celsius
139          pt1 = pt_p(k,j,i) - 273.15
140          pt2 = pt1 * pt1
141          pt3 = pt1 * pt2
142          pt4 = pt2 * pt2
143
144          sa1  = sa_p(k,j,i)
145          sa15 = sa1 * SQRT( sa1 )
146          sa2  = sa1 * sa1
147
148          rho(k,j,i) = ( nom(1)           + nom(2)*pt1     + nom(3)*pt2     + &
149                         nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 + &
150                         nom(7)*sa2       + nom(8)*p1      + nom(9)*p1*pt2  + &
151                         nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2   &
152                       ) /                                                    &
153                       ( den(1)           + den(2)*pt1     + den(3)*pt2     + &
154                         den(4)*pt3       + den(5)*pt4     + den(6)*sa1     + &
155                         den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    + &
156                         den(10)*sa15*pt2 + den(11)*p1     + den(12)*p2*pt3 + &
157                         den(13)*p3*pt1                                       &
158                       )
159       ENDDO
160!
161!--    Neumann conditions are assumed at bottom and top boundary
162       rho(nzt+1,j,i)            = rho(nzt,j,i)
163       rho(nzb_s_inner(j,i),j,i) = rho(nzb_s_inner(j,i)+1,j,i)
164
165    END SUBROUTINE eqn_state_seawater_ij
166
167
168!------------------------------------------------------------------------------!
169! Equation of state as a function
170!------------------------------------------------------------------------------!
171    REAL FUNCTION eqn_state_seawater_func( p, pt, sa )
172
173       IMPLICIT NONE
174
175       REAL ::  p, p1, p2, p3, pt, pt1, pt2, pt3, pt4, sa, sa15, sa2
176
177!
178!--    Pressure is needed in dbar
179       p1 = p  * 1E-4
180       p2 = p1 * p1
181       p3 = p2 * p1
182
183!
184!--    Temperature needed in degree Celsius
185       pt1 = pt - 273.15
186       pt2 = pt1 * pt1
187       pt3 = pt1 * pt2
188       pt4 = pt2 * pt2
189
190       sa15 = sa * SQRT( sa )
191       sa2  = sa * sa
192
193
194       eqn_state_seawater_func =                                               &
195         ( nom(1)        + nom(2)*pt1       + nom(3)*pt2    + nom(4)*pt3     + &
196           nom(5)*sa     + nom(6)*sa*pt1    + nom(7)*sa2    + nom(8)*p1      + &
197           nom(9)*p1*pt2 + nom(10)*p1*sa    + nom(11)*p2    + nom(12)*p2*pt2   &
198         ) /                                                                   &
199         ( den(1)        + den(2)*pt1       + den(3)*pt2    + den(4)*pt3     + &
200           den(5)*pt4    + den(6)*sa        + den(7)*sa*pt1 + den(8)*sa*pt3  + &
201           den(9)*sa15   + den(10)*sa15*pt2 + den(11)*p1    + den(12)*p2*pt3 + &
202           den(13)*p3*pt1                                                      &
203         )
204
205
206    END FUNCTION eqn_state_seawater_func
207
208 END MODULE eqn_state_seawater_mod
Note: See TracBrowser for help on using the repository browser.