source: palm/trunk/SOURCE/eqn_state_seawater.f90 @ 2000

Last change on this file since 2000 was 2000, checked in by knoop, 5 years ago

Forced header and separation lines into 80 columns

  • Property svn:keywords set to Id
File size: 10.7 KB
Line 
1!> @file eqn_state_seawater.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2016 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! Forced header and separation lines into 80 columns
23!
24! Former revisions:
25! -----------------
26! $Id: eqn_state_seawater.f90 2000 2016-08-20 18:09:15Z knoop $
27!
28! 1873 2016-04-18 14:50:06Z maronga
29! Module renamed (removed _mod)
30!
31!
32! 1850 2016-04-08 13:29:27Z maronga
33! Module renamed
34!
35!
36! 1682 2015-10-07 23:56:08Z knoop
37! Code annotations made doxygen readable
38!
39! 1353 2014-04-08 15:21:23Z heinze
40! REAL constants provided with KIND-attribute
41!
42! 1320 2014-03-20 08:40:49Z raasch
43! ONLY-attribute added to USE-statements,
44! kind-parameters added to all INTEGER and REAL declaration statements,
45! kinds are defined in new module kinds,
46! revision history before 2012 removed,
47! comment fields (!:) to be used for variable explanations added to
48! all variable declaration statements
49!
50! 1036 2012-10-22 13:43:42Z raasch
51! code put under GPL (PALM 3.9)
52!
53! 97 2007-06-21 08:23:15Z raasch
54! Initial revision
55!
56!
57! Description:
58! ------------
59!> Equation of state for seawater as a function of potential temperature,
60!> salinity, and pressure.
61!> For coefficients see Jackett et al., 2006: J. Atm. Ocean Tech.
62!> eqn_state_seawater calculates the potential density referred at hyp(0).
63!> eqn_state_seawater_func calculates density.
64!------------------------------------------------------------------------------!
65 MODULE eqn_state_seawater_mod
66 
67   
68    USE kinds
69
70    IMPLICIT NONE
71
72    PRIVATE
73    PUBLIC eqn_state_seawater, eqn_state_seawater_func
74
75    REAL(wp), DIMENSION(12), PARAMETER ::  nom =                               &
76                          (/ 9.9984085444849347D2,   7.3471625860981584D0,     &
77                            -5.3211231792841769D-2,  3.6492439109814549D-4,    &
78                             2.5880571023991390D0,  -6.7168282786692354D-3,    &
79                             1.9203202055760151D-3,  1.1798263740430364D-2,    &
80                             9.8920219266399117D-8,  4.6996642771754730D-6,    &
81                            -2.5862187075154352D-8, -3.2921414007960662D-12 /)
82                          !<
83
84    REAL(wp), DIMENSION(13), PARAMETER ::  den =                               &
85                          (/ 1.0D0,                  7.2815210113327091D-3,    &
86                            -4.4787265461983921D-5,  3.3851002965802430D-7,    &
87                             1.3651202389758572D-10, 1.7632126669040377D-3,    &
88                            -8.8066583251206474D-6, -1.8832689434804897D-10,   &
89                             5.7463776745432097D-6,  1.4716275472242334D-9,    &
90                             6.7103246285651894D-6, -2.4461698007024582D-17,   &
91                            -9.1534417604289062D-18 /)
92                          !<
93
94    INTERFACE eqn_state_seawater
95       MODULE PROCEDURE eqn_state_seawater
96       MODULE PROCEDURE eqn_state_seawater_ij
97    END INTERFACE eqn_state_seawater
98 
99    INTERFACE eqn_state_seawater_func
100       MODULE PROCEDURE eqn_state_seawater_func
101    END INTERFACE eqn_state_seawater_func
102 
103 CONTAINS
104
105
106!------------------------------------------------------------------------------!
107! Description:
108! ------------
109!> Call for all grid points
110!------------------------------------------------------------------------------!
111    SUBROUTINE eqn_state_seawater
112
113       USE arrays_3d,                                                          &
114           ONLY:  hyp, prho, pt_p, rho, sa_p
115       USE indices,                                                            &
116           ONLY:  nxl, nxr, nyn, nys, nzb_s_inner, nzt
117
118       IMPLICIT NONE
119
120       INTEGER(iwp) ::  i  !<
121       INTEGER(iwp) ::  j  !<
122       INTEGER(iwp) ::  k  !<
123
124       REAL(wp) ::  pden  !<
125       REAL(wp) ::  pnom  !<
126       REAL(wp) ::  p1    !<
127       REAL(wp) ::  p2    !<
128       REAL(wp) ::  p3    !<
129       REAL(wp) ::  pt1   !<
130       REAL(wp) ::  pt2   !<
131       REAL(wp) ::  pt3   !<
132       REAL(wp) ::  pt4   !<
133       REAL(wp) ::  sa1   !<
134       REAL(wp) ::  sa15  !<
135       REAL(wp) ::  sa2   !<
136       
137                       
138
139       DO  i = nxl, nxr
140          DO  j = nys, nyn
141             DO  k = nzb_s_inner(j,i)+1, nzt
142!
143!--             Pressure is needed in dbar
144                p1 = hyp(k) * 1E-4_wp
145                p2 = p1 * p1
146                p3 = p2 * p1
147
148!
149!--             Temperature needed in degree Celsius
150                pt1 = pt_p(k,j,i) - 273.15_wp
151                pt2 = pt1 * pt1
152                pt3 = pt1 * pt2
153                pt4 = pt2 * pt2
154
155                sa1  = sa_p(k,j,i)
156                sa15 = sa1 * SQRT( sa1 )
157                sa2  = sa1 * sa1
158
159                pnom = nom(1)           + nom(2)*pt1     + nom(3)*pt2     +    &
160                       nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 +    &
161                       nom(7)*sa2
162
163                pden = den(1)           + den(2)*pt1     + den(3)*pt2     +    &
164                       den(4)*pt3       + den(5)*pt4     + den(6)*sa1     +    &
165                       den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    +    &
166                       den(10)*sa15*pt2
167
168!
169!--             Potential density (without pressure terms)
170                prho(k,j,i) = pnom / pden
171
172                pnom = pnom +             nom(8)*p1      + nom(9)*p1*pt2  +    &
173                       nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2
174
175                pden = pden +             den(11)*p1     + den(12)*p2*pt3 +    &
176                       den(13)*p3*pt1
177
178!
179!--             In-situ density
180                rho(k,j,i) = pnom / pden
181
182             ENDDO
183!
184!--          Neumann conditions are assumed at bottom and top boundary
185             prho(nzt+1,j,i)            = prho(nzt,j,i)
186             prho(nzb_s_inner(j,i),j,i) = prho(nzb_s_inner(j,i)+1,j,i)
187             rho(nzt+1,j,i)             = rho(nzt,j,i)
188             rho(nzb_s_inner(j,i),j,i)  = rho(nzb_s_inner(j,i)+1,j,i)
189
190          ENDDO
191       ENDDO
192
193    END SUBROUTINE eqn_state_seawater
194
195
196!------------------------------------------------------------------------------!
197! Description:
198! ------------
199!> Call for grid point i,j
200!------------------------------------------------------------------------------!
201    SUBROUTINE eqn_state_seawater_ij( i, j )
202
203       USE arrays_3d,                                                          &
204           ONLY:  hyp, prho, pt_p, rho, sa_p
205           
206       USE indices,                                                            &
207           ONLY:  nzb_s_inner, nzt
208
209       IMPLICIT NONE
210
211       INTEGER(iwp) ::  i, j, k
212
213       REAL(wp)     ::  pden, pnom, p1, p2, p3, pt1, pt2, pt3, pt4, sa1, sa15, &
214                        sa2
215
216       DO  k = nzb_s_inner(j,i)+1, nzt
217!
218!--       Pressure is needed in dbar
219          p1 = hyp(k) * 1E-4_wp
220          p2 = p1 * p1
221          p3 = p2 * p1
222
223!
224!--       Temperature needed in degree Celsius
225          pt1 = pt_p(k,j,i) - 273.15_wp
226          pt2 = pt1 * pt1
227          pt3 = pt1 * pt2
228          pt4 = pt2 * pt2
229
230          sa1  = sa_p(k,j,i)
231          sa15 = sa1 * SQRT( sa1 )
232          sa2  = sa1 * sa1
233
234          pnom = nom(1)           + nom(2)*pt1     + nom(3)*pt2     +          &
235                 nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 +          &
236                 nom(7)*sa2
237
238          pden = den(1)           + den(2)*pt1     + den(3)*pt2     +          &
239                 den(4)*pt3       + den(5)*pt4     + den(6)*sa1     +          &
240                 den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    +          &
241                 den(10)*sa15*pt2
242
243!
244!--       Potential density (without pressure terms)
245          prho(k,j,i) = pnom / pden
246
247          pnom = pnom +             nom(8)*p1      + nom(9)*p1*pt2  +          &
248                 nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2
249          pden = pden +             den(11)*p1     + den(12)*p2*pt3 +          &
250                 den(13)*p3*pt1
251
252!
253!--       In-situ density
254          rho(k,j,i) = pnom / pden
255
256
257       ENDDO
258
259!
260!--    Neumann conditions are assumed at bottom and top boundary
261       prho(nzt+1,j,i)            = prho(nzt,j,i)
262       prho(nzb_s_inner(j,i),j,i) = prho(nzb_s_inner(j,i)+1,j,i)
263       rho(nzt+1,j,i)             = rho(nzt,j,i)
264       rho(nzb_s_inner(j,i),j,i)  = rho(nzb_s_inner(j,i)+1,j,i)
265
266    END SUBROUTINE eqn_state_seawater_ij
267
268
269!------------------------------------------------------------------------------!
270! Description:
271! ------------
272!> Equation of state as a function
273!------------------------------------------------------------------------------!
274    REAL(wp) FUNCTION eqn_state_seawater_func( p, pt, sa )
275
276       IMPLICIT NONE
277
278       REAL(wp) ::  p      !<
279       REAL(wp) ::  p1     !<
280       REAL(wp) ::  p2     !<
281       REAL(wp) ::  p3     !<
282       REAL(wp) ::  pt     !<
283       REAL(wp) ::  pt1    !<
284       REAL(wp) ::  pt2    !<
285       REAL(wp) ::  pt3    !<
286       REAL(wp) ::  pt4    !<
287       REAL(wp) ::  sa     !<
288       REAL(wp) ::  sa15   !<
289       REAL(wp) ::  sa2    !<
290
291!
292!--    Pressure is needed in dbar
293       p1 = p  * 1E-4_wp
294       p2 = p1 * p1
295       p3 = p2 * p1
296
297!
298!--    Temperature needed in degree Celsius
299       pt1 = pt - 273.15_wp
300       pt2 = pt1 * pt1
301       pt3 = pt1 * pt2
302       pt4 = pt2 * pt2
303
304       sa15 = sa * SQRT( sa )
305       sa2  = sa * sa
306
307
308       eqn_state_seawater_func =                                               &
309         ( nom(1)        + nom(2)*pt1       + nom(3)*pt2    + nom(4)*pt3     + &
310           nom(5)*sa     + nom(6)*sa*pt1    + nom(7)*sa2    + nom(8)*p1      + &
311           nom(9)*p1*pt2 + nom(10)*p1*sa    + nom(11)*p2    + nom(12)*p2*pt2   &
312         ) /                                                                   &
313         ( den(1)        + den(2)*pt1       + den(3)*pt2    + den(4)*pt3     + &
314           den(5)*pt4    + den(6)*sa        + den(7)*sa*pt1 + den(8)*sa*pt3  + &
315           den(9)*sa15   + den(10)*sa15*pt2 + den(11)*p1    + den(12)*p2*pt3 + &
316           den(13)*p3*pt1                                                      &
317         )
318
319
320    END FUNCTION eqn_state_seawater_func
321
322 END MODULE eqn_state_seawater_mod
Note: See TracBrowser for help on using the repository browser.