source: palm/trunk/SOURCE/eqn_state_seawater.f90 @ 1036

Last change on this file since 1036 was 1036, checked in by raasch, 9 years ago

code has been put under the GNU General Public License (v3)

  • Property svn:keywords set to Id
File size: 8.6 KB
Line 
1 MODULE eqn_state_seawater_mod
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: eqn_state_seawater.f90 1036 2012-10-22 13:43:42Z raasch $
27!
28! 388 2009-09-23 09:40:33Z raasch
29! Potential density is additionally calculated in eqn_state_seawater,
30! first constant in array den also defined as type double.
31!
32! 97 2007-06-21 08:23:15Z raasch
33! Initial revision
34!
35!
36! Description:
37! ------------
38! Equation of state for seawater as a function of potential temperature,
39! salinity, and pressure.
40! For coefficients see Jackett et al., 2006: J. Atm. Ocean Tech.
41! eqn_state_seawater calculates the potential density referred at hyp(0).
42! eqn_state_seawater_func calculates density.
43!------------------------------------------------------------------------------!
44
45    IMPLICIT NONE
46
47    PRIVATE
48    PUBLIC eqn_state_seawater, eqn_state_seawater_func
49
50    REAL, DIMENSION(12), PARAMETER ::  nom =                             &
51                      (/ 9.9984085444849347D2,   7.3471625860981584D0,   &
52                        -5.3211231792841769D-2,  3.6492439109814549D-4,  &
53                         2.5880571023991390D0,  -6.7168282786692354D-3,  &
54                         1.9203202055760151D-3,  1.1798263740430364D-2,  &
55                         9.8920219266399117D-8,  4.6996642771754730D-6,  &
56                        -2.5862187075154352D-8, -3.2921414007960662D-12 /)
57
58    REAL, DIMENSION(13), PARAMETER ::  den =                             &
59                      (/ 1.0D0,                  7.2815210113327091D-3,  &
60                        -4.4787265461983921D-5,  3.3851002965802430D-7,  &
61                         1.3651202389758572D-10, 1.7632126669040377D-3,  &
62                        -8.8066583251206474D-6, -1.8832689434804897D-10, &
63                         5.7463776745432097D-6,  1.4716275472242334D-9,  &
64                         6.7103246285651894D-6, -2.4461698007024582D-17, &
65                        -9.1534417604289062D-18 /)
66
67    INTERFACE eqn_state_seawater
68       MODULE PROCEDURE eqn_state_seawater
69       MODULE PROCEDURE eqn_state_seawater_ij
70    END INTERFACE eqn_state_seawater
71 
72    INTERFACE eqn_state_seawater_func
73       MODULE PROCEDURE eqn_state_seawater_func
74    END INTERFACE eqn_state_seawater_func
75 
76 CONTAINS
77
78
79!------------------------------------------------------------------------------!
80! Call for all grid points
81!------------------------------------------------------------------------------!
82    SUBROUTINE eqn_state_seawater
83
84       USE arrays_3d
85       USE indices
86
87       IMPLICIT NONE
88
89       INTEGER ::  i, j, k
90
91       REAL ::  pden, pnom, p1, p2, p3, pt1, pt2, pt3, pt4, sa1, sa15, sa2
92
93       DO  i = nxl, nxr
94          DO  j = nys, nyn
95             DO  k = nzb_s_inner(j,i)+1, nzt
96!
97!--             Pressure is needed in dbar
98                p1 = hyp(k) * 1E-4
99                p2 = p1 * p1
100                p3 = p2 * p1
101
102!
103!--             Temperature needed in degree Celsius
104                pt1 = pt_p(k,j,i) - 273.15
105                pt2 = pt1 * pt1
106                pt3 = pt1 * pt2
107                pt4 = pt2 * pt2
108
109                sa1  = sa_p(k,j,i)
110                sa15 = sa1 * SQRT( sa1 )
111                sa2  = sa1 * sa1
112
113                pnom = nom(1)           + nom(2)*pt1     + nom(3)*pt2     + &
114                       nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 + &
115                       nom(7)*sa2
116
117                pden = den(1)           + den(2)*pt1     + den(3)*pt2     + &
118                       den(4)*pt3       + den(5)*pt4     + den(6)*sa1     + &
119                       den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    + &
120                       den(10)*sa15*pt2
121
122!
123!--             Potential density (without pressure terms)
124                prho(k,j,i) = pnom / pden
125
126                pnom = pnom +             nom(8)*p1      + nom(9)*p1*pt2  + &
127                       nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2
128
129                pden = pden +             den(11)*p1     + den(12)*p2*pt3 + &
130                       den(13)*p3*pt1
131
132!
133!--             In-situ density
134                rho(k,j,i) = pnom / pden
135
136             ENDDO
137!
138!--          Neumann conditions are assumed at bottom and top boundary
139             prho(nzt+1,j,i)            = prho(nzt,j,i)
140             prho(nzb_s_inner(j,i),j,i) = prho(nzb_s_inner(j,i)+1,j,i)
141             rho(nzt+1,j,i)             = rho(nzt,j,i)
142             rho(nzb_s_inner(j,i),j,i)  = rho(nzb_s_inner(j,i)+1,j,i)
143
144          ENDDO
145       ENDDO
146
147    END SUBROUTINE eqn_state_seawater
148
149
150!------------------------------------------------------------------------------!
151! Call for grid point i,j
152!------------------------------------------------------------------------------!
153    SUBROUTINE eqn_state_seawater_ij( i, j )
154
155       USE arrays_3d
156       USE indices
157
158       IMPLICIT NONE
159
160       INTEGER ::  i, j, k
161
162       REAL ::  pden, pnom, p1, p2, p3, pt1, pt2, pt3, pt4, sa1, sa15, sa2
163
164       DO  k = nzb_s_inner(j,i)+1, nzt
165!
166!--       Pressure is needed in dbar
167          p1 = hyp(k) * 1E-4
168          p2 = p1 * p1
169          p3 = p2 * p1
170
171!
172!--       Temperature needed in degree Celsius
173          pt1 = pt_p(k,j,i) - 273.15
174          pt2 = pt1 * pt1
175          pt3 = pt1 * pt2
176          pt4 = pt2 * pt2
177
178          sa1  = sa_p(k,j,i)
179          sa15 = sa1 * SQRT( sa1 )
180          sa2  = sa1 * sa1
181
182          pnom = nom(1)           + nom(2)*pt1     + nom(3)*pt2     + &
183                 nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 + &
184                 nom(7)*sa2
185
186          pden = den(1)           + den(2)*pt1     + den(3)*pt2     + &
187                 den(4)*pt3       + den(5)*pt4     + den(6)*sa1     + &
188                 den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    + &
189                 den(10)*sa15*pt2
190
191!
192!--       Potential density (without pressure terms)
193          prho(k,j,i) = pnom / pden
194
195          pnom = pnom +             nom(8)*p1      + nom(9)*p1*pt2  + &
196                 nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2
197          pden = pden +             den(11)*p1     + den(12)*p2*pt3 + &
198                 den(13)*p3*pt1
199
200!
201!--       In-situ density
202          rho(k,j,i) = pnom / pden
203
204
205       ENDDO
206
207!
208!--    Neumann conditions are assumed at bottom and top boundary
209       prho(nzt+1,j,i)            = prho(nzt,j,i)
210       prho(nzb_s_inner(j,i),j,i) = prho(nzb_s_inner(j,i)+1,j,i)
211       rho(nzt+1,j,i)             = rho(nzt,j,i)
212       rho(nzb_s_inner(j,i),j,i)  = rho(nzb_s_inner(j,i)+1,j,i)
213
214    END SUBROUTINE eqn_state_seawater_ij
215
216
217!------------------------------------------------------------------------------!
218! Equation of state as a function
219!------------------------------------------------------------------------------!
220    REAL FUNCTION eqn_state_seawater_func( p, pt, sa )
221
222       IMPLICIT NONE
223
224       REAL ::  p, p1, p2, p3, pt, pt1, pt2, pt3, pt4, sa, sa15, sa2
225
226!
227!--    Pressure is needed in dbar
228       p1 = p  * 1E-4
229       p2 = p1 * p1
230       p3 = p2 * p1
231
232!
233!--    Temperature needed in degree Celsius
234       pt1 = pt - 273.15
235       pt2 = pt1 * pt1
236       pt3 = pt1 * pt2
237       pt4 = pt2 * pt2
238
239       sa15 = sa * SQRT( sa )
240       sa2  = sa * sa
241
242
243       eqn_state_seawater_func =                                               &
244         ( nom(1)        + nom(2)*pt1       + nom(3)*pt2    + nom(4)*pt3     + &
245           nom(5)*sa     + nom(6)*sa*pt1    + nom(7)*sa2    + nom(8)*p1      + &
246           nom(9)*p1*pt2 + nom(10)*p1*sa    + nom(11)*p2    + nom(12)*p2*pt2   &
247         ) /                                                                   &
248         ( den(1)        + den(2)*pt1       + den(3)*pt2    + den(4)*pt3     + &
249           den(5)*pt4    + den(6)*sa        + den(7)*sa*pt1 + den(8)*sa*pt3  + &
250           den(9)*sa15   + den(10)*sa15*pt2 + den(11)*p1    + den(12)*p2*pt3 + &
251           den(13)*p3*pt1                                                      &
252         )
253
254
255    END FUNCTION eqn_state_seawater_func
256
257 END MODULE eqn_state_seawater_mod
Note: See TracBrowser for help on using the repository browser.