source: palm/trunk/SOURCE/diffusion_w_mod.f90 @ 1850

Last change on this file since 1850 was 1850, checked in by maronga, 5 years ago

added _mod string to several filenames to meet the naming convection for modules

  • Property svn:keywords set to Id
File size: 22.7 KB
Line 
1!> @file diffusion_w_mod.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! Module renamed
22!
23!
24! Former revisions:
25! -----------------
26! $Id: diffusion_w_mod.f90 1850 2016-04-08 13:29:27Z maronga $
27!
28! 1682 2015-10-07 23:56:08Z knoop
29! Code annotations made doxygen readable
30!
31! 1374 2014-04-25 12:55:07Z raasch
32! vsws + vswst removed from acc-present-list
33!
34! 1353 2014-04-08 15:21:23Z heinze
35! REAL constants provided with KIND-attribute
36!
37! 1340 2014-03-25 19:45:13Z kanani
38! REAL constants defined as wp-kind
39!
40! 1322 2014-03-20 16:38:49Z raasch
41! REAL constants defined as wp-kind
42!
43! 1320 2014-03-20 08:40:49Z raasch
44! ONLY-attribute added to USE-statements,
45! kind-parameters added to all INTEGER and REAL declaration statements,
46! kinds are defined in new module kinds,
47! revision history before 2012 removed,
48! comment fields (!:) to be used for variable explanations added to
49! all variable declaration statements
50!
51! 1257 2013-11-08 15:18:40Z raasch
52! openacc loop and loop vector clauses removed, declare create moved after
53! the FORTRAN declaration statement
54!
55! 1128 2013-04-12 06:19:32Z raasch
56! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
57! j_north
58!
59! 1036 2012-10-22 13:43:42Z raasch
60! code put under GPL (PALM 3.9)
61!
62! 1015 2012-09-27 09:23:24Z raasch
63! accelerator version (*_acc) added
64!
65! 1001 2012-09-13 14:08:46Z raasch
66! arrays comunicated by module instead of parameter list
67!
68! 978 2012-08-09 08:28:32Z fricke
69! outflow damping layer removed
70! kmxm_x/_z and kmxp_x/_z change to kmxm and kmxp
71! kmym_y/_z and kmyp_y/_z change to kmym and kmyp
72!
73! Revision 1.1  1997/09/12 06:24:11  raasch
74! Initial revision
75!
76!
77! Description:
78! ------------
79!> Diffusion term of the w-component
80!------------------------------------------------------------------------------!
81 MODULE diffusion_w_mod
82 
83
84    USE wall_fluxes_mod,                                                       &
85        ONLY :  wall_fluxes, wall_fluxes_acc
86
87    PRIVATE
88    PUBLIC diffusion_w, diffusion_w_acc
89
90    INTERFACE diffusion_w
91       MODULE PROCEDURE diffusion_w
92       MODULE PROCEDURE diffusion_w_ij
93    END INTERFACE diffusion_w
94
95    INTERFACE diffusion_w_acc
96       MODULE PROCEDURE diffusion_w_acc
97    END INTERFACE diffusion_w_acc
98
99 CONTAINS
100
101
102!------------------------------------------------------------------------------!
103! Description:
104! ------------
105!> Call for all grid points
106!------------------------------------------------------------------------------!
107    SUBROUTINE diffusion_w
108
109       USE arrays_3d,                                                          &         
110           ONLY :  ddzu, ddzw, km, tend, u, v, w
111           
112       USE control_parameters,                                                 & 
113           ONLY :  topography
114           
115       USE grid_variables,                                                     &     
116           ONLY :  ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
117           
118       USE indices,                                                            &           
119           ONLY :  nxl, nxr, nyn, nys, nzb, nzb_w_inner, nzb_w_outer, nzt
120           
121       USE kinds
122
123       IMPLICIT NONE
124
125       INTEGER(iwp) ::  i     !<
126       INTEGER(iwp) ::  j     !<
127       INTEGER(iwp) ::  k     !<
128       
129       REAL(wp) ::  kmxm  !<
130       REAL(wp) ::  kmxp  !<
131       REAL(wp) ::  kmym  !<
132       REAL(wp) ::  kmyp  !<
133
134       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsus  !<
135       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsvs  !<
136
137
138!
139!--    First calculate horizontal momentum flux w'u' and/or w'v' at vertical
140!--    walls, if neccessary
141       IF ( topography /= 'flat' )  THEN
142          CALL wall_fluxes( wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp, nzb_w_inner,             &
143                            nzb_w_outer, wall_w_x )
144          CALL wall_fluxes( wsvs, 0.0_wp, 0.0_wp, 1.0_wp, 0.0_wp, nzb_w_inner,             &
145                            nzb_w_outer, wall_w_y )
146       ENDIF
147
148       DO  i = nxl, nxr
149          DO  j = nys, nyn
150             DO  k = nzb_w_outer(j,i)+1, nzt-1
151!
152!--             Interpolate eddy diffusivities on staggered gridpoints
153                kmxp = 0.25_wp *                                               &
154                       ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
155                kmxm = 0.25_wp *                                               &
156                       ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
157                kmyp = 0.25_wp *                                               &
158                       ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
159                kmym = 0.25_wp *                                               &
160                       ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
161
162                tend(k,j,i) = tend(k,j,i)                                      &
163                      & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
164                      &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
165                      &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx           &
166                      &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)     &
167                      &   ) * ddx                                              &
168                      & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
169                      &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
170                      &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy           &
171                      &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)     &
172                      &   ) * ddy                                              &
173                      & + 2.0_wp * (                                           &
174                      &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)  &
175                      & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k)  &
176                      &            ) * ddzu(k+1)
177             ENDDO
178
179!
180!--          Wall functions at all vertical walls, where necessary
181             IF ( wall_w_x(j,i) /= 0.0_wp  .OR.  wall_w_y(j,i) /= 0.0_wp )  THEN
182
183                DO  k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i)
184!
185!--                Interpolate eddy diffusivities on staggered gridpoints
186                   kmxp = 0.25_wp *                                            &
187                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
188                   kmxm = 0.25_wp *                                            &
189                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
190                   kmyp = 0.25_wp *                                            &
191                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
192                   kmym = 0.25_wp *                                            &
193                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
194
195                   tend(k,j,i) = tend(k,j,i)                                   &
196                                 + (   fwxp(j,i) * (                           &
197                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
198                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
199                                                   )                           &
200                                     - fwxm(j,i) * (                           &
201                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
202                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
203                                                   )                           &
204                                     + wall_w_x(j,i) * wsus(k,j,i)             &
205                                   ) * ddx                                     &
206                                 + (   fwyp(j,i) * (                           &
207                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
208                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
209                                                   )                           &
210                                     - fwym(j,i) * (                           &
211                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
212                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
213                                                   )                           &
214                                     + wall_w_y(j,i) * wsvs(k,j,i)             &
215                                   ) * ddy                                     &
216                                 + 2.0_wp * (                                  &
217                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
218                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
219                                            ) * ddzu(k+1)
220                ENDDO
221             ENDIF
222
223          ENDDO
224       ENDDO
225
226    END SUBROUTINE diffusion_w
227
228
229!------------------------------------------------------------------------------!
230! Description:
231! ------------
232!> Call for all grid points - accelerator version
233!------------------------------------------------------------------------------!
234    SUBROUTINE diffusion_w_acc
235
236       USE arrays_3d,                                                          &
237           ONLY :  ddzu, ddzw, km, tend, u, v, w
238           
239       USE control_parameters,                                                 &
240           ONLY :  topography
241           
242       USE grid_variables,                                                     &
243           ONLY : ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
244           
245       USE indices,                                                            &
246           ONLY :  i_left, i_right, j_north, j_south, nxl, nxr, nyn, nys, nzb, &
247                   nzb_w_inner, nzb_w_outer, nzt
248                   
249       USE kinds
250
251       IMPLICIT NONE
252
253       INTEGER(iwp) ::  i     !<
254       INTEGER(iwp) ::  j     !<
255       INTEGER(iwp) ::  k     !<
256       
257       REAL(wp) ::  kmxm  !<
258       REAL(wp) ::  kmxp  !<
259       REAL(wp) ::  kmym  !<
260       REAL(wp) ::  kmyp  !<
261
262       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsus  !<
263       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsvs  !<
264       !$acc declare create ( wsus, wsvs )
265
266!
267!--    First calculate horizontal momentum flux w'u' and/or w'v' at vertical
268!--    walls, if neccessary
269       IF ( topography /= 'flat' )  THEN
270          CALL wall_fluxes_acc( wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp,          &
271                                nzb_w_inner, nzb_w_outer, wall_w_x )
272          CALL wall_fluxes_acc( wsvs, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp,          &
273                                nzb_w_inner, nzb_w_outer, wall_w_y )
274       ENDIF
275
276       !$acc kernels present ( u, v, w, km, tend )                             &
277       !$acc         present ( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y )           &
278       !$acc         present ( nzb_w_inner, nzb_w_outer )
279       DO  i = i_left, i_right
280          DO  j = j_south, j_north
281             DO  k = 1, nzt
282                IF ( k > nzb_w_outer(j,i) )  THEN
283!
284!--                Interpolate eddy diffusivities on staggered gridpoints
285                   kmxp = 0.25_wp *                                            &
286                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
287                   kmxm = 0.25_wp *                                            &
288                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
289                   kmyp = 0.25_wp *                                            &
290                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
291                   kmym = 0.25_wp *                                            &
292                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
293
294                   tend(k,j,i) = tend(k,j,i)                                     &
295                         & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx        &
296                         &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)  &
297                         &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx          &
298                         &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)    &
299                         &   ) * ddx                                             &
300                         & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy        &
301                         &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)  &
302                         &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy          &
303                         &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)    &
304                         &   ) * ddy                                             &
305                         & + 2.0_wp * (                                          &
306                         &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
307                         & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
308                         &            ) * ddzu(k+1)
309                ENDIF
310             ENDDO
311
312!
313!--          Wall functions at all vertical walls, where necessary
314             DO  k = 1,nzt
315
316                IF ( k > nzb_w_inner(j,i)  .AND.  k <= nzb_w_outer(j,i)  .AND. &
317                     wall_w_x(j,i) /= 0.0_wp  .AND.  wall_w_y(j,i) /= 0.0_wp )  THEN
318!
319!--                Interpolate eddy diffusivities on staggered gridpoints
320                   kmxp = 0.25_wp *                                            &
321                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
322                   kmxm = 0.25_wp *                                            &
323                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
324                   kmyp = 0.25_wp *                                            &
325                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
326                   kmym = 0.25_wp *                                            &
327                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
328
329                   tend(k,j,i) = tend(k,j,i)                                   &
330                                 + (   fwxp(j,i) * (                           &
331                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
332                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
333                                                   )                           &
334                                     - fwxm(j,i) * (                           &
335                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
336                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
337                                                   )                           &
338                                     + wall_w_x(j,i) * wsus(k,j,i)             &
339                                   ) * ddx                                     &
340                                 + (   fwyp(j,i) * (                           &
341                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
342                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
343                                                   )                           &
344                                     - fwym(j,i) * (                           &
345                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
346                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
347                                                   )                           &
348                                     + wall_w_y(j,i) * wsvs(k,j,i)             &
349                                   ) * ddy                                     &
350                                 + 2.0_wp * (                                  &
351                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
352                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
353                                            ) * ddzu(k+1)
354                ENDIF
355             ENDDO
356
357          ENDDO
358       ENDDO
359       !$acc end kernels
360
361    END SUBROUTINE diffusion_w_acc
362
363
364!------------------------------------------------------------------------------!
365! Description:
366! ------------
367!> Call for grid point i,j
368!------------------------------------------------------------------------------!
369    SUBROUTINE diffusion_w_ij( i, j )
370
371       USE arrays_3d,                                                          &         
372           ONLY :  ddzu, ddzw, km, tend, u, v, w
373           
374       USE control_parameters,                                                 & 
375           ONLY :  topography
376           
377       USE grid_variables,                                                     &     
378           ONLY :  ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
379           
380       USE indices,                                                            &           
381           ONLY :  nxl, nxr, nyn, nys, nzb, nzb_w_inner, nzb_w_outer, nzt
382           
383       USE kinds
384
385       IMPLICIT NONE
386
387       INTEGER(iwp) ::  i     !<
388       INTEGER(iwp) ::  j     !<
389       INTEGER(iwp) ::  k     !<
390       
391       REAL(wp) ::  kmxm  !<
392       REAL(wp) ::  kmxp  !<
393       REAL(wp) ::  kmym  !<
394       REAL(wp) ::  kmyp  !<
395
396       REAL(wp), DIMENSION(nzb:nzt+1) ::  wsus
397       REAL(wp), DIMENSION(nzb:nzt+1) ::  wsvs
398
399
400       DO  k = nzb_w_outer(j,i)+1, nzt-1
401!
402!--       Interpolate eddy diffusivities on staggered gridpoints
403          kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
404          kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
405          kmyp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
406          kmym = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
407
408          tend(k,j,i) = tend(k,j,i)                                            &
409                      & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
410                      &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
411                      &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx           &
412                      &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)     &
413                      &   ) * ddx                                              &
414                      & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
415                      &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
416                      &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy           &
417                      &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)     &
418                      &   ) * ddy                                              &
419                      & + 2.0_wp * (                                           &
420                      &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)  &
421                      & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k)  &
422                      &            ) * ddzu(k+1)
423       ENDDO
424
425!
426!--    Wall functions at all vertical walls, where necessary
427       IF ( wall_w_x(j,i) /= 0.0_wp  .OR.  wall_w_y(j,i) /= 0.0_wp )  THEN
428
429!
430!--       Calculate the horizontal momentum fluxes w'u' and/or w'v'
431          IF ( wall_w_x(j,i) /= 0.0_wp )  THEN
432             CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i),     &
433                               wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp )
434          ELSE
435             wsus = 0.0_wp
436          ENDIF
437
438          IF ( wall_w_y(j,i) /= 0.0_wp )  THEN
439             CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i),     &
440                               wsvs, 0.0_wp, 0.0_wp, 1.0_wp, 0.0_wp )
441          ELSE
442             wsvs = 0.0_wp
443          ENDIF
444
445          DO  k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i)
446!
447!--          Interpolate eddy diffusivities on staggered gridpoints
448             kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
449             kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
450             kmyp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
451             kmym = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
452
453             tend(k,j,i) = tend(k,j,i)                                         &
454                                 + (   fwxp(j,i) * (                           &
455                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
456                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
457                                                   )                           &
458                                     - fwxm(j,i) * (                           &
459                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
460                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
461                                                   )                           &
462                                     + wall_w_x(j,i) * wsus(k)                 &
463                                   ) * ddx                                     &
464                                 + (   fwyp(j,i) * (                           &
465                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
466                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
467                                                   )                           &
468                                     - fwym(j,i) * (                           &
469                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
470                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
471                                                   )                           &
472                                     + wall_w_y(j,i) * wsvs(k)                 &
473                                   ) * ddy                                     &
474                                 + 2.0_wp * (                                  &
475                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
476                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
477                                            ) * ddzu(k+1)
478          ENDDO
479       ENDIF
480
481    END SUBROUTINE diffusion_w_ij
482
483 END MODULE diffusion_w_mod
Note: See TracBrowser for help on using the repository browser.