source: palm/trunk/SOURCE/diffusion_w.f90 @ 1873

Last change on this file since 1873 was 1873, checked in by maronga, 5 years ago

revised renaming of modules

  • Property svn:keywords set to Id
File size: 22.8 KB
Line 
1!> @file diffusion_w.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! Module renamed (removed _mod)
22!
23!
24! Former revisions:
25! -----------------
26! $Id: diffusion_w.f90 1873 2016-04-18 14:50:06Z maronga $
27!
28! 1850 2016-04-08 13:29:27Z maronga
29! Module renamed
30!
31!
32! 1682 2015-10-07 23:56:08Z knoop
33! Code annotations made doxygen readable
34!
35! 1374 2014-04-25 12:55:07Z raasch
36! vsws + vswst removed from acc-present-list
37!
38! 1353 2014-04-08 15:21:23Z heinze
39! REAL constants provided with KIND-attribute
40!
41! 1340 2014-03-25 19:45:13Z kanani
42! REAL constants defined as wp-kind
43!
44! 1322 2014-03-20 16:38:49Z raasch
45! REAL constants defined as wp-kind
46!
47! 1320 2014-03-20 08:40:49Z raasch
48! ONLY-attribute added to USE-statements,
49! kind-parameters added to all INTEGER and REAL declaration statements,
50! kinds are defined in new module kinds,
51! revision history before 2012 removed,
52! comment fields (!:) to be used for variable explanations added to
53! all variable declaration statements
54!
55! 1257 2013-11-08 15:18:40Z raasch
56! openacc loop and loop vector clauses removed, declare create moved after
57! the FORTRAN declaration statement
58!
59! 1128 2013-04-12 06:19:32Z raasch
60! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
61! j_north
62!
63! 1036 2012-10-22 13:43:42Z raasch
64! code put under GPL (PALM 3.9)
65!
66! 1015 2012-09-27 09:23:24Z raasch
67! accelerator version (*_acc) added
68!
69! 1001 2012-09-13 14:08:46Z raasch
70! arrays comunicated by module instead of parameter list
71!
72! 978 2012-08-09 08:28:32Z fricke
73! outflow damping layer removed
74! kmxm_x/_z and kmxp_x/_z change to kmxm and kmxp
75! kmym_y/_z and kmyp_y/_z change to kmym and kmyp
76!
77! Revision 1.1  1997/09/12 06:24:11  raasch
78! Initial revision
79!
80!
81! Description:
82! ------------
83!> Diffusion term of the w-component
84!------------------------------------------------------------------------------!
85 MODULE diffusion_w_mod
86 
87
88    USE wall_fluxes_mod,                                                       &
89        ONLY :  wall_fluxes, wall_fluxes_acc
90
91    PRIVATE
92    PUBLIC diffusion_w, diffusion_w_acc
93
94    INTERFACE diffusion_w
95       MODULE PROCEDURE diffusion_w
96       MODULE PROCEDURE diffusion_w_ij
97    END INTERFACE diffusion_w
98
99    INTERFACE diffusion_w_acc
100       MODULE PROCEDURE diffusion_w_acc
101    END INTERFACE diffusion_w_acc
102
103 CONTAINS
104
105
106!------------------------------------------------------------------------------!
107! Description:
108! ------------
109!> Call for all grid points
110!------------------------------------------------------------------------------!
111    SUBROUTINE diffusion_w
112
113       USE arrays_3d,                                                          &         
114           ONLY :  ddzu, ddzw, km, tend, u, v, w
115           
116       USE control_parameters,                                                 & 
117           ONLY :  topography
118           
119       USE grid_variables,                                                     &     
120           ONLY :  ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
121           
122       USE indices,                                                            &           
123           ONLY :  nxl, nxr, nyn, nys, nzb, nzb_w_inner, nzb_w_outer, nzt
124           
125       USE kinds
126
127       IMPLICIT NONE
128
129       INTEGER(iwp) ::  i     !<
130       INTEGER(iwp) ::  j     !<
131       INTEGER(iwp) ::  k     !<
132       
133       REAL(wp) ::  kmxm  !<
134       REAL(wp) ::  kmxp  !<
135       REAL(wp) ::  kmym  !<
136       REAL(wp) ::  kmyp  !<
137
138       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsus  !<
139       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsvs  !<
140
141
142!
143!--    First calculate horizontal momentum flux w'u' and/or w'v' at vertical
144!--    walls, if neccessary
145       IF ( topography /= 'flat' )  THEN
146          CALL wall_fluxes( wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp, nzb_w_inner,             &
147                            nzb_w_outer, wall_w_x )
148          CALL wall_fluxes( wsvs, 0.0_wp, 0.0_wp, 1.0_wp, 0.0_wp, nzb_w_inner,             &
149                            nzb_w_outer, wall_w_y )
150       ENDIF
151
152       DO  i = nxl, nxr
153          DO  j = nys, nyn
154             DO  k = nzb_w_outer(j,i)+1, nzt-1
155!
156!--             Interpolate eddy diffusivities on staggered gridpoints
157                kmxp = 0.25_wp *                                               &
158                       ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
159                kmxm = 0.25_wp *                                               &
160                       ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
161                kmyp = 0.25_wp *                                               &
162                       ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
163                kmym = 0.25_wp *                                               &
164                       ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
165
166                tend(k,j,i) = tend(k,j,i)                                      &
167                      & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
168                      &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
169                      &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx           &
170                      &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)     &
171                      &   ) * ddx                                              &
172                      & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
173                      &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
174                      &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy           &
175                      &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)     &
176                      &   ) * ddy                                              &
177                      & + 2.0_wp * (                                           &
178                      &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)  &
179                      & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k)  &
180                      &            ) * ddzu(k+1)
181             ENDDO
182
183!
184!--          Wall functions at all vertical walls, where necessary
185             IF ( wall_w_x(j,i) /= 0.0_wp  .OR.  wall_w_y(j,i) /= 0.0_wp )  THEN
186
187                DO  k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i)
188!
189!--                Interpolate eddy diffusivities on staggered gridpoints
190                   kmxp = 0.25_wp *                                            &
191                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
192                   kmxm = 0.25_wp *                                            &
193                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
194                   kmyp = 0.25_wp *                                            &
195                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
196                   kmym = 0.25_wp *                                            &
197                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
198
199                   tend(k,j,i) = tend(k,j,i)                                   &
200                                 + (   fwxp(j,i) * (                           &
201                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
202                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
203                                                   )                           &
204                                     - fwxm(j,i) * (                           &
205                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
206                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
207                                                   )                           &
208                                     + wall_w_x(j,i) * wsus(k,j,i)             &
209                                   ) * ddx                                     &
210                                 + (   fwyp(j,i) * (                           &
211                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
212                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
213                                                   )                           &
214                                     - fwym(j,i) * (                           &
215                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
216                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
217                                                   )                           &
218                                     + wall_w_y(j,i) * wsvs(k,j,i)             &
219                                   ) * ddy                                     &
220                                 + 2.0_wp * (                                  &
221                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
222                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
223                                            ) * ddzu(k+1)
224                ENDDO
225             ENDIF
226
227          ENDDO
228       ENDDO
229
230    END SUBROUTINE diffusion_w
231
232
233!------------------------------------------------------------------------------!
234! Description:
235! ------------
236!> Call for all grid points - accelerator version
237!------------------------------------------------------------------------------!
238    SUBROUTINE diffusion_w_acc
239
240       USE arrays_3d,                                                          &
241           ONLY :  ddzu, ddzw, km, tend, u, v, w
242           
243       USE control_parameters,                                                 &
244           ONLY :  topography
245           
246       USE grid_variables,                                                     &
247           ONLY : ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
248           
249       USE indices,                                                            &
250           ONLY :  i_left, i_right, j_north, j_south, nxl, nxr, nyn, nys, nzb, &
251                   nzb_w_inner, nzb_w_outer, nzt
252                   
253       USE kinds
254
255       IMPLICIT NONE
256
257       INTEGER(iwp) ::  i     !<
258       INTEGER(iwp) ::  j     !<
259       INTEGER(iwp) ::  k     !<
260       
261       REAL(wp) ::  kmxm  !<
262       REAL(wp) ::  kmxp  !<
263       REAL(wp) ::  kmym  !<
264       REAL(wp) ::  kmyp  !<
265
266       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsus  !<
267       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsvs  !<
268       !$acc declare create ( wsus, wsvs )
269
270!
271!--    First calculate horizontal momentum flux w'u' and/or w'v' at vertical
272!--    walls, if neccessary
273       IF ( topography /= 'flat' )  THEN
274          CALL wall_fluxes_acc( wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp,          &
275                                nzb_w_inner, nzb_w_outer, wall_w_x )
276          CALL wall_fluxes_acc( wsvs, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp,          &
277                                nzb_w_inner, nzb_w_outer, wall_w_y )
278       ENDIF
279
280       !$acc kernels present ( u, v, w, km, tend )                             &
281       !$acc         present ( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y )           &
282       !$acc         present ( nzb_w_inner, nzb_w_outer )
283       DO  i = i_left, i_right
284          DO  j = j_south, j_north
285             DO  k = 1, nzt
286                IF ( k > nzb_w_outer(j,i) )  THEN
287!
288!--                Interpolate eddy diffusivities on staggered gridpoints
289                   kmxp = 0.25_wp *                                            &
290                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
291                   kmxm = 0.25_wp *                                            &
292                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
293                   kmyp = 0.25_wp *                                            &
294                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
295                   kmym = 0.25_wp *                                            &
296                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
297
298                   tend(k,j,i) = tend(k,j,i)                                     &
299                         & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx        &
300                         &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)  &
301                         &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx          &
302                         &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)    &
303                         &   ) * ddx                                             &
304                         & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy        &
305                         &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)  &
306                         &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy          &
307                         &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)    &
308                         &   ) * ddy                                             &
309                         & + 2.0_wp * (                                          &
310                         &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
311                         & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
312                         &            ) * ddzu(k+1)
313                ENDIF
314             ENDDO
315
316!
317!--          Wall functions at all vertical walls, where necessary
318             DO  k = 1,nzt
319
320                IF ( k > nzb_w_inner(j,i)  .AND.  k <= nzb_w_outer(j,i)  .AND. &
321                     wall_w_x(j,i) /= 0.0_wp  .AND.  wall_w_y(j,i) /= 0.0_wp )  THEN
322!
323!--                Interpolate eddy diffusivities on staggered gridpoints
324                   kmxp = 0.25_wp *                                            &
325                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
326                   kmxm = 0.25_wp *                                            &
327                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
328                   kmyp = 0.25_wp *                                            &
329                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
330                   kmym = 0.25_wp *                                            &
331                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
332
333                   tend(k,j,i) = tend(k,j,i)                                   &
334                                 + (   fwxp(j,i) * (                           &
335                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
336                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
337                                                   )                           &
338                                     - fwxm(j,i) * (                           &
339                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
340                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
341                                                   )                           &
342                                     + wall_w_x(j,i) * wsus(k,j,i)             &
343                                   ) * ddx                                     &
344                                 + (   fwyp(j,i) * (                           &
345                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
346                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
347                                                   )                           &
348                                     - fwym(j,i) * (                           &
349                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
350                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
351                                                   )                           &
352                                     + wall_w_y(j,i) * wsvs(k,j,i)             &
353                                   ) * ddy                                     &
354                                 + 2.0_wp * (                                  &
355                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
356                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
357                                            ) * ddzu(k+1)
358                ENDIF
359             ENDDO
360
361          ENDDO
362       ENDDO
363       !$acc end kernels
364
365    END SUBROUTINE diffusion_w_acc
366
367
368!------------------------------------------------------------------------------!
369! Description:
370! ------------
371!> Call for grid point i,j
372!------------------------------------------------------------------------------!
373    SUBROUTINE diffusion_w_ij( i, j )
374
375       USE arrays_3d,                                                          &         
376           ONLY :  ddzu, ddzw, km, tend, u, v, w
377           
378       USE control_parameters,                                                 & 
379           ONLY :  topography
380           
381       USE grid_variables,                                                     &     
382           ONLY :  ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
383           
384       USE indices,                                                            &           
385           ONLY :  nxl, nxr, nyn, nys, nzb, nzb_w_inner, nzb_w_outer, nzt
386           
387       USE kinds
388
389       IMPLICIT NONE
390
391       INTEGER(iwp) ::  i     !<
392       INTEGER(iwp) ::  j     !<
393       INTEGER(iwp) ::  k     !<
394       
395       REAL(wp) ::  kmxm  !<
396       REAL(wp) ::  kmxp  !<
397       REAL(wp) ::  kmym  !<
398       REAL(wp) ::  kmyp  !<
399
400       REAL(wp), DIMENSION(nzb:nzt+1) ::  wsus
401       REAL(wp), DIMENSION(nzb:nzt+1) ::  wsvs
402
403
404       DO  k = nzb_w_outer(j,i)+1, nzt-1
405!
406!--       Interpolate eddy diffusivities on staggered gridpoints
407          kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
408          kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
409          kmyp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
410          kmym = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
411
412          tend(k,j,i) = tend(k,j,i)                                            &
413                      & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
414                      &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
415                      &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx           &
416                      &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)     &
417                      &   ) * ddx                                              &
418                      & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
419                      &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
420                      &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy           &
421                      &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)     &
422                      &   ) * ddy                                              &
423                      & + 2.0_wp * (                                           &
424                      &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)  &
425                      & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k)  &
426                      &            ) * ddzu(k+1)
427       ENDDO
428
429!
430!--    Wall functions at all vertical walls, where necessary
431       IF ( wall_w_x(j,i) /= 0.0_wp  .OR.  wall_w_y(j,i) /= 0.0_wp )  THEN
432
433!
434!--       Calculate the horizontal momentum fluxes w'u' and/or w'v'
435          IF ( wall_w_x(j,i) /= 0.0_wp )  THEN
436             CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i),     &
437                               wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp )
438          ELSE
439             wsus = 0.0_wp
440          ENDIF
441
442          IF ( wall_w_y(j,i) /= 0.0_wp )  THEN
443             CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i),     &
444                               wsvs, 0.0_wp, 0.0_wp, 1.0_wp, 0.0_wp )
445          ELSE
446             wsvs = 0.0_wp
447          ENDIF
448
449          DO  k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i)
450!
451!--          Interpolate eddy diffusivities on staggered gridpoints
452             kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
453             kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
454             kmyp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
455             kmym = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
456
457             tend(k,j,i) = tend(k,j,i)                                         &
458                                 + (   fwxp(j,i) * (                           &
459                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
460                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
461                                                   )                           &
462                                     - fwxm(j,i) * (                           &
463                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
464                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
465                                                   )                           &
466                                     + wall_w_x(j,i) * wsus(k)                 &
467                                   ) * ddx                                     &
468                                 + (   fwyp(j,i) * (                           &
469                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
470                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
471                                                   )                           &
472                                     - fwym(j,i) * (                           &
473                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
474                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
475                                                   )                           &
476                                     + wall_w_y(j,i) * wsvs(k)                 &
477                                   ) * ddy                                     &
478                                 + 2.0_wp * (                                  &
479                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
480                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
481                                            ) * ddzu(k+1)
482          ENDDO
483       ENDIF
484
485    END SUBROUTINE diffusion_w_ij
486
487 END MODULE diffusion_w_mod
Note: See TracBrowser for help on using the repository browser.