source: palm/trunk/SOURCE/diffusion_w.f90 @ 1128

Last change on this file since 1128 was 1128, checked in by raasch, 8 years ago

asynchronous transfer of ghost point data for acc-optimized version

  • Property svn:keywords set to Id
File size: 19.2 KB
Line 
1 MODULE diffusion_w_mod
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
23! j_north
24!
25! Former revisions:
26! -----------------
27! $Id: diffusion_w.f90 1128 2013-04-12 06:19:32Z raasch $
28!
29! 1036 2012-10-22 13:43:42Z raasch
30! code put under GPL (PALM 3.9)
31!
32! 1015 2012-09-27 09:23:24Z raasch
33! accelerator version (*_acc) added
34!
35! 1001 2012-09-13 14:08:46Z raasch
36! arrays comunicated by module instead of parameter list
37!
38! 978 2012-08-09 08:28:32Z fricke
39! outflow damping layer removed
40! kmxm_x/_z and kmxp_x/_z change to kmxm and kmxp
41! kmym_y/_z and kmyp_y/_z change to kmym and kmyp
42!
43! 667 2010-12-23 12:06:00Z suehring/gryschka
44! nxl-1, nxr+1, nys-1, nyn+1 replaced by nxlg, nxrg, nysg, nyng
45!
46! 366 2009-08-25 08:06:27Z raasch
47! bc_lr/bc_ns replaced by bc_lr_cyc/bc_ns_cyc
48!
49! 75 2007-03-22 09:54:05Z raasch
50! Wall functions now include diabatic conditions, call of routine wall_fluxes,
51! z0 removed from argument list
52!
53! 20 2007-02-26 00:12:32Z raasch
54! Bugfix: ddzw dimensioned 1:nzt"+1"
55!
56! RCS Log replace by Id keyword, revision history cleaned up
57!
58! Revision 1.12  2006/02/23 10:38:03  raasch
59! nzb_2d replaced by nzb_w_outer, wall functions added for all vertical walls,
60! +z0 in argument list
61! WARNING: loops containing the MAX function are still not properly vectorized!
62!
63! Revision 1.1  1997/09/12 06:24:11  raasch
64! Initial revision
65!
66!
67! Description:
68! ------------
69! Diffusion term of the w-component
70!------------------------------------------------------------------------------!
71
72    USE wall_fluxes_mod
73
74    PRIVATE
75    PUBLIC diffusion_w, diffusion_w_acc
76
77    INTERFACE diffusion_w
78       MODULE PROCEDURE diffusion_w
79       MODULE PROCEDURE diffusion_w_ij
80    END INTERFACE diffusion_w
81
82    INTERFACE diffusion_w_acc
83       MODULE PROCEDURE diffusion_w_acc
84    END INTERFACE diffusion_w_acc
85
86 CONTAINS
87
88
89!------------------------------------------------------------------------------!
90! Call for all grid points
91!------------------------------------------------------------------------------!
92    SUBROUTINE diffusion_w
93
94       USE arrays_3d
95       USE control_parameters
96       USE grid_variables
97       USE indices
98
99       IMPLICIT NONE
100
101       INTEGER ::  i, j, k
102       REAL    ::  kmxm, kmxp, kmym, kmyp
103
104       REAL, DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsus, wsvs
105
106
107!
108!--    First calculate horizontal momentum flux w'u' and/or w'v' at vertical
109!--    walls, if neccessary
110       IF ( topography /= 'flat' )  THEN
111          CALL wall_fluxes( wsus, 0.0, 0.0, 0.0, 1.0, nzb_w_inner, &
112                            nzb_w_outer, wall_w_x )
113          CALL wall_fluxes( wsvs, 0.0, 0.0, 1.0, 0.0, nzb_w_inner, &
114                            nzb_w_outer, wall_w_y )
115       ENDIF
116
117       DO  i = nxl, nxr
118          DO  j = nys, nyn
119             DO  k = nzb_w_outer(j,i)+1, nzt-1
120!
121!--             Interpolate eddy diffusivities on staggered gridpoints
122                kmxp = 0.25 * &
123                       ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
124                kmxm = 0.25 * &
125                       ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
126                kmyp = 0.25 * &
127                       ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
128                kmym = 0.25 * &
129                       ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
130
131                tend(k,j,i) = tend(k,j,i)                                      &
132                      & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
133                      &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
134                      &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx           &
135                      &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)     &
136                      &   ) * ddx                                              &
137                      & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
138                      &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
139                      &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy           &
140                      &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)     &
141                      &   ) * ddy                                              &
142                      & + 2.0 * (                                              &
143                      &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)  &
144                      & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k)  &
145                      &         ) * ddzu(k+1)
146             ENDDO
147
148!
149!--          Wall functions at all vertical walls, where necessary
150             IF ( wall_w_x(j,i) /= 0.0  .OR.  wall_w_y(j,i) /= 0.0 )  THEN
151
152                DO  k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i)
153!
154!--                Interpolate eddy diffusivities on staggered gridpoints
155                   kmxp = 0.25 * &
156                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
157                   kmxm = 0.25 * &
158                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
159                   kmyp = 0.25 * &
160                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
161                   kmym = 0.25 * &
162                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
163
164                   tend(k,j,i) = tend(k,j,i)                                   &
165                                 + (   fwxp(j,i) * (                           &
166                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
167                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
168                                                   )                           &
169                                     - fwxm(j,i) * (                           &
170                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
171                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
172                                                   )                           &
173                                     + wall_w_x(j,i) * wsus(k,j,i)             &
174                                   ) * ddx                                     &
175                                 + (   fwyp(j,i) * (                           &
176                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
177                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
178                                                   )                           &
179                                     - fwym(j,i) * (                           &
180                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
181                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
182                                                   )                           &
183                                     + wall_w_y(j,i) * wsvs(k,j,i)             &
184                                   ) * ddy                                     &
185                                 + 2.0 * (                                     &
186                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
187                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
188                                         ) * ddzu(k+1)
189                ENDDO
190             ENDIF
191
192          ENDDO
193       ENDDO
194
195    END SUBROUTINE diffusion_w
196
197
198!------------------------------------------------------------------------------!
199! Call for all grid points - accelerator version
200!------------------------------------------------------------------------------!
201    SUBROUTINE diffusion_w_acc
202
203       USE arrays_3d
204       USE control_parameters
205       USE grid_variables
206       USE indices
207
208       IMPLICIT NONE
209
210       INTEGER ::  i, j, k
211       REAL    ::  kmxm, kmxp, kmym, kmyp
212
213       !$acc declare create ( wsus, wsvs )
214       REAL, DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  wsus, wsvs
215
216
217!
218!--    First calculate horizontal momentum flux w'u' and/or w'v' at vertical
219!--    walls, if neccessary
220       IF ( topography /= 'flat' )  THEN
221          CALL wall_fluxes_acc( wsus, 0.0, 0.0, 0.0, 1.0, nzb_w_inner, &
222                                nzb_w_outer, wall_w_x )
223          CALL wall_fluxes_acc( wsvs, 0.0, 0.0, 1.0, 0.0, nzb_w_inner, &
224                                nzb_w_outer, wall_w_y )
225       ENDIF
226
227       !$acc kernels present ( u, v, w, km, tend, vsws, vswst )    &
228       !$acc         present ( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y )           &
229       !$acc         present ( nzb_w_inner, nzb_w_outer )
230       !$acc loop
231       DO  i = i_left, i_right
232          DO  j = j_south, j_north
233             !$acc loop vector( 32 )
234             DO  k = 1, nzt
235                IF ( k > nzb_w_outer(j,i) )  THEN
236!
237!--                Interpolate eddy diffusivities on staggered gridpoints
238                   kmxp = 0.25 * &
239                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
240                   kmxm = 0.25 * &
241                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
242                   kmyp = 0.25 * &
243                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
244                   kmym = 0.25 * &
245                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
246
247                   tend(k,j,i) = tend(k,j,i)                                     &
248                         & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx        &
249                         &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)  &
250                         &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx          &
251                         &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)    &
252                         &   ) * ddx                                             &
253                         & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy        &
254                         &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)  &
255                         &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy          &
256                         &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)    &
257                         &   ) * ddy                                             &
258                         & + 2.0 * (                                             &
259                         &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
260                         & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
261                         &         ) * ddzu(k+1)
262                ENDIF
263             ENDDO
264
265!
266!--          Wall functions at all vertical walls, where necessary
267             !$acc loop vector( 32 )
268             DO  k = 1,nzt
269
270                IF ( k > nzb_w_inner(j,i)  .AND.  k <= nzb_w_outer(j,i)  .AND. &
271                     wall_w_x(j,i) /= 0.0  .AND.  wall_w_y(j,i) /= 0.0 )  THEN
272!
273!--                Interpolate eddy diffusivities on staggered gridpoints
274                   kmxp = 0.25 * &
275                          ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
276                   kmxm = 0.25 * &
277                          ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
278                   kmyp = 0.25 * &
279                          ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
280                   kmym = 0.25 * &
281                          ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
282
283                   tend(k,j,i) = tend(k,j,i)                                   &
284                                 + (   fwxp(j,i) * (                           &
285                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
286                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
287                                                   )                           &
288                                     - fwxm(j,i) * (                           &
289                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
290                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
291                                                   )                           &
292                                     + wall_w_x(j,i) * wsus(k,j,i)             &
293                                   ) * ddx                                     &
294                                 + (   fwyp(j,i) * (                           &
295                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
296                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
297                                                   )                           &
298                                     - fwym(j,i) * (                           &
299                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
300                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
301                                                   )                           &
302                                     + wall_w_y(j,i) * wsvs(k,j,i)             &
303                                   ) * ddy                                     &
304                                 + 2.0 * (                                     &
305                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
306                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
307                                         ) * ddzu(k+1)
308                ENDIF
309             ENDDO
310
311          ENDDO
312       ENDDO
313       !$acc end kernels
314
315    END SUBROUTINE diffusion_w_acc
316
317
318!------------------------------------------------------------------------------!
319! Call for grid point i,j
320!------------------------------------------------------------------------------!
321    SUBROUTINE diffusion_w_ij( i, j )
322
323       USE arrays_3d
324       USE control_parameters
325       USE grid_variables
326       USE indices
327
328       IMPLICIT NONE
329
330       INTEGER ::  i, j, k
331       REAL    ::  kmxm, kmxp, kmym, kmyp
332
333       REAL, DIMENSION(nzb:nzt+1) ::  wsus, wsvs
334
335
336       DO  k = nzb_w_outer(j,i)+1, nzt-1
337!
338!--       Interpolate eddy diffusivities on staggered gridpoints
339          kmxp = 0.25 * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
340          kmxm = 0.25 * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
341          kmyp = 0.25 * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
342          kmym = 0.25 * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
343
344          tend(k,j,i) = tend(k,j,i)                                            &
345                      & + ( kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
346                      &   + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
347                      &   - kmxm * ( w(k,j,i)   - w(k,j,i-1) ) * ddx           &
348                      &   - kmxm * ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)     &
349                      &   ) * ddx                                              &
350                      & + ( kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
351                      &   + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
352                      &   - kmym * ( w(k,j,i)   - w(k,j-1,i) ) * ddy           &
353                      &   - kmym * ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)     &
354                      &   ) * ddy                                              &
355                      & + 2.0 * (                                              &
356                      &   km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)  &
357                      & - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k)  &
358                      &         ) * ddzu(k+1)
359       ENDDO
360
361!
362!--    Wall functions at all vertical walls, where necessary
363       IF ( wall_w_x(j,i) /= 0.0  .OR.  wall_w_y(j,i) /= 0.0 )  THEN
364
365!
366!--       Calculate the horizontal momentum fluxes w'u' and/or w'v'
367          IF ( wall_w_x(j,i) /= 0.0 )  THEN
368             CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i), &
369                               wsus, 0.0, 0.0, 0.0, 1.0 )
370          ELSE
371             wsus = 0.0
372          ENDIF
373
374          IF ( wall_w_y(j,i) /= 0.0 )  THEN
375             CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i),  &
376                               wsvs, 0.0, 0.0, 1.0, 0.0 )
377          ELSE
378             wsvs = 0.0
379          ENDIF
380
381          DO  k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i)
382!
383!--          Interpolate eddy diffusivities on staggered gridpoints
384             kmxp = 0.25 * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) )
385             kmxm = 0.25 * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) )
386             kmyp = 0.25 * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) )
387             kmym = 0.25 * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
388
389             tend(k,j,i) = tend(k,j,i)                                         &
390                                 + (   fwxp(j,i) * (                           &
391                            kmxp * ( w(k,j,i+1)   - w(k,j,i)   ) * ddx         &
392                          + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1)   &
393                                                   )                           &
394                                     - fwxm(j,i) * (                           &
395                            kmxm * ( w(k,j,i)     - w(k,j,i-1) ) * ddx         &
396                          + kmxm * ( u(k+1,j,i)   - u(k,j,i)   ) * ddzu(k+1)   &
397                                                   )                           &
398                                     + wall_w_x(j,i) * wsus(k)                 &
399                                   ) * ddx                                     &
400                                 + (   fwyp(j,i) * (                           &
401                            kmyp * ( w(k,j+1,i)   - w(k,j,i)   ) * ddy         &
402                          + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1)   &
403                                                   )                           &
404                                     - fwym(j,i) * (                           &
405                            kmym * ( w(k,j,i)     - w(k,j-1,i) ) * ddy         &
406                          + kmym * ( v(k+1,j,i)   - v(k,j,i)   ) * ddzu(k+1)   &
407                                                   )                           &
408                                     + wall_w_y(j,i) * wsvs(k)                 &
409                                   ) * ddy                                     &
410                                 + 2.0 * (                                     &
411                           km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) &
412                         - km(k,j,i)   * ( w(k,j,i)   - w(k-1,j,i) ) * ddzw(k) &
413                                         ) * ddzu(k+1)
414          ENDDO
415       ENDIF
416
417    END SUBROUTINE diffusion_w_ij
418
419 END MODULE diffusion_w_mod
Note: See TracBrowser for help on using the repository browser.