source: palm/trunk/SOURCE/diffusion_v.f90 @ 2232

Last change on this file since 2232 was 2232, checked in by suehring, 4 years ago

Adjustments according new topography and surface-modelling concept implemented

  • Property svn:keywords set to Id
File size: 23.8 KB
Line 
1!> @file diffusion_v.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! Adjustments to new topography and surface concept
23!
24! Former revisions:
25! -----------------
26! $Id: diffusion_v.f90 2232 2017-05-30 17:47:52Z suehring $
27!
28! 2118 2017-01-17 16:38:49Z raasch
29! OpenACC version of subroutine removed
30!
31! 2037 2016-10-26 11:15:40Z knoop
32! Anelastic approximation implemented
33!
34! 2000 2016-08-20 18:09:15Z knoop
35! Forced header and separation lines into 80 columns
36!
37! 1873 2016-04-18 14:50:06Z maronga
38! Module renamed (removed _mod)
39!
40! 1850 2016-04-08 13:29:27Z maronga
41! Module renamed
42!
43! 1740 2016-01-13 08:19:40Z raasch
44! unnecessary calculations of kmzm and kmzp in wall bounded parts removed
45!
46! 1682 2015-10-07 23:56:08Z knoop
47! Code annotations made doxygen readable
48!
49! 1340 2014-03-25 19:45:13Z kanani
50! REAL constants defined as wp-kind
51!
52! 1320 2014-03-20 08:40:49Z raasch
53! ONLY-attribute added to USE-statements,
54! kind-parameters added to all INTEGER and REAL declaration statements,
55! kinds are defined in new module kinds,
56! revision history before 2012 removed,
57! comment fields (!:) to be used for variable explanations added to
58! all variable declaration statements
59!
60! 1257 2013-11-08 15:18:40Z raasch
61! openacc loop and loop vector clauses removed, declare create moved after
62! the FORTRAN declaration statement
63!
64! 1128 2013-04-12 06:19:32Z raasch
65! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
66! j_north
67!
68! 1036 2012-10-22 13:43:42Z raasch
69! code put under GPL (PALM 3.9)
70!
71! 1015 2012-09-27 09:23:24Z raasch
72! accelerator version (*_acc) added
73!
74! 1001 2012-09-13 14:08:46Z raasch
75! arrays comunicated by module instead of parameter list
76!
77! 978 2012-08-09 08:28:32Z fricke
78! outflow damping layer removed
79! kmxm_x/_y and kmxp_x/_y change to kmxm and kmxp
80!
81! Revision 1.1  1997/09/12 06:24:01  raasch
82! Initial revision
83!
84!
85! Description:
86! ------------
87!> Diffusion term of the v-component
88!------------------------------------------------------------------------------!
89 MODULE diffusion_v_mod
90 
91
92    PRIVATE
93    PUBLIC diffusion_v
94
95    INTERFACE diffusion_v
96       MODULE PROCEDURE diffusion_v
97       MODULE PROCEDURE diffusion_v_ij
98    END INTERFACE diffusion_v
99
100 CONTAINS
101
102
103!------------------------------------------------------------------------------!
104! Description:
105! ------------
106!> Call for all grid points
107!------------------------------------------------------------------------------!
108    SUBROUTINE diffusion_v
109
110       USE arrays_3d,                                                          &
111           ONLY:  ddzu, ddzw, km, tend, u, v, w, drho_air, rho_air_zw
112       
113       USE control_parameters,                                                 &
114           ONLY:  constant_top_momentumflux, use_surface_fluxes,               &
115                  use_top_fluxes
116       
117       USE grid_variables,                                                     &
118           ONLY:  ddx, ddy, ddy2
119       
120       USE indices,                                                            &
121           ONLY:  nxl, nxr, nyn, nys, nysv, nzb, nzt, wall_flags_0
122       
123       USE kinds
124
125       USE surface_mod,                                                        &
126           ONLY :  surf_def_h, surf_def_v, surf_lsm_h, surf_lsm_v, surf_usm_h, &
127                   surf_usm_v
128
129       IMPLICIT NONE
130
131       INTEGER(iwp) ::  i             !< running index x direction
132       INTEGER(iwp) ::  j             !< running index y direction
133       INTEGER(iwp) ::  k             !< running index z direction
134       INTEGER(iwp) ::  l             !< running index of surface type, south- or north-facing wall
135       INTEGER(iwp) ::  m             !< running index surface elements
136       INTEGER(iwp) ::  surf_e        !< End index of surface elements at (j,i)-gridpoint
137       INTEGER(iwp) ::  surf_s        !< Start index of surface elements at (j,i)-gridpoint
138
139       REAL(wp)     ::  flag          !< flag to mask topography grid points
140       REAL(wp)     ::  kmxm          !<
141       REAL(wp)     ::  kmxp          !<
142       REAL(wp)     ::  kmzm          !<
143       REAL(wp)     ::  kmzp          !<
144       REAL(wp)     ::  mask_bottom   !< flag to mask vertical upward-facing surface 
145       REAL(wp)     ::  mask_east     !< flag to mask vertical surface south of the grid point
146       REAL(wp)     ::  mask_west     !< flag to mask vertical surface north of the grid point
147       REAL(wp)     ::  mask_top      !< flag to mask vertical downward-facing surface     
148
149       DO  i = nxl, nxr
150          DO  j = nysv, nyn
151!
152!--          Compute horizontal diffusion
153             DO  k = nzb+1, nzt
154
155!
156!--             Predetermine flag to mask topography and wall-bounded grid points.
157!--             It is sufficient to masked only east- and west-facing surfaces, which
158!--             need special treatment for the v-component.
159                flag      = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i),   2 ) ) 
160                mask_east = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i+1), 2 ) )
161                mask_west = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i-1), 2 ) )
162!
163!--             Interpolate eddy diffusivities on staggered gridpoints
164                kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) )
165                kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) )
166
167                tend(k,j,i) = tend(k,j,i) +    (                             &
168                          mask_east * kmxp * (                               &
169                                 ( v(k,j,i+1) - v(k,j,i)     ) * ddx         &
170                               + ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy         &
171                                             )                               &
172                        - mask_west * kmxm * (                               &
173                                 ( v(k,j,i) - v(k,j,i-1) ) * ddx             &
174                               + ( u(k,j,i) - u(k,j-1,i) ) * ddy             &
175                                             )                               &
176                                               ) * ddx  * flag               &
177                                    + 2.0_wp * (                             &
178                                  km(k,j,i)   * ( v(k,j+1,i) - v(k,j,i)   )  &
179                                - km(k,j-1,i) * ( v(k,j,i)   - v(k,j-1,i) )  &
180                                               ) * ddy2 * flag
181
182             ENDDO
183
184!
185!--          Add horizontal momentum flux v'u' at east- (l=2) and west-facing (l=3)
186!--          surfaces. Note, in the the flat case, loops won't be entered as
187!--          start_index > end_index. Furtermore, note, no vertical natural surfaces
188!--          so far.           
189!--          Default-type surfaces
190             DO  l = 2, 3
191                surf_s = surf_def_v(l)%start_index(j,i)
192                surf_e = surf_def_v(l)%end_index(j,i)
193                DO  m = surf_s, surf_e
194                   k           = surf_def_v(l)%k(m)
195                   tend(k,j,i) = tend(k,j,i) +                                 &
196                                    surf_def_v(l)%mom_flux_uv(m) * ddx
197                ENDDO   
198             ENDDO
199!
200!--          Natural-type surfaces
201             DO  l = 2, 3
202                surf_s = surf_lsm_v(l)%start_index(j,i)
203                surf_e = surf_lsm_v(l)%end_index(j,i)
204                DO  m = surf_s, surf_e
205                   k           = surf_lsm_v(l)%k(m)
206                   tend(k,j,i) = tend(k,j,i) +                                 &
207                                    surf_lsm_v(l)%mom_flux_uv(m) * ddx
208                ENDDO   
209             ENDDO
210!
211!--          Urban-type surfaces
212             DO  l = 2, 3
213                surf_s = surf_usm_v(l)%start_index(j,i)
214                surf_e = surf_usm_v(l)%end_index(j,i)
215                DO  m = surf_s, surf_e
216                   k           = surf_usm_v(l)%k(m)
217                   tend(k,j,i) = tend(k,j,i) +                                 &
218                                    surf_usm_v(l)%mom_flux_uv(m) * ddx
219                ENDDO   
220             ENDDO
221!
222!--          Compute vertical diffusion. In case of simulating a surface layer,
223!--          respective grid diffusive fluxes are masked (flag 10) within this
224!--          loop, and added further below, else, simple gradient approach is
225!--          applied. Model top is also mask if top-momentum flux is given.
226             DO  k = nzb+1, nzt
227!
228!--             Determine flags to mask topography below and above. Flag 2 is
229!--             used to mask topography in general, while flag 8 implies also
230!--             information about use_surface_fluxes. Flag 9 is used to control
231!--             momentum flux at model top. 
232                mask_bottom = MERGE( 1.0_wp, 0.0_wp,                           &
233                                     BTEST( wall_flags_0(k-1,j,i), 8 ) ) 
234                mask_top    = MERGE( 1.0_wp, 0.0_wp,                           &
235                                     BTEST( wall_flags_0(k+1,j,i), 8 ) ) *     &
236                              MERGE( 1.0_wp, 0.0_wp,                           &
237                                     BTEST( wall_flags_0(k+1,j,i), 9 ) ) 
238                flag        = MERGE( 1.0_wp, 0.0_wp,                           &
239                                     BTEST( wall_flags_0(k,j,i), 2 ) ) 
240!
241!--             Interpolate eddy diffusivities on staggered gridpoints
242                kmzp = 0.25_wp * &
243                       ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
244                kmzm = 0.25_wp * &
245                       ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) )
246
247                tend(k,j,i) = tend(k,j,i)                                      &
248                      & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)     &
249                      &            + ( w(k,j,i) - w(k,j-1,i) ) * ddy           &
250                      &            ) * rho_air_zw(k)   * mask_top              &
251                      &   - kmzm * ( ( v(k,j,i)   - v(k-1,j,i)   ) * ddzu(k)   &
252                      &            + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy       &
253                      &            ) * rho_air_zw(k-1) * mask_bottom           &
254                      &   ) * ddzw(k) * drho_air(k) * flag
255             ENDDO
256
257!
258!--          Vertical diffusion at the first grid point above the surface,
259!--          if the momentum flux at the bottom is given by the Prandtl law
260!--          or if it is prescribed by the user.
261!--          Difference quotient of the momentum flux is not formed over
262!--          half of the grid spacing (2.0*ddzw(k)) any more, since the
263!--          comparison with other (LES) models showed that the values of
264!--          the momentum flux becomes too large in this case.
265             IF ( use_surface_fluxes )  THEN
266!
267!--             Default-type surfaces, upward-facing
268                surf_s = surf_def_h(0)%start_index(j,i)
269                surf_e = surf_def_h(0)%end_index(j,i)
270                DO  m = surf_s, surf_e
271                   k   = surf_def_h(0)%k(m)
272
273                   tend(k,j,i) = tend(k,j,i)                                   &
274                        + ( - ( - surf_def_h(0)%vsws(m) )                      &
275                          ) * ddzw(k) * drho_air(k)
276                ENDDO
277!
278!--             Default-type surfaces, dowward-facing
279                surf_s = surf_def_h(1)%start_index(j,i)
280                surf_e = surf_def_h(1)%end_index(j,i)
281                DO  m = surf_s, surf_e
282                   k   = surf_def_h(1)%k(m)
283
284                   tend(k,j,i) = tend(k,j,i)                                   &
285                        + ( - surf_def_h(1)%vsws(m)                            &
286                          ) * ddzw(k) * drho_air(k)
287                ENDDO
288!
289!--             Natural-type surfaces, upward-facing
290                surf_s = surf_lsm_h%start_index(j,i)
291                surf_e = surf_lsm_h%end_index(j,i)
292                DO  m = surf_s, surf_e
293                   k   = surf_lsm_h%k(m)
294
295                   tend(k,j,i) = tend(k,j,i)                                   &
296                        + ( - ( - surf_lsm_h%vsws(m) )                         &
297                          ) * ddzw(k) * drho_air(k)
298
299                ENDDO
300!
301!--             Urban-type surfaces, upward-facing
302                surf_s = surf_usm_h%start_index(j,i)
303                surf_e = surf_usm_h%end_index(j,i)
304                DO  m = surf_s, surf_e
305                   k   = surf_usm_h%k(m)
306
307                   tend(k,j,i) = tend(k,j,i)                                   &
308                        + ( - ( - surf_usm_h%vsws(m) )                         &
309                          ) * ddzw(k) * drho_air(k)
310
311                ENDDO
312             ENDIF
313!
314!--          Add momentum flux at model top
315             IF ( use_top_fluxes )  THEN
316                surf_s = surf_def_h(2)%start_index(j,i)
317                surf_e = surf_def_h(2)%end_index(j,i)
318                DO  m = surf_s, surf_e
319
320                   k   = surf_def_h(2)%k(m)
321
322                   tend(k,j,i) = tend(k,j,i)                                   &
323                           + ( - surf_def_h(2)%vsws(m) ) * ddzw(k) * drho_air(k)
324                ENDDO
325             ENDIF
326
327          ENDDO
328       ENDDO
329
330    END SUBROUTINE diffusion_v
331
332
333!------------------------------------------------------------------------------!
334! Description:
335! ------------
336!> Call for grid point i,j
337!------------------------------------------------------------------------------!
338    SUBROUTINE diffusion_v_ij( i, j )
339
340       USE arrays_3d,                                                          &
341           ONLY:  ddzu, ddzw, km, tend, u, v, w, drho_air, rho_air_zw
342       
343       USE control_parameters,                                                 &
344           ONLY:  constant_top_momentumflux, use_surface_fluxes,               &
345                  use_top_fluxes
346       
347       USE grid_variables,                                                     &
348           ONLY:  ddx, ddy, ddy2
349       
350       USE indices,                                                            &
351           ONLY:  nzb, nzt, wall_flags_0
352       
353       USE kinds
354
355       USE surface_mod,                                                        &
356           ONLY :  surf_def_h, surf_def_v, surf_lsm_h, surf_lsm_v, surf_usm_h, &
357                   surf_usm_v
358
359       IMPLICIT NONE
360
361
362       INTEGER(iwp) ::  i             !< running index x direction
363       INTEGER(iwp) ::  j             !< running index y direction
364       INTEGER(iwp) ::  k             !< running index z direction
365       INTEGER(iwp) ::  l             !< running index of surface type, south- or north-facing wall
366       INTEGER(iwp) ::  m             !< running index surface elements
367       INTEGER(iwp) ::  surf_e        !< End index of surface elements at (j,i)-gridpoint
368       INTEGER(iwp) ::  surf_s        !< Start index of surface elements at (j,i)-gridpoint
369
370       REAL(wp)     ::  flag          !< flag to mask topography grid points
371       REAL(wp)     ::  kmxm          !<
372       REAL(wp)     ::  kmxp          !<
373       REAL(wp)     ::  kmzm          !<
374       REAL(wp)     ::  kmzp          !<
375       REAL(wp)     ::  mask_bottom   !< flag to mask vertical upward-facing surface 
376       REAL(wp)     ::  mask_east     !< flag to mask vertical surface south of the grid point
377       REAL(wp)     ::  mask_west     !< flag to mask vertical surface north of the grid point
378       REAL(wp)     ::  mask_top      !< flag to mask vertical downward-facing surface
379
380!
381!--    Compute horizontal diffusion
382       DO  k = nzb+1, nzt
383!
384!--       Predetermine flag to mask topography and wall-bounded grid points.
385!--       It is sufficient to masked only east- and west-facing surfaces, which
386!--       need special treatment for the v-component.
387          flag      = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i),   2 ) ) 
388          mask_east = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i+1), 2 ) )
389          mask_west = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i-1), 2 ) )
390!
391!--       Interpolate eddy diffusivities on staggered gridpoints
392          kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) )
393          kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) )
394
395          tend(k,j,i) = tend(k,j,i) +          (                             &
396                          mask_east * kmxp * (                               &
397                                 ( v(k,j,i+1) - v(k,j,i)     ) * ddx         &
398                               + ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy         &
399                                             )                               &
400                        - mask_west * kmxm * (                               &
401                                 ( v(k,j,i) - v(k,j,i-1) ) * ddx             &
402                               + ( u(k,j,i) - u(k,j-1,i) ) * ddy             &
403                                             )                               &
404                                               ) * ddx  * flag               &
405                                    + 2.0_wp * (                             &
406                                  km(k,j,i)   * ( v(k,j+1,i) - v(k,j,i)   )  &
407                                - km(k,j-1,i) * ( v(k,j,i)   - v(k,j-1,i) )  &
408                                               ) * ddy2 * flag
409       ENDDO
410
411!
412!--    Add horizontal momentum flux v'u' at east- (l=2) and west-facing (l=3)
413!--    surfaces. Note, in the the flat case, loops won't be entered as
414!--    start_index > end_index. Furtermore, note, no vertical natural surfaces
415!--    so far.           
416!--    Default-type surfaces
417       DO  l = 2, 3
418          surf_s = surf_def_v(l)%start_index(j,i)
419          surf_e = surf_def_v(l)%end_index(j,i)
420          DO  m = surf_s, surf_e
421             k           = surf_def_v(l)%k(m)
422             tend(k,j,i) = tend(k,j,i) + surf_def_v(l)%mom_flux_uv(m) * ddx
423          ENDDO   
424       ENDDO
425!
426!--    Natural-type surfaces
427       DO  l = 2, 3
428          surf_s = surf_lsm_v(l)%start_index(j,i)
429          surf_e = surf_lsm_v(l)%end_index(j,i)
430          DO  m = surf_s, surf_e
431             k           = surf_lsm_v(l)%k(m)
432             tend(k,j,i) = tend(k,j,i) + surf_lsm_v(l)%mom_flux_uv(m) * ddx
433          ENDDO   
434       ENDDO
435!
436!--    Urban-type surfaces
437       DO  l = 2, 3
438          surf_s = surf_usm_v(l)%start_index(j,i)
439          surf_e = surf_usm_v(l)%end_index(j,i)
440          DO  m = surf_s, surf_e
441             k           = surf_usm_v(l)%k(m)
442             tend(k,j,i) = tend(k,j,i) + surf_usm_v(l)%mom_flux_uv(m) * ddx
443          ENDDO   
444       ENDDO
445!
446!--    Compute vertical diffusion. In case of simulating a surface layer,
447!--    respective grid diffusive fluxes are masked (flag 8) within this
448!--    loop, and added further below, else, simple gradient approach is
449!--    applied. Model top is also mask if top-momentum flux is given.
450       DO  k = nzb+1, nzt
451!
452!--       Determine flags to mask topography below and above. Flag 2 is
453!--       used to mask topography in general, while flag 10 implies also
454!--       information about use_surface_fluxes. Flag 9 is used to control
455!--       momentum flux at model top. 
456          mask_bottom = MERGE( 1.0_wp, 0.0_wp,                                 &
457                               BTEST( wall_flags_0(k-1,j,i), 8 ) ) 
458          mask_top    = MERGE( 1.0_wp, 0.0_wp,                                 &
459                               BTEST( wall_flags_0(k+1,j,i), 8 ) ) *           &
460                        MERGE( 1.0_wp, 0.0_wp,                                 &
461                               BTEST( wall_flags_0(k+1,j,i), 9 ) ) 
462          flag        = MERGE( 1.0_wp, 0.0_wp,                                 &
463                               BTEST( wall_flags_0(k,j,i), 2 ) )
464!
465!--       Interpolate eddy diffusivities on staggered gridpoints
466          kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
467          kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) )
468
469          tend(k,j,i) = tend(k,j,i)                                            &
470                      & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)     &
471                      &            + ( w(k,j,i) - w(k,j-1,i) ) * ddy           &
472                      &            ) * rho_air_zw(k)   * mask_top              &
473                      &   - kmzm * ( ( v(k,j,i)   - v(k-1,j,i)   ) * ddzu(k)   &
474                      &            + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy       &
475                      &            ) * rho_air_zw(k-1) * mask_bottom           &
476                      &   ) * ddzw(k) * drho_air(k) * flag
477       ENDDO
478
479!
480!--    Vertical diffusion at the first grid point above the surface, if the
481!--    momentum flux at the bottom is given by the Prandtl law or if it is
482!--    prescribed by the user.
483!--    Difference quotient of the momentum flux is not formed over half of
484!--    the grid spacing (2.0*ddzw(k)) any more, since the comparison with
485!--    other (LES) models showed that the values of the momentum flux becomes
486!--    too large in this case.
487       IF ( use_surface_fluxes )  THEN
488!
489!--       Default-type surfaces, upward-facing
490          surf_s = surf_def_h(0)%start_index(j,i)
491          surf_e = surf_def_h(0)%end_index(j,i)
492          DO  m = surf_s, surf_e
493             k   = surf_def_h(0)%k(m)
494
495             tend(k,j,i) = tend(k,j,i)                                         &
496                        + ( - ( - surf_def_h(0)%vsws(m) )                      &
497                          ) * ddzw(k) * drho_air(k)
498          ENDDO
499!
500!--       Default-type surfaces, dowward-facing
501          surf_s = surf_def_h(1)%start_index(j,i)
502          surf_e = surf_def_h(1)%end_index(j,i)
503          DO  m = surf_s, surf_e
504             k   = surf_def_h(1)%k(m)
505
506             tend(k,j,i) = tend(k,j,i)                                         &
507                        + ( - surf_def_h(1)%vsws(m)                            &
508                          ) * ddzw(k) * drho_air(k)
509          ENDDO
510!
511!--       Natural-type surfaces, upward-facing
512          surf_s = surf_lsm_h%start_index(j,i)
513          surf_e = surf_lsm_h%end_index(j,i)
514          DO  m = surf_s, surf_e
515             k   = surf_lsm_h%k(m)
516
517             tend(k,j,i) = tend(k,j,i)                                         &
518                        + ( - ( - surf_lsm_h%vsws(m) )                         &
519                          ) * ddzw(k) * drho_air(k)
520
521          ENDDO
522!
523!--       Urban-type surfaces, upward-facing
524          surf_s = surf_usm_h%start_index(j,i)
525          surf_e = surf_usm_h%end_index(j,i)
526          DO  m = surf_s, surf_e
527             k   = surf_usm_h%k(m)
528
529             tend(k,j,i) = tend(k,j,i)                                         &
530                        + ( - ( - surf_usm_h%vsws(m) )                         &
531                          ) * ddzw(k) * drho_air(k)
532
533          ENDDO
534       ENDIF
535!
536!--    Add momentum flux at model top
537       IF ( use_top_fluxes )  THEN
538          surf_s = surf_def_h(2)%start_index(j,i)
539          surf_e = surf_def_h(2)%end_index(j,i)
540          DO  m = surf_s, surf_e
541
542             k   = surf_def_h(2)%k(m)
543
544             tend(k,j,i) = tend(k,j,i)                                         &
545                           + ( - surf_def_h(2)%vsws(m) ) * ddzw(k) * drho_air(k)
546          ENDDO
547       ENDIF
548
549    END SUBROUTINE diffusion_v_ij
550
551 END MODULE diffusion_v_mod
Note: See TracBrowser for help on using the repository browser.