source: palm/trunk/SOURCE/diffusion_v.f90 @ 2119

Last change on this file since 2119 was 2119, checked in by raasch, 4 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 18.2 KB
Line 
1!> @file diffusion_v.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: diffusion_v.f90 2119 2017-01-17 16:51:50Z raasch $
27!
28! 2118 2017-01-17 16:38:49Z raasch
29! OpenACC version of subroutine removed
30!
31! 2037 2016-10-26 11:15:40Z knoop
32! Anelastic approximation implemented
33!
34! 2000 2016-08-20 18:09:15Z knoop
35! Forced header and separation lines into 80 columns
36!
37! 1873 2016-04-18 14:50:06Z maronga
38! Module renamed (removed _mod)
39!
40! 1850 2016-04-08 13:29:27Z maronga
41! Module renamed
42!
43! 1740 2016-01-13 08:19:40Z raasch
44! unnecessary calculations of kmzm and kmzp in wall bounded parts removed
45!
46! 1682 2015-10-07 23:56:08Z knoop
47! Code annotations made doxygen readable
48!
49! 1340 2014-03-25 19:45:13Z kanani
50! REAL constants defined as wp-kind
51!
52! 1320 2014-03-20 08:40:49Z raasch
53! ONLY-attribute added to USE-statements,
54! kind-parameters added to all INTEGER and REAL declaration statements,
55! kinds are defined in new module kinds,
56! revision history before 2012 removed,
57! comment fields (!:) to be used for variable explanations added to
58! all variable declaration statements
59!
60! 1257 2013-11-08 15:18:40Z raasch
61! openacc loop and loop vector clauses removed, declare create moved after
62! the FORTRAN declaration statement
63!
64! 1128 2013-04-12 06:19:32Z raasch
65! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
66! j_north
67!
68! 1036 2012-10-22 13:43:42Z raasch
69! code put under GPL (PALM 3.9)
70!
71! 1015 2012-09-27 09:23:24Z raasch
72! accelerator version (*_acc) added
73!
74! 1001 2012-09-13 14:08:46Z raasch
75! arrays comunicated by module instead of parameter list
76!
77! 978 2012-08-09 08:28:32Z fricke
78! outflow damping layer removed
79! kmxm_x/_y and kmxp_x/_y change to kmxm and kmxp
80!
81! Revision 1.1  1997/09/12 06:24:01  raasch
82! Initial revision
83!
84!
85! Description:
86! ------------
87!> Diffusion term of the v-component
88!------------------------------------------------------------------------------!
89 MODULE diffusion_v_mod
90 
91
92    USE wall_fluxes_mod
93
94    PRIVATE
95    PUBLIC diffusion_v
96
97    INTERFACE diffusion_v
98       MODULE PROCEDURE diffusion_v
99       MODULE PROCEDURE diffusion_v_ij
100    END INTERFACE diffusion_v
101
102 CONTAINS
103
104
105!------------------------------------------------------------------------------!
106! Description:
107! ------------
108!> Call for all grid points
109!------------------------------------------------------------------------------!
110    SUBROUTINE diffusion_v
111
112       USE arrays_3d,                                                          &
113           ONLY:  ddzu, ddzw, km, tend, u, v, vsws, vswst, w,                  &
114                  drho_air, rho_air_zw
115       
116       USE control_parameters,                                                 &
117           ONLY:  constant_top_momentumflux, topography, use_surface_fluxes,   &
118                  use_top_fluxes
119       
120       USE grid_variables,                                                     &
121           ONLY:  ddx, ddy, ddy2, fxm, fxp, wall_v
122       
123       USE indices,                                                            &
124           ONLY:  nxl, nxr, nyn, nys, nysv, nzb, nzb_diff_v, nzb_v_inner,      &
125                  nzb_v_outer, nzt, nzt_diff
126       
127       USE kinds
128
129       IMPLICIT NONE
130
131       INTEGER(iwp) ::  i     !<
132       INTEGER(iwp) ::  j     !<
133       INTEGER(iwp) ::  k     !<
134       REAL(wp)     ::  kmxm  !<
135       REAL(wp)     ::  kmxp  !<
136       REAL(wp)     ::  kmzm  !<
137       REAL(wp)     ::  kmzp  !<
138
139       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  vsus  !<
140
141!
142!--    First calculate horizontal momentum flux v'u' at vertical walls,
143!--    if neccessary
144       IF ( topography /= 'flat' )  THEN
145          CALL wall_fluxes( vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp, nzb_v_inner, &
146                            nzb_v_outer, wall_v )
147       ENDIF
148
149       DO  i = nxl, nxr
150          DO  j = nysv, nyn
151!
152!--          Compute horizontal diffusion
153             DO  k = nzb_v_outer(j,i)+1, nzt
154!
155!--             Interpolate eddy diffusivities on staggered gridpoints
156                kmxp = 0.25_wp * &
157                       ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) )
158                kmxm = 0.25_wp * &
159                       ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) )
160
161                tend(k,j,i) = tend(k,j,i)                                      &
162                      & + ( kmxp * ( v(k,j,i+1) - v(k,j,i)     ) * ddx         &
163                      &   + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy         &
164                      &   - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx             &
165                      &   - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy             &
166                      &   ) * ddx                                              &
167                      & + 2.0_wp * (                                           &
168                      &           km(k,j,i)   * ( v(k,j+1,i) - v(k,j,i) )      &
169                      &         - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) )      &
170                      &            ) * ddy2
171             ENDDO
172
173!
174!--          Wall functions at the left and right walls, respectively
175             IF ( wall_v(j,i) /= 0.0_wp )  THEN
176
177                DO  k = nzb_v_inner(j,i)+1, nzb_v_outer(j,i)
178                   kmxp = 0.25_wp *                                            &
179                          ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) )
180                   kmxm = 0.25_wp *                                            &
181                          ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) )
182                   
183                   tend(k,j,i) = tend(k,j,i)                                   &
184                                 + 2.0_wp * (                                  &
185                                       km(k,j,i)   * ( v(k,j+1,i) - v(k,j,i) ) &
186                                     - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) &
187                                            ) * ddy2                           &
188                                 + (   fxp(j,i) * (                            &
189                                  kmxp * ( v(k,j,i+1) - v(k,j,i)     ) * ddx   &
190                                + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy   &
191                                                  )                            &
192                                     - fxm(j,i) * (                            &
193                                  kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx       &
194                                + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy       &
195                                                  )                            &
196                                     + wall_v(j,i) * vsus(k,j,i)               &
197                                   ) * ddx
198                ENDDO
199             ENDIF
200
201!
202!--          Compute vertical diffusion. In case of simulating a Prandtl
203!--          layer, index k starts at nzb_v_inner+2.
204             DO  k = nzb_diff_v(j,i), nzt_diff
205!
206!--             Interpolate eddy diffusivities on staggered gridpoints
207                kmzp = 0.25_wp * &
208                       ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
209                kmzm = 0.25_wp * &
210                       ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) )
211
212                tend(k,j,i) = tend(k,j,i)                                      &
213                      & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)     &
214                      &            + ( w(k,j,i) - w(k,j-1,i) ) * ddy           &
215                      &            ) * rho_air_zw(k)                           &
216                      &   - kmzm * ( ( v(k,j,i)   - v(k-1,j,i)   ) * ddzu(k)   &
217                      &            + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy       &
218                      &            ) * rho_air_zw(k-1)                         &
219                      &   ) * ddzw(k) * drho_air(k)
220             ENDDO
221
222!
223!--          Vertical diffusion at the first grid point above the surface,
224!--          if the momentum flux at the bottom is given by the Prandtl law
225!--          or if it is prescribed by the user.
226!--          Difference quotient of the momentum flux is not formed over
227!--          half of the grid spacing (2.0*ddzw(k)) any more, since the
228!--          comparison with other (LES) models showed that the values of
229!--          the momentum flux becomes too large in this case.
230!--          The term containing w(k-1,..) (see above equation) is removed here
231!--          because the vertical velocity is assumed to be zero at the surface.
232             IF ( use_surface_fluxes )  THEN
233                k = nzb_v_inner(j,i)+1
234!
235!--             Interpolate eddy diffusivities on staggered gridpoints
236                kmzp = 0.25_wp *                                               &
237                       ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
238
239                tend(k,j,i) = tend(k,j,i)                                      &
240                      & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)   &
241                      &            + ( w(k,j,i)   - w(k,j-1,i) ) * ddy         &
242                      &            ) * rho_air_zw(k)                           &
243                      &   - ( -vsws(j,i) )                                     &
244                      &   ) * ddzw(k) * drho_air(k)
245             ENDIF
246
247!
248!--          Vertical diffusion at the first gridpoint below the top boundary,
249!--          if the momentum flux at the top is prescribed by the user
250             IF ( use_top_fluxes  .AND.  constant_top_momentumflux )  THEN
251                k = nzt
252!
253!--             Interpolate eddy diffusivities on staggered gridpoints
254                kmzm = 0.25_wp *                                               &
255                       ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) )
256
257                tend(k,j,i) = tend(k,j,i)                                      &
258                      & + ( ( -vswst(j,i) )                                    &
259                      &   - kmzm * ( ( v(k,j,i)   - v(k-1,j,i)   ) * ddzu(k)   &
260                      &            + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy       &
261                      &            ) * rho_air_zw(k-1)                         &
262                      &   ) * ddzw(k) * drho_air(k)
263             ENDIF
264
265          ENDDO
266       ENDDO
267
268    END SUBROUTINE diffusion_v
269
270
271!------------------------------------------------------------------------------!
272! Description:
273! ------------
274!> Call for grid point i,j
275!------------------------------------------------------------------------------!
276    SUBROUTINE diffusion_v_ij( i, j )
277
278       USE arrays_3d,                                                          &
279           ONLY:  ddzu, ddzw, km, tend, u, v, vsws, vswst, w,                  &
280                  drho_air, rho_air_zw
281       
282       USE control_parameters,                                                 &
283           ONLY:  constant_top_momentumflux, use_surface_fluxes, use_top_fluxes
284       
285       USE grid_variables,                                                     &
286           ONLY:  ddx, ddy, ddy2, fxm, fxp, wall_v
287       
288       USE indices,                                                            &
289           ONLY:  nzb, nzb_diff_v, nzb_v_inner, nzb_v_outer, nzt, nzt_diff
290       
291       USE kinds
292
293       IMPLICIT NONE
294
295       INTEGER(iwp) ::  i     !<
296       INTEGER(iwp) ::  j     !<
297       INTEGER(iwp) ::  k     !<
298       REAL(wp)     ::  kmxm  !<
299       REAL(wp)     ::  kmxp  !<
300       REAL(wp)     ::  kmzm  !<
301       REAL(wp)     ::  kmzp  !<
302
303       REAL(wp), DIMENSION(nzb:nzt+1) ::  vsus  !<
304
305!
306!--    Compute horizontal diffusion
307       DO  k = nzb_v_outer(j,i)+1, nzt
308!
309!--       Interpolate eddy diffusivities on staggered gridpoints
310          kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) )
311          kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) )
312
313          tend(k,j,i) = tend(k,j,i)                                            &
314                      & + ( kmxp * ( v(k,j,i+1) - v(k,j,i)     ) * ddx         &
315                      &   + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy         &
316                      &   - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx             &
317                      &   - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy             &
318                      &   ) * ddx                                              &
319                      & + 2.0_wp * (                                           &
320                      &           km(k,j,i)   * ( v(k,j+1,i) - v(k,j,i) )      &
321                      &         - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) )      &
322                      &            ) * ddy2
323       ENDDO
324
325!
326!--    Wall functions at the left and right walls, respectively
327       IF ( wall_v(j,i) /= 0.0_wp )  THEN
328
329!
330!--       Calculate the horizontal momentum flux v'u'
331          CALL wall_fluxes( i, j, nzb_v_inner(j,i)+1, nzb_v_outer(j,i),        &
332                            vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp )
333
334          DO  k = nzb_v_inner(j,i)+1, nzb_v_outer(j,i)
335             kmxp = 0.25_wp *                                                  &
336                    ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) )
337             kmxm = 0.25_wp *                                                  &
338                    ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) )
339
340             tend(k,j,i) = tend(k,j,i)                                         &
341                                 + 2.0_wp * (                                  &
342                                       km(k,j,i)   * ( v(k,j+1,i) - v(k,j,i) ) &
343                                     - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) &
344                                            ) * ddy2                           &
345                                 + (   fxp(j,i) * (                            &
346                                  kmxp * ( v(k,j,i+1) - v(k,j,i)     ) * ddx   &
347                                + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy   &
348                                                  )                            &
349                                     - fxm(j,i) * (                            &
350                                  kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx       &
351                                + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy       &
352                                                  )                            &
353                                     + wall_v(j,i) * vsus(k)                   &
354                                   ) * ddx
355          ENDDO
356       ENDIF
357
358!
359!--    Compute vertical diffusion. In case of simulating a Prandtl layer,
360!--    index k starts at nzb_v_inner+2.
361       DO  k = nzb_diff_v(j,i), nzt_diff
362!
363!--       Interpolate eddy diffusivities on staggered gridpoints
364          kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
365          kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) )
366
367          tend(k,j,i) = tend(k,j,i)                                            &
368                      & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)     &
369                      &            + ( w(k,j,i) - w(k,j-1,i) ) * ddy           &
370                      &            ) * rho_air_zw(k)                           &
371                      &   - kmzm * ( ( v(k,j,i)   - v(k-1,j,i)   ) * ddzu(k)   &
372                      &            + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy       &
373                      &            ) * rho_air_zw(k-1)                         &
374                      &   ) * ddzw(k) * drho_air(k)
375       ENDDO
376
377!
378!--    Vertical diffusion at the first grid point above the surface, if the
379!--    momentum flux at the bottom is given by the Prandtl law or if it is
380!--    prescribed by the user.
381!--    Difference quotient of the momentum flux is not formed over half of
382!--    the grid spacing (2.0*ddzw(k)) any more, since the comparison with
383!--    other (LES) models showed that the values of the momentum flux becomes
384!--    too large in this case.
385!--    The term containing w(k-1,..) (see above equation) is removed here
386!--    because the vertical velocity is assumed to be zero at the surface.
387       IF ( use_surface_fluxes )  THEN
388          k = nzb_v_inner(j,i)+1
389!
390!--       Interpolate eddy diffusivities on staggered gridpoints
391          kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) )
392
393          tend(k,j,i) = tend(k,j,i)                                            &
394                      & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i)   ) * ddzu(k+1)   &
395                      &            + ( w(k,j,i)   - w(k,j-1,i) ) * ddy         &
396                      &            ) * rho_air_zw(k)                           &
397                      &   - ( -vsws(j,i) )                                     &
398                      &   ) * ddzw(k) * drho_air(k)
399       ENDIF
400
401!
402!--    Vertical diffusion at the first gridpoint below the top boundary,
403!--    if the momentum flux at the top is prescribed by the user
404       IF ( use_top_fluxes  .AND.  constant_top_momentumflux )  THEN
405          k = nzt
406!
407!--       Interpolate eddy diffusivities on staggered gridpoints
408          kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) )
409
410          tend(k,j,i) = tend(k,j,i)                                            &
411                      & + ( ( -vswst(j,i) )                                    &
412                      &   - kmzm * ( ( v(k,j,i)   - v(k-1,j,i)   ) * ddzu(k)   &
413                      &            + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy       &
414                      &            ) * rho_air_zw(k-1)                         &
415                      &   ) * ddzw(k) * drho_air(k)
416       ENDIF
417
418    END SUBROUTINE diffusion_v_ij
419
420 END MODULE diffusion_v_mod
Note: See TracBrowser for help on using the repository browser.