| 1 | !> @file diffusion_v.f90 |
|---|
| 2 | !------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the |
|---|
| 6 | ! terms of the GNU General Public License as published by the Free Software |
|---|
| 7 | ! Foundation, either version 3 of the License, or (at your option) any later |
|---|
| 8 | ! version. |
|---|
| 9 | ! |
|---|
| 10 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 11 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 12 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 13 | ! |
|---|
| 14 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 15 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 16 | ! |
|---|
| 17 | ! Copyright 1997-2017 Leibniz Universitaet Hannover |
|---|
| 18 | !------------------------------------------------------------------------------! |
|---|
| 19 | ! |
|---|
| 20 | ! Current revisions: |
|---|
| 21 | ! ----------------- |
|---|
| 22 | ! OpenACC version of subroutine removed |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: diffusion_v.f90 2118 2017-01-17 16:38:49Z raasch $ |
|---|
| 27 | ! |
|---|
| 28 | ! 2037 2016-10-26 11:15:40Z knoop |
|---|
| 29 | ! Anelastic approximation implemented |
|---|
| 30 | ! |
|---|
| 31 | ! 2000 2016-08-20 18:09:15Z knoop |
|---|
| 32 | ! Forced header and separation lines into 80 columns |
|---|
| 33 | ! |
|---|
| 34 | ! 1873 2016-04-18 14:50:06Z maronga |
|---|
| 35 | ! Module renamed (removed _mod) |
|---|
| 36 | ! |
|---|
| 37 | ! 1850 2016-04-08 13:29:27Z maronga |
|---|
| 38 | ! Module renamed |
|---|
| 39 | ! |
|---|
| 40 | ! 1740 2016-01-13 08:19:40Z raasch |
|---|
| 41 | ! unnecessary calculations of kmzm and kmzp in wall bounded parts removed |
|---|
| 42 | ! |
|---|
| 43 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 44 | ! Code annotations made doxygen readable |
|---|
| 45 | ! |
|---|
| 46 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 47 | ! REAL constants defined as wp-kind |
|---|
| 48 | ! |
|---|
| 49 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 50 | ! ONLY-attribute added to USE-statements, |
|---|
| 51 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 52 | ! kinds are defined in new module kinds, |
|---|
| 53 | ! revision history before 2012 removed, |
|---|
| 54 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 55 | ! all variable declaration statements |
|---|
| 56 | ! |
|---|
| 57 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 58 | ! openacc loop and loop vector clauses removed, declare create moved after |
|---|
| 59 | ! the FORTRAN declaration statement |
|---|
| 60 | ! |
|---|
| 61 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 62 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 63 | ! j_north |
|---|
| 64 | ! |
|---|
| 65 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 66 | ! code put under GPL (PALM 3.9) |
|---|
| 67 | ! |
|---|
| 68 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 69 | ! accelerator version (*_acc) added |
|---|
| 70 | ! |
|---|
| 71 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 72 | ! arrays comunicated by module instead of parameter list |
|---|
| 73 | ! |
|---|
| 74 | ! 978 2012-08-09 08:28:32Z fricke |
|---|
| 75 | ! outflow damping layer removed |
|---|
| 76 | ! kmxm_x/_y and kmxp_x/_y change to kmxm and kmxp |
|---|
| 77 | ! |
|---|
| 78 | ! Revision 1.1 1997/09/12 06:24:01 raasch |
|---|
| 79 | ! Initial revision |
|---|
| 80 | ! |
|---|
| 81 | ! |
|---|
| 82 | ! Description: |
|---|
| 83 | ! ------------ |
|---|
| 84 | !> Diffusion term of the v-component |
|---|
| 85 | !------------------------------------------------------------------------------! |
|---|
| 86 | MODULE diffusion_v_mod |
|---|
| 87 | |
|---|
| 88 | |
|---|
| 89 | USE wall_fluxes_mod |
|---|
| 90 | |
|---|
| 91 | PRIVATE |
|---|
| 92 | PUBLIC diffusion_v |
|---|
| 93 | |
|---|
| 94 | INTERFACE diffusion_v |
|---|
| 95 | MODULE PROCEDURE diffusion_v |
|---|
| 96 | MODULE PROCEDURE diffusion_v_ij |
|---|
| 97 | END INTERFACE diffusion_v |
|---|
| 98 | |
|---|
| 99 | CONTAINS |
|---|
| 100 | |
|---|
| 101 | |
|---|
| 102 | !------------------------------------------------------------------------------! |
|---|
| 103 | ! Description: |
|---|
| 104 | ! ------------ |
|---|
| 105 | !> Call for all grid points |
|---|
| 106 | !------------------------------------------------------------------------------! |
|---|
| 107 | SUBROUTINE diffusion_v |
|---|
| 108 | |
|---|
| 109 | USE arrays_3d, & |
|---|
| 110 | ONLY: ddzu, ddzw, km, tend, u, v, vsws, vswst, w, & |
|---|
| 111 | drho_air, rho_air_zw |
|---|
| 112 | |
|---|
| 113 | USE control_parameters, & |
|---|
| 114 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 115 | use_top_fluxes |
|---|
| 116 | |
|---|
| 117 | USE grid_variables, & |
|---|
| 118 | ONLY: ddx, ddy, ddy2, fxm, fxp, wall_v |
|---|
| 119 | |
|---|
| 120 | USE indices, & |
|---|
| 121 | ONLY: nxl, nxr, nyn, nys, nysv, nzb, nzb_diff_v, nzb_v_inner, & |
|---|
| 122 | nzb_v_outer, nzt, nzt_diff |
|---|
| 123 | |
|---|
| 124 | USE kinds |
|---|
| 125 | |
|---|
| 126 | IMPLICIT NONE |
|---|
| 127 | |
|---|
| 128 | INTEGER(iwp) :: i !< |
|---|
| 129 | INTEGER(iwp) :: j !< |
|---|
| 130 | INTEGER(iwp) :: k !< |
|---|
| 131 | REAL(wp) :: kmxm !< |
|---|
| 132 | REAL(wp) :: kmxp !< |
|---|
| 133 | REAL(wp) :: kmzm !< |
|---|
| 134 | REAL(wp) :: kmzp !< |
|---|
| 135 | |
|---|
| 136 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: vsus !< |
|---|
| 137 | |
|---|
| 138 | ! |
|---|
| 139 | !-- First calculate horizontal momentum flux v'u' at vertical walls, |
|---|
| 140 | !-- if neccessary |
|---|
| 141 | IF ( topography /= 'flat' ) THEN |
|---|
| 142 | CALL wall_fluxes( vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp, nzb_v_inner, & |
|---|
| 143 | nzb_v_outer, wall_v ) |
|---|
| 144 | ENDIF |
|---|
| 145 | |
|---|
| 146 | DO i = nxl, nxr |
|---|
| 147 | DO j = nysv, nyn |
|---|
| 148 | ! |
|---|
| 149 | !-- Compute horizontal diffusion |
|---|
| 150 | DO k = nzb_v_outer(j,i)+1, nzt |
|---|
| 151 | ! |
|---|
| 152 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 153 | kmxp = 0.25_wp * & |
|---|
| 154 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 155 | kmxm = 0.25_wp * & |
|---|
| 156 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 157 | |
|---|
| 158 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 159 | & + ( kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 160 | & + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 161 | & - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 162 | & - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 163 | & ) * ddx & |
|---|
| 164 | & + 2.0_wp * ( & |
|---|
| 165 | & km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 166 | & - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 167 | & ) * ddy2 |
|---|
| 168 | ENDDO |
|---|
| 169 | |
|---|
| 170 | ! |
|---|
| 171 | !-- Wall functions at the left and right walls, respectively |
|---|
| 172 | IF ( wall_v(j,i) /= 0.0_wp ) THEN |
|---|
| 173 | |
|---|
| 174 | DO k = nzb_v_inner(j,i)+1, nzb_v_outer(j,i) |
|---|
| 175 | kmxp = 0.25_wp * & |
|---|
| 176 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 177 | kmxm = 0.25_wp * & |
|---|
| 178 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 179 | |
|---|
| 180 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 181 | + 2.0_wp * ( & |
|---|
| 182 | km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 183 | - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 184 | ) * ddy2 & |
|---|
| 185 | + ( fxp(j,i) * ( & |
|---|
| 186 | kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 187 | + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 188 | ) & |
|---|
| 189 | - fxm(j,i) * ( & |
|---|
| 190 | kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 191 | + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 192 | ) & |
|---|
| 193 | + wall_v(j,i) * vsus(k,j,i) & |
|---|
| 194 | ) * ddx |
|---|
| 195 | ENDDO |
|---|
| 196 | ENDIF |
|---|
| 197 | |
|---|
| 198 | ! |
|---|
| 199 | !-- Compute vertical diffusion. In case of simulating a Prandtl |
|---|
| 200 | !-- layer, index k starts at nzb_v_inner+2. |
|---|
| 201 | DO k = nzb_diff_v(j,i), nzt_diff |
|---|
| 202 | ! |
|---|
| 203 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 204 | kmzp = 0.25_wp * & |
|---|
| 205 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 206 | kmzm = 0.25_wp * & |
|---|
| 207 | ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 208 | |
|---|
| 209 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 210 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 211 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 212 | & ) * rho_air_zw(k) & |
|---|
| 213 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 214 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 215 | & ) * rho_air_zw(k-1) & |
|---|
| 216 | & ) * ddzw(k) * drho_air(k) |
|---|
| 217 | ENDDO |
|---|
| 218 | |
|---|
| 219 | ! |
|---|
| 220 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 221 | !-- if the momentum flux at the bottom is given by the Prandtl law |
|---|
| 222 | !-- or if it is prescribed by the user. |
|---|
| 223 | !-- Difference quotient of the momentum flux is not formed over |
|---|
| 224 | !-- half of the grid spacing (2.0*ddzw(k)) any more, since the |
|---|
| 225 | !-- comparison with other (LES) models showed that the values of |
|---|
| 226 | !-- the momentum flux becomes too large in this case. |
|---|
| 227 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 228 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 229 | IF ( use_surface_fluxes ) THEN |
|---|
| 230 | k = nzb_v_inner(j,i)+1 |
|---|
| 231 | ! |
|---|
| 232 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 233 | kmzp = 0.25_wp * & |
|---|
| 234 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 235 | |
|---|
| 236 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 237 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 238 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 239 | & ) * rho_air_zw(k) & |
|---|
| 240 | & - ( -vsws(j,i) ) & |
|---|
| 241 | & ) * ddzw(k) * drho_air(k) |
|---|
| 242 | ENDIF |
|---|
| 243 | |
|---|
| 244 | ! |
|---|
| 245 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 246 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 247 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 248 | k = nzt |
|---|
| 249 | ! |
|---|
| 250 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 251 | kmzm = 0.25_wp * & |
|---|
| 252 | ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 253 | |
|---|
| 254 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 255 | & + ( ( -vswst(j,i) ) & |
|---|
| 256 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 257 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 258 | & ) * rho_air_zw(k-1) & |
|---|
| 259 | & ) * ddzw(k) * drho_air(k) |
|---|
| 260 | ENDIF |
|---|
| 261 | |
|---|
| 262 | ENDDO |
|---|
| 263 | ENDDO |
|---|
| 264 | |
|---|
| 265 | END SUBROUTINE diffusion_v |
|---|
| 266 | |
|---|
| 267 | |
|---|
| 268 | !------------------------------------------------------------------------------! |
|---|
| 269 | ! Description: |
|---|
| 270 | ! ------------ |
|---|
| 271 | !> Call for grid point i,j |
|---|
| 272 | !------------------------------------------------------------------------------! |
|---|
| 273 | SUBROUTINE diffusion_v_ij( i, j ) |
|---|
| 274 | |
|---|
| 275 | USE arrays_3d, & |
|---|
| 276 | ONLY: ddzu, ddzw, km, tend, u, v, vsws, vswst, w, & |
|---|
| 277 | drho_air, rho_air_zw |
|---|
| 278 | |
|---|
| 279 | USE control_parameters, & |
|---|
| 280 | ONLY: constant_top_momentumflux, use_surface_fluxes, use_top_fluxes |
|---|
| 281 | |
|---|
| 282 | USE grid_variables, & |
|---|
| 283 | ONLY: ddx, ddy, ddy2, fxm, fxp, wall_v |
|---|
| 284 | |
|---|
| 285 | USE indices, & |
|---|
| 286 | ONLY: nzb, nzb_diff_v, nzb_v_inner, nzb_v_outer, nzt, nzt_diff |
|---|
| 287 | |
|---|
| 288 | USE kinds |
|---|
| 289 | |
|---|
| 290 | IMPLICIT NONE |
|---|
| 291 | |
|---|
| 292 | INTEGER(iwp) :: i !< |
|---|
| 293 | INTEGER(iwp) :: j !< |
|---|
| 294 | INTEGER(iwp) :: k !< |
|---|
| 295 | REAL(wp) :: kmxm !< |
|---|
| 296 | REAL(wp) :: kmxp !< |
|---|
| 297 | REAL(wp) :: kmzm !< |
|---|
| 298 | REAL(wp) :: kmzp !< |
|---|
| 299 | |
|---|
| 300 | REAL(wp), DIMENSION(nzb:nzt+1) :: vsus !< |
|---|
| 301 | |
|---|
| 302 | ! |
|---|
| 303 | !-- Compute horizontal diffusion |
|---|
| 304 | DO k = nzb_v_outer(j,i)+1, nzt |
|---|
| 305 | ! |
|---|
| 306 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 307 | kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 308 | kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 309 | |
|---|
| 310 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 311 | & + ( kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 312 | & + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 313 | & - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 314 | & - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 315 | & ) * ddx & |
|---|
| 316 | & + 2.0_wp * ( & |
|---|
| 317 | & km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 318 | & - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 319 | & ) * ddy2 |
|---|
| 320 | ENDDO |
|---|
| 321 | |
|---|
| 322 | ! |
|---|
| 323 | !-- Wall functions at the left and right walls, respectively |
|---|
| 324 | IF ( wall_v(j,i) /= 0.0_wp ) THEN |
|---|
| 325 | |
|---|
| 326 | ! |
|---|
| 327 | !-- Calculate the horizontal momentum flux v'u' |
|---|
| 328 | CALL wall_fluxes( i, j, nzb_v_inner(j,i)+1, nzb_v_outer(j,i), & |
|---|
| 329 | vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp ) |
|---|
| 330 | |
|---|
| 331 | DO k = nzb_v_inner(j,i)+1, nzb_v_outer(j,i) |
|---|
| 332 | kmxp = 0.25_wp * & |
|---|
| 333 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 334 | kmxm = 0.25_wp * & |
|---|
| 335 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 336 | |
|---|
| 337 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 338 | + 2.0_wp * ( & |
|---|
| 339 | km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 340 | - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 341 | ) * ddy2 & |
|---|
| 342 | + ( fxp(j,i) * ( & |
|---|
| 343 | kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 344 | + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 345 | ) & |
|---|
| 346 | - fxm(j,i) * ( & |
|---|
| 347 | kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 348 | + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 349 | ) & |
|---|
| 350 | + wall_v(j,i) * vsus(k) & |
|---|
| 351 | ) * ddx |
|---|
| 352 | ENDDO |
|---|
| 353 | ENDIF |
|---|
| 354 | |
|---|
| 355 | ! |
|---|
| 356 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 357 | !-- index k starts at nzb_v_inner+2. |
|---|
| 358 | DO k = nzb_diff_v(j,i), nzt_diff |
|---|
| 359 | ! |
|---|
| 360 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 361 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 362 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 363 | |
|---|
| 364 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 365 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 366 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 367 | & ) * rho_air_zw(k) & |
|---|
| 368 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 369 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 370 | & ) * rho_air_zw(k-1) & |
|---|
| 371 | & ) * ddzw(k) * drho_air(k) |
|---|
| 372 | ENDDO |
|---|
| 373 | |
|---|
| 374 | ! |
|---|
| 375 | !-- Vertical diffusion at the first grid point above the surface, if the |
|---|
| 376 | !-- momentum flux at the bottom is given by the Prandtl law or if it is |
|---|
| 377 | !-- prescribed by the user. |
|---|
| 378 | !-- Difference quotient of the momentum flux is not formed over half of |
|---|
| 379 | !-- the grid spacing (2.0*ddzw(k)) any more, since the comparison with |
|---|
| 380 | !-- other (LES) models showed that the values of the momentum flux becomes |
|---|
| 381 | !-- too large in this case. |
|---|
| 382 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 383 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 384 | IF ( use_surface_fluxes ) THEN |
|---|
| 385 | k = nzb_v_inner(j,i)+1 |
|---|
| 386 | ! |
|---|
| 387 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 388 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 389 | |
|---|
| 390 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 391 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 392 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 393 | & ) * rho_air_zw(k) & |
|---|
| 394 | & - ( -vsws(j,i) ) & |
|---|
| 395 | & ) * ddzw(k) * drho_air(k) |
|---|
| 396 | ENDIF |
|---|
| 397 | |
|---|
| 398 | ! |
|---|
| 399 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 400 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 401 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 402 | k = nzt |
|---|
| 403 | ! |
|---|
| 404 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 405 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 406 | |
|---|
| 407 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 408 | & + ( ( -vswst(j,i) ) & |
|---|
| 409 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 410 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 411 | & ) * rho_air_zw(k-1) & |
|---|
| 412 | & ) * ddzw(k) * drho_air(k) |
|---|
| 413 | ENDIF |
|---|
| 414 | |
|---|
| 415 | END SUBROUTINE diffusion_v_ij |
|---|
| 416 | |
|---|
| 417 | END MODULE diffusion_v_mod |
|---|
