| 1 | !> @file diffusion_v.f90 |
|---|
| 2 | !------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the |
|---|
| 6 | ! terms of the GNU General Public License as published by the Free Software |
|---|
| 7 | ! Foundation, either version 3 of the License, or (at your option) any later |
|---|
| 8 | ! version. |
|---|
| 9 | ! |
|---|
| 10 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 11 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 12 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 13 | ! |
|---|
| 14 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 15 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 16 | ! |
|---|
| 17 | ! Copyright 1997-2016 Leibniz Universitaet Hannover |
|---|
| 18 | !------------------------------------------------------------------------------! |
|---|
| 19 | ! |
|---|
| 20 | ! Current revisions: |
|---|
| 21 | ! ----------------- |
|---|
| 22 | ! Anelastic approximation implemented |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: diffusion_v.f90 2037 2016-10-26 11:15:40Z knoop $ |
|---|
| 27 | ! |
|---|
| 28 | ! 2000 2016-08-20 18:09:15Z knoop |
|---|
| 29 | ! Forced header and separation lines into 80 columns |
|---|
| 30 | ! |
|---|
| 31 | ! 1873 2016-04-18 14:50:06Z maronga |
|---|
| 32 | ! Module renamed (removed _mod) |
|---|
| 33 | ! |
|---|
| 34 | ! |
|---|
| 35 | ! 1850 2016-04-08 13:29:27Z maronga |
|---|
| 36 | ! Module renamed |
|---|
| 37 | ! |
|---|
| 38 | ! |
|---|
| 39 | ! 1740 2016-01-13 08:19:40Z raasch |
|---|
| 40 | ! unnecessary calculations of kmzm and kmzp in wall bounded parts removed |
|---|
| 41 | ! |
|---|
| 42 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 43 | ! Code annotations made doxygen readable |
|---|
| 44 | ! |
|---|
| 45 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 46 | ! REAL constants defined as wp-kind |
|---|
| 47 | ! |
|---|
| 48 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 49 | ! ONLY-attribute added to USE-statements, |
|---|
| 50 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 51 | ! kinds are defined in new module kinds, |
|---|
| 52 | ! revision history before 2012 removed, |
|---|
| 53 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 54 | ! all variable declaration statements |
|---|
| 55 | ! |
|---|
| 56 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 57 | ! openacc loop and loop vector clauses removed, declare create moved after |
|---|
| 58 | ! the FORTRAN declaration statement |
|---|
| 59 | ! |
|---|
| 60 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 61 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 62 | ! j_north |
|---|
| 63 | ! |
|---|
| 64 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 65 | ! code put under GPL (PALM 3.9) |
|---|
| 66 | ! |
|---|
| 67 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 68 | ! accelerator version (*_acc) added |
|---|
| 69 | ! |
|---|
| 70 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 71 | ! arrays comunicated by module instead of parameter list |
|---|
| 72 | ! |
|---|
| 73 | ! 978 2012-08-09 08:28:32Z fricke |
|---|
| 74 | ! outflow damping layer removed |
|---|
| 75 | ! kmxm_x/_y and kmxp_x/_y change to kmxm and kmxp |
|---|
| 76 | ! |
|---|
| 77 | ! Revision 1.1 1997/09/12 06:24:01 raasch |
|---|
| 78 | ! Initial revision |
|---|
| 79 | ! |
|---|
| 80 | ! |
|---|
| 81 | ! Description: |
|---|
| 82 | ! ------------ |
|---|
| 83 | !> Diffusion term of the v-component |
|---|
| 84 | !------------------------------------------------------------------------------! |
|---|
| 85 | MODULE diffusion_v_mod |
|---|
| 86 | |
|---|
| 87 | |
|---|
| 88 | USE wall_fluxes_mod |
|---|
| 89 | |
|---|
| 90 | PRIVATE |
|---|
| 91 | PUBLIC diffusion_v, diffusion_v_acc |
|---|
| 92 | |
|---|
| 93 | INTERFACE diffusion_v |
|---|
| 94 | MODULE PROCEDURE diffusion_v |
|---|
| 95 | MODULE PROCEDURE diffusion_v_ij |
|---|
| 96 | END INTERFACE diffusion_v |
|---|
| 97 | |
|---|
| 98 | INTERFACE diffusion_v_acc |
|---|
| 99 | MODULE PROCEDURE diffusion_v_acc |
|---|
| 100 | END INTERFACE diffusion_v_acc |
|---|
| 101 | |
|---|
| 102 | CONTAINS |
|---|
| 103 | |
|---|
| 104 | |
|---|
| 105 | !------------------------------------------------------------------------------! |
|---|
| 106 | ! Description: |
|---|
| 107 | ! ------------ |
|---|
| 108 | !> Call for all grid points |
|---|
| 109 | !------------------------------------------------------------------------------! |
|---|
| 110 | SUBROUTINE diffusion_v |
|---|
| 111 | |
|---|
| 112 | USE arrays_3d, & |
|---|
| 113 | ONLY: ddzu, ddzw, km, tend, u, v, vsws, vswst, w, & |
|---|
| 114 | drho_air, rho_air_zw |
|---|
| 115 | |
|---|
| 116 | USE control_parameters, & |
|---|
| 117 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 118 | use_top_fluxes |
|---|
| 119 | |
|---|
| 120 | USE grid_variables, & |
|---|
| 121 | ONLY: ddx, ddy, ddy2, fxm, fxp, wall_v |
|---|
| 122 | |
|---|
| 123 | USE indices, & |
|---|
| 124 | ONLY: nxl, nxr, nyn, nys, nysv, nzb, nzb_diff_v, nzb_v_inner, & |
|---|
| 125 | nzb_v_outer, nzt, nzt_diff |
|---|
| 126 | |
|---|
| 127 | USE kinds |
|---|
| 128 | |
|---|
| 129 | IMPLICIT NONE |
|---|
| 130 | |
|---|
| 131 | INTEGER(iwp) :: i !< |
|---|
| 132 | INTEGER(iwp) :: j !< |
|---|
| 133 | INTEGER(iwp) :: k !< |
|---|
| 134 | REAL(wp) :: kmxm !< |
|---|
| 135 | REAL(wp) :: kmxp !< |
|---|
| 136 | REAL(wp) :: kmzm !< |
|---|
| 137 | REAL(wp) :: kmzp !< |
|---|
| 138 | |
|---|
| 139 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: vsus !< |
|---|
| 140 | |
|---|
| 141 | ! |
|---|
| 142 | !-- First calculate horizontal momentum flux v'u' at vertical walls, |
|---|
| 143 | !-- if neccessary |
|---|
| 144 | IF ( topography /= 'flat' ) THEN |
|---|
| 145 | CALL wall_fluxes( vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp, nzb_v_inner, & |
|---|
| 146 | nzb_v_outer, wall_v ) |
|---|
| 147 | ENDIF |
|---|
| 148 | |
|---|
| 149 | DO i = nxl, nxr |
|---|
| 150 | DO j = nysv, nyn |
|---|
| 151 | ! |
|---|
| 152 | !-- Compute horizontal diffusion |
|---|
| 153 | DO k = nzb_v_outer(j,i)+1, nzt |
|---|
| 154 | ! |
|---|
| 155 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 156 | kmxp = 0.25_wp * & |
|---|
| 157 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 158 | kmxm = 0.25_wp * & |
|---|
| 159 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 160 | |
|---|
| 161 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 162 | & + ( kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 163 | & + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 164 | & - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 165 | & - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 166 | & ) * ddx & |
|---|
| 167 | & + 2.0_wp * ( & |
|---|
| 168 | & km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 169 | & - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 170 | & ) * ddy2 |
|---|
| 171 | ENDDO |
|---|
| 172 | |
|---|
| 173 | ! |
|---|
| 174 | !-- Wall functions at the left and right walls, respectively |
|---|
| 175 | IF ( wall_v(j,i) /= 0.0_wp ) THEN |
|---|
| 176 | |
|---|
| 177 | DO k = nzb_v_inner(j,i)+1, nzb_v_outer(j,i) |
|---|
| 178 | kmxp = 0.25_wp * & |
|---|
| 179 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 180 | kmxm = 0.25_wp * & |
|---|
| 181 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 182 | |
|---|
| 183 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 184 | + 2.0_wp * ( & |
|---|
| 185 | km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 186 | - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 187 | ) * ddy2 & |
|---|
| 188 | + ( fxp(j,i) * ( & |
|---|
| 189 | kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 190 | + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 191 | ) & |
|---|
| 192 | - fxm(j,i) * ( & |
|---|
| 193 | kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 194 | + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 195 | ) & |
|---|
| 196 | + wall_v(j,i) * vsus(k,j,i) & |
|---|
| 197 | ) * ddx |
|---|
| 198 | ENDDO |
|---|
| 199 | ENDIF |
|---|
| 200 | |
|---|
| 201 | ! |
|---|
| 202 | !-- Compute vertical diffusion. In case of simulating a Prandtl |
|---|
| 203 | !-- layer, index k starts at nzb_v_inner+2. |
|---|
| 204 | DO k = nzb_diff_v(j,i), nzt_diff |
|---|
| 205 | ! |
|---|
| 206 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 207 | kmzp = 0.25_wp * & |
|---|
| 208 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 209 | kmzm = 0.25_wp * & |
|---|
| 210 | ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 211 | |
|---|
| 212 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 213 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 214 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 215 | & ) * rho_air_zw(k) & |
|---|
| 216 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 217 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 218 | & ) * rho_air_zw(k-1) & |
|---|
| 219 | & ) * ddzw(k) * drho_air(k) |
|---|
| 220 | ENDDO |
|---|
| 221 | |
|---|
| 222 | ! |
|---|
| 223 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 224 | !-- if the momentum flux at the bottom is given by the Prandtl law |
|---|
| 225 | !-- or if it is prescribed by the user. |
|---|
| 226 | !-- Difference quotient of the momentum flux is not formed over |
|---|
| 227 | !-- half of the grid spacing (2.0*ddzw(k)) any more, since the |
|---|
| 228 | !-- comparison with other (LES) models showed that the values of |
|---|
| 229 | !-- the momentum flux becomes too large in this case. |
|---|
| 230 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 231 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 232 | IF ( use_surface_fluxes ) THEN |
|---|
| 233 | k = nzb_v_inner(j,i)+1 |
|---|
| 234 | ! |
|---|
| 235 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 236 | kmzp = 0.25_wp * & |
|---|
| 237 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 238 | |
|---|
| 239 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 240 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 241 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 242 | & ) * rho_air_zw(k) & |
|---|
| 243 | & - ( -vsws(j,i) ) & |
|---|
| 244 | & ) * ddzw(k) * drho_air(k) |
|---|
| 245 | ENDIF |
|---|
| 246 | |
|---|
| 247 | ! |
|---|
| 248 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 249 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 250 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 251 | k = nzt |
|---|
| 252 | ! |
|---|
| 253 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 254 | kmzm = 0.25_wp * & |
|---|
| 255 | ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 256 | |
|---|
| 257 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 258 | & + ( ( -vswst(j,i) ) & |
|---|
| 259 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 260 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 261 | & ) * rho_air_zw(k-1) & |
|---|
| 262 | & ) * ddzw(k) * drho_air(k) |
|---|
| 263 | ENDIF |
|---|
| 264 | |
|---|
| 265 | ENDDO |
|---|
| 266 | ENDDO |
|---|
| 267 | |
|---|
| 268 | END SUBROUTINE diffusion_v |
|---|
| 269 | |
|---|
| 270 | |
|---|
| 271 | !------------------------------------------------------------------------------! |
|---|
| 272 | ! Description: |
|---|
| 273 | ! ------------ |
|---|
| 274 | !> Call for all grid points - accelerator version |
|---|
| 275 | !------------------------------------------------------------------------------! |
|---|
| 276 | SUBROUTINE diffusion_v_acc |
|---|
| 277 | |
|---|
| 278 | USE arrays_3d, & |
|---|
| 279 | ONLY: ddzu, ddzw, km, tend, u, v, vsws, vswst, w, & |
|---|
| 280 | drho_air, rho_air_zw |
|---|
| 281 | |
|---|
| 282 | USE control_parameters, & |
|---|
| 283 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 284 | use_top_fluxes |
|---|
| 285 | |
|---|
| 286 | USE grid_variables, & |
|---|
| 287 | ONLY: ddx, ddy, ddy2, fxm, fxp, wall_v |
|---|
| 288 | |
|---|
| 289 | USE indices, & |
|---|
| 290 | ONLY: i_left, i_right, j_north, j_south, nxl, nxr, nyn, nys, nzb, & |
|---|
| 291 | nzb_diff_v, nzb_v_inner, nzb_v_outer, nzt, nzt_diff |
|---|
| 292 | |
|---|
| 293 | USE kinds |
|---|
| 294 | |
|---|
| 295 | IMPLICIT NONE |
|---|
| 296 | |
|---|
| 297 | INTEGER(iwp) :: i !< |
|---|
| 298 | INTEGER(iwp) :: j !< |
|---|
| 299 | INTEGER(iwp) :: k !< |
|---|
| 300 | REAL(wp) :: kmxm !< |
|---|
| 301 | REAL(wp) :: kmxp !< |
|---|
| 302 | REAL(wp) :: kmzm !< |
|---|
| 303 | REAL(wp) :: kmzp !< |
|---|
| 304 | |
|---|
| 305 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: vsus !< |
|---|
| 306 | !$acc declare create ( vsus ) |
|---|
| 307 | |
|---|
| 308 | ! |
|---|
| 309 | !-- First calculate horizontal momentum flux v'u' at vertical walls, |
|---|
| 310 | !-- if neccessary |
|---|
| 311 | IF ( topography /= 'flat' ) THEN |
|---|
| 312 | CALL wall_fluxes_acc( vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp, & |
|---|
| 313 | nzb_v_inner, nzb_v_outer, wall_v ) |
|---|
| 314 | ENDIF |
|---|
| 315 | |
|---|
| 316 | !$acc kernels present ( u, v, w, km, tend, vsws, vswst ) & |
|---|
| 317 | !$acc present ( ddzu, ddzw, fxm, fxp, wall_v ) & |
|---|
| 318 | !$acc present ( nzb_v_inner, nzb_v_outer, nzb_diff_v ) |
|---|
| 319 | DO i = i_left, i_right |
|---|
| 320 | DO j = j_south, j_north |
|---|
| 321 | ! |
|---|
| 322 | !-- Compute horizontal diffusion |
|---|
| 323 | DO k = 1, nzt |
|---|
| 324 | IF ( k > nzb_v_outer(j,i) ) THEN |
|---|
| 325 | ! |
|---|
| 326 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 327 | kmxp = 0.25_wp * & |
|---|
| 328 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 329 | kmxm = 0.25_wp * & |
|---|
| 330 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 331 | |
|---|
| 332 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 333 | & + ( kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 334 | & + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 335 | & - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 336 | & - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 337 | & ) * ddx & |
|---|
| 338 | & + 2.0_wp * ( & |
|---|
| 339 | & km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 340 | & - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 341 | & ) * ddy2 |
|---|
| 342 | ENDIF |
|---|
| 343 | ENDDO |
|---|
| 344 | |
|---|
| 345 | ! |
|---|
| 346 | !-- Wall functions at the left and right walls, respectively |
|---|
| 347 | DO k = 1, nzt |
|---|
| 348 | IF( k > nzb_v_inner(j,i) .AND. k <= nzb_v_outer(j,i) .AND. & |
|---|
| 349 | wall_v(j,i) /= 0.0_wp ) THEN |
|---|
| 350 | |
|---|
| 351 | kmxp = 0.25_wp * & |
|---|
| 352 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 353 | kmxm = 0.25_wp * & |
|---|
| 354 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 355 | |
|---|
| 356 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 357 | + 2.0_wp * ( & |
|---|
| 358 | km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 359 | - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 360 | ) * ddy2 & |
|---|
| 361 | + ( fxp(j,i) * ( & |
|---|
| 362 | kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 363 | + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 364 | ) & |
|---|
| 365 | - fxm(j,i) * ( & |
|---|
| 366 | kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 367 | + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 368 | ) & |
|---|
| 369 | + wall_v(j,i) * vsus(k,j,i) & |
|---|
| 370 | ) * ddx |
|---|
| 371 | ENDIF |
|---|
| 372 | ENDDO |
|---|
| 373 | |
|---|
| 374 | ! |
|---|
| 375 | !-- Compute vertical diffusion. In case of simulating a Prandtl |
|---|
| 376 | !-- layer, index k starts at nzb_v_inner+2. |
|---|
| 377 | DO k = 1, nzt_diff |
|---|
| 378 | IF ( k >= nzb_diff_v(j,i) ) THEN |
|---|
| 379 | ! |
|---|
| 380 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 381 | kmzp = 0.25_wp * & |
|---|
| 382 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 383 | kmzm = 0.25_wp * & |
|---|
| 384 | ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 385 | |
|---|
| 386 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 387 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)& |
|---|
| 388 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 389 | & ) * rho_air_zw(k) & |
|---|
| 390 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k)& |
|---|
| 391 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 392 | & ) * rho_air_zw(k-1) & |
|---|
| 393 | & ) * ddzw(k) * drho_air(k) |
|---|
| 394 | ENDIF |
|---|
| 395 | ENDDO |
|---|
| 396 | |
|---|
| 397 | ENDDO |
|---|
| 398 | ENDDO |
|---|
| 399 | |
|---|
| 400 | ! |
|---|
| 401 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 402 | !-- if the momentum flux at the bottom is given by the Prandtl law |
|---|
| 403 | !-- or if it is prescribed by the user. |
|---|
| 404 | !-- Difference quotient of the momentum flux is not formed over |
|---|
| 405 | !-- half of the grid spacing (2.0*ddzw(k)) any more, since the |
|---|
| 406 | !-- comparison with other (LES) models showed that the values of |
|---|
| 407 | !-- the momentum flux becomes too large in this case. |
|---|
| 408 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 409 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 410 | IF ( use_surface_fluxes ) THEN |
|---|
| 411 | |
|---|
| 412 | DO i = i_left, i_right |
|---|
| 413 | DO j = j_south, j_north |
|---|
| 414 | |
|---|
| 415 | k = nzb_v_inner(j,i)+1 |
|---|
| 416 | ! |
|---|
| 417 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 418 | kmzp = 0.25_wp * & |
|---|
| 419 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 420 | |
|---|
| 421 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 422 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 423 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 424 | & ) * rho_air_zw(k) & |
|---|
| 425 | & - ( -vsws(j,i) ) & |
|---|
| 426 | & ) * ddzw(k) * drho_air(k) |
|---|
| 427 | ENDDO |
|---|
| 428 | ENDDO |
|---|
| 429 | |
|---|
| 430 | ENDIF |
|---|
| 431 | |
|---|
| 432 | ! |
|---|
| 433 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 434 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 435 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 436 | |
|---|
| 437 | k = nzt |
|---|
| 438 | |
|---|
| 439 | DO i = i_left, i_right |
|---|
| 440 | DO j = j_south, j_north |
|---|
| 441 | |
|---|
| 442 | ! |
|---|
| 443 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 444 | kmzm = 0.25_wp * & |
|---|
| 445 | ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 446 | |
|---|
| 447 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 448 | & + ( ( -vswst(j,i) ) & |
|---|
| 449 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 450 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 451 | & ) * rho_air_zw(k-1) & |
|---|
| 452 | & ) * ddzw(k) * drho_air(k) |
|---|
| 453 | ENDDO |
|---|
| 454 | ENDDO |
|---|
| 455 | |
|---|
| 456 | ENDIF |
|---|
| 457 | !$acc end kernels |
|---|
| 458 | |
|---|
| 459 | END SUBROUTINE diffusion_v_acc |
|---|
| 460 | |
|---|
| 461 | |
|---|
| 462 | !------------------------------------------------------------------------------! |
|---|
| 463 | ! Description: |
|---|
| 464 | ! ------------ |
|---|
| 465 | !> Call for grid point i,j |
|---|
| 466 | !------------------------------------------------------------------------------! |
|---|
| 467 | SUBROUTINE diffusion_v_ij( i, j ) |
|---|
| 468 | |
|---|
| 469 | USE arrays_3d, & |
|---|
| 470 | ONLY: ddzu, ddzw, km, tend, u, v, vsws, vswst, w, & |
|---|
| 471 | drho_air, rho_air_zw |
|---|
| 472 | |
|---|
| 473 | USE control_parameters, & |
|---|
| 474 | ONLY: constant_top_momentumflux, use_surface_fluxes, use_top_fluxes |
|---|
| 475 | |
|---|
| 476 | USE grid_variables, & |
|---|
| 477 | ONLY: ddx, ddy, ddy2, fxm, fxp, wall_v |
|---|
| 478 | |
|---|
| 479 | USE indices, & |
|---|
| 480 | ONLY: nzb, nzb_diff_v, nzb_v_inner, nzb_v_outer, nzt, nzt_diff |
|---|
| 481 | |
|---|
| 482 | USE kinds |
|---|
| 483 | |
|---|
| 484 | IMPLICIT NONE |
|---|
| 485 | |
|---|
| 486 | INTEGER(iwp) :: i !< |
|---|
| 487 | INTEGER(iwp) :: j !< |
|---|
| 488 | INTEGER(iwp) :: k !< |
|---|
| 489 | REAL(wp) :: kmxm !< |
|---|
| 490 | REAL(wp) :: kmxp !< |
|---|
| 491 | REAL(wp) :: kmzm !< |
|---|
| 492 | REAL(wp) :: kmzp !< |
|---|
| 493 | |
|---|
| 494 | REAL(wp), DIMENSION(nzb:nzt+1) :: vsus !< |
|---|
| 495 | |
|---|
| 496 | ! |
|---|
| 497 | !-- Compute horizontal diffusion |
|---|
| 498 | DO k = nzb_v_outer(j,i)+1, nzt |
|---|
| 499 | ! |
|---|
| 500 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 501 | kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 502 | kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 503 | |
|---|
| 504 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 505 | & + ( kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 506 | & + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 507 | & - kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 508 | & - kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 509 | & ) * ddx & |
|---|
| 510 | & + 2.0_wp * ( & |
|---|
| 511 | & km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 512 | & - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 513 | & ) * ddy2 |
|---|
| 514 | ENDDO |
|---|
| 515 | |
|---|
| 516 | ! |
|---|
| 517 | !-- Wall functions at the left and right walls, respectively |
|---|
| 518 | IF ( wall_v(j,i) /= 0.0_wp ) THEN |
|---|
| 519 | |
|---|
| 520 | ! |
|---|
| 521 | !-- Calculate the horizontal momentum flux v'u' |
|---|
| 522 | CALL wall_fluxes( i, j, nzb_v_inner(j,i)+1, nzb_v_outer(j,i), & |
|---|
| 523 | vsus, 0.0_wp, 1.0_wp, 0.0_wp, 0.0_wp ) |
|---|
| 524 | |
|---|
| 525 | DO k = nzb_v_inner(j,i)+1, nzb_v_outer(j,i) |
|---|
| 526 | kmxp = 0.25_wp * & |
|---|
| 527 | ( km(k,j,i)+km(k,j,i+1)+km(k,j-1,i)+km(k,j-1,i+1) ) |
|---|
| 528 | kmxm = 0.25_wp * & |
|---|
| 529 | ( km(k,j,i)+km(k,j,i-1)+km(k,j-1,i)+km(k,j-1,i-1) ) |
|---|
| 530 | |
|---|
| 531 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 532 | + 2.0_wp * ( & |
|---|
| 533 | km(k,j,i) * ( v(k,j+1,i) - v(k,j,i) ) & |
|---|
| 534 | - km(k,j-1,i) * ( v(k,j,i) - v(k,j-1,i) ) & |
|---|
| 535 | ) * ddy2 & |
|---|
| 536 | + ( fxp(j,i) * ( & |
|---|
| 537 | kmxp * ( v(k,j,i+1) - v(k,j,i) ) * ddx & |
|---|
| 538 | + kmxp * ( u(k,j,i+1) - u(k,j-1,i+1) ) * ddy & |
|---|
| 539 | ) & |
|---|
| 540 | - fxm(j,i) * ( & |
|---|
| 541 | kmxm * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 542 | + kmxm * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 543 | ) & |
|---|
| 544 | + wall_v(j,i) * vsus(k) & |
|---|
| 545 | ) * ddx |
|---|
| 546 | ENDDO |
|---|
| 547 | ENDIF |
|---|
| 548 | |
|---|
| 549 | ! |
|---|
| 550 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 551 | !-- index k starts at nzb_v_inner+2. |
|---|
| 552 | DO k = nzb_diff_v(j,i), nzt_diff |
|---|
| 553 | ! |
|---|
| 554 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 555 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 556 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 557 | |
|---|
| 558 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 559 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 560 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 561 | & ) * rho_air_zw(k) & |
|---|
| 562 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 563 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 564 | & ) * rho_air_zw(k-1) & |
|---|
| 565 | & ) * ddzw(k) * drho_air(k) |
|---|
| 566 | ENDDO |
|---|
| 567 | |
|---|
| 568 | ! |
|---|
| 569 | !-- Vertical diffusion at the first grid point above the surface, if the |
|---|
| 570 | !-- momentum flux at the bottom is given by the Prandtl law or if it is |
|---|
| 571 | !-- prescribed by the user. |
|---|
| 572 | !-- Difference quotient of the momentum flux is not formed over half of |
|---|
| 573 | !-- the grid spacing (2.0*ddzw(k)) any more, since the comparison with |
|---|
| 574 | !-- other (LES) models showed that the values of the momentum flux becomes |
|---|
| 575 | !-- too large in this case. |
|---|
| 576 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 577 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 578 | IF ( use_surface_fluxes ) THEN |
|---|
| 579 | k = nzb_v_inner(j,i)+1 |
|---|
| 580 | ! |
|---|
| 581 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 582 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 583 | |
|---|
| 584 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 585 | & + ( kmzp * ( ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 586 | & + ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 587 | & ) * rho_air_zw(k) & |
|---|
| 588 | & - ( -vsws(j,i) ) & |
|---|
| 589 | & ) * ddzw(k) * drho_air(k) |
|---|
| 590 | ENDIF |
|---|
| 591 | |
|---|
| 592 | ! |
|---|
| 593 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 594 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 595 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 596 | k = nzt |
|---|
| 597 | ! |
|---|
| 598 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 599 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j-1,i)+km(k-1,j-1,i) ) |
|---|
| 600 | |
|---|
| 601 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 602 | & + ( ( -vswst(j,i) ) & |
|---|
| 603 | & - kmzm * ( ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k) & |
|---|
| 604 | & + ( w(k-1,j,i) - w(k-1,j-1,i) ) * ddy & |
|---|
| 605 | & ) * rho_air_zw(k-1) & |
|---|
| 606 | & ) * ddzw(k) * drho_air(k) |
|---|
| 607 | ENDIF |
|---|
| 608 | |
|---|
| 609 | END SUBROUTINE diffusion_v_ij |
|---|
| 610 | |
|---|
| 611 | END MODULE diffusion_v_mod |
|---|
