source: palm/trunk/SOURCE/diffusion_u.f90 @ 2118

Last change on this file since 2118 was 2118, checked in by raasch, 5 years ago

all OpenACC directives and related parts removed from the code

  • Property svn:keywords set to Id
File size: 18.4 KB
Line 
1!> @file diffusion_u.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! OpenACC version of subroutine removed
23!
24! Former revisions:
25! -----------------
26! $Id: diffusion_u.f90 2118 2017-01-17 16:38:49Z raasch $
27!
28! 2037 2016-10-26 11:15:40Z knoop
29! Anelastic approximation implemented
30!
31! 2000 2016-08-20 18:09:15Z knoop
32! Forced header and separation lines into 80 columns
33!
34! 1873 2016-04-18 14:50:06Z maronga
35! Module renamed (removed _mod)
36!
37! 1850 2016-04-08 13:29:27Z maronga
38! Module renamed
39!
40! 1740 2016-01-13 08:19:40Z raasch
41! unnecessary calculations of kmzm and kmzp in wall bounded parts removed
42!
43! 1691 2015-10-26 16:17:44Z maronga
44! Formatting corrections.
45!
46! 1682 2015-10-07 23:56:08Z knoop
47! Code annotations made doxygen readable
48!
49! 1340 2014-03-25 19:45:13Z kanani
50! REAL constants defined as wp-kind
51!
52! 1320 2014-03-20 08:40:49Z raasch
53! ONLY-attribute added to USE-statements,
54! kind-parameters added to all INTEGER and REAL declaration statements,
55! kinds are defined in new module kinds,
56! revision history before 2012 removed,
57! comment fields (!:) to be used for variable explanations added to
58! all variable declaration statements
59!
60! 1257 2013-11-08 15:18:40Z raasch
61! openacc loop and loop vector clauses removed, declare create moved after
62! the FORTRAN declaration statement
63!
64! 1128 2013-04-12 06:19:32Z raasch
65! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
66! j_north
67!
68! 1036 2012-10-22 13:43:42Z raasch
69! code put under GPL (PALM 3.9)
70!
71! 1015 2012-09-27 09:23:24Z raasch
72! accelerator version (*_acc) added
73!
74! 1001 2012-09-13 14:08:46Z raasch
75! arrays comunicated by module instead of parameter list
76!
77! 978 2012-08-09 08:28:32Z fricke
78! outflow damping layer removed
79! kmym_x/_y and kmyp_x/_y change to kmym and kmyp
80!
81! Revision 1.1  1997/09/12 06:23:51  raasch
82! Initial revision
83!
84!
85! Description:
86! ------------
87!> Diffusion term of the u-component
88!> @todo additional damping (needed for non-cyclic bc) causes bad vectorization
89!>       and slows down the speed on NEC about 5-10%
90!------------------------------------------------------------------------------!
91 MODULE diffusion_u_mod
92 
93
94    USE wall_fluxes_mod
95
96    PRIVATE
97    PUBLIC diffusion_u
98
99    INTERFACE diffusion_u
100       MODULE PROCEDURE diffusion_u
101       MODULE PROCEDURE diffusion_u_ij
102    END INTERFACE diffusion_u
103
104 CONTAINS
105
106
107!------------------------------------------------------------------------------!
108! Description:
109! ------------
110!> Call for all grid points
111!------------------------------------------------------------------------------!
112    SUBROUTINE diffusion_u
113
114       USE arrays_3d,                                                          &
115           ONLY:  ddzu, ddzw, km, tend, u, usws, uswst, v, w,                  &
116                  drho_air, rho_air_zw
117       
118       USE control_parameters,                                                 &
119           ONLY:  constant_top_momentumflux, topography, use_surface_fluxes,   &
120                  use_top_fluxes
121       
122       USE grid_variables,                                                     &
123           ONLY:  ddx, ddx2, ddy, fym, fyp, wall_u
124       
125       USE indices,                                                            &
126           ONLY:  nxl, nxlu, nxr, nyn, nys, nzb, nzb_diff_u, nzb_u_inner,      &
127                  nzb_u_outer, nzt, nzt_diff
128       
129       USE kinds
130
131       IMPLICIT NONE
132
133       INTEGER(iwp) ::  i     !<
134       INTEGER(iwp) ::  j     !<
135       INTEGER(iwp) ::  k     !<
136       REAL(wp)     ::  kmym  !<
137       REAL(wp)     ::  kmyp  !<
138       REAL(wp)     ::  kmzm  !<
139       REAL(wp)     ::  kmzp  !<
140
141       REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) ::  usvs  !<
142
143!
144!--    First calculate horizontal momentum flux u'v' at vertical walls,
145!--    if neccessary
146       IF ( topography /= 'flat' )  THEN
147          CALL wall_fluxes( usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, nzb_u_inner, &
148                            nzb_u_outer, wall_u )
149       ENDIF
150
151       DO  i = nxlu, nxr
152          DO  j = nys, nyn
153!
154!--          Compute horizontal diffusion
155             DO  k = nzb_u_outer(j,i)+1, nzt
156!
157!--             Interpolate eddy diffusivities on staggered gridpoints
158                kmyp = 0.25_wp *                                               &
159                       ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) )
160                kmym = 0.25_wp *                                               &
161                       ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) )
162
163                tend(k,j,i) = tend(k,j,i)                                      &
164                      & + 2.0_wp * (                                           &
165                      &           km(k,j,i)   * ( u(k,j,i+1) - u(k,j,i)   )    &
166                      &         - km(k,j,i-1) * ( u(k,j,i)   - u(k,j,i-1) )    &
167                      &            ) * ddx2                                    &
168                      & + ( kmyp * ( u(k,j+1,i) - u(k,j,i)     ) * ddy         &
169                      &   + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx         &
170                      &   - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy             &
171                      &   - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx             &
172                      &   ) * ddy
173             ENDDO
174
175!
176!--          Wall functions at the north and south walls, respectively
177             IF ( wall_u(j,i) /= 0.0_wp )  THEN
178
179                DO  k = nzb_u_inner(j,i)+1, nzb_u_outer(j,i)
180                   kmyp = 0.25_wp *                                            &
181                          ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) )
182                   kmym = 0.25_wp *                                            &
183                          ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) )
184
185                   tend(k,j,i) = tend(k,j,i)                                   &
186                                 + 2.0_wp * (                                  &
187                                       km(k,j,i)   * ( u(k,j,i+1) - u(k,j,i) ) &
188                                     - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) &
189                                            ) * ddx2                           &
190                                 + (   fyp(j,i) * (                            &
191                                  kmyp * ( u(k,j+1,i) - u(k,j,i)     ) * ddy   &
192                                + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx   &
193                                                  )                            &
194                                     - fym(j,i) * (                            &
195                                  kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy       &
196                                + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx       &
197                                                  )                            &
198                                     + wall_u(j,i) * usvs(k,j,i)               &
199                                   ) * ddy
200                ENDDO
201             ENDIF
202
203!
204!--          Compute vertical diffusion. In case of simulating a Prandtl layer,
205!--          index k starts at nzb_u_inner+2.
206             DO  k = nzb_diff_u(j,i), nzt_diff
207!
208!--             Interpolate eddy diffusivities on staggered gridpoints
209                kmzp = 0.25_wp *                                               &
210                       ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) )
211                kmzm = 0.25_wp *                                               &
212                       ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) )
213
214                tend(k,j,i) = tend(k,j,i)                                      &
215                      & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)   &
216                      &            + ( w(k,j,i)   - w(k,j,i-1) ) * ddx         &
217                      &            ) * rho_air_zw(k)                           &
218                      &   - kmzm * ( ( u(k,j,i)   - u(k-1,j,i)   ) * ddzu(k)   &
219                      &            + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx       &
220                      &            ) * rho_air_zw(k-1)                         &
221                      &   ) * ddzw(k) * drho_air(k)
222             ENDDO
223
224!
225!--          Vertical diffusion at the first grid point above the surface,
226!--          if the momentum flux at the bottom is given by the Prandtl law or
227!--          if it is prescribed by the user.
228!--          Difference quotient of the momentum flux is not formed over half
229!--          of the grid spacing (2.0*ddzw(k)) any more, since the comparison
230!--          with other (LES) models showed that the values of the momentum
231!--          flux becomes too large in this case.
232!--          The term containing w(k-1,..) (see above equation) is removed here
233!--          because the vertical velocity is assumed to be zero at the surface.
234             IF ( use_surface_fluxes )  THEN
235                k = nzb_u_inner(j,i)+1
236!
237!--             Interpolate eddy diffusivities on staggered gridpoints
238                kmzp = 0.25_wp *                                               &
239                      ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) )
240
241                tend(k,j,i) = tend(k,j,i)                                      &
242                      & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)   &
243                      &            + ( w(k,j,i)   - w(k,j,i-1) ) * ddx         &
244                      &            ) * rho_air_zw(k)                           &
245                      &   - ( -usws(j,i) )                                     &
246                      &   ) * ddzw(k) * drho_air(k)
247             ENDIF
248
249!
250!--          Vertical diffusion at the first gridpoint below the top boundary,
251!--          if the momentum flux at the top is prescribed by the user
252             IF ( use_top_fluxes  .AND.  constant_top_momentumflux )  THEN
253                k = nzt
254!
255!--             Interpolate eddy diffusivities on staggered gridpoints
256                kmzm = 0.25_wp *                                               &
257                       ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) )
258
259                tend(k,j,i) = tend(k,j,i)                                      &
260                      & + ( ( -uswst(j,i) )                                    &
261                      &   - kmzm * ( ( u(k,j,i)   - u(k-1,j,i)   ) * ddzu(k)   &
262                      &            + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx       &
263                      &            ) * rho_air_zw(k-1)                         &
264                      &   ) * ddzw(k) * drho_air(k)
265             ENDIF
266
267          ENDDO
268       ENDDO
269
270    END SUBROUTINE diffusion_u
271
272
273!------------------------------------------------------------------------------!
274! Description:
275! ------------
276!> Call for grid point i,j
277!------------------------------------------------------------------------------!
278    SUBROUTINE diffusion_u_ij( i, j )
279
280       USE arrays_3d,                                                          &
281           ONLY:  ddzu, ddzw, km, tend, u, usws, uswst, v, w,                  &
282                  drho_air, rho_air_zw
283       
284       USE control_parameters,                                                 &
285           ONLY:  constant_top_momentumflux, use_surface_fluxes, use_top_fluxes
286       
287       USE grid_variables,                                                     &
288           ONLY:  ddx, ddx2, ddy, fym, fyp, wall_u
289       
290       USE indices,                                                            &
291           ONLY:  nzb, nzb_diff_u, nzb_u_inner, nzb_u_outer, nzt, nzt_diff
292       
293       USE kinds
294
295       IMPLICIT NONE
296
297       INTEGER(iwp) ::  i     !<
298       INTEGER(iwp) ::  j     !<
299       INTEGER(iwp) ::  k     !<
300       REAL(wp)     ::  kmym  !<
301       REAL(wp)     ::  kmyp  !<
302       REAL(wp)     ::  kmzm  !<
303       REAL(wp)     ::  kmzp  !<
304
305       REAL(wp), DIMENSION(nzb:nzt+1) ::  usvs  !<
306
307!
308!--    Compute horizontal diffusion
309       DO  k = nzb_u_outer(j,i)+1, nzt
310!
311!--       Interpolate eddy diffusivities on staggered gridpoints
312          kmyp = 0.25_wp * ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) )
313          kmym = 0.25_wp * ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) )
314
315          tend(k,j,i) = tend(k,j,i)                                            &
316                      & + 2.0_wp * (                                           &
317                      &           km(k,j,i)   * ( u(k,j,i+1) - u(k,j,i)   )    &
318                      &         - km(k,j,i-1) * ( u(k,j,i)   - u(k,j,i-1) )    &
319                      &            ) * ddx2                                    &
320                      & + ( kmyp * ( u(k,j+1,i) - u(k,j,i)     ) * ddy         &
321                      &   + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx         &
322                      &   - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy             &
323                      &   - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx             &
324                      &   ) * ddy
325       ENDDO
326
327!
328!--    Wall functions at the north and south walls, respectively
329       IF ( wall_u(j,i) /= 0.0_wp )  THEN
330
331!
332!--       Calculate the horizontal momentum flux u'v'
333          CALL wall_fluxes( i, j, nzb_u_inner(j,i)+1, nzb_u_outer(j,i),        &
334                            usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp )
335
336          DO  k = nzb_u_inner(j,i)+1, nzb_u_outer(j,i)
337             kmyp = 0.25_wp * ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) )
338             kmym = 0.25_wp * ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) )
339
340             tend(k,j,i) = tend(k,j,i)                                         &
341                                 + 2.0_wp * (                                  &
342                                       km(k,j,i)   * ( u(k,j,i+1) - u(k,j,i) ) &
343                                     - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) &
344                                            ) * ddx2                           &
345                                 + (   fyp(j,i) * (                            &
346                                  kmyp * ( u(k,j+1,i) - u(k,j,i)     ) * ddy   &
347                                + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx   &
348                                                  )                            &
349                                     - fym(j,i) * (                            &
350                                  kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy       &
351                                + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx       &
352                                                  )                            &
353                                     + wall_u(j,i) * usvs(k)                   &
354                                   ) * ddy
355          ENDDO
356       ENDIF
357
358!
359!--    Compute vertical diffusion. In case of simulating a Prandtl layer,
360!--    index k starts at nzb_u_inner+2.
361       DO  k = nzb_diff_u(j,i), nzt_diff
362!
363!--       Interpolate eddy diffusivities on staggered gridpoints
364          kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) )
365          kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) )
366
367          tend(k,j,i) = tend(k,j,i)                                            &
368                      & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)   &
369                      &            + ( w(k,j,i)   - w(k,j,i-1) ) * ddx         &
370                      &            ) * rho_air_zw(k)                           &
371                      &   - kmzm * ( ( u(k,j,i)   - u(k-1,j,i)   ) * ddzu(k)   &
372                      &            + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx       &
373                      &            ) * rho_air_zw(k-1)                         &
374                      &   ) * ddzw(k) * drho_air(k)
375       ENDDO
376
377!
378!--    Vertical diffusion at the first grid point above the surface, if the
379!--    momentum flux at the bottom is given by the Prandtl law or if it is
380!--    prescribed by the user.
381!--    Difference quotient of the momentum flux is not formed over half of
382!--    the grid spacing (2.0*ddzw(k)) any more, since the comparison with
383!--    other (LES) models showed that the values of the momentum flux becomes
384!--    too large in this case.
385!--    The term containing w(k-1,..) (see above equation) is removed here
386!--    because the vertical velocity is assumed to be zero at the surface.
387       IF ( use_surface_fluxes )  THEN
388          k = nzb_u_inner(j,i)+1
389!
390!--       Interpolate eddy diffusivities on staggered gridpoints
391          kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) )
392
393          tend(k,j,i) = tend(k,j,i)                                            &
394                      & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i)   ) * ddzu(k+1)   &
395                      &            + ( w(k,j,i)   - w(k,j,i-1) ) * ddx         &
396                      &            ) * rho_air_zw(k)                           &
397                      &   - ( -usws(j,i) )                                     &
398                      &   ) * ddzw(k) * drho_air(k)
399       ENDIF
400
401!
402!--    Vertical diffusion at the first gridpoint below the top boundary,
403!--    if the momentum flux at the top is prescribed by the user
404       IF ( use_top_fluxes  .AND.  constant_top_momentumflux )  THEN
405          k = nzt
406!
407!--       Interpolate eddy diffusivities on staggered gridpoints
408          kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) )
409
410          tend(k,j,i) = tend(k,j,i)                                            &
411                      & + ( ( -uswst(j,i) )                                    &
412                      &   - kmzm * ( ( u(k,j,i)   - u(k-1,j,i)   ) * ddzu(k)   &
413                      &            + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx       &
414                      &            ) * rho_air_zw(k-1)                         &
415                      &   ) * ddzw(k) * drho_air(k)
416       ENDIF
417
418    END SUBROUTINE diffusion_u_ij
419
420 END MODULE diffusion_u_mod
Note: See TracBrowser for help on using the repository browser.