| 1 | !> @file diffusion_u.f90 |
|---|
| 2 | !------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the |
|---|
| 6 | ! terms of the GNU General Public License as published by the Free Software |
|---|
| 7 | ! Foundation, either version 3 of the License, or (at your option) any later |
|---|
| 8 | ! version. |
|---|
| 9 | ! |
|---|
| 10 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 11 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 12 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 13 | ! |
|---|
| 14 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 15 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 16 | ! |
|---|
| 17 | ! Copyright 1997-2016 Leibniz Universitaet Hannover |
|---|
| 18 | !------------------------------------------------------------------------------! |
|---|
| 19 | ! |
|---|
| 20 | ! Current revisions: |
|---|
| 21 | ! ----------------- |
|---|
| 22 | ! Anelastic approximation implemented |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: diffusion_u.f90 2037 2016-10-26 11:15:40Z knoop $ |
|---|
| 27 | ! |
|---|
| 28 | ! 2000 2016-08-20 18:09:15Z knoop |
|---|
| 29 | ! Forced header and separation lines into 80 columns |
|---|
| 30 | ! |
|---|
| 31 | ! 1873 2016-04-18 14:50:06Z maronga |
|---|
| 32 | ! Module renamed (removed _mod) |
|---|
| 33 | ! |
|---|
| 34 | ! |
|---|
| 35 | ! 1850 2016-04-08 13:29:27Z maronga |
|---|
| 36 | ! Module renamed |
|---|
| 37 | ! |
|---|
| 38 | ! |
|---|
| 39 | ! 1740 2016-01-13 08:19:40Z raasch |
|---|
| 40 | ! unnecessary calculations of kmzm and kmzp in wall bounded parts removed |
|---|
| 41 | ! |
|---|
| 42 | ! 1691 2015-10-26 16:17:44Z maronga |
|---|
| 43 | ! Formatting corrections. |
|---|
| 44 | ! |
|---|
| 45 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 46 | ! Code annotations made doxygen readable |
|---|
| 47 | ! |
|---|
| 48 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 49 | ! REAL constants defined as wp-kind |
|---|
| 50 | ! |
|---|
| 51 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 52 | ! ONLY-attribute added to USE-statements, |
|---|
| 53 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 54 | ! kinds are defined in new module kinds, |
|---|
| 55 | ! revision history before 2012 removed, |
|---|
| 56 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 57 | ! all variable declaration statements |
|---|
| 58 | ! |
|---|
| 59 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 60 | ! openacc loop and loop vector clauses removed, declare create moved after |
|---|
| 61 | ! the FORTRAN declaration statement |
|---|
| 62 | ! |
|---|
| 63 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 64 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 65 | ! j_north |
|---|
| 66 | ! |
|---|
| 67 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 68 | ! code put under GPL (PALM 3.9) |
|---|
| 69 | ! |
|---|
| 70 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 71 | ! accelerator version (*_acc) added |
|---|
| 72 | ! |
|---|
| 73 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 74 | ! arrays comunicated by module instead of parameter list |
|---|
| 75 | ! |
|---|
| 76 | ! 978 2012-08-09 08:28:32Z fricke |
|---|
| 77 | ! outflow damping layer removed |
|---|
| 78 | ! kmym_x/_y and kmyp_x/_y change to kmym and kmyp |
|---|
| 79 | ! |
|---|
| 80 | ! Revision 1.1 1997/09/12 06:23:51 raasch |
|---|
| 81 | ! Initial revision |
|---|
| 82 | ! |
|---|
| 83 | ! |
|---|
| 84 | ! Description: |
|---|
| 85 | ! ------------ |
|---|
| 86 | !> Diffusion term of the u-component |
|---|
| 87 | !> @todo additional damping (needed for non-cyclic bc) causes bad vectorization |
|---|
| 88 | !> and slows down the speed on NEC about 5-10% |
|---|
| 89 | !------------------------------------------------------------------------------! |
|---|
| 90 | MODULE diffusion_u_mod |
|---|
| 91 | |
|---|
| 92 | |
|---|
| 93 | USE wall_fluxes_mod |
|---|
| 94 | |
|---|
| 95 | PRIVATE |
|---|
| 96 | PUBLIC diffusion_u, diffusion_u_acc |
|---|
| 97 | |
|---|
| 98 | INTERFACE diffusion_u |
|---|
| 99 | MODULE PROCEDURE diffusion_u |
|---|
| 100 | MODULE PROCEDURE diffusion_u_ij |
|---|
| 101 | END INTERFACE diffusion_u |
|---|
| 102 | |
|---|
| 103 | INTERFACE diffusion_u_acc |
|---|
| 104 | MODULE PROCEDURE diffusion_u_acc |
|---|
| 105 | END INTERFACE diffusion_u_acc |
|---|
| 106 | |
|---|
| 107 | CONTAINS |
|---|
| 108 | |
|---|
| 109 | |
|---|
| 110 | !------------------------------------------------------------------------------! |
|---|
| 111 | ! Description: |
|---|
| 112 | ! ------------ |
|---|
| 113 | !> Call for all grid points |
|---|
| 114 | !------------------------------------------------------------------------------! |
|---|
| 115 | SUBROUTINE diffusion_u |
|---|
| 116 | |
|---|
| 117 | USE arrays_3d, & |
|---|
| 118 | ONLY: ddzu, ddzw, km, tend, u, usws, uswst, v, w, & |
|---|
| 119 | drho_air, rho_air_zw |
|---|
| 120 | |
|---|
| 121 | USE control_parameters, & |
|---|
| 122 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 123 | use_top_fluxes |
|---|
| 124 | |
|---|
| 125 | USE grid_variables, & |
|---|
| 126 | ONLY: ddx, ddx2, ddy, fym, fyp, wall_u |
|---|
| 127 | |
|---|
| 128 | USE indices, & |
|---|
| 129 | ONLY: nxl, nxlu, nxr, nyn, nys, nzb, nzb_diff_u, nzb_u_inner, & |
|---|
| 130 | nzb_u_outer, nzt, nzt_diff |
|---|
| 131 | |
|---|
| 132 | USE kinds |
|---|
| 133 | |
|---|
| 134 | IMPLICIT NONE |
|---|
| 135 | |
|---|
| 136 | INTEGER(iwp) :: i !< |
|---|
| 137 | INTEGER(iwp) :: j !< |
|---|
| 138 | INTEGER(iwp) :: k !< |
|---|
| 139 | REAL(wp) :: kmym !< |
|---|
| 140 | REAL(wp) :: kmyp !< |
|---|
| 141 | REAL(wp) :: kmzm !< |
|---|
| 142 | REAL(wp) :: kmzp !< |
|---|
| 143 | |
|---|
| 144 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: usvs !< |
|---|
| 145 | |
|---|
| 146 | ! |
|---|
| 147 | !-- First calculate horizontal momentum flux u'v' at vertical walls, |
|---|
| 148 | !-- if neccessary |
|---|
| 149 | IF ( topography /= 'flat' ) THEN |
|---|
| 150 | CALL wall_fluxes( usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, nzb_u_inner, & |
|---|
| 151 | nzb_u_outer, wall_u ) |
|---|
| 152 | ENDIF |
|---|
| 153 | |
|---|
| 154 | DO i = nxlu, nxr |
|---|
| 155 | DO j = nys, nyn |
|---|
| 156 | ! |
|---|
| 157 | !-- Compute horizontal diffusion |
|---|
| 158 | DO k = nzb_u_outer(j,i)+1, nzt |
|---|
| 159 | ! |
|---|
| 160 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 161 | kmyp = 0.25_wp * & |
|---|
| 162 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 163 | kmym = 0.25_wp * & |
|---|
| 164 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 165 | |
|---|
| 166 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 167 | & + 2.0_wp * ( & |
|---|
| 168 | & km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 169 | & - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 170 | & ) * ddx2 & |
|---|
| 171 | & + ( kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 172 | & + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 173 | & - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 174 | & - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 175 | & ) * ddy |
|---|
| 176 | ENDDO |
|---|
| 177 | |
|---|
| 178 | ! |
|---|
| 179 | !-- Wall functions at the north and south walls, respectively |
|---|
| 180 | IF ( wall_u(j,i) /= 0.0_wp ) THEN |
|---|
| 181 | |
|---|
| 182 | DO k = nzb_u_inner(j,i)+1, nzb_u_outer(j,i) |
|---|
| 183 | kmyp = 0.25_wp * & |
|---|
| 184 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 185 | kmym = 0.25_wp * & |
|---|
| 186 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 187 | |
|---|
| 188 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 189 | + 2.0_wp * ( & |
|---|
| 190 | km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 191 | - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 192 | ) * ddx2 & |
|---|
| 193 | + ( fyp(j,i) * ( & |
|---|
| 194 | kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 195 | + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 196 | ) & |
|---|
| 197 | - fym(j,i) * ( & |
|---|
| 198 | kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 199 | + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 200 | ) & |
|---|
| 201 | + wall_u(j,i) * usvs(k,j,i) & |
|---|
| 202 | ) * ddy |
|---|
| 203 | ENDDO |
|---|
| 204 | ENDIF |
|---|
| 205 | |
|---|
| 206 | ! |
|---|
| 207 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 208 | !-- index k starts at nzb_u_inner+2. |
|---|
| 209 | DO k = nzb_diff_u(j,i), nzt_diff |
|---|
| 210 | ! |
|---|
| 211 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 212 | kmzp = 0.25_wp * & |
|---|
| 213 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 214 | kmzm = 0.25_wp * & |
|---|
| 215 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 216 | |
|---|
| 217 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 218 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 219 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 220 | & ) * rho_air_zw(k) & |
|---|
| 221 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 222 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 223 | & ) * rho_air_zw(k-1) & |
|---|
| 224 | & ) * ddzw(k) * drho_air(k) |
|---|
| 225 | ENDDO |
|---|
| 226 | |
|---|
| 227 | ! |
|---|
| 228 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 229 | !-- if the momentum flux at the bottom is given by the Prandtl law or |
|---|
| 230 | !-- if it is prescribed by the user. |
|---|
| 231 | !-- Difference quotient of the momentum flux is not formed over half |
|---|
| 232 | !-- of the grid spacing (2.0*ddzw(k)) any more, since the comparison |
|---|
| 233 | !-- with other (LES) models showed that the values of the momentum |
|---|
| 234 | !-- flux becomes too large in this case. |
|---|
| 235 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 236 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 237 | IF ( use_surface_fluxes ) THEN |
|---|
| 238 | k = nzb_u_inner(j,i)+1 |
|---|
| 239 | ! |
|---|
| 240 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 241 | kmzp = 0.25_wp * & |
|---|
| 242 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 243 | |
|---|
| 244 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 245 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 246 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 247 | & ) * rho_air_zw(k) & |
|---|
| 248 | & - ( -usws(j,i) ) & |
|---|
| 249 | & ) * ddzw(k) * drho_air(k) |
|---|
| 250 | ENDIF |
|---|
| 251 | |
|---|
| 252 | ! |
|---|
| 253 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 254 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 255 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 256 | k = nzt |
|---|
| 257 | ! |
|---|
| 258 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 259 | kmzm = 0.25_wp * & |
|---|
| 260 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 261 | |
|---|
| 262 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 263 | & + ( ( -uswst(j,i) ) & |
|---|
| 264 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 265 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 266 | & ) * rho_air_zw(k-1) & |
|---|
| 267 | & ) * ddzw(k) * drho_air(k) |
|---|
| 268 | ENDIF |
|---|
| 269 | |
|---|
| 270 | ENDDO |
|---|
| 271 | ENDDO |
|---|
| 272 | |
|---|
| 273 | END SUBROUTINE diffusion_u |
|---|
| 274 | |
|---|
| 275 | |
|---|
| 276 | !------------------------------------------------------------------------------! |
|---|
| 277 | ! Description: |
|---|
| 278 | ! ------------ |
|---|
| 279 | !> Call for all grid points - accelerator version |
|---|
| 280 | !------------------------------------------------------------------------------! |
|---|
| 281 | SUBROUTINE diffusion_u_acc |
|---|
| 282 | |
|---|
| 283 | USE arrays_3d, & |
|---|
| 284 | ONLY: ddzu, ddzw, km, tend, u, usws, uswst, v, w, & |
|---|
| 285 | drho_air, rho_air_zw |
|---|
| 286 | |
|---|
| 287 | USE control_parameters, & |
|---|
| 288 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 289 | use_top_fluxes |
|---|
| 290 | |
|---|
| 291 | USE grid_variables, & |
|---|
| 292 | ONLY: ddx, ddx2, ddy, fym, fyp, wall_u |
|---|
| 293 | |
|---|
| 294 | USE indices, & |
|---|
| 295 | ONLY: i_left, i_right, j_north, j_south, nxl, nxr, nyn, nys, nzb, & |
|---|
| 296 | nzb_diff_u, nzb_u_inner, nzb_u_outer, nzt, nzt_diff |
|---|
| 297 | |
|---|
| 298 | USE kinds |
|---|
| 299 | |
|---|
| 300 | IMPLICIT NONE |
|---|
| 301 | |
|---|
| 302 | INTEGER(iwp) :: i !< |
|---|
| 303 | INTEGER(iwp) :: j !< |
|---|
| 304 | INTEGER(iwp) :: k !< |
|---|
| 305 | REAL(wp) :: kmym !< |
|---|
| 306 | REAL(wp) :: kmyp !< |
|---|
| 307 | REAL(wp) :: kmzm !< |
|---|
| 308 | REAL(wp) :: kmzp !< |
|---|
| 309 | |
|---|
| 310 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: usvs !< |
|---|
| 311 | !$acc declare create ( usvs ) |
|---|
| 312 | |
|---|
| 313 | ! |
|---|
| 314 | !-- First calculate horizontal momentum flux u'v' at vertical walls, |
|---|
| 315 | !-- if neccessary |
|---|
| 316 | IF ( topography /= 'flat' ) THEN |
|---|
| 317 | CALL wall_fluxes_acc( usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, & |
|---|
| 318 | nzb_u_inner, nzb_u_outer, wall_u ) |
|---|
| 319 | ENDIF |
|---|
| 320 | |
|---|
| 321 | !$acc kernels present ( u, v, w, km, tend, usws, uswst ) & |
|---|
| 322 | !$acc present ( ddzu, ddzw, fym, fyp, wall_u ) & |
|---|
| 323 | !$acc present ( nzb_u_inner, nzb_u_outer, nzb_diff_u ) |
|---|
| 324 | DO i = i_left, i_right |
|---|
| 325 | DO j = j_south, j_north |
|---|
| 326 | ! |
|---|
| 327 | !-- Compute horizontal diffusion |
|---|
| 328 | DO k = 1, nzt |
|---|
| 329 | IF ( k > nzb_u_outer(j,i) ) THEN |
|---|
| 330 | ! |
|---|
| 331 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 332 | kmyp = 0.25_wp * & |
|---|
| 333 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 334 | kmym = 0.25_wp * & |
|---|
| 335 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 336 | |
|---|
| 337 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 338 | & + 2.0_wp * ( & |
|---|
| 339 | & km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 340 | & - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 341 | & ) * ddx2 & |
|---|
| 342 | & + ( kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 343 | & + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 344 | & - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 345 | & - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 346 | & ) * ddy |
|---|
| 347 | ENDIF |
|---|
| 348 | ENDDO |
|---|
| 349 | |
|---|
| 350 | ! |
|---|
| 351 | !-- Wall functions at the north and south walls, respectively |
|---|
| 352 | DO k = 1, nzt |
|---|
| 353 | IF( k > nzb_u_inner(j,i) .AND. k <= nzb_u_outer(j,i) .AND. & |
|---|
| 354 | wall_u(j,i) /= 0.0_wp ) THEN |
|---|
| 355 | |
|---|
| 356 | kmyp = 0.25_wp * & |
|---|
| 357 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 358 | kmym = 0.25_wp * & |
|---|
| 359 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 360 | |
|---|
| 361 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 362 | + 2.0_wp * ( & |
|---|
| 363 | km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 364 | - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 365 | ) * ddx2 & |
|---|
| 366 | + ( fyp(j,i) * ( & |
|---|
| 367 | kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 368 | + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 369 | ) & |
|---|
| 370 | - fym(j,i) * ( & |
|---|
| 371 | kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 372 | + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 373 | ) & |
|---|
| 374 | + wall_u(j,i) * usvs(k,j,i) & |
|---|
| 375 | ) * ddy |
|---|
| 376 | ENDIF |
|---|
| 377 | ENDDO |
|---|
| 378 | |
|---|
| 379 | ! |
|---|
| 380 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 381 | !-- index k starts at nzb_u_inner+2. |
|---|
| 382 | DO k = 1, nzt_diff |
|---|
| 383 | IF ( k >= nzb_diff_u(j,i) ) THEN |
|---|
| 384 | ! |
|---|
| 385 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 386 | kmzp = 0.25_wp * & |
|---|
| 387 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 388 | kmzm = 0.25_wp * & |
|---|
| 389 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 390 | |
|---|
| 391 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 392 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1)& |
|---|
| 393 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 394 | & ) * rho_air_zw(k) & |
|---|
| 395 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k)& |
|---|
| 396 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 397 | & ) * rho_air_zw(k-1) & |
|---|
| 398 | & ) * ddzw(k) * drho_air(k) |
|---|
| 399 | ENDIF |
|---|
| 400 | ENDDO |
|---|
| 401 | |
|---|
| 402 | ENDDO |
|---|
| 403 | ENDDO |
|---|
| 404 | |
|---|
| 405 | ! |
|---|
| 406 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 407 | !-- if the momentum flux at the bottom is given by the Prandtl law or |
|---|
| 408 | !-- if it is prescribed by the user. |
|---|
| 409 | !-- Difference quotient of the momentum flux is not formed over half |
|---|
| 410 | !-- of the grid spacing (2.0*ddzw(k)) any more, since the comparison |
|---|
| 411 | !-- with other (LES) models showed that the values of the momentum |
|---|
| 412 | !-- flux becomes too large in this case. |
|---|
| 413 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 414 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 415 | IF ( use_surface_fluxes ) THEN |
|---|
| 416 | |
|---|
| 417 | DO i = i_left, i_right |
|---|
| 418 | DO j = j_south, j_north |
|---|
| 419 | |
|---|
| 420 | k = nzb_u_inner(j,i)+1 |
|---|
| 421 | ! |
|---|
| 422 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 423 | kmzp = 0.25_wp * & |
|---|
| 424 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 425 | |
|---|
| 426 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 427 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 428 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 429 | & ) * rho_air_zw(k) & |
|---|
| 430 | & - ( -usws(j,i) ) & |
|---|
| 431 | & ) * ddzw(k) * drho_air(k) |
|---|
| 432 | ENDDO |
|---|
| 433 | ENDDO |
|---|
| 434 | |
|---|
| 435 | ENDIF |
|---|
| 436 | |
|---|
| 437 | ! |
|---|
| 438 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 439 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 440 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 441 | |
|---|
| 442 | k = nzt |
|---|
| 443 | |
|---|
| 444 | DO i = i_left, i_right |
|---|
| 445 | DO j = j_south, j_north |
|---|
| 446 | |
|---|
| 447 | ! |
|---|
| 448 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 449 | kmzm = 0.25_wp * & |
|---|
| 450 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 451 | |
|---|
| 452 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 453 | & + ( ( -uswst(j,i) ) & |
|---|
| 454 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 455 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 456 | & ) * rho_air_zw(k-1) & |
|---|
| 457 | & ) * ddzw(k) * drho_air(k) |
|---|
| 458 | ENDDO |
|---|
| 459 | ENDDO |
|---|
| 460 | |
|---|
| 461 | ENDIF |
|---|
| 462 | !$acc end kernels |
|---|
| 463 | |
|---|
| 464 | END SUBROUTINE diffusion_u_acc |
|---|
| 465 | |
|---|
| 466 | |
|---|
| 467 | !------------------------------------------------------------------------------! |
|---|
| 468 | ! Description: |
|---|
| 469 | ! ------------ |
|---|
| 470 | !> Call for grid point i,j |
|---|
| 471 | !------------------------------------------------------------------------------! |
|---|
| 472 | SUBROUTINE diffusion_u_ij( i, j ) |
|---|
| 473 | |
|---|
| 474 | USE arrays_3d, & |
|---|
| 475 | ONLY: ddzu, ddzw, km, tend, u, usws, uswst, v, w, & |
|---|
| 476 | drho_air, rho_air_zw |
|---|
| 477 | |
|---|
| 478 | USE control_parameters, & |
|---|
| 479 | ONLY: constant_top_momentumflux, use_surface_fluxes, use_top_fluxes |
|---|
| 480 | |
|---|
| 481 | USE grid_variables, & |
|---|
| 482 | ONLY: ddx, ddx2, ddy, fym, fyp, wall_u |
|---|
| 483 | |
|---|
| 484 | USE indices, & |
|---|
| 485 | ONLY: nzb, nzb_diff_u, nzb_u_inner, nzb_u_outer, nzt, nzt_diff |
|---|
| 486 | |
|---|
| 487 | USE kinds |
|---|
| 488 | |
|---|
| 489 | IMPLICIT NONE |
|---|
| 490 | |
|---|
| 491 | INTEGER(iwp) :: i !< |
|---|
| 492 | INTEGER(iwp) :: j !< |
|---|
| 493 | INTEGER(iwp) :: k !< |
|---|
| 494 | REAL(wp) :: kmym !< |
|---|
| 495 | REAL(wp) :: kmyp !< |
|---|
| 496 | REAL(wp) :: kmzm !< |
|---|
| 497 | REAL(wp) :: kmzp !< |
|---|
| 498 | |
|---|
| 499 | REAL(wp), DIMENSION(nzb:nzt+1) :: usvs !< |
|---|
| 500 | |
|---|
| 501 | ! |
|---|
| 502 | !-- Compute horizontal diffusion |
|---|
| 503 | DO k = nzb_u_outer(j,i)+1, nzt |
|---|
| 504 | ! |
|---|
| 505 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 506 | kmyp = 0.25_wp * ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 507 | kmym = 0.25_wp * ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 508 | |
|---|
| 509 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 510 | & + 2.0_wp * ( & |
|---|
| 511 | & km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 512 | & - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 513 | & ) * ddx2 & |
|---|
| 514 | & + ( kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 515 | & + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 516 | & - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 517 | & - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 518 | & ) * ddy |
|---|
| 519 | ENDDO |
|---|
| 520 | |
|---|
| 521 | ! |
|---|
| 522 | !-- Wall functions at the north and south walls, respectively |
|---|
| 523 | IF ( wall_u(j,i) /= 0.0_wp ) THEN |
|---|
| 524 | |
|---|
| 525 | ! |
|---|
| 526 | !-- Calculate the horizontal momentum flux u'v' |
|---|
| 527 | CALL wall_fluxes( i, j, nzb_u_inner(j,i)+1, nzb_u_outer(j,i), & |
|---|
| 528 | usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp ) |
|---|
| 529 | |
|---|
| 530 | DO k = nzb_u_inner(j,i)+1, nzb_u_outer(j,i) |
|---|
| 531 | kmyp = 0.25_wp * ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 532 | kmym = 0.25_wp * ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 533 | |
|---|
| 534 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 535 | + 2.0_wp * ( & |
|---|
| 536 | km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 537 | - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 538 | ) * ddx2 & |
|---|
| 539 | + ( fyp(j,i) * ( & |
|---|
| 540 | kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 541 | + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 542 | ) & |
|---|
| 543 | - fym(j,i) * ( & |
|---|
| 544 | kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 545 | + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 546 | ) & |
|---|
| 547 | + wall_u(j,i) * usvs(k) & |
|---|
| 548 | ) * ddy |
|---|
| 549 | ENDDO |
|---|
| 550 | ENDIF |
|---|
| 551 | |
|---|
| 552 | ! |
|---|
| 553 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 554 | !-- index k starts at nzb_u_inner+2. |
|---|
| 555 | DO k = nzb_diff_u(j,i), nzt_diff |
|---|
| 556 | ! |
|---|
| 557 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 558 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 559 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 560 | |
|---|
| 561 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 562 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 563 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 564 | & ) * rho_air_zw(k) & |
|---|
| 565 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 566 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 567 | & ) * rho_air_zw(k-1) & |
|---|
| 568 | & ) * ddzw(k) * drho_air(k) |
|---|
| 569 | ENDDO |
|---|
| 570 | |
|---|
| 571 | ! |
|---|
| 572 | !-- Vertical diffusion at the first grid point above the surface, if the |
|---|
| 573 | !-- momentum flux at the bottom is given by the Prandtl law or if it is |
|---|
| 574 | !-- prescribed by the user. |
|---|
| 575 | !-- Difference quotient of the momentum flux is not formed over half of |
|---|
| 576 | !-- the grid spacing (2.0*ddzw(k)) any more, since the comparison with |
|---|
| 577 | !-- other (LES) models showed that the values of the momentum flux becomes |
|---|
| 578 | !-- too large in this case. |
|---|
| 579 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 580 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 581 | IF ( use_surface_fluxes ) THEN |
|---|
| 582 | k = nzb_u_inner(j,i)+1 |
|---|
| 583 | ! |
|---|
| 584 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 585 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 586 | |
|---|
| 587 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 588 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 589 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 590 | & ) * rho_air_zw(k) & |
|---|
| 591 | & - ( -usws(j,i) ) & |
|---|
| 592 | & ) * ddzw(k) * drho_air(k) |
|---|
| 593 | ENDIF |
|---|
| 594 | |
|---|
| 595 | ! |
|---|
| 596 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 597 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 598 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 599 | k = nzt |
|---|
| 600 | ! |
|---|
| 601 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 602 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 603 | |
|---|
| 604 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 605 | & + ( ( -uswst(j,i) ) & |
|---|
| 606 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 607 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 608 | & ) * rho_air_zw(k-1) & |
|---|
| 609 | & ) * ddzw(k) * drho_air(k) |
|---|
| 610 | ENDIF |
|---|
| 611 | |
|---|
| 612 | END SUBROUTINE diffusion_u_ij |
|---|
| 613 | |
|---|
| 614 | END MODULE diffusion_u_mod |
|---|
