| 1 | !> @file diffusion_s_mod.f90 |
|---|
| 2 | !--------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the terms |
|---|
| 6 | ! of the GNU General Public License as published by the Free Software Foundation, |
|---|
| 7 | ! either version 3 of the License, or (at your option) any later version. |
|---|
| 8 | ! |
|---|
| 9 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 10 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 11 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 12 | ! |
|---|
| 13 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 14 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 15 | ! |
|---|
| 16 | ! Copyright 1997-2016 Leibniz Universitaet Hannover |
|---|
| 17 | !--------------------------------------------------------------------------------! |
|---|
| 18 | ! |
|---|
| 19 | ! Current revisions: |
|---|
| 20 | ! ------------------ |
|---|
| 21 | ! Module renamed |
|---|
| 22 | ! |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: diffusion_s_mod.f90 1850 2016-04-08 13:29:27Z maronga $ |
|---|
| 27 | ! |
|---|
| 28 | ! 1691 2015-10-26 16:17:44Z maronga |
|---|
| 29 | ! Formatting corrections. |
|---|
| 30 | ! |
|---|
| 31 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 32 | ! Code annotations made doxygen readable |
|---|
| 33 | ! |
|---|
| 34 | ! 1374 2014-04-25 12:55:07Z raasch |
|---|
| 35 | ! missing variables added to ONLY list |
|---|
| 36 | ! |
|---|
| 37 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 38 | ! REAL constants defined as wp-kind |
|---|
| 39 | ! |
|---|
| 40 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 41 | ! ONLY-attribute added to USE-statements, |
|---|
| 42 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 43 | ! kinds are defined in new module kinds, |
|---|
| 44 | ! revision history before 2012 removed, |
|---|
| 45 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 46 | ! all variable declaration statements |
|---|
| 47 | ! |
|---|
| 48 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 49 | ! openacc loop and loop vector clauses removed |
|---|
| 50 | ! |
|---|
| 51 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 52 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 53 | ! j_north |
|---|
| 54 | ! |
|---|
| 55 | ! 1092 2013-02-02 11:24:22Z raasch |
|---|
| 56 | ! unused variables removed |
|---|
| 57 | ! |
|---|
| 58 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 59 | ! code put under GPL (PALM 3.9) |
|---|
| 60 | ! |
|---|
| 61 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 62 | ! accelerator version (*_acc) added |
|---|
| 63 | ! |
|---|
| 64 | ! 1010 2012-09-20 07:59:54Z raasch |
|---|
| 65 | ! cpp switch __nopointer added for pointer free version |
|---|
| 66 | ! |
|---|
| 67 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 68 | ! some arrays comunicated by module instead of parameter list |
|---|
| 69 | ! |
|---|
| 70 | ! Revision 1.1 2000/04/13 14:54:02 schroeter |
|---|
| 71 | ! Initial revision |
|---|
| 72 | ! |
|---|
| 73 | ! |
|---|
| 74 | ! Description: |
|---|
| 75 | ! ------------ |
|---|
| 76 | !> Diffusion term of scalar quantities (temperature and water content) |
|---|
| 77 | !------------------------------------------------------------------------------! |
|---|
| 78 | MODULE diffusion_s_mod |
|---|
| 79 | |
|---|
| 80 | |
|---|
| 81 | PRIVATE |
|---|
| 82 | PUBLIC diffusion_s, diffusion_s_acc |
|---|
| 83 | |
|---|
| 84 | INTERFACE diffusion_s |
|---|
| 85 | MODULE PROCEDURE diffusion_s |
|---|
| 86 | MODULE PROCEDURE diffusion_s_ij |
|---|
| 87 | END INTERFACE diffusion_s |
|---|
| 88 | |
|---|
| 89 | INTERFACE diffusion_s_acc |
|---|
| 90 | MODULE PROCEDURE diffusion_s_acc |
|---|
| 91 | END INTERFACE diffusion_s_acc |
|---|
| 92 | |
|---|
| 93 | CONTAINS |
|---|
| 94 | |
|---|
| 95 | |
|---|
| 96 | !------------------------------------------------------------------------------! |
|---|
| 97 | ! Description: |
|---|
| 98 | ! ------------ |
|---|
| 99 | !> Call for all grid points |
|---|
| 100 | !------------------------------------------------------------------------------! |
|---|
| 101 | SUBROUTINE diffusion_s( s, s_flux_b, s_flux_t, wall_s_flux ) |
|---|
| 102 | |
|---|
| 103 | USE arrays_3d, & |
|---|
| 104 | ONLY: ddzu, ddzw, kh, tend |
|---|
| 105 | |
|---|
| 106 | USE control_parameters, & |
|---|
| 107 | ONLY: use_surface_fluxes, use_top_fluxes |
|---|
| 108 | |
|---|
| 109 | USE grid_variables, & |
|---|
| 110 | ONLY: ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 111 | |
|---|
| 112 | USE indices, & |
|---|
| 113 | ONLY: nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, & |
|---|
| 114 | nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, nzt, nzt_diff |
|---|
| 115 | |
|---|
| 116 | USE kinds |
|---|
| 117 | |
|---|
| 118 | IMPLICIT NONE |
|---|
| 119 | |
|---|
| 120 | INTEGER(iwp) :: i !< |
|---|
| 121 | INTEGER(iwp) :: j !< |
|---|
| 122 | INTEGER(iwp) :: k !< |
|---|
| 123 | REAL(wp) :: wall_s_flux(0:4) !< |
|---|
| 124 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_b, s_flux_t !< |
|---|
| 125 | #if defined( __nopointer ) |
|---|
| 126 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: s !< |
|---|
| 127 | #else |
|---|
| 128 | REAL(wp), DIMENSION(:,:,:), POINTER :: s !< |
|---|
| 129 | #endif |
|---|
| 130 | |
|---|
| 131 | DO i = nxl, nxr |
|---|
| 132 | DO j = nys,nyn |
|---|
| 133 | ! |
|---|
| 134 | !-- Compute horizontal diffusion |
|---|
| 135 | DO k = nzb_s_outer(j,i)+1, nzt |
|---|
| 136 | |
|---|
| 137 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 138 | + 0.5_wp * ( & |
|---|
| 139 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 140 | - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 141 | ) * ddx2 & |
|---|
| 142 | + 0.5_wp * ( & |
|---|
| 143 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 144 | - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 145 | ) * ddy2 |
|---|
| 146 | ENDDO |
|---|
| 147 | |
|---|
| 148 | ! |
|---|
| 149 | !-- Apply prescribed horizontal wall heatflux where necessary |
|---|
| 150 | IF ( ( wall_w_x(j,i) /= 0.0_wp ) .OR. ( wall_w_y(j,i) /= 0.0_wp ) & |
|---|
| 151 | ) THEN |
|---|
| 152 | DO k = nzb_s_inner(j,i)+1, nzb_s_outer(j,i) |
|---|
| 153 | |
|---|
| 154 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 155 | + ( fwxp(j,i) * 0.5_wp * & |
|---|
| 156 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 157 | + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1) & |
|---|
| 158 | -fwxm(j,i) * 0.5_wp * & |
|---|
| 159 | ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 160 | + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2) & |
|---|
| 161 | ) * ddx2 & |
|---|
| 162 | + ( fwyp(j,i) * 0.5_wp * & |
|---|
| 163 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 164 | + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3) & |
|---|
| 165 | -fwym(j,i) * 0.5_wp * & |
|---|
| 166 | ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 167 | + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4) & |
|---|
| 168 | ) * ddy2 |
|---|
| 169 | ENDDO |
|---|
| 170 | ENDIF |
|---|
| 171 | |
|---|
| 172 | ! |
|---|
| 173 | !-- Compute vertical diffusion. In case that surface fluxes have been |
|---|
| 174 | !-- prescribed or computed at bottom and/or top, index k starts/ends at |
|---|
| 175 | !-- nzb+2 or nzt-1, respectively. |
|---|
| 176 | DO k = nzb_diff_s_inner(j,i), nzt_diff |
|---|
| 177 | |
|---|
| 178 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 179 | + 0.5_wp * ( & |
|---|
| 180 | ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1) & |
|---|
| 181 | - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k) & |
|---|
| 182 | ) * ddzw(k) |
|---|
| 183 | ENDDO |
|---|
| 184 | |
|---|
| 185 | ! |
|---|
| 186 | !-- Vertical diffusion at the first computational gridpoint along |
|---|
| 187 | !-- z-direction |
|---|
| 188 | IF ( use_surface_fluxes ) THEN |
|---|
| 189 | |
|---|
| 190 | k = nzb_s_inner(j,i)+1 |
|---|
| 191 | |
|---|
| 192 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 193 | + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) ) & |
|---|
| 194 | * ( s(k+1,j,i)-s(k,j,i) ) & |
|---|
| 195 | * ddzu(k+1) & |
|---|
| 196 | + s_flux_b(j,i) & |
|---|
| 197 | ) * ddzw(k) |
|---|
| 198 | |
|---|
| 199 | ENDIF |
|---|
| 200 | |
|---|
| 201 | ! |
|---|
| 202 | !-- Vertical diffusion at the last computational gridpoint along |
|---|
| 203 | !-- z-direction |
|---|
| 204 | IF ( use_top_fluxes ) THEN |
|---|
| 205 | |
|---|
| 206 | k = nzt |
|---|
| 207 | |
|---|
| 208 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 209 | + ( - s_flux_t(j,i) & |
|---|
| 210 | - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )& |
|---|
| 211 | * ( s(k,j,i)-s(k-1,j,i) ) & |
|---|
| 212 | * ddzu(k) & |
|---|
| 213 | ) * ddzw(k) |
|---|
| 214 | |
|---|
| 215 | ENDIF |
|---|
| 216 | |
|---|
| 217 | ENDDO |
|---|
| 218 | ENDDO |
|---|
| 219 | |
|---|
| 220 | END SUBROUTINE diffusion_s |
|---|
| 221 | |
|---|
| 222 | |
|---|
| 223 | !------------------------------------------------------------------------------! |
|---|
| 224 | ! Description: |
|---|
| 225 | ! ------------ |
|---|
| 226 | !> Call for all grid points - accelerator version |
|---|
| 227 | !------------------------------------------------------------------------------! |
|---|
| 228 | SUBROUTINE diffusion_s_acc( s, s_flux_b, s_flux_t, wall_s_flux ) |
|---|
| 229 | |
|---|
| 230 | USE arrays_3d, & |
|---|
| 231 | ONLY: ddzu, ddzw, kh, tend |
|---|
| 232 | |
|---|
| 233 | USE control_parameters, & |
|---|
| 234 | ONLY: use_surface_fluxes, use_top_fluxes |
|---|
| 235 | |
|---|
| 236 | USE grid_variables, & |
|---|
| 237 | ONLY: ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 238 | |
|---|
| 239 | USE indices, & |
|---|
| 240 | ONLY: i_left, i_right, j_north, j_south, nxlg, nxrg, nyng, nysg, & |
|---|
| 241 | nzb, nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, nzt, nzt_diff |
|---|
| 242 | |
|---|
| 243 | USE kinds |
|---|
| 244 | |
|---|
| 245 | IMPLICIT NONE |
|---|
| 246 | |
|---|
| 247 | INTEGER(iwp) :: i !< |
|---|
| 248 | INTEGER(iwp) :: j !< |
|---|
| 249 | INTEGER(iwp) :: k !< |
|---|
| 250 | REAL(wp) :: wall_s_flux(0:4) !< |
|---|
| 251 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_b !< |
|---|
| 252 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_t !< |
|---|
| 253 | #if defined( __nopointer ) |
|---|
| 254 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: s !< |
|---|
| 255 | #else |
|---|
| 256 | REAL(wp), DIMENSION(:,:,:), POINTER :: s !< |
|---|
| 257 | #endif |
|---|
| 258 | |
|---|
| 259 | !$acc kernels present( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, kh ) & |
|---|
| 260 | !$acc present( nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, s ) & |
|---|
| 261 | !$acc present( s_flux_b, s_flux_t, tend, wall_s_flux ) & |
|---|
| 262 | !$acc present( wall_w_x, wall_w_y ) |
|---|
| 263 | DO i = i_left, i_right |
|---|
| 264 | DO j = j_south, j_north |
|---|
| 265 | ! |
|---|
| 266 | !-- Compute horizontal diffusion |
|---|
| 267 | DO k = 1, nzt |
|---|
| 268 | IF ( k > nzb_s_outer(j,i) ) THEN |
|---|
| 269 | |
|---|
| 270 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 271 | + 0.5_wp * ( & |
|---|
| 272 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 273 | - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 274 | ) * ddx2 & |
|---|
| 275 | + 0.5_wp * ( & |
|---|
| 276 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 277 | - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 278 | ) * ddy2 |
|---|
| 279 | ENDIF |
|---|
| 280 | ENDDO |
|---|
| 281 | |
|---|
| 282 | ! |
|---|
| 283 | !-- Apply prescribed horizontal wall heatflux where necessary |
|---|
| 284 | DO k = 1, nzt |
|---|
| 285 | IF ( k > nzb_s_inner(j,i) .AND. k <= nzb_s_outer(j,i) .AND. & |
|---|
| 286 | ( wall_w_x(j,i) /= 0.0_wp .OR. wall_w_y(j,i) /= 0.0_wp ) ) & |
|---|
| 287 | THEN |
|---|
| 288 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 289 | + ( fwxp(j,i) * 0.5_wp * & |
|---|
| 290 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 291 | + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1) & |
|---|
| 292 | -fwxm(j,i) * 0.5_wp * & |
|---|
| 293 | ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 294 | + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2) & |
|---|
| 295 | ) * ddx2 & |
|---|
| 296 | + ( fwyp(j,i) * 0.5_wp * & |
|---|
| 297 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 298 | + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3) & |
|---|
| 299 | -fwym(j,i) * 0.5_wp * & |
|---|
| 300 | ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 301 | + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4) & |
|---|
| 302 | ) * ddy2 |
|---|
| 303 | ENDIF |
|---|
| 304 | ENDDO |
|---|
| 305 | |
|---|
| 306 | ! |
|---|
| 307 | !-- Compute vertical diffusion. In case that surface fluxes have been |
|---|
| 308 | !-- prescribed or computed at bottom and/or top, index k starts/ends at |
|---|
| 309 | !-- nzb+2 or nzt-1, respectively. |
|---|
| 310 | DO k = 1, nzt_diff |
|---|
| 311 | IF ( k >= nzb_diff_s_inner(j,i) ) THEN |
|---|
| 312 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 313 | + 0.5_wp * ( & |
|---|
| 314 | ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1) & |
|---|
| 315 | - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k) & |
|---|
| 316 | ) * ddzw(k) |
|---|
| 317 | ENDIF |
|---|
| 318 | ENDDO |
|---|
| 319 | |
|---|
| 320 | ! |
|---|
| 321 | !-- Vertical diffusion at the first computational gridpoint along |
|---|
| 322 | !-- z-direction |
|---|
| 323 | DO k = 1, nzt |
|---|
| 324 | IF ( use_surface_fluxes .AND. k == nzb_s_inner(j,i)+1 ) THEN |
|---|
| 325 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 326 | + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) )& |
|---|
| 327 | * ( s(k+1,j,i)-s(k,j,i) ) & |
|---|
| 328 | * ddzu(k+1) & |
|---|
| 329 | + s_flux_b(j,i) & |
|---|
| 330 | ) * ddzw(k) |
|---|
| 331 | ENDIF |
|---|
| 332 | |
|---|
| 333 | ! |
|---|
| 334 | !-- Vertical diffusion at the last computational gridpoint along |
|---|
| 335 | !-- z-direction |
|---|
| 336 | IF ( use_top_fluxes .AND. k == nzt ) THEN |
|---|
| 337 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 338 | + ( - s_flux_t(j,i) & |
|---|
| 339 | - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )& |
|---|
| 340 | * ( s(k,j,i)-s(k-1,j,i) ) & |
|---|
| 341 | * ddzu(k) & |
|---|
| 342 | ) * ddzw(k) |
|---|
| 343 | ENDIF |
|---|
| 344 | ENDDO |
|---|
| 345 | |
|---|
| 346 | ENDDO |
|---|
| 347 | ENDDO |
|---|
| 348 | !$acc end kernels |
|---|
| 349 | |
|---|
| 350 | END SUBROUTINE diffusion_s_acc |
|---|
| 351 | |
|---|
| 352 | |
|---|
| 353 | !------------------------------------------------------------------------------! |
|---|
| 354 | ! Description: |
|---|
| 355 | ! ------------ |
|---|
| 356 | !> Call for grid point i,j |
|---|
| 357 | !------------------------------------------------------------------------------! |
|---|
| 358 | SUBROUTINE diffusion_s_ij( i, j, s, s_flux_b, s_flux_t, wall_s_flux ) |
|---|
| 359 | |
|---|
| 360 | USE arrays_3d, & |
|---|
| 361 | ONLY: ddzu, ddzw, kh, tend |
|---|
| 362 | |
|---|
| 363 | USE control_parameters, & |
|---|
| 364 | ONLY: use_surface_fluxes, use_top_fluxes |
|---|
| 365 | |
|---|
| 366 | USE grid_variables, & |
|---|
| 367 | ONLY: ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 368 | |
|---|
| 369 | USE indices, & |
|---|
| 370 | ONLY: nxlg, nxrg, nyng, nysg, nzb, nzb_diff_s_inner, nzb_s_inner, & |
|---|
| 371 | nzb_s_outer, nzt, nzt_diff |
|---|
| 372 | |
|---|
| 373 | USE kinds |
|---|
| 374 | |
|---|
| 375 | IMPLICIT NONE |
|---|
| 376 | |
|---|
| 377 | INTEGER(iwp) :: i !< |
|---|
| 378 | INTEGER(iwp) :: j !< |
|---|
| 379 | INTEGER(iwp) :: k !< |
|---|
| 380 | REAL(wp) :: wall_s_flux(0:4) !< |
|---|
| 381 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_b !< |
|---|
| 382 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_t !< |
|---|
| 383 | #if defined( __nopointer ) |
|---|
| 384 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: s !< |
|---|
| 385 | #else |
|---|
| 386 | REAL(wp), DIMENSION(:,:,:), POINTER :: s !< |
|---|
| 387 | #endif |
|---|
| 388 | |
|---|
| 389 | ! |
|---|
| 390 | !-- Compute horizontal diffusion |
|---|
| 391 | DO k = nzb_s_outer(j,i)+1, nzt |
|---|
| 392 | |
|---|
| 393 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 394 | + 0.5_wp * ( & |
|---|
| 395 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 396 | - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 397 | ) * ddx2 & |
|---|
| 398 | + 0.5_wp * ( & |
|---|
| 399 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 400 | - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 401 | ) * ddy2 |
|---|
| 402 | ENDDO |
|---|
| 403 | |
|---|
| 404 | ! |
|---|
| 405 | !-- Apply prescribed horizontal wall heatflux where necessary |
|---|
| 406 | IF ( ( wall_w_x(j,i) /= 0.0_wp ) .OR. ( wall_w_y(j,i) /= 0.0_wp ) ) & |
|---|
| 407 | THEN |
|---|
| 408 | DO k = nzb_s_inner(j,i)+1, nzb_s_outer(j,i) |
|---|
| 409 | |
|---|
| 410 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 411 | + ( fwxp(j,i) * 0.5_wp * & |
|---|
| 412 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 413 | + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1) & |
|---|
| 414 | -fwxm(j,i) * 0.5_wp * & |
|---|
| 415 | ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 416 | + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2) & |
|---|
| 417 | ) * ddx2 & |
|---|
| 418 | + ( fwyp(j,i) * 0.5_wp * & |
|---|
| 419 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 420 | + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3) & |
|---|
| 421 | -fwym(j,i) * 0.5_wp * & |
|---|
| 422 | ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 423 | + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4) & |
|---|
| 424 | ) * ddy2 |
|---|
| 425 | ENDDO |
|---|
| 426 | ENDIF |
|---|
| 427 | |
|---|
| 428 | ! |
|---|
| 429 | !-- Compute vertical diffusion. In case that surface fluxes have been |
|---|
| 430 | !-- prescribed or computed at bottom and/or top, index k starts/ends at |
|---|
| 431 | !-- nzb+2 or nzt-1, respectively. |
|---|
| 432 | DO k = nzb_diff_s_inner(j,i), nzt_diff |
|---|
| 433 | |
|---|
| 434 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 435 | + 0.5_wp * ( & |
|---|
| 436 | ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1) & |
|---|
| 437 | - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k) & |
|---|
| 438 | ) * ddzw(k) |
|---|
| 439 | ENDDO |
|---|
| 440 | |
|---|
| 441 | ! |
|---|
| 442 | !-- Vertical diffusion at the first computational gridpoint along z-direction |
|---|
| 443 | IF ( use_surface_fluxes ) THEN |
|---|
| 444 | |
|---|
| 445 | k = nzb_s_inner(j,i)+1 |
|---|
| 446 | |
|---|
| 447 | tend(k,j,i) = tend(k,j,i) + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) ) & |
|---|
| 448 | * ( s(k+1,j,i)-s(k,j,i) ) & |
|---|
| 449 | * ddzu(k+1) & |
|---|
| 450 | + s_flux_b(j,i) & |
|---|
| 451 | ) * ddzw(k) |
|---|
| 452 | |
|---|
| 453 | ENDIF |
|---|
| 454 | |
|---|
| 455 | ! |
|---|
| 456 | !-- Vertical diffusion at the last computational gridpoint along z-direction |
|---|
| 457 | IF ( use_top_fluxes ) THEN |
|---|
| 458 | |
|---|
| 459 | k = nzt |
|---|
| 460 | |
|---|
| 461 | tend(k,j,i) = tend(k,j,i) + ( - s_flux_t(j,i) & |
|---|
| 462 | - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) ) & |
|---|
| 463 | * ( s(k,j,i)-s(k-1,j,i) ) & |
|---|
| 464 | * ddzu(k) & |
|---|
| 465 | ) * ddzw(k) |
|---|
| 466 | |
|---|
| 467 | ENDIF |
|---|
| 468 | |
|---|
| 469 | END SUBROUTINE diffusion_s_ij |
|---|
| 470 | |
|---|
| 471 | END MODULE diffusion_s_mod |
|---|
