| 1 | !> @file diffusion_s.f90 |
|---|
| 2 | !------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the |
|---|
| 6 | ! terms of the GNU General Public License as published by the Free Software |
|---|
| 7 | ! Foundation, either version 3 of the License, or (at your option) any later |
|---|
| 8 | ! version. |
|---|
| 9 | ! |
|---|
| 10 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 11 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 12 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 13 | ! |
|---|
| 14 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 15 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 16 | ! |
|---|
| 17 | ! Copyright 1997-2016 Leibniz Universitaet Hannover |
|---|
| 18 | !------------------------------------------------------------------------------! |
|---|
| 19 | ! |
|---|
| 20 | ! Current revisions: |
|---|
| 21 | ! ------------------ |
|---|
| 22 | ! Forced header and separation lines into 80 columns |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: diffusion_s.f90 2000 2016-08-20 18:09:15Z knoop $ |
|---|
| 27 | ! |
|---|
| 28 | ! 1873 2016-04-18 14:50:06Z maronga |
|---|
| 29 | ! Module renamed (removed _mod) |
|---|
| 30 | ! |
|---|
| 31 | ! |
|---|
| 32 | ! 1850 2016-04-08 13:29:27Z maronga |
|---|
| 33 | ! Module renamed |
|---|
| 34 | ! |
|---|
| 35 | ! |
|---|
| 36 | ! 1691 2015-10-26 16:17:44Z maronga |
|---|
| 37 | ! Formatting corrections. |
|---|
| 38 | ! |
|---|
| 39 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 40 | ! Code annotations made doxygen readable |
|---|
| 41 | ! |
|---|
| 42 | ! 1374 2014-04-25 12:55:07Z raasch |
|---|
| 43 | ! missing variables added to ONLY list |
|---|
| 44 | ! |
|---|
| 45 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 46 | ! REAL constants defined as wp-kind |
|---|
| 47 | ! |
|---|
| 48 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 49 | ! ONLY-attribute added to USE-statements, |
|---|
| 50 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 51 | ! kinds are defined in new module kinds, |
|---|
| 52 | ! revision history before 2012 removed, |
|---|
| 53 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 54 | ! all variable declaration statements |
|---|
| 55 | ! |
|---|
| 56 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 57 | ! openacc loop and loop vector clauses removed |
|---|
| 58 | ! |
|---|
| 59 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 60 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 61 | ! j_north |
|---|
| 62 | ! |
|---|
| 63 | ! 1092 2013-02-02 11:24:22Z raasch |
|---|
| 64 | ! unused variables removed |
|---|
| 65 | ! |
|---|
| 66 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 67 | ! code put under GPL (PALM 3.9) |
|---|
| 68 | ! |
|---|
| 69 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 70 | ! accelerator version (*_acc) added |
|---|
| 71 | ! |
|---|
| 72 | ! 1010 2012-09-20 07:59:54Z raasch |
|---|
| 73 | ! cpp switch __nopointer added for pointer free version |
|---|
| 74 | ! |
|---|
| 75 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 76 | ! some arrays comunicated by module instead of parameter list |
|---|
| 77 | ! |
|---|
| 78 | ! Revision 1.1 2000/04/13 14:54:02 schroeter |
|---|
| 79 | ! Initial revision |
|---|
| 80 | ! |
|---|
| 81 | ! |
|---|
| 82 | ! Description: |
|---|
| 83 | ! ------------ |
|---|
| 84 | !> Diffusion term of scalar quantities (temperature and water content) |
|---|
| 85 | !------------------------------------------------------------------------------! |
|---|
| 86 | MODULE diffusion_s_mod |
|---|
| 87 | |
|---|
| 88 | |
|---|
| 89 | PRIVATE |
|---|
| 90 | PUBLIC diffusion_s, diffusion_s_acc |
|---|
| 91 | |
|---|
| 92 | INTERFACE diffusion_s |
|---|
| 93 | MODULE PROCEDURE diffusion_s |
|---|
| 94 | MODULE PROCEDURE diffusion_s_ij |
|---|
| 95 | END INTERFACE diffusion_s |
|---|
| 96 | |
|---|
| 97 | INTERFACE diffusion_s_acc |
|---|
| 98 | MODULE PROCEDURE diffusion_s_acc |
|---|
| 99 | END INTERFACE diffusion_s_acc |
|---|
| 100 | |
|---|
| 101 | CONTAINS |
|---|
| 102 | |
|---|
| 103 | |
|---|
| 104 | !------------------------------------------------------------------------------! |
|---|
| 105 | ! Description: |
|---|
| 106 | ! ------------ |
|---|
| 107 | !> Call for all grid points |
|---|
| 108 | !------------------------------------------------------------------------------! |
|---|
| 109 | SUBROUTINE diffusion_s( s, s_flux_b, s_flux_t, wall_s_flux ) |
|---|
| 110 | |
|---|
| 111 | USE arrays_3d, & |
|---|
| 112 | ONLY: ddzu, ddzw, kh, tend |
|---|
| 113 | |
|---|
| 114 | USE control_parameters, & |
|---|
| 115 | ONLY: use_surface_fluxes, use_top_fluxes |
|---|
| 116 | |
|---|
| 117 | USE grid_variables, & |
|---|
| 118 | ONLY: ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 119 | |
|---|
| 120 | USE indices, & |
|---|
| 121 | ONLY: nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, & |
|---|
| 122 | nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, nzt, nzt_diff |
|---|
| 123 | |
|---|
| 124 | USE kinds |
|---|
| 125 | |
|---|
| 126 | IMPLICIT NONE |
|---|
| 127 | |
|---|
| 128 | INTEGER(iwp) :: i !< |
|---|
| 129 | INTEGER(iwp) :: j !< |
|---|
| 130 | INTEGER(iwp) :: k !< |
|---|
| 131 | REAL(wp) :: wall_s_flux(0:4) !< |
|---|
| 132 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_b, s_flux_t !< |
|---|
| 133 | #if defined( __nopointer ) |
|---|
| 134 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: s !< |
|---|
| 135 | #else |
|---|
| 136 | REAL(wp), DIMENSION(:,:,:), POINTER :: s !< |
|---|
| 137 | #endif |
|---|
| 138 | |
|---|
| 139 | DO i = nxl, nxr |
|---|
| 140 | DO j = nys,nyn |
|---|
| 141 | ! |
|---|
| 142 | !-- Compute horizontal diffusion |
|---|
| 143 | DO k = nzb_s_outer(j,i)+1, nzt |
|---|
| 144 | |
|---|
| 145 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 146 | + 0.5_wp * ( & |
|---|
| 147 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 148 | - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 149 | ) * ddx2 & |
|---|
| 150 | + 0.5_wp * ( & |
|---|
| 151 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 152 | - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 153 | ) * ddy2 |
|---|
| 154 | ENDDO |
|---|
| 155 | |
|---|
| 156 | ! |
|---|
| 157 | !-- Apply prescribed horizontal wall heatflux where necessary |
|---|
| 158 | IF ( ( wall_w_x(j,i) /= 0.0_wp ) .OR. ( wall_w_y(j,i) /= 0.0_wp ) & |
|---|
| 159 | ) THEN |
|---|
| 160 | DO k = nzb_s_inner(j,i)+1, nzb_s_outer(j,i) |
|---|
| 161 | |
|---|
| 162 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 163 | + ( fwxp(j,i) * 0.5_wp * & |
|---|
| 164 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 165 | + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1) & |
|---|
| 166 | -fwxm(j,i) * 0.5_wp * & |
|---|
| 167 | ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 168 | + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2) & |
|---|
| 169 | ) * ddx2 & |
|---|
| 170 | + ( fwyp(j,i) * 0.5_wp * & |
|---|
| 171 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 172 | + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3) & |
|---|
| 173 | -fwym(j,i) * 0.5_wp * & |
|---|
| 174 | ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 175 | + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4) & |
|---|
| 176 | ) * ddy2 |
|---|
| 177 | ENDDO |
|---|
| 178 | ENDIF |
|---|
| 179 | |
|---|
| 180 | ! |
|---|
| 181 | !-- Compute vertical diffusion. In case that surface fluxes have been |
|---|
| 182 | !-- prescribed or computed at bottom and/or top, index k starts/ends at |
|---|
| 183 | !-- nzb+2 or nzt-1, respectively. |
|---|
| 184 | DO k = nzb_diff_s_inner(j,i), nzt_diff |
|---|
| 185 | |
|---|
| 186 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 187 | + 0.5_wp * ( & |
|---|
| 188 | ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1) & |
|---|
| 189 | - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k) & |
|---|
| 190 | ) * ddzw(k) |
|---|
| 191 | ENDDO |
|---|
| 192 | |
|---|
| 193 | ! |
|---|
| 194 | !-- Vertical diffusion at the first computational gridpoint along |
|---|
| 195 | !-- z-direction |
|---|
| 196 | IF ( use_surface_fluxes ) THEN |
|---|
| 197 | |
|---|
| 198 | k = nzb_s_inner(j,i)+1 |
|---|
| 199 | |
|---|
| 200 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 201 | + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) ) & |
|---|
| 202 | * ( s(k+1,j,i)-s(k,j,i) ) & |
|---|
| 203 | * ddzu(k+1) & |
|---|
| 204 | + s_flux_b(j,i) & |
|---|
| 205 | ) * ddzw(k) |
|---|
| 206 | |
|---|
| 207 | ENDIF |
|---|
| 208 | |
|---|
| 209 | ! |
|---|
| 210 | !-- Vertical diffusion at the last computational gridpoint along |
|---|
| 211 | !-- z-direction |
|---|
| 212 | IF ( use_top_fluxes ) THEN |
|---|
| 213 | |
|---|
| 214 | k = nzt |
|---|
| 215 | |
|---|
| 216 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 217 | + ( - s_flux_t(j,i) & |
|---|
| 218 | - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )& |
|---|
| 219 | * ( s(k,j,i)-s(k-1,j,i) ) & |
|---|
| 220 | * ddzu(k) & |
|---|
| 221 | ) * ddzw(k) |
|---|
| 222 | |
|---|
| 223 | ENDIF |
|---|
| 224 | |
|---|
| 225 | ENDDO |
|---|
| 226 | ENDDO |
|---|
| 227 | |
|---|
| 228 | END SUBROUTINE diffusion_s |
|---|
| 229 | |
|---|
| 230 | |
|---|
| 231 | !------------------------------------------------------------------------------! |
|---|
| 232 | ! Description: |
|---|
| 233 | ! ------------ |
|---|
| 234 | !> Call for all grid points - accelerator version |
|---|
| 235 | !------------------------------------------------------------------------------! |
|---|
| 236 | SUBROUTINE diffusion_s_acc( s, s_flux_b, s_flux_t, wall_s_flux ) |
|---|
| 237 | |
|---|
| 238 | USE arrays_3d, & |
|---|
| 239 | ONLY: ddzu, ddzw, kh, tend |
|---|
| 240 | |
|---|
| 241 | USE control_parameters, & |
|---|
| 242 | ONLY: use_surface_fluxes, use_top_fluxes |
|---|
| 243 | |
|---|
| 244 | USE grid_variables, & |
|---|
| 245 | ONLY: ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 246 | |
|---|
| 247 | USE indices, & |
|---|
| 248 | ONLY: i_left, i_right, j_north, j_south, nxlg, nxrg, nyng, nysg, & |
|---|
| 249 | nzb, nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, nzt, nzt_diff |
|---|
| 250 | |
|---|
| 251 | USE kinds |
|---|
| 252 | |
|---|
| 253 | IMPLICIT NONE |
|---|
| 254 | |
|---|
| 255 | INTEGER(iwp) :: i !< |
|---|
| 256 | INTEGER(iwp) :: j !< |
|---|
| 257 | INTEGER(iwp) :: k !< |
|---|
| 258 | REAL(wp) :: wall_s_flux(0:4) !< |
|---|
| 259 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_b !< |
|---|
| 260 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_t !< |
|---|
| 261 | #if defined( __nopointer ) |
|---|
| 262 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: s !< |
|---|
| 263 | #else |
|---|
| 264 | REAL(wp), DIMENSION(:,:,:), POINTER :: s !< |
|---|
| 265 | #endif |
|---|
| 266 | |
|---|
| 267 | !$acc kernels present( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, kh ) & |
|---|
| 268 | !$acc present( nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, s ) & |
|---|
| 269 | !$acc present( s_flux_b, s_flux_t, tend, wall_s_flux ) & |
|---|
| 270 | !$acc present( wall_w_x, wall_w_y ) |
|---|
| 271 | DO i = i_left, i_right |
|---|
| 272 | DO j = j_south, j_north |
|---|
| 273 | ! |
|---|
| 274 | !-- Compute horizontal diffusion |
|---|
| 275 | DO k = 1, nzt |
|---|
| 276 | IF ( k > nzb_s_outer(j,i) ) THEN |
|---|
| 277 | |
|---|
| 278 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 279 | + 0.5_wp * ( & |
|---|
| 280 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 281 | - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 282 | ) * ddx2 & |
|---|
| 283 | + 0.5_wp * ( & |
|---|
| 284 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 285 | - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 286 | ) * ddy2 |
|---|
| 287 | ENDIF |
|---|
| 288 | ENDDO |
|---|
| 289 | |
|---|
| 290 | ! |
|---|
| 291 | !-- Apply prescribed horizontal wall heatflux where necessary |
|---|
| 292 | DO k = 1, nzt |
|---|
| 293 | IF ( k > nzb_s_inner(j,i) .AND. k <= nzb_s_outer(j,i) .AND. & |
|---|
| 294 | ( wall_w_x(j,i) /= 0.0_wp .OR. wall_w_y(j,i) /= 0.0_wp ) ) & |
|---|
| 295 | THEN |
|---|
| 296 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 297 | + ( fwxp(j,i) * 0.5_wp * & |
|---|
| 298 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 299 | + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1) & |
|---|
| 300 | -fwxm(j,i) * 0.5_wp * & |
|---|
| 301 | ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 302 | + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2) & |
|---|
| 303 | ) * ddx2 & |
|---|
| 304 | + ( fwyp(j,i) * 0.5_wp * & |
|---|
| 305 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 306 | + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3) & |
|---|
| 307 | -fwym(j,i) * 0.5_wp * & |
|---|
| 308 | ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 309 | + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4) & |
|---|
| 310 | ) * ddy2 |
|---|
| 311 | ENDIF |
|---|
| 312 | ENDDO |
|---|
| 313 | |
|---|
| 314 | ! |
|---|
| 315 | !-- Compute vertical diffusion. In case that surface fluxes have been |
|---|
| 316 | !-- prescribed or computed at bottom and/or top, index k starts/ends at |
|---|
| 317 | !-- nzb+2 or nzt-1, respectively. |
|---|
| 318 | DO k = 1, nzt_diff |
|---|
| 319 | IF ( k >= nzb_diff_s_inner(j,i) ) THEN |
|---|
| 320 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 321 | + 0.5_wp * ( & |
|---|
| 322 | ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1) & |
|---|
| 323 | - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k) & |
|---|
| 324 | ) * ddzw(k) |
|---|
| 325 | ENDIF |
|---|
| 326 | ENDDO |
|---|
| 327 | |
|---|
| 328 | ! |
|---|
| 329 | !-- Vertical diffusion at the first computational gridpoint along |
|---|
| 330 | !-- z-direction |
|---|
| 331 | DO k = 1, nzt |
|---|
| 332 | IF ( use_surface_fluxes .AND. k == nzb_s_inner(j,i)+1 ) THEN |
|---|
| 333 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 334 | + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) )& |
|---|
| 335 | * ( s(k+1,j,i)-s(k,j,i) ) & |
|---|
| 336 | * ddzu(k+1) & |
|---|
| 337 | + s_flux_b(j,i) & |
|---|
| 338 | ) * ddzw(k) |
|---|
| 339 | ENDIF |
|---|
| 340 | |
|---|
| 341 | ! |
|---|
| 342 | !-- Vertical diffusion at the last computational gridpoint along |
|---|
| 343 | !-- z-direction |
|---|
| 344 | IF ( use_top_fluxes .AND. k == nzt ) THEN |
|---|
| 345 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 346 | + ( - s_flux_t(j,i) & |
|---|
| 347 | - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )& |
|---|
| 348 | * ( s(k,j,i)-s(k-1,j,i) ) & |
|---|
| 349 | * ddzu(k) & |
|---|
| 350 | ) * ddzw(k) |
|---|
| 351 | ENDIF |
|---|
| 352 | ENDDO |
|---|
| 353 | |
|---|
| 354 | ENDDO |
|---|
| 355 | ENDDO |
|---|
| 356 | !$acc end kernels |
|---|
| 357 | |
|---|
| 358 | END SUBROUTINE diffusion_s_acc |
|---|
| 359 | |
|---|
| 360 | |
|---|
| 361 | !------------------------------------------------------------------------------! |
|---|
| 362 | ! Description: |
|---|
| 363 | ! ------------ |
|---|
| 364 | !> Call for grid point i,j |
|---|
| 365 | !------------------------------------------------------------------------------! |
|---|
| 366 | SUBROUTINE diffusion_s_ij( i, j, s, s_flux_b, s_flux_t, wall_s_flux ) |
|---|
| 367 | |
|---|
| 368 | USE arrays_3d, & |
|---|
| 369 | ONLY: ddzu, ddzw, kh, tend |
|---|
| 370 | |
|---|
| 371 | USE control_parameters, & |
|---|
| 372 | ONLY: use_surface_fluxes, use_top_fluxes |
|---|
| 373 | |
|---|
| 374 | USE grid_variables, & |
|---|
| 375 | ONLY: ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 376 | |
|---|
| 377 | USE indices, & |
|---|
| 378 | ONLY: nxlg, nxrg, nyng, nysg, nzb, nzb_diff_s_inner, nzb_s_inner, & |
|---|
| 379 | nzb_s_outer, nzt, nzt_diff |
|---|
| 380 | |
|---|
| 381 | USE kinds |
|---|
| 382 | |
|---|
| 383 | IMPLICIT NONE |
|---|
| 384 | |
|---|
| 385 | INTEGER(iwp) :: i !< |
|---|
| 386 | INTEGER(iwp) :: j !< |
|---|
| 387 | INTEGER(iwp) :: k !< |
|---|
| 388 | REAL(wp) :: wall_s_flux(0:4) !< |
|---|
| 389 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_b !< |
|---|
| 390 | REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) :: s_flux_t !< |
|---|
| 391 | #if defined( __nopointer ) |
|---|
| 392 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: s !< |
|---|
| 393 | #else |
|---|
| 394 | REAL(wp), DIMENSION(:,:,:), POINTER :: s !< |
|---|
| 395 | #endif |
|---|
| 396 | |
|---|
| 397 | ! |
|---|
| 398 | !-- Compute horizontal diffusion |
|---|
| 399 | DO k = nzb_s_outer(j,i)+1, nzt |
|---|
| 400 | |
|---|
| 401 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 402 | + 0.5_wp * ( & |
|---|
| 403 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 404 | - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 405 | ) * ddx2 & |
|---|
| 406 | + 0.5_wp * ( & |
|---|
| 407 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 408 | - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 409 | ) * ddy2 |
|---|
| 410 | ENDDO |
|---|
| 411 | |
|---|
| 412 | ! |
|---|
| 413 | !-- Apply prescribed horizontal wall heatflux where necessary |
|---|
| 414 | IF ( ( wall_w_x(j,i) /= 0.0_wp ) .OR. ( wall_w_y(j,i) /= 0.0_wp ) ) & |
|---|
| 415 | THEN |
|---|
| 416 | DO k = nzb_s_inner(j,i)+1, nzb_s_outer(j,i) |
|---|
| 417 | |
|---|
| 418 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 419 | + ( fwxp(j,i) * 0.5_wp * & |
|---|
| 420 | ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) ) & |
|---|
| 421 | + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1) & |
|---|
| 422 | -fwxm(j,i) * 0.5_wp * & |
|---|
| 423 | ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) ) & |
|---|
| 424 | + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2) & |
|---|
| 425 | ) * ddx2 & |
|---|
| 426 | + ( fwyp(j,i) * 0.5_wp * & |
|---|
| 427 | ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) ) & |
|---|
| 428 | + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3) & |
|---|
| 429 | -fwym(j,i) * 0.5_wp * & |
|---|
| 430 | ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) ) & |
|---|
| 431 | + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4) & |
|---|
| 432 | ) * ddy2 |
|---|
| 433 | ENDDO |
|---|
| 434 | ENDIF |
|---|
| 435 | |
|---|
| 436 | ! |
|---|
| 437 | !-- Compute vertical diffusion. In case that surface fluxes have been |
|---|
| 438 | !-- prescribed or computed at bottom and/or top, index k starts/ends at |
|---|
| 439 | !-- nzb+2 or nzt-1, respectively. |
|---|
| 440 | DO k = nzb_diff_s_inner(j,i), nzt_diff |
|---|
| 441 | |
|---|
| 442 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 443 | + 0.5_wp * ( & |
|---|
| 444 | ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1) & |
|---|
| 445 | - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k) & |
|---|
| 446 | ) * ddzw(k) |
|---|
| 447 | ENDDO |
|---|
| 448 | |
|---|
| 449 | ! |
|---|
| 450 | !-- Vertical diffusion at the first computational gridpoint along z-direction |
|---|
| 451 | IF ( use_surface_fluxes ) THEN |
|---|
| 452 | |
|---|
| 453 | k = nzb_s_inner(j,i)+1 |
|---|
| 454 | |
|---|
| 455 | tend(k,j,i) = tend(k,j,i) + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) ) & |
|---|
| 456 | * ( s(k+1,j,i)-s(k,j,i) ) & |
|---|
| 457 | * ddzu(k+1) & |
|---|
| 458 | + s_flux_b(j,i) & |
|---|
| 459 | ) * ddzw(k) |
|---|
| 460 | |
|---|
| 461 | ENDIF |
|---|
| 462 | |
|---|
| 463 | ! |
|---|
| 464 | !-- Vertical diffusion at the last computational gridpoint along z-direction |
|---|
| 465 | IF ( use_top_fluxes ) THEN |
|---|
| 466 | |
|---|
| 467 | k = nzt |
|---|
| 468 | |
|---|
| 469 | tend(k,j,i) = tend(k,j,i) + ( - s_flux_t(j,i) & |
|---|
| 470 | - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) ) & |
|---|
| 471 | * ( s(k,j,i)-s(k-1,j,i) ) & |
|---|
| 472 | * ddzu(k) & |
|---|
| 473 | ) * ddzw(k) |
|---|
| 474 | |
|---|
| 475 | ENDIF |
|---|
| 476 | |
|---|
| 477 | END SUBROUTINE diffusion_s_ij |
|---|
| 478 | |
|---|
| 479 | END MODULE diffusion_s_mod |
|---|
