source: palm/trunk/SOURCE/diffusion_s.f90 @ 1873

Last change on this file since 1873 was 1873, checked in by maronga, 5 years ago

revised renaming of modules

  • Property svn:keywords set to Id
File size: 20.1 KB
Line 
1!> @file diffusion_s.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! ------------------
21! Module renamed (removed _mod)
22!
23!
24! Former revisions:
25! -----------------
26! $Id: diffusion_s.f90 1873 2016-04-18 14:50:06Z maronga $
27!
28! 1850 2016-04-08 13:29:27Z maronga
29! Module renamed
30!
31!
32! 1691 2015-10-26 16:17:44Z maronga
33! Formatting corrections.
34!
35! 1682 2015-10-07 23:56:08Z knoop
36! Code annotations made doxygen readable
37!
38! 1374 2014-04-25 12:55:07Z raasch
39! missing variables added to ONLY list
40!
41! 1340 2014-03-25 19:45:13Z kanani
42! REAL constants defined as wp-kind
43!
44! 1320 2014-03-20 08:40:49Z raasch
45! ONLY-attribute added to USE-statements,
46! kind-parameters added to all INTEGER and REAL declaration statements,
47! kinds are defined in new module kinds,
48! revision history before 2012 removed,
49! comment fields (!:) to be used for variable explanations added to
50! all variable declaration statements
51!
52! 1257 2013-11-08 15:18:40Z raasch
53! openacc loop and loop vector clauses removed
54!
55! 1128 2013-04-12 06:19:32Z raasch
56! loop index bounds in accelerator version replaced by i_left, i_right, j_south,
57! j_north
58!
59! 1092 2013-02-02 11:24:22Z raasch
60! unused variables removed
61!
62! 1036 2012-10-22 13:43:42Z raasch
63! code put under GPL (PALM 3.9)
64!
65! 1015 2012-09-27 09:23:24Z raasch
66! accelerator version (*_acc) added
67!
68! 1010 2012-09-20 07:59:54Z raasch
69! cpp switch __nopointer added for pointer free version
70!
71! 1001 2012-09-13 14:08:46Z raasch
72! some arrays comunicated by module instead of parameter list
73!
74! Revision 1.1  2000/04/13 14:54:02  schroeter
75! Initial revision
76!
77!
78! Description:
79! ------------
80!> Diffusion term of scalar quantities (temperature and water content)
81!------------------------------------------------------------------------------!
82 MODULE diffusion_s_mod
83 
84
85    PRIVATE
86    PUBLIC diffusion_s, diffusion_s_acc
87
88    INTERFACE diffusion_s
89       MODULE PROCEDURE diffusion_s
90       MODULE PROCEDURE diffusion_s_ij
91    END INTERFACE diffusion_s
92
93    INTERFACE diffusion_s_acc
94       MODULE PROCEDURE diffusion_s_acc
95    END INTERFACE diffusion_s_acc
96
97 CONTAINS
98
99
100!------------------------------------------------------------------------------!
101! Description:
102! ------------
103!> Call for all grid points
104!------------------------------------------------------------------------------!
105    SUBROUTINE diffusion_s( s, s_flux_b, s_flux_t, wall_s_flux )
106
107       USE arrays_3d,                                                          &
108           ONLY:  ddzu, ddzw, kh, tend
109       
110       USE control_parameters,                                                 & 
111           ONLY: use_surface_fluxes, use_top_fluxes
112       
113       USE grid_variables,                                                     &
114           ONLY:  ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
115       
116       USE indices,                                                            &
117           ONLY:  nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb,             &
118                  nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, nzt, nzt_diff
119       
120       USE kinds
121
122       IMPLICIT NONE
123
124       INTEGER(iwp) ::  i                 !<
125       INTEGER(iwp) ::  j                 !<
126       INTEGER(iwp) ::  k                 !<
127       REAL(wp)     ::  wall_s_flux(0:4)  !<
128       REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  s_flux_b, s_flux_t !<
129#if defined( __nopointer )
130       REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  s  !<
131#else
132       REAL(wp), DIMENSION(:,:,:), POINTER ::  s  !<
133#endif
134
135       DO  i = nxl, nxr
136          DO  j = nys,nyn
137!
138!--          Compute horizontal diffusion
139             DO  k = nzb_s_outer(j,i)+1, nzt
140
141                tend(k,j,i) = tend(k,j,i)                                      &
142                                          + 0.5_wp * (                         &
143                        ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) )  &
144                      - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) )  &
145                                                     ) * ddx2                  &
146                                          + 0.5_wp * (                         &
147                        ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) )  &
148                      - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) )  &
149                                                     ) * ddy2
150             ENDDO
151
152!
153!--          Apply prescribed horizontal wall heatflux where necessary
154             IF ( ( wall_w_x(j,i) /= 0.0_wp ) .OR. ( wall_w_y(j,i) /= 0.0_wp ) &
155                )  THEN
156                DO  k = nzb_s_inner(j,i)+1, nzb_s_outer(j,i)
157
158                   tend(k,j,i) = tend(k,j,i)                                   &
159                                                + ( fwxp(j,i) * 0.5_wp *       &
160                        ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) )  &
161                        + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1)              &
162                                                   -fwxm(j,i) * 0.5_wp *       &
163                        ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) )  &
164                        + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2)              &
165                                                  ) * ddx2                     &
166                                                + ( fwyp(j,i) * 0.5_wp *       &
167                        ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) )  &
168                        + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3)              &
169                                                   -fwym(j,i) * 0.5_wp *       &
170                        ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) )  &
171                        + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4)              &
172                                                  ) * ddy2
173                ENDDO
174             ENDIF
175
176!
177!--          Compute vertical diffusion. In case that surface fluxes have been
178!--          prescribed or computed at bottom and/or top, index k starts/ends at
179!--          nzb+2 or nzt-1, respectively.
180             DO  k = nzb_diff_s_inner(j,i), nzt_diff
181
182                tend(k,j,i) = tend(k,j,i)                                      &
183                                       + 0.5_wp * (                            &
184            ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1)  &
185          - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k)    &
186                                                  ) * ddzw(k)
187             ENDDO
188
189!
190!--          Vertical diffusion at the first computational gridpoint along
191!--          z-direction
192             IF ( use_surface_fluxes )  THEN
193
194                k = nzb_s_inner(j,i)+1
195
196                tend(k,j,i) = tend(k,j,i)                                      &
197                                       + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) )  &
198                                                  * ( s(k+1,j,i)-s(k,j,i) )    &
199                                                  * ddzu(k+1)                  &
200                                           + s_flux_b(j,i)                     &
201                                         ) * ddzw(k)
202
203             ENDIF
204
205!
206!--          Vertical diffusion at the last computational gridpoint along
207!--          z-direction
208             IF ( use_top_fluxes )  THEN
209
210                k = nzt
211
212                tend(k,j,i) = tend(k,j,i)                                      &
213                                       + ( - s_flux_t(j,i)                     &
214                                           - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )&
215                                                    * ( s(k,j,i)-s(k-1,j,i) )  &
216                                                    * ddzu(k)                  &
217                                         ) * ddzw(k)
218
219             ENDIF
220
221          ENDDO
222       ENDDO
223
224    END SUBROUTINE diffusion_s
225
226
227!------------------------------------------------------------------------------!
228! Description:
229! ------------
230!> Call for all grid points - accelerator version
231!------------------------------------------------------------------------------!
232    SUBROUTINE diffusion_s_acc( s, s_flux_b, s_flux_t, wall_s_flux )
233
234       USE arrays_3d,                                                          &
235           ONLY:  ddzu, ddzw, kh, tend
236           
237       USE control_parameters,                                                 & 
238           ONLY: use_surface_fluxes, use_top_fluxes
239       
240       USE grid_variables,                                                     &
241           ONLY:  ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
242       
243       USE indices, &
244           ONLY: i_left, i_right, j_north, j_south, nxlg, nxrg, nyng, nysg,    &
245                 nzb, nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, nzt, nzt_diff
246           
247       USE kinds
248
249       IMPLICIT NONE
250
251       INTEGER(iwp) ::  i                 !<
252       INTEGER(iwp) ::  j                 !<
253       INTEGER(iwp) ::  k                 !<
254       REAL(wp)     ::  wall_s_flux(0:4)  !<
255       REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  s_flux_b !<
256       REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  s_flux_t !<
257#if defined( __nopointer )
258       REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  s  !<
259#else
260       REAL(wp), DIMENSION(:,:,:), POINTER ::  s  !<
261#endif
262
263       !$acc kernels present( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, kh )        &
264       !$acc         present( nzb_diff_s_inner, nzb_s_inner, nzb_s_outer, s ) &
265       !$acc         present( s_flux_b, s_flux_t, tend, wall_s_flux )         &
266       !$acc         present( wall_w_x, wall_w_y )
267       DO  i = i_left, i_right
268          DO  j = j_south, j_north
269!
270!--          Compute horizontal diffusion
271             DO  k = 1, nzt
272                IF ( k > nzb_s_outer(j,i) )  THEN
273
274                   tend(k,j,i) = tend(k,j,i)                                   &
275                                          + 0.5_wp * (                         &
276                        ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) )  &
277                      - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) )  &
278                                                     ) * ddx2                  &
279                                          + 0.5_wp * (                         &
280                        ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) )  &
281                      - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) )  &
282                                                     ) * ddy2
283                ENDIF
284             ENDDO
285
286!
287!--          Apply prescribed horizontal wall heatflux where necessary
288             DO  k = 1, nzt
289                IF ( k > nzb_s_inner(j,i)  .AND.  k <= nzb_s_outer(j,i)  .AND. &
290                     ( wall_w_x(j,i) /= 0.0_wp  .OR.  wall_w_y(j,i) /= 0.0_wp ) )    &
291                THEN
292                   tend(k,j,i) = tend(k,j,i)                                   &
293                                                + ( fwxp(j,i) * 0.5_wp *       &
294                        ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) )  &
295                        + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1)              &
296                                                   -fwxm(j,i) * 0.5_wp *       &
297                        ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) )  &
298                        + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2)              &
299                                                  ) * ddx2                     &
300                                                + ( fwyp(j,i) * 0.5_wp *       &
301                        ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) )  &
302                        + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3)              &
303                                                   -fwym(j,i) * 0.5_wp *       &
304                        ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) )  &
305                        + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4)              &
306                                                  ) * ddy2
307                ENDIF
308             ENDDO
309
310!
311!--          Compute vertical diffusion. In case that surface fluxes have been
312!--          prescribed or computed at bottom and/or top, index k starts/ends at
313!--          nzb+2 or nzt-1, respectively.
314             DO  k = 1, nzt_diff
315                IF ( k >= nzb_diff_s_inner(j,i) )  THEN
316                   tend(k,j,i) = tend(k,j,i)                                   &
317                                       + 0.5_wp * (                            &
318            ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1)  &
319          - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k)    &
320                                                  ) * ddzw(k)
321                ENDIF
322             ENDDO
323
324!
325!--          Vertical diffusion at the first computational gridpoint along
326!--          z-direction
327             DO  k = 1, nzt
328                IF ( use_surface_fluxes  .AND.  k == nzb_s_inner(j,i)+1 )  THEN
329                   tend(k,j,i) = tend(k,j,i)                                   &
330                                          + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) )&
331                                                     * ( s(k+1,j,i)-s(k,j,i) ) &
332                                                     * ddzu(k+1)               &
333                                              + s_flux_b(j,i)                  &
334                                            ) * ddzw(k)
335                ENDIF
336
337!
338!--             Vertical diffusion at the last computational gridpoint along
339!--             z-direction
340                IF ( use_top_fluxes  .AND.  k == nzt )  THEN
341                   tend(k,j,i) = tend(k,j,i)                                   &
342                                          + ( - s_flux_t(j,i)                  &
343                                              - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )&
344                                                       * ( s(k,j,i)-s(k-1,j,i) )  &
345                                                       * ddzu(k)                  &
346                                            ) * ddzw(k)
347                ENDIF
348             ENDDO
349
350          ENDDO
351       ENDDO
352       !$acc end kernels
353
354    END SUBROUTINE diffusion_s_acc
355
356
357!------------------------------------------------------------------------------!
358! Description:
359! ------------
360!> Call for grid point i,j
361!------------------------------------------------------------------------------!
362    SUBROUTINE diffusion_s_ij( i, j, s, s_flux_b, s_flux_t, wall_s_flux )
363
364       USE arrays_3d,                                                          &
365           ONLY:  ddzu, ddzw, kh, tend
366           
367       USE control_parameters,                                                 & 
368           ONLY: use_surface_fluxes, use_top_fluxes
369       
370       USE grid_variables,                                                     &
371           ONLY:  ddx2, ddy2, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y
372       
373       USE indices,                                                            &
374           ONLY:  nxlg, nxrg, nyng, nysg, nzb, nzb_diff_s_inner, nzb_s_inner,  &
375                  nzb_s_outer, nzt, nzt_diff
376       
377       USE kinds
378
379       IMPLICIT NONE
380
381       INTEGER(iwp) ::  i                 !<
382       INTEGER(iwp) ::  j                 !<
383       INTEGER(iwp) ::  k                 !<
384       REAL(wp)     ::  wall_s_flux(0:4)  !<
385       REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  s_flux_b  !<
386       REAL(wp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  s_flux_t  !<
387#if defined( __nopointer )
388       REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  s !<
389#else
390       REAL(wp), DIMENSION(:,:,:), POINTER ::  s  !<
391#endif
392
393!
394!--    Compute horizontal diffusion
395       DO  k = nzb_s_outer(j,i)+1, nzt
396
397          tend(k,j,i) = tend(k,j,i)                                            &
398                                          + 0.5_wp * (                         &
399                        ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) )  &
400                      - ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) )  &
401                                                     ) * ddx2                  &
402                                          + 0.5_wp * (                         &
403                        ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) )  &
404                      - ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) )  &
405                                                     ) * ddy2
406       ENDDO
407
408!
409!--    Apply prescribed horizontal wall heatflux where necessary
410       IF ( ( wall_w_x(j,i) /= 0.0_wp ) .OR. ( wall_w_y(j,i) /= 0.0_wp ) )     &
411       THEN
412          DO  k = nzb_s_inner(j,i)+1, nzb_s_outer(j,i)
413
414             tend(k,j,i) = tend(k,j,i)                                         &
415                                                + ( fwxp(j,i) * 0.5_wp *       &
416                        ( kh(k,j,i) + kh(k,j,i+1) ) * ( s(k,j,i+1)-s(k,j,i) )  &
417                        + ( 1.0_wp - fwxp(j,i) ) * wall_s_flux(1)              &
418                                                   -fwxm(j,i) * 0.5_wp *       &
419                        ( kh(k,j,i) + kh(k,j,i-1) ) * ( s(k,j,i)-s(k,j,i-1) )  &
420                        + ( 1.0_wp - fwxm(j,i) ) * wall_s_flux(2)              &
421                                                  ) * ddx2                     &
422                                                + ( fwyp(j,i) * 0.5_wp *       &
423                        ( kh(k,j,i) + kh(k,j+1,i) ) * ( s(k,j+1,i)-s(k,j,i) )  &
424                        + ( 1.0_wp - fwyp(j,i) ) * wall_s_flux(3)              &
425                                                   -fwym(j,i) * 0.5_wp *       &
426                        ( kh(k,j,i) + kh(k,j-1,i) ) * ( s(k,j,i)-s(k,j-1,i) )  &
427                        + ( 1.0_wp - fwym(j,i) ) * wall_s_flux(4)              &
428                                                  ) * ddy2
429          ENDDO
430       ENDIF
431
432!
433!--    Compute vertical diffusion. In case that surface fluxes have been
434!--    prescribed or computed at bottom and/or top, index k starts/ends at
435!--    nzb+2 or nzt-1, respectively.
436       DO  k = nzb_diff_s_inner(j,i), nzt_diff
437
438          tend(k,j,i) = tend(k,j,i)                                            &
439                                       + 0.5_wp * (                            &
440            ( kh(k,j,i) + kh(k+1,j,i) ) * ( s(k+1,j,i)-s(k,j,i) ) * ddzu(k+1)  &
441          - ( kh(k,j,i) + kh(k-1,j,i) ) * ( s(k,j,i)-s(k-1,j,i) ) * ddzu(k)    &
442                                                  ) * ddzw(k)
443       ENDDO
444
445!
446!--    Vertical diffusion at the first computational gridpoint along z-direction
447       IF ( use_surface_fluxes )  THEN
448
449          k = nzb_s_inner(j,i)+1
450
451          tend(k,j,i) = tend(k,j,i) + ( 0.5_wp * ( kh(k,j,i)+kh(k+1,j,i) )     &
452                                               * ( s(k+1,j,i)-s(k,j,i) )       &
453                                               * ddzu(k+1)                     &
454                                        + s_flux_b(j,i)                        &
455                                      ) * ddzw(k)
456
457       ENDIF
458
459!
460!--    Vertical diffusion at the last computational gridpoint along z-direction
461       IF ( use_top_fluxes )  THEN
462
463          k = nzt
464
465          tend(k,j,i) = tend(k,j,i) + ( - s_flux_t(j,i)                        &
466                                      - 0.5_wp * ( kh(k-1,j,i)+kh(k,j,i) )     &
467                                               * ( s(k,j,i)-s(k-1,j,i) )       &
468                                               * ddzu(k)                       &
469                                      ) * ddzw(k)
470
471       ENDIF
472
473    END SUBROUTINE diffusion_s_ij
474
475 END MODULE diffusion_s_mod
Note: See TracBrowser for help on using the repository browser.