MODULE diffusion_e_mod

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: diffusion_e.f90,v $
! Revision 1.18  2006/08/04 14:29:43  raasch
! dissipation is stored in extra array diss if needed later on for calculating
! the sgs particle velocities
!
! Revision 1.17  2006/02/23 10:31:46  raasch
! nzb_2d replaced by nzb_s_inner
!
! Revision 1.16  2004/01/30 10:18:18  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.15  2003/03/14 13:39:33  raasch
! Loop optimization for diffusion_e, l and ll are now automatic arrays
!
! Revision 1.14  2003/03/12 16:25:03  raasch
! Full code replaced in the call for all gridpoints instead of calling the
! _ij version (required by NEC, because otherwise no vectorization)
!
! Revision 1.13  2002/12/19 14:25:28  raasch
! Correction of mixing length term (l(k)/ll(k)). The condition kh=3*km in
! the unstable case is now also exactly met in the wall adjustment region.
! Factor 0.7 in wall adjustment part replaced by variable
! wall_adjustment_factor, which is set to ... in modules.f90.
!
! Revision 1.12  2002/06/11 12:51:59  raasch
! Former subroutine changed to a module which allows to be called for all grid
! points of a single vertical column with index i,j or for all grid points by
! using function overloading.
! 1D-array l is allocated only once in the first call.
!
! Revision 1.11  2001/08/21 08:24:34  raasch
! Wall adjustment of mixing length to 0.7 z can be switched off
!
! Revision 1.10  2001/03/30 07:06:30  raasch
! Near surface mixing length is limited to 0.7*zu,
! e**1.5 replaced by e*SQRT(e) (more than 10% total increase in performance
! of this routine),
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.9  2001/01/22 06:05:28  raasch
! Module test_variables removed
!
! Revision 1.8  2001/01/02 17:27:00  raasch
! -dpt_dz_d, dpt_dz_u
!
! Revision 1.7  2000/07/03 12:56:34  raasch
! array l changed from dummy argument to local allocatable array,
! dummy arguments, whose corresponding actual arguments are pointers,
! are now also defined as pointers
! all comments translated into English
!
! Revision 1.6  2000/04/18 08:10:12  schroeter
! Revision 1.4 wieder rueckgaengig gemacht, das Stabilitaets-
! kriterium basiert nun wieder auf zentralen Differenzen
!
! Revision 1.5  2000/04/13 14:33:08  schroeter
! je nach Initialisierungsmodus (trocken/feucht) fliesst in die
! Berechnung des Mischungsweges pt oder vpt ein, wird durch
! entsprechende Variablenuebergabe geregelt
!
! Revision 1.4  99/02/17  09:15:52  09:15:52  raasch (Siegfried Raasch)
! Dissipation jetzt gemaess dem originalen Deardorff-Ansatz
! Kriterium fuer reduzierten Mischungsweg im stabil geschichteten Fall enger
! gefasst (Schichtung muss sowohl oberhalb als auch unterhalb des betrachteten
! Gitterpunkts stabil sein)
! 
! Revision 1.3  1998/07/06 12:10:56  raasch
! + USE test_variables
!
! Revision 1.2  1998/03/11 11:48:59  raasch
! Anpassung des Mischungsweges an den Prandtlschen Mischungsweg moeglich
!
! Revision 1.1  1997/09/19 07:40:24  raasch
! Initial revision
!
!
! Description:
! ------------
! Diffusion- and dissipation terms for the TKE
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC diffusion_e
    

    INTERFACE diffusion_e
       MODULE PROCEDURE diffusion_e
       MODULE PROCEDURE diffusion_e_ij
    END INTERFACE diffusion_e
 
 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE diffusion_e( ddzu, dd2zu, ddzw, diss, e, km, l_grid, theta, &
                            rif, tend, zu )

       USE control_parameters
       USE grid_variables
       USE indices
       USE particle_attributes

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL            ::  dpt_dz, l_stable, phi_m
       REAL            ::  ddzu(1:nzt+1), dd2zu(1:nzt), ddzw(1:nzt), &
                           l_grid(1:nzt), zu(0:nzt+1)
       REAL, DIMENSION(nzb:nzt+1,nys-1:nyn+1,nxl-1:nxr+1) :: diss, tend
       REAL, DIMENSION(:,:), POINTER   ::  rif
       REAL, DIMENSION(:,:,:), POINTER ::  e, km, theta
       REAL, DIMENSION(nzb+1:nzt-1,nys:nyn) ::  dissipation, l, ll
 

       DO  i = nxl, nxr
          DO  j = nys, nyn
!
!--          First, calculate phi-function for eventually adjusting the &
!--          mixing length to the prandtl mixing length
             IF ( adjust_mixing_length  .AND.  prandtl_layer )  THEN
                IF ( rif(j,i) >= 0.0 )  THEN
                   phi_m = 1.0 + 5.0 * rif(j,i)
                ELSE
                   phi_m = 1.0 / SQRT( SQRT( 1.0 - 16.0 * rif(j,i) ) )
                ENDIF
             ENDIF

             DO  k = nzb_s_inner(j,i)+1, nzt-1
!
!--             Calculate the mixing length (for dissipation)
                dpt_dz = ( theta(k+1,j,i) - theta(k-1,j,i) ) * dd2zu(k)
                IF ( dpt_dz > 0.0 ) THEN
                   l_stable = 0.76 * SQRT( e(k,j,i) ) / &
                                     SQRT( g / theta(k,j,i) * dpt_dz ) + 1E-5
                ELSE
                   l_stable = l_grid(k)
                ENDIF
!
!--             Adjustment of the mixing length
                IF ( wall_adjustment )  THEN
                   l(k,j)  = MIN( wall_adjustment_factor * zu(k), l_grid(k), &
                                  l_stable )
                   ll(k,j) = MIN( wall_adjustment_factor * zu(k), l_grid(k) )
                ELSE
                   l(k,j)  = MIN( l_grid(k), l_stable )
                   ll(k,j) = l_grid(k)
                ENDIF
                IF ( adjust_mixing_length  .AND.  prandtl_layer )  THEN
                   l(k,j)  = MIN( l(k,j),  kappa * zu(k) / phi_m )
                   ll(k,j) = MIN( ll(k,j), kappa * zu(k) / phi_m )
                ENDIF

             ENDDO
          ENDDO
!
!--       Calculate the tendency terms
          DO  j = nys, nyn
             DO  k = nzb_s_inner(j,i)+1, nzt-1

                 dissipation(k,j) = ( 0.19 + 0.74 * l(k,j) / ll(k,j) ) * &
                                    e(k,j,i) * SQRT( e(k,j,i) ) / l(k,j)

                 tend(k,j,i) = tend(k,j,i)                                     &
                                        + (                                    &
                          ( km(k,j,i)+km(k,j,i+1) ) * ( e(k,j,i+1)-e(k,j,i) )  &
                        - ( km(k,j,i)+km(k,j,i-1) ) * ( e(k,j,i)-e(k,j,i-1) )  &
                                          ) * ddx2                             &
                                        + (                                    &
                          ( km(k,j,i)+km(k,j+1,i) ) * ( e(k,j+1,i)-e(k,j,i) )  &
                        - ( km(k,j,i)+km(k,j-1,i) ) * ( e(k,j,i)-e(k,j-1,i) )  &
                                          ) * ddy2                             &
                                        + (                                    &
               ( km(k,j,i)+km(k+1,j,i) ) * ( e(k+1,j,i)-e(k,j,i) ) * ddzu(k+1) &
             - ( km(k,j,i)+km(k-1,j,i) ) * ( e(k,j,i)-e(k-1,j,i) ) * ddzu(k)   &
                                          ) * ddzw(k)                          &
                             - dissipation(k,j)

             ENDDO
          ENDDO

!
!--       Store dissipation if needed for calculating the sgs particle
!--       velocities
          IF ( use_sgs_for_particles )  THEN
             DO  j = nys, nyn
                DO  k = nzb_s_inner(j,i)+1, nzt-1
                   diss(k,j,i) = dissipation(k,j)
                ENDDO
             ENDDO
          ENDIF

       ENDDO

!
!--    Boundary condition for dissipation
       IF ( use_sgs_for_particles )  THEN
          DO  i = nxl, nxr
             DO  j = nys, nyn
                diss(nzb_s_inner(j,i),j,i) = diss(nzb_s_inner(j,i)+1,j,i)
             ENDDO
          ENDDO
       ENDIF

    END SUBROUTINE diffusion_e


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE diffusion_e_ij( i, j, ddzu, dd2zu, ddzw, diss, e, km, l_grid, &
                               theta, rif, tend, zu )

       USE control_parameters
       USE grid_variables
       USE indices
       USE particle_attributes

       IMPLICIT NONE

       INTEGER         ::  i, j, k
       REAL            ::  dpt_dz, l_stable, phi_m
       REAL            ::  ddzu(1:nzt+1), dd2zu(1:nzt), ddzw(1:nzt), &
                           l_grid(1:nzt), zu(0:nzt+1)
       REAL, DIMENSION(nzb:nzt+1,nys-1:nyn+1,nxl-1:nxr+1) ::  diss, tend
       REAL, DIMENSION(:,:), POINTER   ::  rif
       REAL, DIMENSION(:,:,:), POINTER ::  e, km, theta
       REAL, DIMENSION(nzb+1:nzt-1)    ::  dissipation, l, ll


!
!--    First, calculate phi-function for eventually adjusting the mixing length
!--    to the prandtl mixing length
       IF ( adjust_mixing_length  .AND.  prandtl_layer )  THEN
          IF ( rif(j,i) >= 0.0 )  THEN
             phi_m = 1.0 + 5.0 * rif(j,i)
          ELSE
             phi_m = 1.0 / SQRT( SQRT( 1.0 - 16.0 * rif(j,i) ) )
          ENDIF
       ENDIF

!
!--    Calculate the mixing length (for dissipation)
       DO  k = nzb_s_inner(j,i)+1, nzt-1
          dpt_dz = ( theta(k+1,j,i) - theta(k-1,j,i) ) * dd2zu(k)
          IF ( dpt_dz > 0.0 ) THEN
             l_stable = 0.76 * SQRT( e(k,j,i) ) / &
                               SQRT( g / theta(k,j,i) * dpt_dz ) + 1E-5
          ELSE
             l_stable = l_grid(k)
          ENDIF
!
!--       Adjustment of the mixing length
          IF ( wall_adjustment )  THEN
             l(k)  = MIN( wall_adjustment_factor * zu(k), l_grid(k), l_stable )
             ll(k) = MIN( wall_adjustment_factor * zu(k), l_grid(k) )
          ELSE
             l(k)  = MIN( l_grid(k), l_stable )
             ll(k) = l_grid(k)
          ENDIF
          IF ( adjust_mixing_length  .AND.  prandtl_layer )  THEN
             l(k)  = MIN( l(k),  kappa * zu(k) / phi_m )
             ll(k) = MIN( ll(k), kappa * zu(k) / phi_m )
          ENDIF

!
!--       Calculate the tendency term
          dissipation(k) = ( 0.19 + 0.74 * l(k) / ll(k) ) * e(k,j,i) * &
                           SQRT( e(k,j,i) ) / l(k)

          tend(k,j,i) = tend(k,j,i)                                           &
                                       + (                                    &
                         ( km(k,j,i)+km(k,j,i+1) ) * ( e(k,j,i+1)-e(k,j,i) )  &
                       - ( km(k,j,i)+km(k,j,i-1) ) * ( e(k,j,i)-e(k,j,i-1) )  &
                                         ) * ddx2                             &
                                       + (                                    &
                         ( km(k,j,i)+km(k,j+1,i) ) * ( e(k,j+1,i)-e(k,j,i) )  &
                       - ( km(k,j,i)+km(k,j-1,i) ) * ( e(k,j,i)-e(k,j-1,i) )  &
                                         ) * ddy2                             &
                                       + (                                    &
              ( km(k,j,i)+km(k+1,j,i) ) * ( e(k+1,j,i)-e(k,j,i) ) * ddzu(k+1) &
            - ( km(k,j,i)+km(k-1,j,i) ) * ( e(k,j,i)-e(k-1,j,i) ) * ddzu(k)   &
                                         ) * ddzw(k)                          &
                                       - dissipation(k)

       ENDDO

!
!--    Store dissipation if needed for calculating the sgs particle velocities
       IF ( use_sgs_for_particles )  THEN
          DO  k = nzb_s_inner(j,i)+1, nzt-1
             diss(k,j,i) = dissipation(k)
          ENDDO
!
!--       Boundary condition for dissipation
          diss(nzb_s_inner(j,i),j,i) = diss(nzb_s_inner(j,i)+1,j,i)
       ENDIF

    END SUBROUTINE diffusion_e_ij

 END MODULE diffusion_e_mod