source: palm/trunk/SOURCE/calc_liquid_water_content.f90 @ 2101

Last change on this file since 2101 was 2101, checked in by suehring, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 4.8 KB
Line 
1!> @file calc_liquid_water_content.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: calc_liquid_water_content.f90 2101 2017-01-05 16:42:31Z suehring $
27!
28! 2000 2016-08-20 18:09:15Z knoop
29! Forced header and separation lines into 80 columns
30!
31! 1822 2016-04-07 07:49:42Z hoffmann
32! icloud_scheme removed. microphysics_seifert added.
33!
34! 1682 2015-10-07 23:56:08Z knoop
35! Code annotations made doxygen readable
36!
37! 1353 2014-04-08 15:21:23Z heinze
38! REAL constants provided with KIND-attribute
39!
40! 1320 2014-03-20 08:40:49Z raasch
41! ONLY-attribute added to USE-statements,
42! kind-parameters added to all INTEGER and REAL declaration statements,
43! kinds are defined in new module kinds,
44! revision history before 2012 removed,
45! comment fields (!:) to be used for variable explanations added to
46! all variable declaration statements
47!
48! 1253 2013-11-07 10:48:12Z fricke
49! Bugfix: q is set to qr in case that q is smaller than qr
50!
51! 1115 2013-03-26 18:16:16Z hoffmann
52! drizzle can be used independently from precipitation
53!
54! 1053 2012-11-13 17:11:03Z hoffmann
55! description expanded to the two-moment cloud scheme
56!
57! 1036 2012-10-22 13:43:42Z raasch
58! code put under GPL (PALM 3.9)
59!
60! Revision 1.1  2000/04/13 14:50:45  schroeter
61! Initial revision
62!
63!
64!
65! Description:
66! ------------
67!> Calculation of the liquid water content (0%-or-100%-scheme). This scheme is
68!> used by the one and the two moment cloud physics scheme. Using the two moment
69!> scheme, this calculation results in the cloud water content.
70!------------------------------------------------------------------------------!
71 SUBROUTINE calc_liquid_water_content
72 
73
74
75    USE arrays_3d,                                                             &
76        ONLY:  hyp, pt, q, qc, ql, qr
77
78    USE cloud_parameters,                                                      &
79        ONLY:  l_d_cp, l_d_r, t_d_pt
80
81    USE control_parameters,                                                    &
82        ONLY:  microphysics_seifert
83
84    USE indices,                                                               &
85        ONLY:  nxlg, nxrg, nyng, nysg, nzb_s_inner, nzt
86
87    USE kinds
88
89    USE pegrid
90
91
92    IMPLICIT NONE
93
94    INTEGER(iwp) ::  i !<
95    INTEGER(iwp) ::  j !<
96    INTEGER(iwp) ::  k !<
97
98    REAL(wp) ::  alpha !<
99    REAL(wp) ::  e_s   !<
100    REAL(wp) ::  q_s   !<
101    REAL(wp) ::  t_l   !<
102
103    DO  i = nxlg, nxrg
104       DO  j = nysg, nyng
105          DO  k = nzb_s_inner(j,i)+1, nzt
106
107!
108!--          Compute the liquid water temperature
109             t_l = t_d_pt(k) * pt(k,j,i)
110
111!
112!--          Compute saturation water vapor pressure at t_l
113             e_s = 610.78_wp * EXP( 17.269_wp * ( t_l - 273.16_wp ) /          &
114                                                ( t_l - 35.86_wp ) )
115
116!
117!--          Compute approximation of saturation humidity
118             q_s = 0.622_wp * e_s / ( hyp(k) - 0.378_wp * e_s )
119
120!
121!--          Correction factor
122             alpha = 0.622_wp * l_d_r * l_d_cp / ( t_l * t_l )
123
124!
125!--          Correction of the approximated value
126!--          (see: Cuijpers + Duynkerke, 1993, JAS, 23)
127             q_s = q_s * ( 1.0_wp + alpha * q(k,j,i) ) / ( 1.0_wp + alpha * q_s )
128
129!
130!--          Compute the liquid water content
131             IF ( microphysics_seifert )  THEN
132                IF ( ( q(k,j,i) - q_s - qr(k,j,i) ) > 0.0_wp ) THEN
133                   qc(k,j,i) = q(k,j,i) - q_s - qr(k,j,i)
134                   ql(k,j,i) = qc(k,j,i) + qr(k,j,i)
135                ELSE
136                   IF ( q(k,j,i) < qr(k,j,i) )  q(k,j,i) = qr(k,j,i)
137                   qc(k,j,i) = 0.0_wp 
138                   ql(k,j,i) = qr(k,j,i)
139                ENDIF
140             ELSE
141                IF ( ( q(k,j,i) - q_s ) > 0.0_wp ) THEN
142                   qc(k,j,i) = q(k,j,i) - q_s
143                   ql(k,j,i) = qc(k,j,i)
144                ELSE
145                   qc(k,j,i) = 0.0_wp
146                   ql(k,j,i) = 0.0_wp
147                ENDIF
148             ENDIF
149          ENDDO
150       ENDDO
151    ENDDO
152   
153 END SUBROUTINE calc_liquid_water_content
Note: See TracBrowser for help on using the repository browser.