source: palm/trunk/SOURCE/calc_liquid_water_content.f90 @ 1

 SUBROUTINE calc_liquid_water_content

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: calc_liquid_water_content.f90,v $
! Revision 1.5  2005/03/26 15:22:06  raasch
! Arguments for non-cyclic boundary conditions added to argument list of
! routine exchange_horiz,
! ql calculated for the ghost points, exchange of ghost points removed
!
! Revision 1.4  2004/01/30 10:15:13  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.3  2001/01/22 05:30:59  raasch
! Module test_variables removed
!
! Revision 1.2  2000/06/13 07:49:32  schroeter
! Horizontal boundary conditions (cyclic) of ql will be set now
!
! Revision 1.1  2000/04/13 14:50:45  schroeter
! Initial revision
!
!
!
! Description:
! ------------
! Calculation of the liquid water content (0%-or-100%-scheme)
!------------------------------------------------------------------------------!


    USE arrays_3d
    USE cloud_parameters
    USE constants
    USE grid_variables
    USE indices
    USE pegrid

    IMPLICIT NONE

    INTEGER :: i, j, k

    REAL :: alpha, e_s, q_s, t_l

    DO  i = nxl-1, nxr+1
       DO  j = nys-1, nyn+1
          DO  k = nzb_2d(j,i)+1, nzt

!
!--          Compute the liquid water temperature
             t_l = t_d_pt(k) * pt(k,j,i)

!
!--          Compute saturation water vapor pressure at t_l
             e_s = 610.78 * EXP( 17.269 * ( t_l - 273.16 ) / &
                                          ( t_l - 35.86 ) )

!
!--          Compute approximation of saturation humidity
             q_s = 0.622 * e_s / &
                   ( hydro_press(k) - 0.378 * e_s )

!
!--          Correction factor
             alpha = 0.622 * l_d_r * l_d_cp / ( t_l * t_l )

!
!--          Correction of the approximated value
!--          (see: Cuijpers + Duynkerke, 1993, JAS, 23)
             q_s = q_s * ( 1.0 + alpha * q(k,j,i) ) / ( 1.0 + alpha * q_s )

!
!--          Compute the liquid water content
             IF ( ( q(k,j,i) - q_s ) > 0.0 ) THEN
                ql(k,j,i) = q(k,j,i) - q_s
             ELSE
                ql(k,j,i) = 0.0 
             ENDIF

          ENDDO
       ENDDO
    ENDDO
    
!
!-- Setting boundary values of ql
!    CALL exchange_horiz( ql, 0, 0 )    

 END SUBROUTINE calc_liquid_water_content