source: palm/trunk/SOURCE/advec_w_up.f90 @ 2

 MODULE advec_w_up_mod

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: advec_w_up.f90,v $
! Revision 1.11  2006/02/23 09:47:23  raasch
! *** empty log message ***
!
! Revision 1.10  2004/01/30 10:13:31  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.9  2003/03/12 16:20:07  raasch
! Full code replaced in the call for all gridpoints instead of calling the
! _ij version (required by NEC, because otherwise no vectorization)
!
! Revision 1.8  2002/06/11 12:28:33  raasch
! Former subroutine changed to a module which allows to be called for all grid
! points of a single vertical column with index i,j or for all grid points by
! using function overloading.
!
! Revision 1.7  2001/03/29 17:37:31  raasch
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.6  2001/01/22 05:21:01  raasch
! Module test_variables removed
!
! Revision 1.5  2000/01/20 10:22:08  letzel
! All comments translated into English
!
! Revision 1.4  1998/07/06 12:06:25  raasch
! + USE test_variables
!
! Revision 1.3  1998/04/21 15:54:20  raasch
! Galilei-Transformation eingebaut
!
! Revision 1.2  1997/09/09 08:28:55  raasch
! Kehrwerte der Gitterweiten implementiert
!
! Revision 1.1  1997/08/29 08:56:33  raasch
! Initial revision
!
!
! Description:
! ------------
! Advection term for the w velocity-component using upstream scheme.
! NOTE: vertical advection at k=1 still has wrong grid spacing for w>0
!       The same problem occurs for all topography boundaries!
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC advec_w_up

    INTERFACE advec_w_up
       MODULE PROCEDURE advec_w_up
       MODULE PROCEDURE advec_w_up_ij
    END INTERFACE advec_w_up

 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE advec_w_up

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  ukomp, vkomp


       DO  i = nxl, nxr
          DO  j = nys, nyn
             DO  k = nzb_w_inner(j,i)+1, nzt-1
!
!--             x-direction
                ukomp = 0.25 * ( u(k,j,i)   + u(k,j,i+1) + &
                                 u(k+1,j,i) + u(k+1,j,i+1) ) - u_gtrans
                IF ( ukomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( w(k,j,i) - w(k,j,i-1) ) * ddx
                ELSE
                   tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( w(k,j,i+1) - w(k,j,i) ) * ddx
                ENDIF
!
!--             y-direction
                vkomp = 0.25 * ( v(k,j,i) + v(k,j+1,i) + &
                                 v(k+1,j,i) + v(k+1,j+1,i) ) - v_gtrans
                IF ( vkomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( w(k,j,i) - w(k,j-1,i) ) * ddy
                ELSE
                   tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( w(k,j+1,i) - w(k,j,i) ) * ddy
                ENDIF
!
!--             z-direction
                IF ( w(k,j,i) > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - w(k,j,i) * &
                                         ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k)
                ELSE
                   tend(k,j,i) = tend(k,j,i) - w(k,j,i) * &
                                         ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)
                ENDIF

             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE advec_w_up


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE advec_w_up_ij( i, j )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  ukomp, vkomp


       DO  k = nzb_w_inner(j,i)+1, nzt-1
!
!--       x-direction
          ukomp = 0.25 * ( u(k,j,i) + u(k,j,i+1) + u(k+1,j,i) + u(k+1,j,i+1) &
                         ) - u_gtrans
          IF ( ukomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( w(k,j,i) - w(k,j,i-1) ) * ddx
          ELSE
             tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( w(k,j,i+1) - w(k,j,i) ) * ddx
          ENDIF
!
!--       y-direction
          vkomp = 0.25 * ( v(k,j,i) + v(k,j+1,i) + v(k+1,j,i) + v(k+1,j+1,i) &
                         ) - v_gtrans
          IF ( vkomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( w(k,j,i) - w(k,j-1,i) ) * ddy
          ELSE
             tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( w(k,j+1,i) - w(k,j,i) ) * ddy
          ENDIF
!
!--       z-direction
          IF ( w(k,j,i) > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - w(k,j,i) * &
                                         ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k)
          ELSE
             tend(k,j,i) = tend(k,j,i) - w(k,j,i) * &
                                         ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1)
          ENDIF

       ENDDO

    END SUBROUTINE advec_w_up_ij

 END MODULE advec_w_up_mod