source: palm/trunk/SOURCE/advec_w_pw.f90 @ 2

 MODULE advec_w_pw_mod

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: advec_w_pw.f90,v $
! Revision 1.15  2006/02/23 09:47:01  raasch
! nzb_2d replaced by nzb_w_inner
!
! Revision 1.14  2004/01/30 10:13:07  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.13  2003/03/12 16:19:29  raasch
! Full code replaced in the call for all gridpoints instead of calling the
! _ij version (required by NEC, because otherwise no vectorization)
!
! Revision 1.12  2002/06/11 12:27:33  raasch
! Former subroutine changed to a module which allows to be called for all grid
! points of a single vertical column with index i,j or for all grid points by
! using function overloading.
!
! Revision 1.11  2001/03/29 17:37:10  raasch
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.10  2001/01/22 05:19:42  raasch
! Module test_variables removed
!
! Revision 1.9  2000/01/20 10:18:31  letzel
! All comments translated into English
!
! Revision 1.8  1998/08/05 06:51:10  raasch
! Alle Gitterpunkte werden gleich behandelt (keine zentralen Differenzenquotien-
! ten mehr bei Vertikaladvektion bei k=1)
!
! Revision 1.1  1997/08/11 06:10:29  raasch
! Initial revision
!
!
! Description:
! ------------
! Advection term for w velocity-component using Piacsek and Williams.
! Vertical advection at the first grid point above the surface is done with
! normal centred differences, because otherwise no information from the surface
! would be communicated upwards due to w=0 at k=nzb.
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC advec_w_pw

    INTERFACE advec_w_pw
       MODULE PROCEDURE advec_w_pw
       MODULE PROCEDURE advec_w_pw_ij
    END INTERFACE advec_w_pw
 
 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE advec_w_pw

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  gu, gv

 
       gu = 2.0 * u_gtrans
       gv = 2.0 * v_gtrans
       DO  i = nxl, nxr
          DO  j = nys, nyn
             DO  k = nzb_w_inner(j,i)+1, nzt
                tend(k,j,i) = tend(k,j,i) - 0.25 * (                           &
                         ( w(k,j,i+1) * ( u(k+1,j,i+1) + u(k,j,i+1) - gu )     &
                         - w(k,j,i-1) * ( u(k+1,j,i) + u(k,j,i) - gu ) ) * ddx &
                       + ( w(k,j+1,i) * ( v(k+1,j+1,i) + v(k,j+1,i) - gv )     &
                         - w(k,j-1,i) * ( v(k+1,j,i) + v(k,j,i) - gv ) ) * ddy &
                       + ( w(k+1,j,i) * ( w(k+1,j,i) + w(k,j,i) )              &
                         - w(k-1,j,i) * ( w(k,j,i) + w(k-1,j,i) ) )            &
                                                                  * ddzu(k+1)  &
                                                   )
             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE advec_w_pw


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE advec_w_pw_ij( i, j )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  gu, gv


       gu = 2.0 * u_gtrans
       gv = 2.0 * v_gtrans
       DO  k = nzb_w_inner(j,i)+1, nzt
          tend(k,j,i) = tend(k,j,i) - 0.25 * (                              &
                         ( w(k,j,i+1) * ( u(k+1,j,i+1) + u(k,j,i+1) - gu )     &
                         - w(k,j,i-1) * ( u(k+1,j,i) + u(k,j,i) - gu ) ) * ddx &
                       + ( w(k,j+1,i) * ( v(k+1,j+1,i) + v(k,j+1,i) - gv )     &
                         - w(k,j-1,i) * ( v(k+1,j,i) + v(k,j,i) - gv ) ) * ddy &
                       + ( w(k+1,j,i) * ( w(k+1,j,i) + w(k,j,i) )              &
                         - w(k-1,j,i) * ( w(k,j,i) + w(k-1,j,i) ) )            &
                                                                  * ddzu(k+1)  &
                                                )
       ENDDO

    END SUBROUTINE advec_w_pw_ij

 END MODULE advec_w_pw_mod