source: palm/trunk/SOURCE/advec_v_up.f90 @ 1873

Last change on this file since 1873 was 1873, checked in by maronga, 8 years ago

revised renaming of modules

  • Property svn:keywords set to Id
File size: 7.3 KB
Line 
1!> @file advec_v_up.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! Module renamed (removed _mod)
22!
23!
24! Former revisions:
25! -----------------
26! $Id: advec_v_up.f90 1873 2016-04-18 14:50:06Z maronga $
27!
28! 1850 2016-04-08 13:29:27Z maronga
29! Module renamed
30!
31!
32! 1682 2015-10-07 23:56:08Z knoop
33! Code annotations made doxygen readable
34!
35! 1353 2014-04-08 15:21:23Z heinze
36! REAL constants provided with KIND-attribute
37!
38! 1320 2014-03-20 08:40:49Z raasch
39! ONLY-attribute added to USE-statements,
40! kind-parameters added to all INTEGER and REAL declaration statements,
41! kinds are defined in new module kinds,
42! revision history before 2012 removed,
43! comment fields (!:) to be used for variable explanations added to
44! all variable declaration statements
45!
46! 1036 2012-10-22 13:43:42Z raasch
47! code put under GPL (PALM 3.9)
48!
49! Revision 1.1  1997/08/29 08:56:05  raasch
50! Initial revision
51!
52!
53! Description:
54! ------------
55!> Advection term for the v velocity-component using upstream scheme.
56!> NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
57!>       The same problem occurs for all topography boundaries!
58!------------------------------------------------------------------------------!
59 MODULE advec_v_up_mod
60 
61
62    PRIVATE
63    PUBLIC advec_v_up
64
65    INTERFACE advec_v_up
66       MODULE PROCEDURE advec_v_up
67       MODULE PROCEDURE advec_v_up_ij
68    END INTERFACE advec_v_up
69
70 CONTAINS
71
72
73!------------------------------------------------------------------------------!
74! Description:
75! ------------
76!> Call for all grid points
77!------------------------------------------------------------------------------!
78    SUBROUTINE advec_v_up
79
80       USE arrays_3d,                                                          &
81           ONLY:  ddzu, tend, u, v, w
82
83       USE control_parameters,                                                 &
84           ONLY:  u_gtrans, v_gtrans
85
86       USE grid_variables,                                                     &
87           ONLY:  ddx, ddy
88
89       USE indices,                                                            &
90           ONLY:  nxl, nxr, nyn, nysv, nzb_v_inner, nzt
91
92       USE kinds
93
94
95       IMPLICIT NONE
96
97       INTEGER(iwp) ::  i !<
98       INTEGER(iwp) ::  j !<
99       INTEGER(iwp) ::  k !<
100
101       REAL(wp) ::  ukomp !<
102       REAL(wp) ::  vkomp !<
103       REAL(wp) ::  wkomp !<       
104
105
106       DO  i = nxl, nxr
107          DO  j = nysv, nyn
108             DO  k = nzb_v_inner(j,i)+1, nzt
109!
110!--             x-direction
111                ukomp = 0.25_wp * ( u(k,j,i)   + u(k,j-1,i) +                  &
112                                 u(k,j,i+1) + u(k,j-1,i+1) ) - u_gtrans
113                IF ( ukomp > 0.0_wp )  THEN
114                   tend(k,j,i) = tend(k,j,i) - ukomp *                         &
115                                         ( v(k,j,i) - v(k,j,i-1) ) * ddx
116                ELSE
117                   tend(k,j,i) = tend(k,j,i) - ukomp *                         &
118                                         ( v(k,j,i+1) - v(k,j,i) ) * ddx
119                ENDIF
120!
121!--             y-direction
122                vkomp = v(k,j,i) - v_gtrans
123                IF ( vkomp > 0.0_wp )  THEN
124                   tend(k,j,i) = tend(k,j,i) - vkomp *                         &
125                                         ( v(k,j,i) - v(k,j-1,i) ) * ddy
126                ELSE
127                   tend(k,j,i) = tend(k,j,i) - vkomp *                         &
128                                         ( v(k,j+1,i) - v(k,j,i) ) * ddy
129                ENDIF
130!
131!--             z-direction
132                wkomp = 0.25_wp * ( w(k,j,i)  + w(k-1,j,i) +                   &
133                                 w(k,j-1,i) + w(k-1,j-1,i) )
134                IF ( wkomp > 0.0_wp )  THEN
135                   tend(k,j,i) = tend(k,j,i) - wkomp *                         &
136                                         ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k)
137                ELSE
138                   tend(k,j,i) = tend(k,j,i) - wkomp *                         &
139                                         ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)
140                ENDIF
141
142             ENDDO
143          ENDDO
144       ENDDO
145
146    END SUBROUTINE advec_v_up
147
148
149!------------------------------------------------------------------------------!
150! Description:
151! ------------
152!> Call for grid point i,j
153!------------------------------------------------------------------------------!
154    SUBROUTINE advec_v_up_ij( i, j )
155
156       USE arrays_3d,                                                          &
157           ONLY:  ddzu, tend, u, v, w
158
159       USE control_parameters,                                                 &
160           ONLY:  u_gtrans, v_gtrans
161
162       USE grid_variables,                                                     &
163           ONLY:  ddx, ddy
164
165       USE indices,                                                            &
166           ONLY:  nzb_v_inner, nzt
167
168       USE kinds
169
170
171       IMPLICIT NONE
172
173       INTEGER(iwp) ::  i !<
174       INTEGER(iwp) ::  j !<
175       INTEGER(iwp) ::  k !<
176
177       REAL(wp) ::  ukomp !<
178       REAL(wp) ::  vkomp !<
179       REAL(wp) ::  wkomp !<
180
181
182       DO  k = nzb_v_inner(j,i)+1, nzt
183!
184!--       x-direction
185          ukomp = 0.25_wp * ( u(k,j,i) + u(k,j-1,i) + u(k,j,i+1) + u(k,j-1,i+1) &
186                         ) - u_gtrans
187          IF ( ukomp > 0.0_wp )  THEN
188             tend(k,j,i) = tend(k,j,i) - ukomp *                               &
189                                         ( v(k,j,i) - v(k,j,i-1) ) * ddx
190          ELSE
191             tend(k,j,i) = tend(k,j,i) - ukomp *                               &
192                                         ( v(k,j,i+1) - v(k,j,i) ) * ddx
193          ENDIF
194!
195!--       y-direction
196          vkomp = v(k,j,i) - v_gtrans
197          IF ( vkomp > 0.0_wp )  THEN
198             tend(k,j,i) = tend(k,j,i) - vkomp *                               &
199                                         ( v(k,j,i) - v(k,j-1,i) ) * ddy
200          ELSE
201             tend(k,j,i) = tend(k,j,i) - vkomp *                               &
202                                         ( v(k,j+1,i) - v(k,j,i) ) * ddy
203          ENDIF
204!
205!--       z-direction
206          wkomp = 0.25_wp * ( w(k,j,i) + w(k-1,j,i) + w(k,j-1,i) + w(k-1,j-1,i) )
207          IF ( wkomp > 0.0_wp )  THEN
208             tend(k,j,i) = tend(k,j,i) - wkomp *                               &
209                                         ( v(k,j,i) - v(k-1,j,i) ) * ddzu(k)
210          ELSE
211             tend(k,j,i) = tend(k,j,i) - wkomp *                               &
212                                         ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1)
213          ENDIF
214
215       ENDDO
216
217    END SUBROUTINE advec_v_up_ij
218
219 END MODULE advec_v_up_mod
Note: See TracBrowser for help on using the repository browser.