source: palm/trunk/SOURCE/advec_u_up.f90 @ 1036

Last change on this file since 1036 was 1036, checked in by raasch, 9 years ago

code has been put under the GNU General Public License (v3)

  • Property svn:keywords set to Id
File size: 5.5 KB
Line 
1 MODULE advec_u_up_mod
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: advec_u_up.f90 1036 2012-10-22 13:43:42Z raasch $
27!
28! 106 2007-08-16 14:30:26Z raasch
29! i loop is starting from nxlu (needed for non-cyclic boundary conditions)
30!
31! 75 2007-03-22 09:54:05Z raasch
32! uxrp eliminated
33!
34! RCS Log replace by Id keyword, revision history cleaned up
35!
36! Revision 1.12  2006/02/23 09:45:04  raasch
37! nzb_2d replaced by nzb_u_inner
38!
39! Revision 1.1  1997/08/29 08:55:25  raasch
40! Initial revision
41!
42!
43! Description:
44! ------------
45! Advection term for the u velocity-component using upstream scheme.
46! NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
47!       The same problem occurs for all topography boundaries!
48!------------------------------------------------------------------------------!
49
50    PRIVATE
51    PUBLIC advec_u_up
52
53    INTERFACE advec_u_up
54       MODULE PROCEDURE advec_u_up
55       MODULE PROCEDURE advec_u_up_ij
56    END INTERFACE advec_u_up
57
58 CONTAINS
59
60
61!------------------------------------------------------------------------------!
62! Call for all grid points
63!------------------------------------------------------------------------------!
64    SUBROUTINE advec_u_up
65
66       USE arrays_3d
67       USE control_parameters
68       USE grid_variables
69       USE indices
70
71       IMPLICIT NONE
72
73       INTEGER ::  i, j, k
74
75       REAL ::  ukomp, vkomp, wkomp
76
77
78       DO  i = nxlu, nxr
79          DO  j = nys, nyn
80             DO  k = nzb_u_inner(j,i)+1, nzt
81!
82!--             x-direction
83                ukomp = u(k,j,i) - u_gtrans
84                IF ( ukomp > 0.0 )  THEN
85                   tend(k,j,i) = tend(k,j,i) - ukomp * &
86                                         ( u(k,j,i) - u(k,j,i-1) ) * ddx
87                ELSE
88                   tend(k,j,i) = tend(k,j,i) - ukomp * &
89                                          ( u(k,j,i+1) - u(k,j,i) ) * ddx
90                ENDIF
91!
92!--             y-direction
93                vkomp = 0.25 * ( v(k,j,i)   + v(k,j+1,i) + &
94                                 v(k,j,i-1) + v(k,j+1,i-1) ) - v_gtrans
95                IF ( vkomp > 0.0 )  THEN
96                   tend(k,j,i) = tend(k,j,i) - vkomp * &
97                                         ( u(k,j,i) - u(k,j-1,i) ) * ddy
98                ELSE
99                   tend(k,j,i) = tend(k,j,i) - vkomp * &
100                                         ( u(k,j+1,i) - u(k,j,i) ) * ddy
101                ENDIF
102!
103!--             z-direction
104                wkomp = 0.25 * ( w(k,j,i)   + w(k-1,j,i) + &
105                                 w(k,j,i-1) + w(k-1,j,i-1) )
106                IF ( wkomp > 0.0 )  THEN
107                   tend(k,j,i) = tend(k,j,i) - wkomp * &
108                                         ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k)
109                ELSE
110                   tend(k,j,i) = tend(k,j,i) - wkomp * &
111                                         ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1)
112                ENDIF
113
114             ENDDO
115          ENDDO
116       ENDDO
117
118    END SUBROUTINE advec_u_up
119
120
121!------------------------------------------------------------------------------!
122! Call for grid point i,j
123!------------------------------------------------------------------------------!
124    SUBROUTINE advec_u_up_ij( i, j )
125
126       USE arrays_3d
127       USE control_parameters
128       USE grid_variables
129       USE indices
130
131       IMPLICIT NONE
132
133       INTEGER ::  i, j, k
134
135       REAL ::  ukomp, vkomp, wkomp
136
137
138       DO  k = nzb_u_inner(j,i)+1, nzt
139!
140!--       x-direction
141          ukomp = u(k,j,i) - u_gtrans
142          IF ( ukomp > 0.0 )  THEN
143             tend(k,j,i) = tend(k,j,i) - ukomp * &
144                                         ( u(k,j,i) - u(k,j,i-1) ) * ddx
145          ELSE
146             tend(k,j,i) = tend(k,j,i) - ukomp * &
147                                         ( u(k,j,i+1) - u(k,j,i) ) * ddx
148          ENDIF
149!
150!--       y-direction
151          vkomp = 0.25 * ( v(k,j,i) + v(k,j+1,i) + v(k,j,i-1) + v(k,j+1,i-1) &
152                         ) - v_gtrans
153          IF ( vkomp > 0.0 )  THEN
154             tend(k,j,i) = tend(k,j,i) - vkomp * &
155                                         ( u(k,j,i) - u(k,j-1,i) ) * ddy
156          ELSE
157             tend(k,j,i) = tend(k,j,i) - vkomp * &
158                                         ( u(k,j+1,i) - u(k,j,i) ) * ddy
159          ENDIF
160!
161!--       z-direction
162          wkomp = 0.25 * ( w(k,j,i) + w(k-1,j,i) + w(k,j,i-1) + w(k-1,j,i-1) )
163          IF ( wkomp > 0.0 )  THEN
164             tend(k,j,i) = tend(k,j,i) - wkomp * &
165                                         ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k)
166          ELSE
167             tend(k,j,i) = tend(k,j,i) - wkomp * &
168                                         ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1)
169          ENDIF
170
171       ENDDO
172
173    END SUBROUTINE advec_u_up_ij
174
175 END MODULE advec_u_up_mod
Note: See TracBrowser for help on using the repository browser.