source: palm/trunk/SOURCE/advec_u_pw.f90 @ 1873

Last change on this file since 1873 was 1873, checked in by maronga, 5 years ago

revised renaming of modules

  • Property svn:keywords set to Id
File size: 5.8 KB
Line 
1!> @file advec_u_pw.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! Module renamed (removed _mod)
22!
23!
24! Former revisions:
25! -----------------
26! $Id: advec_u_pw.f90 1873 2016-04-18 14:50:06Z maronga $
27!
28! 1850 2016-04-08 13:29:27Z maronga
29! Module renamed
30!
31!
32! 1682 2015-10-07 23:56:08Z knoop
33! Code annotations made doxygen readable
34!
35! 1353 2014-04-08 15:21:23Z heinze
36! REAL constants provided with KIND-attribute
37!
38! 1320 2014-03-20 08:40:49Z raasch
39! ONLY-attribute added to USE-statements,
40! kind-parameters added to all INTEGER and REAL declaration statements,
41! kinds are defined in new module kinds,
42! revision history before 2012 removed,
43! comment fields (!:) to be used for variable explanations added to
44! all variable declaration statements
45!
46! 1036 2012-10-22 13:43:42Z raasch
47! code put under GPL (PALM 3.9)
48!
49! Revision 1.1  1997/08/11 06:09:21  raasch
50! Initial revision
51!
52!
53! Description:
54! ------------
55!> Advection term for u velocity-component using Piacsek and Williams.
56!> Vertical advection at the first grid point above the surface is done with
57!> normal centred differences, because otherwise no information from the surface
58!> would be communicated upwards due to w=0 at K=nzb.
59!------------------------------------------------------------------------------!
60 MODULE advec_u_pw_mod
61 
62
63    PRIVATE
64    PUBLIC advec_u_pw
65
66    INTERFACE advec_u_pw
67       MODULE PROCEDURE advec_u_pw
68       MODULE PROCEDURE advec_u_pw_ij
69    END INTERFACE advec_u_pw
70 
71 CONTAINS
72
73
74!------------------------------------------------------------------------------!
75! Description:
76! ------------
77!> Call for all grid points
78!------------------------------------------------------------------------------!
79    SUBROUTINE advec_u_pw
80
81       USE arrays_3d,                                                          &
82           ONLY:  ddzw, tend, u, v, w
83
84       USE control_parameters,                                                 &
85           ONLY:  u_gtrans, v_gtrans
86
87       USE grid_variables,                                                     &
88           ONLY:  ddx, ddy
89
90       USE indices,                                                            &
91           ONLY:  nxlu, nxr, nyn, nys, nzb_u_inner, nzt
92
93       USE kinds
94
95
96       IMPLICIT NONE
97
98       INTEGER(iwp) ::  i !<
99       INTEGER(iwp) ::  j !<
100       INTEGER(iwp) ::  k !<
101       
102       REAL(wp)    ::  gu !<
103       REAL(wp)    ::  gv !<
104 
105       gu = 2.0_wp * u_gtrans
106       gv = 2.0_wp * v_gtrans
107       DO  i = nxlu, nxr
108          DO  j = nys, nyn
109             DO  k = nzb_u_inner(j,i)+1, nzt
110                tend(k,j,i) = tend(k,j,i) - 0.25_wp * (                        &
111                         ( u(k,j,i+1) * ( u(k,j,i+1) + u(k,j,i) - gu )         &
112                         - u(k,j,i-1) * ( u(k,j,i) + u(k,j,i-1) - gu ) ) * ddx &
113                       + ( u(k,j+1,i) * ( v(k,j+1,i) + v(k,j+1,i-1) - gv )     &
114                         - u(k,j-1,i) * ( v(k,j,i) + v(k,j,i-1) - gv ) ) * ddy &
115                       + ( u(k+1,j,i) * ( w(k,j,i) + w(k,j,i-1) )              &
116                         - u(k-1,j,i) * ( w(k-1,j,i) + w(k-1,j,i-1) ) )        &
117                                                                  * ddzw(k)    &
118                                                      )
119             ENDDO
120          ENDDO
121       ENDDO
122
123    END SUBROUTINE advec_u_pw
124
125
126!------------------------------------------------------------------------------!
127! Description:
128! ------------
129!> Call for grid point i,j
130!------------------------------------------------------------------------------!
131    SUBROUTINE advec_u_pw_ij( i, j )
132
133       USE arrays_3d,                                                          &
134           ONLY:  ddzw, tend, u, v, w
135
136       USE control_parameters,                                                 &
137           ONLY:  u_gtrans, v_gtrans
138
139       USE grid_variables,                                                     &
140           ONLY:  ddx, ddy
141
142       USE indices,                                                            &
143           ONLY:  nzb_u_inner, nzt
144
145       USE kinds
146
147
148       IMPLICIT NONE
149
150       INTEGER(iwp) ::  i !<
151       INTEGER(iwp) ::  j !<
152       INTEGER(iwp) ::  k !<
153       
154       REAL(wp)    ::  gu !<
155       REAL(wp)    ::  gv !<
156
157       gu = 2.0_wp * u_gtrans
158       gv = 2.0_wp * v_gtrans
159       DO  k = nzb_u_inner(j,i)+1, nzt
160          tend(k,j,i) = tend(k,j,i) - 0.25_wp * (                              &
161                         ( u(k,j,i+1) * ( u(k,j,i+1) + u(k,j,i) - gu )         &
162                         - u(k,j,i-1) * ( u(k,j,i) + u(k,j,i-1) - gu ) ) * ddx &
163                       + ( u(k,j+1,i) * ( v(k,j+1,i) + v(k,j+1,i-1) - gv )     &
164                         - u(k,j-1,i) * ( v(k,j,i) + v(k,j,i-1) - gv ) ) * ddy &
165                       + ( u(k+1,j,i) * ( w(k,j,i) + w(k,j,i-1) )              &
166                         - u(k-1,j,i) * ( w(k-1,j,i) + w(k-1,j,i-1) ) )        &
167                                                                  * ddzw(k)    &
168                                                )
169       ENDDO
170
171    END SUBROUTINE advec_u_pw_ij
172
173 END MODULE advec_u_pw_mod
Note: See TracBrowser for help on using the repository browser.