source: palm/trunk/SOURCE/advec_s_up.f90 @ 3639

Last change on this file since 3639 was 3636, checked in by raasch, 5 years ago

nopointer option removed

  • Property svn:keywords set to Id
File size: 8.5 KB
Line 
1!> @file advec_s_up.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2018 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: advec_s_up.f90 3636 2018-12-19 13:48:34Z forkel $
27! nopointer option removed
28!
29! 3547 2018-11-21 13:21:24Z suehring
30! variables documented
31!
32! 3538 2018-11-20 10:55:41Z suehring
33! Remove unnecessary double-masking of topography
34!
35! 2718 2018-01-02 08:49:38Z maronga
36! Corrected "Former revisions" section
37!
38! 2696 2017-12-14 17:12:51Z kanani
39! Change in file header (GPL part)
40!
41! 2233 2017-05-30 18:08:54Z suehring
42!
43! 2232 2017-05-30 17:47:52Z suehring
44! topography representation via flags
45!
46! 2000 2016-08-20 18:09:15Z knoop
47! Forced header and separation lines into 80 columns
48!
49! 1873 2016-04-18 14:50:06Z maronga
50! Module renamed (removed _mod)
51!
52!
53! 1850 2016-04-08 13:29:27Z maronga
54! Module renamed
55!
56!
57! 1682 2015-10-07 23:56:08Z knoop
58! Code annotations made doxygen readable
59!
60! 1374 2014-04-25 12:55:07Z raasch
61! missing variables added to ONLY list
62!
63! 1353 2014-04-08 15:21:23Z heinze
64! REAL constants provided with KIND-attribute
65!
66! 1320 2014-03-20 08:40:49Z raasch
67! ONLY-attribute added to USE-statements,
68! kind-parameters added to all INTEGER and REAL declaration statements,
69! kinds are defined in new module kinds,
70! revision history before 2012 removed,
71! comment fields (!:) to be used for variable explanations added to
72! all variable declaration statements
73!
74! 1036 2012-10-22 13:43:42Z raasch
75! code put under GPL (PALM 3.9)
76!
77! 1010 2012-09-20 07:59:54Z raasch
78! cpp switch __nopointer added for pointer free version
79!
80! 981 2012-08-09 14:57:44Z maronga
81! Typo removed
82!
83! Revision 1.1  1997/08/29 08:54:33  raasch
84! Initial revision
85!
86!
87! Description:
88! ------------
89!> Advection term for scalar quantities using the Upstream scheme.
90!> NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
91!>       The same problem occurs for all topography boundaries!
92!------------------------------------------------------------------------------!
93 MODULE advec_s_up_mod
94 
95
96    PRIVATE
97    PUBLIC advec_s_up
98
99    INTERFACE advec_s_up
100       MODULE PROCEDURE advec_s_up
101       MODULE PROCEDURE advec_s_up_ij
102    END INTERFACE advec_s_up
103
104 CONTAINS
105
106
107!------------------------------------------------------------------------------!
108! Description:
109! ------------
110!> Call for all grid points
111!------------------------------------------------------------------------------!
112    SUBROUTINE advec_s_up( sk )
113
114       USE arrays_3d,                                                          &
115           ONLY:  ddzu, tend, u, v, w
116
117       USE control_parameters,                                                 &
118           ONLY:  u_gtrans, v_gtrans
119
120       USE grid_variables,                                                     &
121           ONLY:  ddx, ddy
122
123       USE indices,                                                            &
124           ONLY:  nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, nzt
125
126       USE kinds
127
128
129       IMPLICIT NONE
130
131       INTEGER(iwp) ::  i !< grid index along x-direction
132       INTEGER(iwp) ::  j !< grid index along y-direction
133       INTEGER(iwp) ::  k !< grid index along z-direction
134
135       REAL(wp) ::  ukomp !< advection velocity along x-direction
136       REAL(wp) ::  vkomp !< advection velocity along y-direction
137       REAL(wp) ::  wkomp !< advection velocity along z-direction
138
139       REAL(wp), DIMENSION(:,:,:), POINTER ::  sk !< treated scalar
140
141
142       DO  i = nxl, nxr
143          DO  j = nys, nyn
144             DO  k = nzb+1, nzt
145!
146!--             x-direction
147                ukomp = 0.5_wp * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
148                IF ( ukomp > 0.0_wp )  THEN
149                   tend(k,j,i) = tend(k,j,i) - ukomp *                         &
150                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
151                ELSE
152                   tend(k,j,i) = tend(k,j,i) - ukomp *                         &
153                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
154                ENDIF
155!
156!--             y-direction
157                vkomp = 0.5_wp * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
158                IF ( vkomp > 0.0_wp )  THEN
159                   tend(k,j,i) = tend(k,j,i) - vkomp *                         &
160                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
161                ELSE
162                   tend(k,j,i) = tend(k,j,i) - vkomp *                         &
163                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
164                ENDIF
165!
166!--             z-direction
167                wkomp = 0.5_wp * ( w(k,j,i) + w(k-1,j,i) )
168                IF ( wkomp > 0.0_wp )  THEN
169                   tend(k,j,i) = tend(k,j,i) - wkomp *                         &
170                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
171                ELSE
172                   tend(k,j,i) = tend(k,j,i) - wkomp *                         &
173                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
174                ENDIF
175
176             ENDDO
177          ENDDO
178       ENDDO
179
180    END SUBROUTINE advec_s_up
181
182
183!------------------------------------------------------------------------------!
184! Description:
185! ------------
186!> Call for grid point i,j
187!------------------------------------------------------------------------------!
188    SUBROUTINE advec_s_up_ij( i, j, sk )
189
190       USE arrays_3d,                                                          &
191           ONLY:  ddzu, tend, u, v, w
192
193       USE control_parameters,                                                 &
194           ONLY:  u_gtrans, v_gtrans
195
196       USE grid_variables,                                                     &
197           ONLY:  ddx, ddy
198
199       USE indices,                                                            &
200           ONLY:  nxlg, nxrg, nyng, nysg, nzb, nzt
201
202       USE kinds
203
204
205       IMPLICIT NONE
206
207       INTEGER(iwp) ::  i !< grid index along x-direction
208       INTEGER(iwp) ::  j !< grid index along y-direction
209       INTEGER(iwp) ::  k !< grid index along z-direction
210
211       REAL(wp) ::  ukomp !< advection velocity along x-direction
212       REAL(wp) ::  vkomp !< advection velocity along y-direction
213       REAL(wp) ::  wkomp !< advection velocity along z-direction
214       
215       REAL(wp), DIMENSION(:,:,:), POINTER ::  sk !< treated scalar
216
217
218       DO  k = nzb+1, nzt
219!
220!--       x-direction
221          ukomp = 0.5_wp * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
222          IF ( ukomp > 0.0_wp )  THEN
223             tend(k,j,i) = tend(k,j,i) - ukomp *                               &
224                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
225          ELSE
226             tend(k,j,i) = tend(k,j,i) - ukomp *                               &
227                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
228          ENDIF
229!
230!--       y-direction
231          vkomp = 0.5_wp * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
232          IF ( vkomp > 0.0_wp )  THEN
233             tend(k,j,i) = tend(k,j,i) - vkomp *                               &
234                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
235          ELSE
236             tend(k,j,i) = tend(k,j,i) - vkomp *                               &
237                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
238          ENDIF
239!
240!--       z-direction
241          wkomp = 0.5_wp * ( w(k,j,i) + w(k-1,j,i) )
242          IF ( wkomp > 0.0_wp )  THEN
243             tend(k,j,i) = tend(k,j,i) - wkomp *                               &
244                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
245          ELSE
246             tend(k,j,i) = tend(k,j,i) - wkomp *                               &
247                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
248          ENDIF
249
250       ENDDO
251
252    END SUBROUTINE advec_s_up_ij
253
254 END MODULE advec_s_up_mod
Note: See TracBrowser for help on using the repository browser.