source: palm/trunk/SOURCE/advec_s_up.f90 @ 2

 MODULE advec_s_up_mod

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Forner revisions:
! -----------------
! $Log: advec_s_up.f90,v $
! Revision 1.11  2006/02/23 09:43:44  raasch
! nzb_2d replaced by nzb_s_inner
!
! Revision 1.10  2004/01/30 10:10:39  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.9  2003/03/12 16:16:25  raasch
! Full code replaced in the call for all gridpoints instead of calling the
! _ij version (required by NEC, because otherwise no vectorization)
!
! Revision 1.8  2002/06/11 12:23:31  raasch
! Former subroutine changed to a module which allows to be called for all grid
! points of a single vertical column with index i,j or for all grid points by
! using function overloading.
! Array sk now declared as a pointer.
!
! Revision 1.7  2001/03/29 17:30:31  raasch
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.6  2001/01/22 04:43:56  raasch
! Module test_variables removed
!
! Revision 1.5  2000/01/20 09:16:59  letzel
! All comments translated into English
!
! Revision 1.4  1998/07/06 12:03:46  raasch
! + USE test_variables
!
! Revision 1.3  1998/04/21 15:52:14  raasch
! Galilei-Transformation eingebaut
!
! Revision 1.2  1997/09/09 08:27:24  raasch
! Kehrwerte der Gitterweiten implementiert
!
! Revision 1.1  1997/08/29 08:54:33  raasch
! Initial revision
!
!
! Description:
! ------------
! Advection term for scalar quantities using the Upstream scheme.
! NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
!       The same problem occurs for all topography boundaries!
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC advec_s_up

    INTERFACE advec_s_up
       MODULE PROCEDURE advec_s_up
       MODULE PROCEDURE advec_s_up_ij
    END INTERFACE advec_s_up

 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE advec_s_up( sk )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k

       REAL ::  ukomp, vkomp, wkomp
       REAL, DIMENSION(:,:,:), POINTER ::  sk


       DO  i = nxl, nxr
          DO  j = nys, nyn
             DO  k = nzb_s_inner(j,i)+1, nzt
!
!--             x-direction
                ukomp = 0.5 * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
                IF ( ukomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
                ELSE
                   tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
                ENDIF
!
!--             y-direction
                vkomp = 0.5 * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
                IF ( vkomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
                ELSE
                   tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
                ENDIF
!
!--             z-direction
                wkomp = 0.5 * ( w(k,j,i) + w(k-1,j,i) )
                IF ( wkomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
                ELSE
                   tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
                ENDIF

             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE advec_s_up


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE advec_s_up_ij( i, j, sk )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k

       REAL ::  ukomp, vkomp, wkomp
       REAL, DIMENSION(:,:,:), POINTER ::  sk


       DO  k = nzb_s_inner(j,i)+1, nzt
!
!--       x-direction
          ukomp = 0.5 * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
          IF ( ukomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
          ELSE
             tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
          ENDIF
!
!--       y-direction
          vkomp = 0.5 * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
          IF ( vkomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
          ELSE
             tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
          ENDIF
!
!--       z-direction
          wkomp = 0.5 * ( w(k,j,i) + w(k-1,j,i) )
          IF ( wkomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
          ELSE
             tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
          ENDIF

       ENDDO

    END SUBROUTINE advec_s_up_ij

 END MODULE advec_s_up_mod