source: palm/trunk/SOURCE/advec_s_up.f90 @ 1036

Last change on this file since 1036 was 1036, checked in by raasch, 11 years ago

code has been put under the GNU General Public License (v3)

  • Property svn:keywords set to Id
File size: 5.6 KB
Line 
1 MODULE advec_s_up_mod
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: advec_s_up.f90 1036 2012-10-22 13:43:42Z raasch $
27!
28! 1010 2012-09-20 07:59:54Z raasch
29! cpp switch __nopointer added for pointer free version
30!
31! 981 2012-08-09 14:57:44Z maronga
32! Typo removed
33!
34! RCS Log replace by Id keyword, revision history cleaned up
35!
36! Revision 1.11  2006/02/23 09:43:44  raasch
37! nzb_2d replaced by nzb_s_inner
38!
39! Revision 1.1  1997/08/29 08:54:33  raasch
40! Initial revision
41!
42!
43! Description:
44! ------------
45! Advection term for scalar quantities using the Upstream scheme.
46! NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
47!       The same problem occurs for all topography boundaries!
48!------------------------------------------------------------------------------!
49
50    PRIVATE
51    PUBLIC advec_s_up
52
53    INTERFACE advec_s_up
54       MODULE PROCEDURE advec_s_up
55       MODULE PROCEDURE advec_s_up_ij
56    END INTERFACE advec_s_up
57
58 CONTAINS
59
60
61!------------------------------------------------------------------------------!
62! Call for all grid points
63!------------------------------------------------------------------------------!
64    SUBROUTINE advec_s_up( sk )
65
66       USE arrays_3d
67       USE control_parameters
68       USE grid_variables
69       USE indices
70
71       IMPLICIT NONE
72
73       INTEGER ::  i, j, k
74
75       REAL ::  ukomp, vkomp, wkomp
76#if defined( __nopointer )
77       REAL, DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  sk
78#else
79       REAL, DIMENSION(:,:,:), POINTER ::  sk
80#endif
81
82
83       DO  i = nxl, nxr
84          DO  j = nys, nyn
85             DO  k = nzb_s_inner(j,i)+1, nzt
86!
87!--             x-direction
88                ukomp = 0.5 * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
89                IF ( ukomp > 0.0 )  THEN
90                   tend(k,j,i) = tend(k,j,i) - ukomp * &
91                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
92                ELSE
93                   tend(k,j,i) = tend(k,j,i) - ukomp * &
94                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
95                ENDIF
96!
97!--             y-direction
98                vkomp = 0.5 * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
99                IF ( vkomp > 0.0 )  THEN
100                   tend(k,j,i) = tend(k,j,i) - vkomp * &
101                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
102                ELSE
103                   tend(k,j,i) = tend(k,j,i) - vkomp * &
104                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
105                ENDIF
106!
107!--             z-direction
108                wkomp = 0.5 * ( w(k,j,i) + w(k-1,j,i) )
109                IF ( wkomp > 0.0 )  THEN
110                   tend(k,j,i) = tend(k,j,i) - wkomp * &
111                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
112                ELSE
113                   tend(k,j,i) = tend(k,j,i) - wkomp * &
114                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
115                ENDIF
116
117             ENDDO
118          ENDDO
119       ENDDO
120
121    END SUBROUTINE advec_s_up
122
123
124!------------------------------------------------------------------------------!
125! Call for grid point i,j
126!------------------------------------------------------------------------------!
127    SUBROUTINE advec_s_up_ij( i, j, sk )
128
129       USE arrays_3d
130       USE control_parameters
131       USE grid_variables
132       USE indices
133
134       IMPLICIT NONE
135
136       INTEGER ::  i, j, k
137
138       REAL ::  ukomp, vkomp, wkomp
139#if defined( __nopointer )
140       REAL, DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  sk
141#else
142       REAL, DIMENSION(:,:,:), POINTER ::  sk
143#endif
144
145
146       DO  k = nzb_s_inner(j,i)+1, nzt
147!
148!--       x-direction
149          ukomp = 0.5 * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
150          IF ( ukomp > 0.0 )  THEN
151             tend(k,j,i) = tend(k,j,i) - ukomp * &
152                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
153          ELSE
154             tend(k,j,i) = tend(k,j,i) - ukomp * &
155                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
156          ENDIF
157!
158!--       y-direction
159          vkomp = 0.5 * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
160          IF ( vkomp > 0.0 )  THEN
161             tend(k,j,i) = tend(k,j,i) - vkomp * &
162                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
163          ELSE
164             tend(k,j,i) = tend(k,j,i) - vkomp * &
165                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
166          ENDIF
167!
168!--       z-direction
169          wkomp = 0.5 * ( w(k,j,i) + w(k-1,j,i) )
170          IF ( wkomp > 0.0 )  THEN
171             tend(k,j,i) = tend(k,j,i) - wkomp * &
172                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
173          ELSE
174             tend(k,j,i) = tend(k,j,i) - wkomp * &
175                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
176          ENDIF
177
178       ENDDO
179
180    END SUBROUTINE advec_s_up_ij
181
182 END MODULE advec_s_up_mod
Note: See TracBrowser for help on using the repository browser.