source: palm/trunk/SOURCE/advec_s_pw.f90 @ 4598

Last change on this file since 4598 was 4488, checked in by raasch, 4 years ago

files re-formatted to follow the PALM coding standard

  • Property svn:keywords set to Id
File size: 8.5 KB
Line 
1!> @file advec_s_pw.f90
2!--------------------------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms of the GNU General
6! Public License as published by the Free Software Foundation, either version 3 of the License, or
7! (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the
10! implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
11! Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with PALM. If not, see
14! <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2020 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: advec_s_pw.f90 4488 2020-04-03 11:34:29Z suehring $
26! file re-formatted to follow the PALM coding standard
27!
28! 4360 2020-01-07 11:25:50Z suehring
29! Corrected "Former revisions" section
30!
31! 3927 2019-04-23 13:24:29Z raasch
32! pointer attribute removed from scalar 3d-array for performance reasons
33!
34! 3665 2019-01-10 08:28:24Z raasch
35! unused variables removed
36!
37! 3655 2019-01-07 16:51:22Z knoop
38! nopointer option removed
39!
40! Revision 1.1  1997/08/29 08:54:20  raasch
41! Initial revision
42!
43!
44! Description:
45! ------------
46!> Advection term for scalar variables using the Piacsek and Williams scheme (form C3). Contrary to
47!> PW itself, for reasons of accuracy their scheme is slightly modified as follows: the values of
48!> those scalars that are used for the computation of the flux divergence are reduced by the value
49!> of the relevant scalar at the location where the difference is computed (sk(k,j,i)).
50!> NOTE: at the first grid point above the surface computation still takes place!
51!--------------------------------------------------------------------------------------------------!
52 MODULE advec_s_pw_mod
53
54
55    PRIVATE
56    PUBLIC advec_s_pw
57
58    INTERFACE advec_s_pw
59       MODULE PROCEDURE advec_s_pw
60       MODULE PROCEDURE advec_s_pw_ij
61    END INTERFACE
62
63 CONTAINS
64
65
66!--------------------------------------------------------------------------------------------------!
67! Description:
68! ------------
69!> Call for all grid points
70!--------------------------------------------------------------------------------------------------!
71 SUBROUTINE advec_s_pw( sk )
72
73    USE arrays_3d,                                                                                 &
74        ONLY:  dd2zu, tend, u, u_stokes_zu, v, v_stokes_zu, w
75
76    USE control_parameters,                                                                        &
77        ONLY:  u_gtrans, v_gtrans
78
79    USE grid_variables,                                                                            &
80        ONLY:  ddx, ddy
81
82    USE indices,                                                                                   &
83        ONLY:  nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, nzt
84
85    USE kinds
86
87
88    IMPLICIT NONE
89
90    INTEGER(iwp) ::  i !< grid index along x-direction
91    INTEGER(iwp) ::  j !< grid index along y-direction
92    INTEGER(iwp) ::  k !< grid index along z-direction
93
94    REAL(wp)     ::  gu  !< local additional advective velocity
95    REAL(wp)     ::  gv  !< local additional advective velocity
96
97    REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  sk
98
99
100    DO  i = nxl, nxr
101       DO  j = nys, nyn
102          DO  k = nzb+1, nzt
103
104!
105!--          Galilean transformation + Stokes drift velocity (ocean only)
106             gu = u_gtrans - u_stokes_zu(k)
107             gv = v_gtrans - v_stokes_zu(k)
108
109             tend(k,j,i) = tend(k,j,i) +                                                           &
110                                  ( -0.5_wp * ( ( u(k,j,i+1)  - gu        ) *                      &
111                                                ( sk(k,j,i+1) - sk(k,j,i) )                        &
112                                              - ( u(k,j,i)    - gu        ) *                      &
113                                                ( sk(k,j,i-1) - sk(k,j,i) )                        &
114                                              ) * ddx                                              &
115                                    -0.5_wp * ( ( v(k,j+1,i)  - gv        ) *                      &
116                                                ( sk(k,j+1,i) - sk(k,j,i) )                        &
117                                              - ( v(k,j,i)    - gv        ) *                      &
118                                                ( sk(k,j-1,i) - sk(k,j,i) )                        &
119                                              ) * ddy                                              &
120                                    -         (   w(k,j,i)                  *                      &
121                                                ( sk(k+1,j,i) - sk(k,j,i) )                        &
122                                              -   w(k-1,j,i)                *                      &
123                                                ( sk(k-1,j,i) - sk(k,j,i) )                        &
124                                              ) * dd2zu(k)                                         &
125                                   )
126          ENDDO
127       ENDDO
128    ENDDO
129
130 END SUBROUTINE advec_s_pw
131
132
133!--------------------------------------------------------------------------------------------------!
134! Description:
135! ------------
136!> Call for grid point i,j
137!--------------------------------------------------------------------------------------------------!
138 SUBROUTINE advec_s_pw_ij( i, j, sk )
139
140    USE arrays_3d,                                                                                 &
141        ONLY:  dd2zu, tend, u, u_stokes_zu, v, v_stokes_zu, w
142
143    USE control_parameters,                                                                        &
144        ONLY:  u_gtrans, v_gtrans
145
146    USE grid_variables,                                                                            &
147        ONLY:  ddx, ddy
148
149    USE indices,                                                                                   &
150        ONLY:  nxlg, nxrg, nyng, nysg, nzb, nzt
151
152    USE kinds
153
154
155    IMPLICIT NONE
156
157    INTEGER(iwp) ::  i !< grid index along x-direction
158    INTEGER(iwp) ::  j !< grid index along y-direction
159    INTEGER(iwp) ::  k !< grid index along z-direction
160
161    REAL(wp)     ::  gu  !< local additional advective velocity
162    REAL(wp)     ::  gv  !< local additional advective velocity
163
164    REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  sk
165
166
167    DO  k = nzb+1, nzt
168
169!
170!--    Galilean transformation + Stokes drift velocity (ocean only)
171       gu = u_gtrans - u_stokes_zu(k)
172       gv = v_gtrans - v_stokes_zu(k)
173
174       tend(k,j,i) = tend(k,j,i) +                                                                 &
175                                 ( -0.5_wp * ( ( u(k,j,i+1)  - gu        ) *                       &
176                                               ( sk(k,j,i+1) - sk(k,j,i) )                         &
177                                             - ( u(k,j,i)    - gu        ) *                       &
178                                               ( sk(k,j,i-1) - sk(k,j,i) )                         &
179                                             ) * ddx                                               &
180                                   -0.5_wp * ( ( v(k,j+1,i)  - gv        ) *                       &
181                                               ( sk(k,j+1,i) - sk(k,j,i) )                         &
182                                             - ( v(k,j,i)    - gv        ) *                       &
183                                               ( sk(k,j-1,i) - sk(k,j,i) )                         &
184                                             ) * ddy                                               &
185                                   -         (   w(k,j,i)                  *                       &
186                                               ( sk(k+1,j,i) - sk(k,j,i) )                         &
187                                             -   w(k-1,j,i)                *                       &
188                                               ( sk(k-1,j,i) - sk(k,j,i) )                         &
189                                             ) * dd2zu(k)                                          &
190                                 )
191    ENDDO
192
193 END SUBROUTINE advec_s_pw_ij
194
195 END MODULE advec_s_pw_mod
Note: See TracBrowser for help on using the repository browser.