| 1 | !> @file advec_s_pw.f90 |
|---|
| 2 | !------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of the PALM model system. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the |
|---|
| 6 | ! terms of the GNU General Public License as published by the Free Software |
|---|
| 7 | ! Foundation, either version 3 of the License, or (at your option) any later |
|---|
| 8 | ! version. |
|---|
| 9 | ! |
|---|
| 10 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 11 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 12 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 13 | ! |
|---|
| 14 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 15 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 16 | ! |
|---|
| 17 | ! Copyright 1997-2020 Leibniz Universitaet Hannover |
|---|
| 18 | !------------------------------------------------------------------------------! |
|---|
| 19 | ! |
|---|
| 20 | ! Current revisions: |
|---|
| 21 | ! ----------------- |
|---|
| 22 | ! |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: advec_s_pw.f90 4360 2020-01-07 11:25:50Z moh.hefny $ |
|---|
| 27 | ! Corrected "Former revisions" section |
|---|
| 28 | ! |
|---|
| 29 | ! 3927 2019-04-23 13:24:29Z raasch |
|---|
| 30 | ! pointer attribute removed from scalar 3d-array for performance reasons |
|---|
| 31 | ! |
|---|
| 32 | ! 3665 2019-01-10 08:28:24Z raasch |
|---|
| 33 | ! unused variables removed |
|---|
| 34 | ! |
|---|
| 35 | ! 3655 2019-01-07 16:51:22Z knoop |
|---|
| 36 | ! nopointer option removed |
|---|
| 37 | ! |
|---|
| 38 | ! Revision 1.1 1997/08/29 08:54:20 raasch |
|---|
| 39 | ! Initial revision |
|---|
| 40 | ! |
|---|
| 41 | ! |
|---|
| 42 | ! Description: |
|---|
| 43 | ! ------------ |
|---|
| 44 | !> Advection term for scalar variables using the Piacsek and Williams scheme |
|---|
| 45 | !> (form C3). Contrary to PW itself, for reasons of accuracy their scheme is |
|---|
| 46 | !> slightly modified as follows: the values of those scalars that are used for |
|---|
| 47 | !> the computation of the flux divergence are reduced by the value of the |
|---|
| 48 | !> relevant scalar at the location where the difference is computed (sk(k,j,i)). |
|---|
| 49 | !> NOTE: at the first grid point above the surface computation still takes place! |
|---|
| 50 | !------------------------------------------------------------------------------! |
|---|
| 51 | MODULE advec_s_pw_mod |
|---|
| 52 | |
|---|
| 53 | |
|---|
| 54 | PRIVATE |
|---|
| 55 | PUBLIC advec_s_pw |
|---|
| 56 | |
|---|
| 57 | INTERFACE advec_s_pw |
|---|
| 58 | MODULE PROCEDURE advec_s_pw |
|---|
| 59 | MODULE PROCEDURE advec_s_pw_ij |
|---|
| 60 | END INTERFACE |
|---|
| 61 | |
|---|
| 62 | CONTAINS |
|---|
| 63 | |
|---|
| 64 | |
|---|
| 65 | !------------------------------------------------------------------------------! |
|---|
| 66 | ! Description: |
|---|
| 67 | ! ------------ |
|---|
| 68 | !> Call for all grid points |
|---|
| 69 | !------------------------------------------------------------------------------! |
|---|
| 70 | SUBROUTINE advec_s_pw( sk ) |
|---|
| 71 | |
|---|
| 72 | USE arrays_3d, & |
|---|
| 73 | ONLY: dd2zu, tend, u, u_stokes_zu, v, v_stokes_zu, w |
|---|
| 74 | |
|---|
| 75 | USE control_parameters, & |
|---|
| 76 | ONLY: u_gtrans, v_gtrans |
|---|
| 77 | |
|---|
| 78 | USE grid_variables, & |
|---|
| 79 | ONLY: ddx, ddy |
|---|
| 80 | |
|---|
| 81 | USE indices, & |
|---|
| 82 | ONLY: nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, nzt |
|---|
| 83 | |
|---|
| 84 | USE kinds |
|---|
| 85 | |
|---|
| 86 | |
|---|
| 87 | IMPLICIT NONE |
|---|
| 88 | |
|---|
| 89 | INTEGER(iwp) :: i !< grid index along x-direction |
|---|
| 90 | INTEGER(iwp) :: j !< grid index along y-direction |
|---|
| 91 | INTEGER(iwp) :: k !< grid index along z-direction |
|---|
| 92 | |
|---|
| 93 | REAL(wp) :: gu !< local additional advective velocity |
|---|
| 94 | REAL(wp) :: gv !< local additional advective velocity |
|---|
| 95 | |
|---|
| 96 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: sk |
|---|
| 97 | |
|---|
| 98 | |
|---|
| 99 | DO i = nxl, nxr |
|---|
| 100 | DO j = nys, nyn |
|---|
| 101 | DO k = nzb+1, nzt |
|---|
| 102 | |
|---|
| 103 | ! |
|---|
| 104 | !-- Galilean transformation + Stokes drift velocity (ocean only) |
|---|
| 105 | gu = u_gtrans - u_stokes_zu(k) |
|---|
| 106 | gv = v_gtrans - v_stokes_zu(k) |
|---|
| 107 | |
|---|
| 108 | tend(k,j,i) = tend(k,j,i) + & |
|---|
| 109 | ( -0.5_wp * ( ( u(k,j,i+1) - gu ) * & |
|---|
| 110 | ( sk(k,j,i+1) - sk(k,j,i) ) & |
|---|
| 111 | - ( u(k,j,i) - gu ) * & |
|---|
| 112 | ( sk(k,j,i-1) - sk(k,j,i) ) & |
|---|
| 113 | ) * ddx & |
|---|
| 114 | -0.5_wp * ( ( v(k,j+1,i) - gv ) * & |
|---|
| 115 | ( sk(k,j+1,i) - sk(k,j,i) ) & |
|---|
| 116 | - ( v(k,j,i) - gv ) * & |
|---|
| 117 | ( sk(k,j-1,i) - sk(k,j,i) ) & |
|---|
| 118 | ) * ddy & |
|---|
| 119 | - ( w(k,j,i) * & |
|---|
| 120 | ( sk(k+1,j,i) - sk(k,j,i) ) & |
|---|
| 121 | - w(k-1,j,i) * & |
|---|
| 122 | ( sk(k-1,j,i) - sk(k,j,i) ) & |
|---|
| 123 | ) * dd2zu(k) & |
|---|
| 124 | ) |
|---|
| 125 | ENDDO |
|---|
| 126 | ENDDO |
|---|
| 127 | ENDDO |
|---|
| 128 | |
|---|
| 129 | END SUBROUTINE advec_s_pw |
|---|
| 130 | |
|---|
| 131 | |
|---|
| 132 | !------------------------------------------------------------------------------! |
|---|
| 133 | ! Description: |
|---|
| 134 | ! ------------ |
|---|
| 135 | !> Call for grid point i,j |
|---|
| 136 | !------------------------------------------------------------------------------! |
|---|
| 137 | SUBROUTINE advec_s_pw_ij( i, j, sk ) |
|---|
| 138 | |
|---|
| 139 | USE arrays_3d, & |
|---|
| 140 | ONLY: dd2zu, tend, u, u_stokes_zu, v, v_stokes_zu, w |
|---|
| 141 | |
|---|
| 142 | USE control_parameters, & |
|---|
| 143 | ONLY: u_gtrans, v_gtrans |
|---|
| 144 | |
|---|
| 145 | USE grid_variables, & |
|---|
| 146 | ONLY: ddx, ddy |
|---|
| 147 | |
|---|
| 148 | USE indices, & |
|---|
| 149 | ONLY: nxlg, nxrg, nyng, nysg, nzb, nzt |
|---|
| 150 | |
|---|
| 151 | USE kinds |
|---|
| 152 | |
|---|
| 153 | |
|---|
| 154 | IMPLICIT NONE |
|---|
| 155 | |
|---|
| 156 | INTEGER(iwp) :: i !< grid index along x-direction |
|---|
| 157 | INTEGER(iwp) :: j !< grid index along y-direction |
|---|
| 158 | INTEGER(iwp) :: k !< grid index along z-direction |
|---|
| 159 | |
|---|
| 160 | REAL(wp) :: gu !< local additional advective velocity |
|---|
| 161 | REAL(wp) :: gv !< local additional advective velocity |
|---|
| 162 | |
|---|
| 163 | REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: sk |
|---|
| 164 | |
|---|
| 165 | |
|---|
| 166 | DO k = nzb+1, nzt |
|---|
| 167 | |
|---|
| 168 | ! |
|---|
| 169 | !-- Galilean transformation + Stokes drift velocity (ocean only) |
|---|
| 170 | gu = u_gtrans - u_stokes_zu(k) |
|---|
| 171 | gv = v_gtrans - v_stokes_zu(k) |
|---|
| 172 | |
|---|
| 173 | tend(k,j,i) = tend(k,j,i) + & |
|---|
| 174 | ( -0.5_wp * ( ( u(k,j,i+1) - gu ) * & |
|---|
| 175 | ( sk(k,j,i+1) - sk(k,j,i) ) & |
|---|
| 176 | - ( u(k,j,i) - gu ) * & |
|---|
| 177 | ( sk(k,j,i-1) - sk(k,j,i) ) & |
|---|
| 178 | ) * ddx & |
|---|
| 179 | -0.5_wp * ( ( v(k,j+1,i) - gv ) * & |
|---|
| 180 | ( sk(k,j+1,i) - sk(k,j,i) ) & |
|---|
| 181 | - ( v(k,j,i) - gv ) * & |
|---|
| 182 | ( sk(k,j-1,i) - sk(k,j,i) ) & |
|---|
| 183 | ) * ddy & |
|---|
| 184 | - ( w(k,j,i) * & |
|---|
| 185 | ( sk(k+1,j,i) - sk(k,j,i) ) & |
|---|
| 186 | - w(k-1,j,i) * & |
|---|
| 187 | ( sk(k-1,j,i) - sk(k,j,i) ) & |
|---|
| 188 | ) * dd2zu(k) & |
|---|
| 189 | ) |
|---|
| 190 | ENDDO |
|---|
| 191 | |
|---|
| 192 | END SUBROUTINE advec_s_pw_ij |
|---|
| 193 | |
|---|
| 194 | END MODULE advec_s_pw_mod |
|---|
