source: palm/tags/release-6.0/SOURCE/time_integration_spinup.f90 @ 4429

Last change on this file since 4429 was 3467, checked in by suehring, 5 years ago

Branch salsa @3446 re-integrated into trunk

  • Property svn:keywords set to Id
File size: 22.2 KB
Line 
1!> @file time_integration_spinup.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2018 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: time_integration_spinup.f90 3467 2018-10-30 19:05:21Z raasch $
27! call to material_heat_model now with check if spinup runs (rvtils)
28!
29! 3337 2018-10-12 15:17:09Z kanani
30! (from branch resler)
31! Add pt1 initialization
32!
33! 3274 2018-09-24 15:42:55Z knoop
34! Modularization of all bulk cloud physics code components
35!
36! 3241 2018-09-12 15:02:00Z raasch
37! unused variables removed
38!
39! 2983 2018-04-18 10:43:40Z suehring
40! Revise limitation of wall-adjacent velocity.
41!
42! 2934 2018-03-26 19:13:22Z suehring
43! Synchronize parent and child models after spinup.
44!
45! 2881 2018-03-13 16:24:40Z maronga
46! Added flag for switching on/off calculation of soil moisture
47!
48! 2818 2018-02-19 16:42:36Z maronga
49! Velocity components near walls/ground are now set to the profiles stored in
50! u_init and v_init. Activated soil moisture calculation during spinup.
51!
52! 2782 2018-02-02 11:51:10Z maronga
53! Bugfix and re-activation of homogeneous setting of velocity components
54! during spinup
55!
56! 2758 2018-01-17 12:55:21Z suehring
57! Comment out homogeneous setting of wind velocity as this will lead to zero
58! friction velocity and cause problems in MOST relationships.
59!
60! 2728 2018-01-09 07:03:53Z maronga
61! Set velocity componenets to homogeneous values during spinup
62!
63! 2724 2018-01-05 12:12:38Z maronga
64! Use dt_spinup for all active components during spinup
65!
66! 2723 2018-01-05 09:27:03Z maronga
67! Bugfix: array rad_sw_in no longer exists and is thus removed from RUN_CONTROL
68! output.
69! Added output of XY and 3D data during spinup.
70! Bugfix: time step in LSM and USM was set to dt_3d instead of dt_spinup
71!
72! 2718 2018-01-02 08:49:38Z maronga
73! Corrected "Former revisions" section
74!
75! 2696 2017-12-14 17:12:51Z kanani
76! Change in file header (GPL part)
77! Added radiation interactions (moved from USM) (MS)
78!
79! 2544 2017-10-13 18:09:32Z maronga
80! Date and time quantities are now read from date_and_time_mod
81!
82! 2299 2017-06-29 10:14:38Z maronga
83! Call of soil model adjusted to avoid prognostic equation for soil moisture
84! during spinup.
85! Better representation of diurnal cycle of near-surface temperature.
86! Excluded prognostic equation for soil moisture during spinup.
87! Added output of run control data for spinup.
88!
89! 2297 2017-06-28 14:35:57Z scharf
90! bugfixes
91!
92! 2296 2017-06-28 07:53:56Z maronga
93! Initial revision
94!
95!
96! Description:
97! ------------
98!> Integration in time of the non-atmospheric model components such as land
99!> surface model and urban surface model
100!------------------------------------------------------------------------------!
101 SUBROUTINE time_integration_spinup
102 
103    USE arrays_3d,                                                             &
104        ONLY:  pt, pt_p, u, u_init, v, v_init
105
106    USE control_parameters,                                                    &
107        ONLY:  averaging_interval_pr, calc_soil_moisture_during_spinup,        &
108               constant_diffusion, constant_flux_layer, coupling_start_time,   &
109               data_output_during_spinup, dopr_n, do_sum,                      &
110               dt_averaging_input_pr, dt_dopr, dt_dots, dt_do2d_xy, dt_do3d,   &
111               dt_spinup, dt_3d, humidity, intermediate_timestep_count,        &
112               intermediate_timestep_count_max, land_surface,                  &
113               simulated_time, simulated_time_chr, skip_time_dopr,             &
114               skip_time_do2d_xy, skip_time_do3d, spinup_pt_amplitude,         &
115               spinup_pt_mean, spinup_time, timestep_count, time_dopr,         &
116               time_dopr_av, time_dots, time_do2d_xy, time_do3d,               &
117               time_run_control, time_since_reference_point, urban_surface
118
119    USE cpulog,                                                                &
120        ONLY:  cpu_log, log_point, log_point_s
121
122    USE date_and_time_mod,                                                     &
123        ONLY: day_of_year_init, time_utc_init
124
125    USE indices,                                                               &
126        ONLY:  nbgp, nzb, nzt, nysg, nyng, nxlg, nxrg
127
128
129    USE land_surface_model_mod,                                                &
130        ONLY:  lsm_energy_balance, lsm_soil_model, lsm_swap_timelevel
131
132    USE pegrid
133
134    USE pmc_interface,                                                         &
135        ONLY:  nested_run
136
137    USE kinds
138
139    USE radiation_model_mod,                                                   &
140        ONLY:  force_radiation_call, radiation, radiation_control,             &
141               radiation_interaction, radiation_interactions, time_radiation
142
143    USE statistics,                                                            &
144        ONLY:  flow_statistics_called
145
146    USE surface_layer_fluxes_mod,                                              &
147        ONLY:  surface_layer_fluxes
148
149    USE surface_mod,                                                           &
150        ONLY :  surf_lsm_h, surf_lsm_v, surf_usm_h,    &
151                surf_usm_v
152
153    USE urban_surface_mod,                                                     &
154        ONLY:  usm_material_heat_model, usm_material_model,                    &
155               usm_surface_energy_balance, usm_swap_timelevel,                 &
156               usm_green_heat_model, usm_temperature_near_surface
157
158
159
160
161    IMPLICIT NONE
162
163    CHARACTER (LEN=9) ::  time_to_string          !<
164 
165    INTEGER(iwp) ::  i !< running index
166    INTEGER(iwp) ::  j !< running index
167    INTEGER(iwp) ::  k !< running index
168    INTEGER(iwp) ::  l !< running index
169    INTEGER(iwp) ::  m !< running index
170
171    INTEGER(iwp) :: current_timestep_number_spinup = 0  !< number if timestep during spinup
172 
173    LOGICAL :: run_control_header_spinup = .FALSE.  !< flag parameter for steering whether the header information must be output
174
175    REAL(wp) ::  pt_spinup   !< temporary storage of temperature
176    REAL(wp) ::  dt_save     !< temporary storage for time step
177                 
178    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  pt_save  !< temporary storage of temperature
179    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  u_save   !< temporary storage of u wind component
180    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  v_save   !< temporary storage of v wind component
181
182
183!
184!-- Save 3D arrays because they are to be changed for spinup purpose
185    ALLOCATE( pt_save(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
186    ALLOCATE( u_save(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
187    ALLOCATE( v_save(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
188
189    CALL exchange_horiz( pt, nbgp )   
190    CALL exchange_horiz( u,  nbgp ) 
191    CALL exchange_horiz( v,  nbgp ) 
192 
193    pt_save = pt
194    u_save  = u
195    v_save  = v
196
197!
198!-- Set the same wall-adjacent velocity to all grid points. The sign of the
199!-- original velocity field must be preserved because the surface schemes crash
200!-- otherwise. The precise reason is still unknown. A minimum velocity of 0.1
201!-- m/s is used to maintain turbulent transfer at the surface.
202    IF ( land_surface )  THEN
203       DO  m = 1, surf_lsm_h%ns
204          i   = surf_lsm_h%i(m)           
205          j   = surf_lsm_h%j(m)
206          k   = surf_lsm_h%k(m)
207          u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
208          v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
209       ENDDO
210
211       DO  l = 0, 3
212          DO  m = 1, surf_lsm_v(l)%ns
213             i   = surf_lsm_v(l)%i(m)           
214             j   = surf_lsm_v(l)%j(m)
215             k   = surf_lsm_v(l)%k(m)
216             u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
217             v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
218          ENDDO
219       ENDDO
220    ENDIF
221
222    IF ( urban_surface )  THEN
223       DO  m = 1, surf_usm_h%ns
224          i   = surf_usm_h%i(m)           
225          j   = surf_usm_h%j(m)
226          k   = surf_usm_h%k(m)
227          u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
228          v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
229       ENDDO
230
231       DO  l = 0, 3
232          DO  m = 1, surf_usm_v(l)%ns
233             i   = surf_usm_v(l)%i(m)           
234             j   = surf_usm_v(l)%j(m)
235             k   = surf_usm_v(l)%k(m)
236             u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
237             v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
238          ENDDO
239       ENDDO
240    ENDIF
241
242    CALL exchange_horiz( u,  nbgp )
243    CALL exchange_horiz( v,  nbgp )
244
245    dt_save = dt_3d
246    dt_3d   = dt_spinup
247
248    CALL location_message( 'starting spinup-sequence', .TRUE. )
249!
250!-- Start of the time loop
251    DO  WHILE ( simulated_time < spinup_time )
252
253       CALL cpu_log( log_point_s(15), 'timesteps spinup', 'start' )
254   
255!
256!--    Start of intermediate step loop
257       intermediate_timestep_count = 0
258       DO  WHILE ( intermediate_timestep_count < &
259                   intermediate_timestep_count_max )
260
261          intermediate_timestep_count = intermediate_timestep_count + 1
262
263!
264!--       Set the steering factors for the prognostic equations which depend
265!--       on the timestep scheme
266          CALL timestep_scheme_steering
267
268
269!
270!--       Estimate a near-surface air temperature based on the position of the
271!--       sun and user input about mean temperature and amplitude. The time is
272!--       shifted by one hour to simulate a lag between air temperature and
273!--       incoming radiation
274          pt_spinup = spinup_pt_mean + spinup_pt_amplitude                     &
275             * solar_angle (time_utc_init + time_since_reference_point - 3600.0)
276
277!
278!--       Map air temperature to all grid points in the vicinity of a surface
279!--       element
280          IF ( land_surface )  THEN
281             DO  m = 1, surf_lsm_h%ns
282                i   = surf_lsm_h%i(m)           
283                j   = surf_lsm_h%j(m)
284                k   = surf_lsm_h%k(m)
285                pt(k,j,i) = pt_spinup
286             ENDDO
287
288             DO  l = 0, 3
289                DO  m = 1, surf_lsm_v(l)%ns
290                   i   = surf_lsm_v(l)%i(m)           
291                   j   = surf_lsm_v(l)%j(m)
292                   k   = surf_lsm_v(l)%k(m)
293                   pt(k,j,i) = pt_spinup
294                ENDDO
295             ENDDO
296          ENDIF
297
298          IF ( urban_surface )  THEN
299             DO  m = 1, surf_usm_h%ns
300                i   = surf_usm_h%i(m)           
301                j   = surf_usm_h%j(m)
302                k   = surf_usm_h%k(m)
303                pt(k,j,i) = pt_spinup
304                !!!!!!!!!!!!!!!!HACK!!!!!!!!!!!!!
305                surf_usm_h%pt1 = pt_spinup
306                !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
307             ENDDO
308
309             DO  l = 0, 3
310                DO  m = 1, surf_usm_v(l)%ns
311                   i   = surf_usm_v(l)%i(m)           
312                   j   = surf_usm_v(l)%j(m)
313                   k   = surf_usm_v(l)%k(m)
314                   pt(k,j,i) = pt_spinup
315                   !!!!!!!!!!!!!!!!HACK!!!!!!!!!!!!!
316                   surf_usm_v(l)%pt1 = pt_spinup
317                   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
318                ENDDO
319             ENDDO
320          ENDIF
321
322          CALL exchange_horiz( pt,  nbgp )   
323
324
325!
326!--       Swap the time levels in preparation for the next time step.
327          timestep_count = timestep_count + 1
328     
329          IF ( land_surface )  THEN
330              CALL lsm_swap_timelevel ( 0 )
331          ENDIF
332
333          IF ( urban_surface )  THEN
334             CALL usm_swap_timelevel ( 0 )
335          ENDIF
336
337          IF ( land_surface )  THEN
338             CALL lsm_swap_timelevel ( MOD( timestep_count, 2) )
339          ENDIF
340
341          IF ( urban_surface )  THEN
342             CALL usm_swap_timelevel ( MOD( timestep_count, 2) )
343          ENDIF
344         
345!
346!--       If required, compute virtual potential temperature
347          IF ( humidity )  THEN
348             CALL compute_vpt 
349          ENDIF 
350
351!
352!--       Compute the diffusion quantities
353          IF ( .NOT. constant_diffusion )  THEN
354
355!
356!--          First the vertical (and horizontal) fluxes in the surface
357!--          (constant flux) layer are computed
358             IF ( constant_flux_layer )  THEN
359                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'start' )
360                CALL surface_layer_fluxes
361                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'stop' )
362             ENDIF
363
364!
365!--          If required, solve the energy balance for the surface and run soil
366!--          model. Call for horizontal as well as vertical surfaces.
367!--          The prognostic equation for soil moisure is switched off
368             IF ( land_surface )  THEN
369
370                CALL cpu_log( log_point(54), 'land_surface', 'start' )
371!
372!--             Call for horizontal upward-facing surfaces
373                CALL lsm_energy_balance( .TRUE., -1 )
374                CALL lsm_soil_model( .TRUE., -1, calc_soil_moisture_during_spinup )
375!
376!--             Call for northward-facing surfaces
377                CALL lsm_energy_balance( .FALSE., 0 )
378                CALL lsm_soil_model( .FALSE., 0, calc_soil_moisture_during_spinup )
379!
380!--             Call for southward-facing surfaces
381                CALL lsm_energy_balance( .FALSE., 1 )
382                CALL lsm_soil_model( .FALSE., 1, calc_soil_moisture_during_spinup )
383!
384!--             Call for eastward-facing surfaces
385                CALL lsm_energy_balance( .FALSE., 2 )
386                CALL lsm_soil_model( .FALSE., 2, calc_soil_moisture_during_spinup )
387!
388!--             Call for westward-facing surfaces
389                CALL lsm_energy_balance( .FALSE., 3 )
390                CALL lsm_soil_model( .FALSE., 3, calc_soil_moisture_during_spinup )
391
392                CALL cpu_log( log_point(54), 'land_surface', 'stop' )
393             ENDIF
394
395!
396!--          If required, solve the energy balance for urban surfaces and run
397!--          the material heat model
398             IF (urban_surface) THEN
399                CALL cpu_log( log_point(74), 'urban_surface', 'start' )
400                CALL usm_surface_energy_balance( .TRUE. )
401                IF ( usm_material_model )  THEN
402                   CALL usm_green_heat_model
403                   CALL usm_material_heat_model( .TRUE. )
404                ENDIF
405                IF ( urban_surface ) THEN
406                   CALL usm_temperature_near_surface
407                ENDIF
408                CALL cpu_log( log_point(74), 'urban_surface', 'stop' )
409             ENDIF
410
411          ENDIF
412
413!
414!--       If required, calculate radiative fluxes and heating rates
415          IF ( radiation .AND. intermediate_timestep_count                     &
416               == intermediate_timestep_count_max )  THEN
417
418               time_radiation = time_radiation + dt_3d
419
420             IF ( time_radiation >= dt_3d .OR. force_radiation_call )          &
421             THEN
422
423                CALL cpu_log( log_point(50), 'radiation', 'start' )
424
425                IF ( .NOT. force_radiation_call )  THEN
426                   time_radiation = time_radiation - dt_3d
427                ENDIF
428
429                CALL radiation_control
430
431                CALL cpu_log( log_point(50), 'radiation', 'stop' )
432
433                IF ( radiation_interactions )  THEN
434                   CALL cpu_log( log_point(75), 'radiation_interaction', 'start' )
435                   CALL radiation_interaction
436                   CALL cpu_log( log_point(75), 'radiation_interaction', 'stop' )
437                ENDIF
438             ENDIF
439          ENDIF
440
441       ENDDO   ! Intermediate step loop
442
443!
444!--    Increase simulation time and output times
445       current_timestep_number_spinup = current_timestep_number_spinup + 1
446       simulated_time             = simulated_time   + dt_3d
447       simulated_time_chr         = time_to_string( simulated_time )
448       time_since_reference_point = simulated_time - coupling_start_time
449
450       IF ( data_output_during_spinup )  THEN
451          IF ( simulated_time >= skip_time_do2d_xy )  THEN
452             time_do2d_xy       = time_do2d_xy     + dt_3d
453          ENDIF
454          IF ( simulated_time >= skip_time_do3d    )  THEN
455             time_do3d          = time_do3d        + dt_3d
456          ENDIF
457          time_dots          = time_dots        + dt_3d
458          IF ( simulated_time >= skip_time_dopr )  THEN
459             time_dopr       = time_dopr        + dt_3d
460          ENDIF
461          time_run_control   = time_run_control + dt_3d
462
463!
464!--       Carry out statistical analysis and output at the requested output times.
465!--       The MOD function is used for calculating the output time counters (like
466!--       time_dopr) in order to regard a possible decrease of the output time
467!--       interval in case of restart runs
468
469!
470!--       Set a flag indicating that so far no statistics have been created
471!--       for this time step
472          flow_statistics_called = .FALSE.
473
474!
475!--       If required, call flow_statistics for averaging in time
476          IF ( averaging_interval_pr /= 0.0_wp  .AND.                          &
477             ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.           &
478             simulated_time >= skip_time_dopr )  THEN
479             time_dopr_av = time_dopr_av + dt_3d
480             IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
481                do_sum = .TRUE.
482                time_dopr_av = MOD( time_dopr_av,                              &
483                               MAX( dt_averaging_input_pr, dt_3d ) )
484             ENDIF
485          ENDIF
486          IF ( do_sum )  CALL flow_statistics
487
488!
489!--       Output of profiles
490          IF ( time_dopr >= dt_dopr )  THEN
491             IF ( dopr_n /= 0 )  CALL data_output_profiles
492             time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
493             time_dopr_av = 0.0_wp    ! due to averaging (see above)
494          ENDIF
495
496!
497!--       Output of time series
498          IF ( time_dots >= dt_dots )  THEN
499             CALL data_output_tseries
500             time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
501          ENDIF
502
503!
504!--       2d-data output (cross-sections)
505          IF ( time_do2d_xy >= dt_do2d_xy )  THEN
506             CALL data_output_2d( 'xy', 0 )
507             time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
508          ENDIF
509
510!
511!--       3d-data output (volume data)
512          IF ( time_do3d >= dt_do3d )  THEN
513             CALL data_output_3d( 0 )
514             time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
515          ENDIF
516
517
518       ENDIF
519
520!
521!--    Computation and output of run control parameters.
522!--    This is also done whenever perturbations have been imposed
523!        IF ( time_run_control >= dt_run_control  .OR.                           &
524!             timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created )       &
525!        THEN
526!           CALL run_control
527!           IF ( time_run_control >= dt_run_control )  THEN
528!              time_run_control = MOD( time_run_control,                         &
529!                                      MAX( dt_run_control, dt_3d ) )
530!           ENDIF
531!        ENDIF
532
533       CALL cpu_log( log_point_s(15), 'timesteps spinup', 'stop' )
534
535
536!
537!--    Run control output
538       IF ( myid == 0 )  THEN
539!
540!--       If necessary, write header
541          IF ( .NOT. run_control_header_spinup )  THEN
542             CALL check_open( 15 )
543             WRITE ( 15, 100 )
544             run_control_header_spinup = .TRUE.
545          ENDIF
546!
547!--       Write some general information about the spinup in run control file
548          WRITE ( 15, 101 )  current_timestep_number_spinup, simulated_time_chr, dt_3d, pt_spinup
549!
550!--       Write buffer contents to disc immediately
551          FLUSH( 15 )
552       ENDIF
553
554
555
556    ENDDO   ! time loop
557
558!
559!-- Write back saved arrays to the 3D arrays
560    pt   = pt_save
561    pt_p = pt_save
562    u    = u_save
563    v    = v_save
564
565!
566!-- Reset time step
567    dt_3d = dt_save
568
569    DEALLOCATE(pt_save)
570    DEALLOCATE(u_save)
571    DEALLOCATE(v_save)
572
573#if defined( __parallel )
574    IF ( nested_run )  CALL MPI_BARRIER( MPI_COMM_WORLD, ierr )
575#endif
576
577    CALL location_message( 'finished spinup-sequence', .TRUE. )
578
579
580!
581!-- Formats
582100 FORMAT (///'Spinup control output:'/  &
583            '--------------------------------'// &
584            'ITER.  HH:MM:SS    DT   PT(z_MO)'/   &
585            '--------------------------------')
586101 FORMAT (I5,2X,A9,1X,F6.2,3X,F6.2,2X,F6.2)
587
588 CONTAINS
589
590!
591!-- Returns the cosine of the solar zenith angle at a given time. This routine
592!-- is similar to that for calculation zenith (see radiation_model_mod.f90)
593    FUNCTION solar_angle( local_time ) 
594
595       USE basic_constants_and_equations_mod,                                  &
596       ONLY:  pi
597     
598       USE kinds
599
600       USE radiation_model_mod,                                                &
601           ONLY:  decl_1, decl_2, decl_3, lat, lon
602
603       IMPLICIT NONE
604
605
606       REAL(wp) ::  solar_angle     !< cosine of the solar zenith angle
607
608       REAL(wp) ::  day             !< day of the year
609       REAL(wp) ::  declination     !< solar declination angle
610       REAL(wp) ::  hour_angle      !< solar hour angle
611       REAL(wp) ::  time_utc        !< current time in UTC
612       REAL(wp), INTENT(IN) :: local_time
613!
614!--    Calculate current day and time based on the initial values and simulation
615!--    time
616
617       day = day_of_year_init + INT(FLOOR( local_time / 86400.0_wp ), KIND=iwp)
618       time_utc = MOD(local_time, 86400.0_wp)
619
620
621!
622!--    Calculate solar declination and hour angle   
623       declination = ASIN( decl_1 * SIN(decl_2 * REAL(day, KIND=wp) - decl_3) )
624       hour_angle  = 2.0_wp * pi * (time_utc / 86400.0_wp) + lon - pi
625
626!
627!--    Calculate cosine of solar zenith angle
628       solar_angle = SIN(lat) * SIN(declination) + COS(lat) * COS(declination) &
629                     * COS(hour_angle)
630
631
632    END FUNCTION solar_angle
633
634
635 END SUBROUTINE time_integration_spinup
Note: See TracBrowser for help on using the repository browser.